gcc/ada/a-except.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                       A D A . E X C E P T I O N S                        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --          Copyright (C) 1992-2002 Free Software Foundation, Inc.          --
  11 --                                                                          --
  12 -- This specification is derived from the Ada Reference Manual for use with --
  13 -- GNAT. The copyright notice above, and the license provisions that follow --
  14 -- apply solely to the  contents of the part following the private keyword. --
  15 --                                                                          --
  16 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  17 -- terms of the  GNU General Public License as published  by the Free Soft- --
  18 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  19 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  20 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  21 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  22 -- for  more details.  You should have  received  a copy of the GNU General --
  23 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  24 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  25 -- MA 02111-1307, USA.                                                      --
  26 --                                                                          --
  27 -- As a special exception,  if other files  instantiate  generics from this --
  28 -- unit, or you link  this unit with other files  to produce an executable, --
  29 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  30 -- covered  by the  GNU  General  Public  License.  This exception does not --
  31 -- however invalidate  any other reasons why  the executable file  might be --
  32 -- covered by the  GNU Public License.                                      --
  33 --                                                                          --
  34 -- GNAT was originally developed  by the GNAT team at  New York University. --
  35 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  36 --                                                                          --
  37 ------------------------------------------------------------------------------
  38
  39 pragma Polling (Off);
  40 --  We must turn polling off for this unit, because otherwise we get
  41 --  elaboration circularities with ourself.
  42
  43 with System;
  44 with System.Standard_Library;
  45
  46 package Ada.Exceptions is
  47
  48    type Exception_Id is private;
  49    Null_Id : constant Exception_Id;
  50
  51    type Exception_Occurrence is limited private;
  52    type Exception_Occurrence_Access is access all Exception_Occurrence;
  53
  54    Null_Occurrence : constant Exception_Occurrence;
  55
  56    function Exception_Name (X : Exception_Occurrence) return String;
  57    --  Same as Exception_Name (Exception_Identity (X))
  58
  59    function Exception_Name (Id : Exception_Id) return String;
  60
  61    procedure Raise_Exception (E : Exception_Id; Message : String := "");
  62    --  Note: it would be really nice to give a pragma No_Return for this
  63    --  procedure, but it would be wrong, since Raise_Exception does return
  64    --  if given the null exception. However we do special case the name in
  65    --  the test in the compiler for issuing a warning for a missing return
  66    --  after this call. Program_Error seems reasonable enough in such a case.
  67    --  See also the routine Raise_Exception_Always in the private part.
  68
  69    function Exception_Message (X : Exception_Occurrence) return String;
  70
  71    procedure Reraise_Occurrence (X : Exception_Occurrence);
  72    --  Note: it would be really nice to give a pragma No_Return for this
  73    --  procedure, but it would be wrong, since Reraise_Occurrence does return
  74    --  if the argument is the null exception occurrence. See also procedure
  75    --  Reraise_Occurrence_Always in the private part of this package.
  76
  77    function Exception_Identity (X : Exception_Occurrence) return Exception_Id;
  78
  79    function Exception_Information (X : Exception_Occurrence) return String;
  80    --  The format of the exception information is as follows:
  81    --
  82    --    exception name (as in Exception_Name)
  83    --    message (or a null line if no message)
  84    --    PID=nnnn
  85    --    0xyyyyyyyy 0xyyyyyyyy ...
  86    --
  87    --  The lines are separated by a ASCII.LF character
  88    --  The nnnn is the partition Id given as decimal digits.
  89    --  The 0x... line represents traceback program counter locations,
  90    --  in order with the first one being the exception location.
  91
  92    --  Note on ordering: the compiler uses the Save_Occurrence procedure, but
  93    --  not the function from Rtsfind, so it is important that the procedure
  94    --  come first, since Rtsfind finds the first matching entity.
  95
  96    procedure Save_Occurrence
  97      (Target : out Exception_Occurrence;
  98       Source : Exception_Occurrence);
  99
 100    function Save_Occurrence
 101      (Source : Exception_Occurrence)
 102       return   Exception_Occurrence_Access;
 103
 104 private
 105    package SSL renames System.Standard_Library;
 106
 107    subtype EOA is Exception_Occurrence_Access;
 108
 109    Exception_Msg_Max_Length : constant := 200;
 110
 111    ------------------
 112    -- Exception_Id --
 113    ------------------
 114
 115    subtype Code_Loc is System.Address;
 116    --  Code location used in building exception tables and for call
 117    --  addresses when propagating an exception (also traceback table)
 118    --  Values of this type are created by using Label'Address or
 119    --  extracted from machine states using Get_Code_Loc.
 120
 121    Null_Loc : constant Code_Loc := System.Null_Address;
 122    --  Null code location, used to flag outer level frame
 123
 124    type Exception_Id is new SSL.Exception_Data_Ptr;
 125
 126    function EId_To_String (X : Exception_Id) return String;
 127    function String_To_EId (S : String) return Exception_Id;
 128    pragma Stream_Convert (Exception_Id, String_To_EId, EId_To_String);
 129    --  Functions for implementing Exception_Id stream attributes
 130
 131    Null_Id : constant Exception_Id := null;
 132
 133    -------------------------
 134    -- Private Subprograms --
 135    -------------------------
 136
 137    function Current_Target_Exception return Exception_Occurrence;
 138    pragma Export
 139      (Ada, Current_Target_Exception,
 140       "__gnat_current_target_exception");
 141    --  This routine should return the current raised exception on targets
 142    --  which have built-in exception handling such as the Java Virtual
 143    --  Machine. For other targets this routine is simply ignored. Currently,
 144    --  only JGNAT uses this. See 4jexcept.ads for details. The pragma Export
 145    --  allows this routine to be accessed elsewhere in the run-time, even
 146    --  though it is in the private part of this package (it is not allowed
 147    --  to be in the visible part, since this is set by the reference manual).
 148
 149    function Exception_Name_Simple (X : Exception_Occurrence) return String;
 150    --  Like Exception_Name, but returns the simple non-qualified name of
 151    --  the exception. This is used to implement the Exception_Name function
 152    --  in Current_Exceptions (the DEC compatible unit). It is called from
 153    --  the compiler generated code (using Rtsfind, which does not respect
 154    --  the private barrier, so we can place this function in the private
 155    --  part where the compiler can find it, but the spec is unchanged.)
 156
 157    procedure Raise_Exception_Always (E : Exception_Id; Message : String := "");
 158    pragma No_Return (Raise_Exception_Always);
 159    pragma Export (Ada, Raise_Exception_Always, "__gnat_raise_exception");
 160    --  This differs from Raise_Exception only in that the caller has determined
 161    --  that for sure the parameter E is not null, and that therefore the call
 162    --  to this procedure cannot return. The expander converts Raise_Exception
 163    --  calls to Raise_Exception_Always if it can determine this is the case.
 164    --  The Export allows this routine to be accessed from Pure units.
 165
 166    procedure Raise_No_Msg (E : Exception_Id);
 167    pragma No_Return (Raise_No_Msg);
 168    --  Raises an exception with no message with given exception id value.
 169    --  Abort is deferred before the raise call.
 170
 171    procedure Raise_From_Signal_Handler
 172      (E : Exception_Id;
 173       M : SSL.Big_String_Ptr);
 174    pragma Export
 175      (Ada, Raise_From_Signal_Handler,
 176            "ada__exceptions__raise_from_signal_handler");
 177    pragma No_Return (Raise_From_Signal_Handler);
 178    --  This routine is used to raise an exception from a signal handler.
 179    --  The signal handler has already stored the machine state (i.e. the
 180    --  state that corresponds to the location at which the signal was
 181    --  raised). E is the Exception_Id specifying what exception is being
 182    --  raised, and M is a pointer to a null-terminated string which is the
 183    --  message to be raised. Note that this routine never returns, so it is
 184    --  permissible to simply jump to this routine, rather than call it. This
 185    --  may be appropriate for systems where the right way to get out of a
 186    --  signal handler is to alter the PC value in the machine state or in
 187    --  some other way ask the operating system to return here rather than
 188    --  to the original location.
 189
 190    procedure Raise_With_C_Msg
 191      (E : Exception_Id;
 192       M : SSL.Big_String_Ptr);
 193    pragma Export (Ada, Raise_With_C_Msg, "ada__exceptions__raise_with_c_msg");
 194    pragma No_Return (Raise_With_C_Msg);
 195    --  Raises an exception with with given exception id value and message.
 196    --  M is a null terminated string with the message to be raised. Abort
 197    --  is deferred before the raise call.
 198
 199    procedure Reraise_Occurrence_Always (X : Exception_Occurrence);
 200    pragma No_Return (Reraise_Occurrence_Always);
 201    --  This differs from Raise_Occurrence only in that the caller guarantees
 202    --  that for sure the parameter X is not the null occurrence, and that
 203    --  therefore this procedure cannot return. The expander uses this routine
 204    --  in the translation of a raise statement with no parameter (reraise).
 205
 206    procedure Reraise_Occurrence_No_Defer (X : Exception_Occurrence);
 207    pragma No_Return (Reraise_Occurrence_No_Defer);
 208    --  Exactly like Reraise_Occurrence, except that abort is not deferred
 209    --  before the call and the parameter X is known not to be the null
 210    --  occurrence. This is used in generated code when it is known
 211    --  that abort is already deferred.
 212
 213    procedure SDP_Table_Build
 214      (SDP_Addresses   : System.Address;
 215       SDP_Count       : Natural;
 216       Elab_Addresses  : System.Address;
 217       Elab_Addr_Count : Natural);
 218    pragma Export (C, SDP_Table_Build, "__gnat_SDP_Table_Build");
 219    --  This is the routine that is called to build and sort the list of
 220    --  subprogram descriptor pointers. In the normal case it is called
 221    --  once at the start of execution, but it can also be called as part
 222    --  of the explicit initialization routine (adainit) when there is no
 223    --  Ada main program. In particular, in the case where multiple Ada
 224    --  libraries are present, this routine can be called more than once
 225    --  for each library, in which case it augments the previously set
 226    --  table with the new entries specified by the parameters.
 227    --
 228    --    SDP_Addresses    Address of the start of the list of addresses of
 229    --                     __gnat_unit_name__SDP values constructed for each
 230    --                     unit, (see System.Exceptions).
 231    --
 232    --    SDP_Count        Number of entries in SDP_Addresses
 233    --
 234    --    Elab_Addresses   Address of the start of a list of addresses of
 235    --                     generated Ada elaboration routines, as well as
 236    --                     one extra entry for the generated main program.
 237    --                     These are used to generate the dummy SDP's that
 238    --                     mark the outer scope.
 239    --
 240    --    Elab_Addr_Count  Number of entries in Elab_Addresses
 241
 242    procedure Break_Start;
 243    pragma Export (C, Break_Start, "__gnat_break_start");
 244    --  This is a dummy procedure that is called at the start of execution.
 245    --  Its sole purpose is to provide a well defined point for the placement
 246    --  of a main program breakpoint. We put the routine in Ada.Exceptions so
 247    --  that the standard mechanism of always stepping up from breakpoints
 248    --  within Ada.Exceptions leaves us sitting in the main program.
 249
 250    -----------------------
 251    -- Polling Interface --
 252    -----------------------
 253
 254    --  The GNAT compiler has an option to generate polling calls to the Poll
 255    --  routine in this package. Specifying the -gnatP option for a compilation
 256    --  causes a call to Ada.Exceptions.Poll to be generated on every subprogram
 257    --  entry and on every iteration of a loop, thus avoiding the possibility of
 258    --  a case of unbounded time between calls.
 259
 260    --  This polling interface may be used for instrumentation or debugging
 261    --  purposes (e.g. implementing watchpoints in software or in the debugger).
 262
 263    --  In the GNAT technology itself, this interface is used to implement
 264    --  immediate aynschronous transfer of control and immediate abort on
 265    --  targets which do not provide for one thread interrupting another.
 266
 267    --  Note: this used to be in a separate unit called System.Poll, but that
 268    --  caused horrible circular elaboration problems between System.Poll and
 269    --  Ada.Exceptions. One way of solving such circularities is unification!
 270
 271    procedure Poll;
 272    --  Check for asynchronous abort. Note that we do not inline the body.
 273    --  This makes the interface more useful for debugging purposes.
 274
 275    --------------------------
 276    -- Exception_Occurrence --
 277    --------------------------
 278
 279    Max_Tracebacks : constant := 50;
 280    --  Maximum number of trace backs stored in exception occurrence
 281
 282    type Tracebacks_Array is array (1 .. Max_Tracebacks) of Code_Loc;
 283    --  Traceback array stored in exception occurrence
 284
 285    type Exception_Occurrence is record
 286       Id : Exception_Id;
 287       --  Exception_Identity for this exception occurrence
 288       --  WARNING System.System.Finalization_Implementation.Finalize_List
 289       --  relies on the fact that this field is always first in the exception
 290       --  occurrence
 291
 292       Msg_Length : Natural := 0;
 293       --  Length of message (zero = no message)
 294
 295       Msg : String (1 .. Exception_Msg_Max_Length);
 296       --  Characters of message
 297
 298       Cleanup_Flag : Boolean;
 299       --  The cleanup flag is normally False, it is set True for an exception
 300       --  occurrence passed to a cleanup routine, and will still be set True
 301       --  when the cleanup routine does a Reraise_Occurrence call using this
 302       --  exception occurrence. This is used to avoid recording a bogus trace
 303       --  back entry from this reraise call.
 304
 305       Exception_Raised : Boolean := False;
 306       --  Set to true to indicate that this exception occurrence has actually
 307       --  been raised. When an exception occurrence is first created, this is
 308       --  set to False, then when it is processed by Raise_Current_Exception,
 309       --  it is set to True. If Raise_Current_Exception is used to raise an
 310       --  exception for which this flag is already True, then it knows that
 311       --  it is dealing with the reraise case (which is useful to distinguish
 312       --  for exception tracing purposes).
 313
 314       Pid : Natural;
 315       --  Partition_Id for partition raising exception
 316
 317       Num_Tracebacks : Natural range 0 .. Max_Tracebacks := 0;
 318       --  Number of traceback entries stored
 319
 320       Tracebacks : Tracebacks_Array;
 321       --  Stored tracebacks (in Tracebacks (1 .. Num_Tracebacks))
 322    end record;
 323
 324    function "=" (Left, Right : Exception_Occurrence) return Boolean
 325      is abstract;
 326    --  Don't allow comparison on exception occurrences, we should not need
 327    --  this, and it would not work right, because of the Msg and Tracebacks
 328    --  fields which have unused entries not copied by Save_Occurrence.
 329
 330    function EO_To_String (X : Exception_Occurrence) return String;
 331    function String_To_EO (S : String) return Exception_Occurrence;
 332    pragma Stream_Convert (Exception_Occurrence, String_To_EO, EO_To_String);
 333    --  Functions for implementing Exception_Occurrence stream attributes
 334
 335    Null_Occurrence : constant Exception_Occurrence := (
 336      Id               => Null_Id,
 337      Msg_Length       => 0,
 338      Msg              => (others => ' '),
 339      Cleanup_Flag     => False,
 340      Exception_Raised => False,
 341      Pid              => 0,
 342      Num_Tracebacks   => 0,
 343      Tracebacks       => (others => Null_Loc));
 344
 345 end Ada.Exceptions;