libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # Find the rest of the source tree framework.
  15 AM_ENABLE_MULTILIB(, ..)
  16
  17 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  18 #
  19 # You will slowly go insane if you do not grok the following fact:  when
  20 # building v3 as part of the compiler, the top-level /target/ becomes the
  21 # library's /host/.  configure then causes --target to default to --host,
  22 # exactly like any other package using autoconf.  Therefore, 'target' and
  23 # 'host' will always be the same.  This makes sense both for native and
  24 # cross compilers, just think about it for a little while.  :-)
  25 #
  26 # Also, if v3 is being configured as part of a cross compiler, the top-level
  27 # configure script will pass the "real" host as $with_cross_host.
  28 #
  29 # Do not delete or change the following two lines.  For why, see
  30 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  31 AC_CANONICAL_SYSTEM
  32 target_alias=${target_alias-$host_alias}
  33
  34 # Handy for debugging:
  35 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  36
  37 if test "$build" != "$host"; then
  38   # We are being configured with some form of cross compiler.
  39   GLIBCXX_IS_NATIVE=false
  40   case "$host","$target" in
  41     # Darwin crosses can use the host system's libraries and headers,
  42     # because of the fat library support.  Of course, it must be the
  43     # same version of Darwin on both sides.  Allow the user to
  44     # just say --target=foo-darwin without a version number to mean
  45     # "the version on this system".
  46       *-*-darwin*,*-*-darwin*)
  47         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  48         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  49         if test $hostos = $targetos -o $targetos = darwin ; then
  50           GLIBCXX_IS_NATIVE=true
  51         fi
  52         ;;
  53
  54       *)
  55         GCC_NO_EXECUTABLES
  56         ;;
  57   esac
  58 else
  59   GLIBCXX_IS_NATIVE=true
  60 fi
  61
  62 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  63 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  64 #  1.x:  minimum required version
  65 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  66 #              of other PACKAGE_* variables will, however, and there's nothing
  67 #              we can do about that; they come from AC_INIT).
  68 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  69 #            file in the top srcdir, etc, etc), so stop complaining.
  70 #  no-dependencies:  turns off auto dependency generation (just for now)
  71 #  no-dist:  we don't want 'dist' and related rules.
  72 #  -Wall:  turns on all automake warnings...
  73 #  -Wno-portability:  ...except this one, since GNU make is now required.
  74 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  75 AH_TEMPLATE(PACKAGE, [Name of package])
  76 AH_TEMPLATE(VERSION, [Version number of package])
  77
  78 # -fno-builtin must be present here so that a non-conflicting form of
  79 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  80
  81 save_CXXFLAGS="$CXXFLAGS"
  82 CXXFLAGS="$CXXFLAGS -fno-builtin"
  83 AC_PROG_CC
  84 AC_PROG_CXX
  85 CXXFLAGS="$save_CXXFLAGS"
  86
  87 # Runs configure.host, and assorted other critical bits.  Sets
  88 # up critical shell variables.
  89 GLIBCXX_CONFIGURE
  90
  91 # Libtool setup.
  92 if test "x${with_newlib}" != "xyes"; then
  93   AC_LIBTOOL_DLOPEN
  94 fi
  95 AM_PROG_LIBTOOL
  96 ACX_LT_HOST_FLAGS
  97 AC_SUBST(enable_shared)
  98 AC_SUBST(enable_static)
  99
 100 if test "$enable_vtable_verify" = yes; then
 101   predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
 102   postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
 103 fi
 104
 105
 106 # libtool variables for C++ shared and position-independent compiles.
 107 #
 108 # Use glibcxx_lt_pic_flag to designate the automake variable
 109 # used to encapsulate the default libtool approach to creating objects
 110 # with position-independent code. Default: -prefer-pic.
 111 #
 112 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 113 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 114 #
 115 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 116 # creating position-independent objects. This varies with the target
 117 # hardware and operating system, but is often: -DPIC -fPIC.
 118 if test "$enable_shared" = yes; then
 119   glibcxx_lt_pic_flag="-prefer-pic"
 120   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 121   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 122
 123 else
 124   glibcxx_lt_pic_flag=
 125   glibcxx_compiler_pic_flag=
 126   glibcxx_compiler_shared_flag=
 127 fi
 128 AC_SUBST(glibcxx_lt_pic_flag)
 129 AC_SUBST(glibcxx_compiler_pic_flag)
 130 AC_SUBST(glibcxx_compiler_shared_flag)
 131
 132 # Override the libtool's pic_flag and pic_mode.
 133 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 134 # NB: this impacts --with-pic and --without-pic.
 135 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 136 pic_mode='default'
 137
 138 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 139 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 140
 141 # Possibly disable most of the library.
 142 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 143 ## than just ignoring the results.  Faster /and/ more correct, win win.
 144 GLIBCXX_ENABLE_HOSTED
 145
 146 # Enable descriptive messages to standard output on termination.
 147 GLIBCXX_ENABLE_VERBOSE
 148
 149 # Enable compiler support that doesn't require linking.
 150 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
 151 GLIBCXX_ENABLE_PCH($is_hosted)
 152 GLIBCXX_ENABLE_THREADS
 153 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 154 GLIBCXX_ENABLE_DECIMAL_FLOAT
 155 GLIBCXX_ENABLE_INT128_FLOAT128
 156 if test "$enable_float128" = yes; then
 157   port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/abi/pre/float128.ver"
 158 fi
 159
 160 # Checks for compiler support that doesn't require linking.
 161 GLIBCXX_CHECK_COMPILER_FEATURES
 162
 163 # Enable all the variable C++ runtime options that don't require linking.
 164 GLIBCXX_ENABLE_CSTDIO
 165 GLIBCXX_ENABLE_CLOCALE
 166 GLIBCXX_ENABLE_ALLOCATOR
 167 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 168 GLIBCXX_ENABLE_LONG_LONG([yes])
 169 GLIBCXX_ENABLE_WCHAR_T([yes])
 170 GLIBCXX_ENABLE_C99([yes])
 171 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 172 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0"])
 173 GLIBCXX_ENABLE_DEBUG([no])
 174 GLIBCXX_ENABLE_PARALLEL([yes])
 175 GLIBCXX_ENABLE_CXX_FLAGS
 176 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 177 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 178 GLIBCXX_ENABLE_PYTHON
 179 GLIBCXX_ENABLE_WERROR([yes])
 180 GLIBCXX_ENABLE_VTABLE_VERIFY([no])
 181
 182 # Checks for operating systems support that doesn't require linking.
 183 GLIBCXX_CHECK_STDIO_PROTO
 184 GLIBCXX_CHECK_SYSTEM_ERROR
 185
 186 # For the streamoff typedef.
 187 GLIBCXX_CHECK_INT64_T
 188
 189 # For LFS support.
 190 GLIBCXX_CHECK_LFS
 191
 192 # For showmanyc_helper().
 193 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 194 GLIBCXX_CHECK_POLL
 195 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 196
 197 # For xsputn_2().
 198 AC_CHECK_HEADERS(sys/uio.h)
 199 GLIBCXX_CHECK_WRITEV
 200
 201 # Check for fenv.h and complex.h before GLIBCXX_CHECK_C99_TR1
 202 # so that the check is done with the C compiler (not C++).
 203 # Checking with C++ can break a canadian cross build if either
 204 # file does not exist in C but does in C++.
 205 AC_CHECK_HEADERS(fenv.h complex.h)
 206
 207 # For C99 support to TR1.
 208 GLIBCXX_CHECK_C99_TR1
 209
 210 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 211 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 212
 213 # For gettimeofday support.
 214 GLIBCXX_CHECK_GETTIMEOFDAY
 215
 216 # For clock_gettime, nanosleep and sched_yield support.
 217 GLIBCXX_ENABLE_LIBSTDCXX_TIME
 218
 219 # Check for tmpnam which is obsolescent in POSIX.1-2008
 220 GLIBCXX_CHECK_TMPNAM
 221
 222 AC_LC_MESSAGES
 223
 224 # For hardware_concurrency
 225 AC_CHECK_HEADERS(sys/sysinfo.h)
 226 GLIBCXX_CHECK_GET_NPROCS
 227 AC_CHECK_HEADERS(unistd.h)
 228 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 229 GLIBCXX_CHECK_SC_NPROC_ONLN
 230 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 231 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 232 GLIBCXX_CHECK_SDT_H
 233
 234 # Check for available headers.
 235 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 236 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 237 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 238 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 239 wchar.h wctype.h])
 240
 241 # Only do link tests if native. Else, hardcode.
 242 if $GLIBCXX_IS_NATIVE; then
 243
 244   # We can do more elaborate tests that assume a working linker.
 245   CANADIAN=no
 246
 247   GLIBCXX_CHECK_LINKER_FEATURES
 248   GLIBCXX_CHECK_MATH_SUPPORT
 249   GLIBCXX_CHECK_STDLIB_SUPPORT
 250
 251   # For /dev/random and /dev/urandom for TR1.
 252   GLIBCXX_CHECK_RANDOM_TR1
 253
 254   # For TLS support.
 255   GCC_CHECK_TLS
 256
 257   AC_CHECK_FUNCS(__cxa_thread_atexit_impl)
 258
 259   # For iconv support.
 260   AM_ICONV
 261
 262 else
 263
 264   # This lets us hard-code the functionality we know we'll have in the cross
 265   # target environment.  "Let" is a sugar-coated word placed on an especially
 266   # dull and tedious hack, actually.
 267   #
 268   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 269   # that involve linking, can't be used:
 270   #    "cannot open sim-crt0.o"
 271   #    "cannot open crt0.o"
 272   # etc.  All this is because there currently exists no unified, consistent
 273   # way for top level CC information to be passed down to target directories:
 274   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 275   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 276   # crosses can be removed.
 277
 278   # If Canadian cross, then don't pick up tools from the build directory.
 279   # Used only in GLIBCXX_EXPORT_INCLUDES.
 280   if test -n "$with_cross_host" &&
 281      test x"$build_alias" != x"$with_cross_host" &&
 282      test x"$build" != x"$target";
 283   then
 284     CANADIAN=yes
 285   else
 286     CANADIAN=no
 287   fi
 288
 289   # Construct crosses by hand, eliminating bits that need ld...
 290   # GLIBCXX_CHECK_MATH_SUPPORT
 291
 292   # First, test for "known" system libraries.  We may be using newlib even
 293   # on a hosted environment.
 294   if test "x${with_newlib}" = "xyes"; then
 295     os_include_dir="os/newlib"
 296     AC_DEFINE(HAVE_HYPOT)
 297
 298     # GLIBCXX_CHECK_STDLIB_SUPPORT
 299     AC_DEFINE(HAVE_STRTOF)
 300
 301     AC_DEFINE(HAVE_ACOSF)
 302     AC_DEFINE(HAVE_ASINF)
 303     AC_DEFINE(HAVE_ATAN2F)
 304     AC_DEFINE(HAVE_ATANF)
 305     AC_DEFINE(HAVE_CEILF)
 306     AC_DEFINE(HAVE_COSF)
 307     AC_DEFINE(HAVE_COSHF)
 308     AC_DEFINE(HAVE_EXPF)
 309     AC_DEFINE(HAVE_FABSF)
 310     AC_DEFINE(HAVE_FLOORF)
 311     AC_DEFINE(HAVE_FMODF)
 312     AC_DEFINE(HAVE_FREXPF)
 313     AC_DEFINE(HAVE_LDEXPF)
 314     AC_DEFINE(HAVE_LOG10F)
 315     AC_DEFINE(HAVE_LOGF)
 316     AC_DEFINE(HAVE_MODFF)
 317     AC_DEFINE(HAVE_POWF)
 318     AC_DEFINE(HAVE_SINF)
 319     AC_DEFINE(HAVE_SINHF)
 320     AC_DEFINE(HAVE_SQRTF)
 321     AC_DEFINE(HAVE_TANF)
 322     AC_DEFINE(HAVE_TANHF)
 323
 324     AC_DEFINE(HAVE_ICONV)
 325   else
 326     GLIBCXX_CROSSCONFIG
 327   fi
 328
 329   # At some point, we should differentiate between architectures
 330   # like x86, which have long double versions, and alpha/powerpc/etc.,
 331   # which don't. For the time being, punt.
 332   if test x"long_double_math_on_this_cpu" = x"yes"; then
 333     AC_DEFINE(HAVE_ACOSL)
 334     AC_DEFINE(HAVE_ASINL)
 335     AC_DEFINE(HAVE_ATAN2L)
 336     AC_DEFINE(HAVE_ATANL)
 337     AC_DEFINE(HAVE_CEILL)
 338     AC_DEFINE(HAVE_COSL)
 339     AC_DEFINE(HAVE_COSHL)
 340     AC_DEFINE(HAVE_EXPL)
 341     AC_DEFINE(HAVE_FABSL)
 342     AC_DEFINE(HAVE_FLOORL)
 343     AC_DEFINE(HAVE_FMODL)
 344     AC_DEFINE(HAVE_FREXPL)
 345     AC_DEFINE(HAVE_LDEXPL)
 346     AC_DEFINE(HAVE_LOG10L)
 347     AC_DEFINE(HAVE_LOGL)
 348     AC_DEFINE(HAVE_MODFL)
 349     AC_DEFINE(HAVE_POWL)
 350     AC_DEFINE(HAVE_SINCOSL)
 351     AC_DEFINE(HAVE_SINL)
 352     AC_DEFINE(HAVE_SINHL)
 353     AC_DEFINE(HAVE_SQRTL)
 354     AC_DEFINE(HAVE_TANL)
 355     AC_DEFINE(HAVE_TANHL)
 356   fi
 357 fi
 358
 359 # Check for _Unwind_GetIPInfo.
 360 GCC_CHECK_UNWIND_GETIPINFO
 361
 362 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 363
 364 GCC_HEADER_STDINT(include/gstdint.h)
 365
 366 GLIBCXX_ENABLE_SYMVERS([yes])
 367 AC_SUBST(libtool_VERSION)
 368
 369 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 370
 371 GLIBCXX_ENABLE_LIBSTDCXX_CXX11_ABI([yes])
 372
 373 ac_ldbl_compat=no
 374 case "$target" in
 375   powerpc*-*-linux* | \
 376   sparc*-*-linux* | \
 377   s390*-*-linux* | \
 378   alpha*-*-linux*)
 379   AC_TRY_COMPILE(, [
 380 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 381 #error no need for long double compatibility
 382 #endif
 383   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 384   if test "$ac_ldbl_compat" = yes; then
 385     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 386               [Define if compatibility should be provided for -mlong-double-64.])
 387     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 388   fi
 389 esac
 390 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 391
 392 # Check if assembler supports disabling hardware capability support.
 393 GLIBCXX_CHECK_ASSEMBLER_HWCAP
 394
 395 # Check if assembler supports rdrand opcode.
 396 GLIBCXX_CHECK_X86_RDRAND
 397
 398 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 399 GLIBCXX_CONFIGURE_TESTSUITE
 400
 401 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 402 GLIBCXX_CHECK_GTHREADS
 403
 404 # Define documentation rules conditionally.
 405
 406 # See if makeinfo has been installed and is modern enough
 407 # that we can use it.
 408 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 409                    [GNU texinfo.* \([0-9][0-9.]*\)],
 410                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 411 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 412
 413 # Check for doxygen
 414 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 415 AC_CHECK_PROG([DOT], dot, yes, no)
 416
 417 # Check for docbook
 418 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 419 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 420 GLIBCXX_CONFIGURE_DOCBOOK
 421
 422 # Check for xml/html dependencies.
 423 AM_CONDITIONAL(BUILD_XML,
 424                test $ac_cv_prog_DOXYGEN = "yes" &&
 425                test $ac_cv_prog_DOT = "yes" &&
 426                test $ac_cv_prog_XSLTPROC = "yes" &&
 427                test $ac_cv_prog_XMLLINT = "yes" &&
 428                test $glibcxx_stylesheets = "yes")
 429
 430 AM_CONDITIONAL(BUILD_HTML,
 431                test $ac_cv_prog_DOXYGEN = "yes" &&
 432                test $ac_cv_prog_DOT = "yes" &&
 433                test $ac_cv_prog_XSLTPROC = "yes" &&
 434                test $ac_cv_prog_XMLLINT = "yes" &&
 435                test $glibcxx_stylesheets = "yes")
 436
 437 # Check for man dependencies.
 438 AM_CONDITIONAL(BUILD_MAN,
 439                test $ac_cv_prog_DOXYGEN = "yes" &&
 440                test $ac_cv_prog_DOT = "yes")
 441
 442 # Check for pdf dependencies.
 443 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 444 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 445 AM_CONDITIONAL(BUILD_PDF,
 446                test $ac_cv_prog_DBLATEX = "yes" &&
 447                test $ac_cv_prog_PDFLATEX = "yes")
 448
 449
 450 # Propagate the target-specific source directories through the build chain.
 451 ATOMICITY_SRCDIR=config/${atomicity_dir}
 452 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 453 ATOMIC_FLAGS=${atomic_flags}
 454 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 455 OS_INC_SRCDIR=config/${os_include_dir}
 456 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 457 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 458 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 459 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 460 AC_SUBST(ATOMICITY_SRCDIR)
 461 AC_SUBST(ATOMIC_WORD_SRCDIR)
 462 AC_SUBST(ATOMIC_FLAGS)
 463 AC_SUBST(CPU_DEFINES_SRCDIR)
 464 AC_SUBST(ABI_TWEAKS_SRCDIR)
 465 AC_SUBST(OS_INC_SRCDIR)
 466 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 467 AC_SUBST(CPU_OPT_EXT_RANDOM)
 468 AC_SUBST(CPU_OPT_BITS_RANDOM)
 469
 470
 471 # Determine cross-compile flags and AM_CONDITIONALs.
 472 #AC_SUBST(GLIBCXX_IS_NATIVE)
 473 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 474 GLIBCXX_EVALUATE_CONDITIONALS
 475
 476 AC_CACHE_SAVE
 477
 478 if test ${multilib} = yes; then
 479   multilib_arg="--enable-multilib"
 480 else
 481   multilib_arg=
 482 fi
 483
 484 # Export all the install information.
 485 GLIBCXX_EXPORT_INSTALL_INFO
 486
 487 # Export all the include and flag information to Makefiles.
 488 GLIBCXX_EXPORT_INCLUDES
 489 GLIBCXX_EXPORT_FLAGS
 490
 491 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 492 dnl which can all be called multiple times as needed, plus one (different)
 493 dnl AC_OUTPUT macro.  This one lists the files to be created:
 494 AC_CONFIG_FILES(Makefile)
 495 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 496 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 497 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 498
 499 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 500 # that multilib installs will end up installed in the correct place.
 501 # The testsuite needs it for multilib-aware ABI baseline files.
 502 # To work around this not being passed down from config-ml.in ->
 503 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 504 # append it here.  Only modify Makefiles that have just been created.
 505 #
 506 # Also, get rid of this simulated-VPATH thing that automake does.
 507 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 508   [cat > vpsed$$ << \_EOF
 509 s!`test -f '$<' || echo '$(srcdir)/'`!!
 510 _EOF
 511    sed -f vpsed$$ $ac_file > tmp$$
 512    mv tmp$$ $ac_file
 513    rm vpsed$$
 514    echo 'MULTISUBDIR =' >> $ac_file
 515    ml_norecursion=yes
 516    . ${multi_basedir}/config-ml.in
 517    AS_UNSET([ml_norecursion])
 518 ])
 519
 520 AC_CONFIG_COMMANDS([generate-headers],
 521   [(cd include && ${MAKE-make} pch_build= )])
 522
 523 dnl And this actually makes things happen:
 524 AC_OUTPUT