libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # Find the rest of the source tree framework.
  15 AM_ENABLE_MULTILIB(, ..)
  16
  17 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  18 #
  19 # You will slowly go insane if you do not grok the following fact:  when
  20 # building v3 as part of the compiler, the top-level /target/ becomes the
  21 # library's /host/.  configure then causes --target to default to --host,
  22 # exactly like any other package using autoconf.  Therefore, 'target' and
  23 # 'host' will always be the same.  This makes sense both for native and
  24 # cross compilers, just think about it for a little while.  :-)
  25 #
  26 # Also, if v3 is being configured as part of a cross compiler, the top-level
  27 # configure script will pass the "real" host as $with_cross_host.
  28 #
  29 # Do not delete or change the following two lines.  For why, see
  30 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  31 AC_CANONICAL_SYSTEM
  32 target_alias=${target_alias-$host_alias}
  33
  34 # Handy for debugging:
  35 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  36
  37 if test "$build" != "$host"; then
  38   # We are being configured with some form of cross compiler.
  39   GLIBCXX_IS_NATIVE=false
  40   case "$host","$target" in
  41     # Darwin crosses can use the host system's libraries and headers,
  42     # because of the fat library support.  Of course, it must be the
  43     # same version of Darwin on both sides.  Allow the user to
  44     # just say --target=foo-darwin without a version number to mean
  45     # "the version on this system".
  46       *-*-darwin*,*-*-darwin*)
  47         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  48         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  49         if test $hostos = $targetos -o $targetos = darwin ; then
  50           GLIBCXX_IS_NATIVE=true
  51         fi
  52         ;;
  53
  54       *)
  55         GCC_NO_EXECUTABLES
  56         ;;
  57   esac
  58 else
  59   GLIBCXX_IS_NATIVE=true
  60 fi
  61
  62 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  63 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  64 #  1.x:  minimum required version
  65 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  66 #              of other PACKAGE_* variables will, however, and there's nothing
  67 #              we can do about that; they come from AC_INIT).
  68 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  69 #            file in the top srcdir, etc, etc), so stop complaining.
  70 #  no-dependencies:  turns off auto dependency generation (just for now)
  71 #  no-dist:  we don't want 'dist' and related rules.
  72 #  -Wall:  turns on all automake warnings...
  73 #  -Wno-portability:  ...except this one, since GNU make is now required.
  74 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  75 AH_TEMPLATE(PACKAGE, [Name of package])
  76 AH_TEMPLATE(VERSION, [Version number of package])
  77
  78 # -fno-builtin must be present here so that a non-conflicting form of
  79 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  80
  81 save_CXXFLAGS="$CXXFLAGS"
  82 CXXFLAGS="$CXXFLAGS -fno-builtin"
  83 AC_PROG_CC
  84 AC_PROG_CXX
  85 CXXFLAGS="$save_CXXFLAGS"
  86
  87 # Runs configure.host, and assorted other critical bits.  Sets
  88 # up critical shell variables.
  89 GLIBCXX_CONFIGURE
  90
  91 # Libtool setup.
  92 if test "x${with_newlib}" != "xyes"; then
  93   AC_LIBTOOL_DLOPEN
  94 fi
  95 AM_PROG_LIBTOOL
  96 ACX_LT_HOST_FLAGS
  97 AC_SUBST(enable_shared)
  98 AC_SUBST(enable_static)
  99
 100 # libtool variables for C++ shared and position-independent compiles.
 101 #
 102 # Use glibcxx_lt_pic_flag to designate the automake variable
 103 # used to encapsulate the default libtool approach to creating objects
 104 # with position-independent code. Default: -prefer-pic.
 105 #
 106 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 107 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 108 #
 109 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 110 # creating position-independent objects. This varies with the target
 111 # hardware and operating system, but is often: -DPIC -fPIC.
 112 if test "$enable_shared" = yes; then
 113   glibcxx_lt_pic_flag="-prefer-pic"
 114   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 115   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 116
 117 else
 118   glibcxx_lt_pic_flag=
 119   glibcxx_compiler_pic_flag=
 120   glibcxx_compiler_shared_flag=
 121 fi
 122 AC_SUBST(glibcxx_lt_pic_flag)
 123 AC_SUBST(glibcxx_compiler_pic_flag)
 124 AC_SUBST(glibcxx_compiler_shared_flag)
 125
 126 # Override the libtool's pic_flag and pic_mode.
 127 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 128 # NB: this impacts --with-pic and --without-pic.
 129 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 130 pic_mode='default'
 131
 132 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 133 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 134
 135 # Possibly disable most of the library.
 136 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 137 ## than just ignoring the results.  Faster /and/ more correct, win win.
 138 GLIBCXX_ENABLE_HOSTED
 139
 140 # Enable descriptive messages to standard output on termination.
 141 GLIBCXX_ENABLE_VERBOSE
 142
 143 # Enable compiler support that doesn't require linking.
 144 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
 145 GLIBCXX_ENABLE_PCH($is_hosted)
 146 GLIBCXX_ENABLE_THREADS
 147 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 148 GLIBCXX_ENABLE_DECIMAL_FLOAT
 149 GLIBCXX_ENABLE_INT128_FLOAT128
 150
 151 # Checks for compiler support that doesn't require linking.
 152 GLIBCXX_CHECK_COMPILER_FEATURES
 153
 154 # Enable all the variable C++ runtime options that don't require linking.
 155 GLIBCXX_ENABLE_CSTDIO
 156 GLIBCXX_ENABLE_CLOCALE
 157 GLIBCXX_ENABLE_ALLOCATOR
 158 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 159 GLIBCXX_ENABLE_LONG_LONG([yes])
 160 GLIBCXX_ENABLE_WCHAR_T([yes])
 161 GLIBCXX_ENABLE_C99([yes])
 162 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 163 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0"])
 164 GLIBCXX_ENABLE_DEBUG([no])
 165 GLIBCXX_ENABLE_PARALLEL([yes])
 166 GLIBCXX_ENABLE_CXX_FLAGS
 167 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 168 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 169 GLIBCXX_ENABLE_PYTHON
 170 GLIBCXX_ENABLE_WERROR([yes])
 171
 172 # Checks for operating systems support that doesn't require linking.
 173 GLIBCXX_CHECK_STDIO_PROTO
 174 GLIBCXX_CHECK_SYSTEM_ERROR
 175
 176 # For the streamoff typedef.
 177 GLIBCXX_CHECK_INT64_T
 178
 179 # For LFS support.
 180 GLIBCXX_CHECK_LFS
 181
 182 # For showmanyc_helper().
 183 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 184 GLIBCXX_CHECK_POLL
 185 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 186
 187 # For xsputn_2().
 188 AC_CHECK_HEADERS(sys/uio.h)
 189 GLIBCXX_CHECK_WRITEV
 190
 191 # For C99 support to TR1.
 192 GLIBCXX_CHECK_C99_TR1
 193
 194 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 195 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 196
 197 # For gettimeofday support.
 198 GLIBCXX_CHECK_GETTIMEOFDAY
 199
 200 # For clock_gettime, nanosleep and sched_yield support.
 201 # NB: The default is [no], because otherwise it requires linking.
 202 GLIBCXX_ENABLE_LIBSTDCXX_TIME([no])
 203
 204 AC_LC_MESSAGES
 205
 206 # For hardware_concurrency
 207 AC_CHECK_HEADERS(sys/sysinfo.h)
 208 GLIBCXX_CHECK_GET_NPROCS
 209 AC_CHECK_HEADERS(unistd.h)
 210 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 211 GLIBCXX_CHECK_SC_NPROC_ONLN
 212 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 213 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 214
 215 # Check for available headers.
 216 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 217 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 218 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 219 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 220 wchar.h wctype.h])
 221
 222 # Only do link tests if native. Else, hardcode.
 223 if $GLIBCXX_IS_NATIVE; then
 224
 225   # We can do more elaborate tests that assume a working linker.
 226   CANADIAN=no
 227
 228   GLIBCXX_CHECK_LINKER_FEATURES
 229   GLIBCXX_CHECK_MATH_SUPPORT
 230   GLIBCXX_CHECK_STDLIB_SUPPORT
 231
 232   # For /dev/random and /dev/urandom for TR1.
 233   GLIBCXX_CHECK_RANDOM_TR1
 234
 235   # For TLS support.
 236   GCC_CHECK_TLS
 237
 238   # For iconv support.
 239   AM_ICONV
 240
 241 else
 242
 243   # This lets us hard-code the functionality we know we'll have in the cross
 244   # target environment.  "Let" is a sugar-coated word placed on an especially
 245   # dull and tedious hack, actually.
 246   #
 247   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 248   # that involve linking, can't be used:
 249   #    "cannot open sim-crt0.o"
 250   #    "cannot open crt0.o"
 251   # etc.  All this is because there currently exists no unified, consistent
 252   # way for top level CC information to be passed down to target directories:
 253   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 254   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 255   # crosses can be removed.
 256
 257   # If Canadian cross, then don't pick up tools from the build directory.
 258   # Used only in GLIBCXX_EXPORT_INCLUDES.
 259   if test -n "$with_cross_host" &&
 260      test x"$build_alias" != x"$with_cross_host" &&
 261      test x"$build" != x"$target";
 262   then
 263     CANADIAN=yes
 264   else
 265     CANADIAN=no
 266   fi
 267
 268   # Construct crosses by hand, eliminating bits that need ld...
 269   # GLIBCXX_CHECK_MATH_SUPPORT
 270
 271   # First, test for "known" system libraries.  We may be using newlib even
 272   # on a hosted environment.
 273   if test "x${with_newlib}" = "xyes"; then
 274     os_include_dir="os/newlib"
 275     AC_DEFINE(HAVE_HYPOT)
 276
 277     # GLIBCXX_CHECK_STDLIB_SUPPORT
 278     AC_DEFINE(HAVE_STRTOF)
 279
 280     AC_DEFINE(HAVE_ACOSF)
 281     AC_DEFINE(HAVE_ASINF)
 282     AC_DEFINE(HAVE_ATAN2F)
 283     AC_DEFINE(HAVE_ATANF)
 284     AC_DEFINE(HAVE_CEILF)
 285     AC_DEFINE(HAVE_COSF)
 286     AC_DEFINE(HAVE_COSHF)
 287     AC_DEFINE(HAVE_EXPF)
 288     AC_DEFINE(HAVE_FABSF)
 289     AC_DEFINE(HAVE_FLOORF)
 290     AC_DEFINE(HAVE_FMODF)
 291     AC_DEFINE(HAVE_FREXPF)
 292     AC_DEFINE(HAVE_LDEXPF)
 293     AC_DEFINE(HAVE_LOG10F)
 294     AC_DEFINE(HAVE_LOGF)
 295     AC_DEFINE(HAVE_MODFF)
 296     AC_DEFINE(HAVE_POWF)
 297     AC_DEFINE(HAVE_SINF)
 298     AC_DEFINE(HAVE_SINHF)
 299     AC_DEFINE(HAVE_SQRTF)
 300     AC_DEFINE(HAVE_TANF)
 301     AC_DEFINE(HAVE_TANHF)
 302
 303     AC_DEFINE(HAVE_ICONV)
 304   else
 305     GLIBCXX_CROSSCONFIG
 306   fi
 307
 308   # At some point, we should differentiate between architectures
 309   # like x86, which have long double versions, and alpha/powerpc/etc.,
 310   # which don't. For the time being, punt.
 311   if test x"long_double_math_on_this_cpu" = x"yes"; then
 312     AC_DEFINE(HAVE_ACOSL)
 313     AC_DEFINE(HAVE_ASINL)
 314     AC_DEFINE(HAVE_ATAN2L)
 315     AC_DEFINE(HAVE_ATANL)
 316     AC_DEFINE(HAVE_CEILL)
 317     AC_DEFINE(HAVE_COSL)
 318     AC_DEFINE(HAVE_COSHL)
 319     AC_DEFINE(HAVE_EXPL)
 320     AC_DEFINE(HAVE_FABSL)
 321     AC_DEFINE(HAVE_FLOORL)
 322     AC_DEFINE(HAVE_FMODL)
 323     AC_DEFINE(HAVE_FREXPL)
 324     AC_DEFINE(HAVE_LDEXPL)
 325     AC_DEFINE(HAVE_LOG10L)
 326     AC_DEFINE(HAVE_LOGL)
 327     AC_DEFINE(HAVE_MODFL)
 328     AC_DEFINE(HAVE_POWL)
 329     AC_DEFINE(HAVE_SINCOSL)
 330     AC_DEFINE(HAVE_SINL)
 331     AC_DEFINE(HAVE_SINHL)
 332     AC_DEFINE(HAVE_SQRTL)
 333     AC_DEFINE(HAVE_TANL)
 334     AC_DEFINE(HAVE_TANHL)
 335   fi
 336 fi
 337
 338 # Check for _Unwind_GetIPInfo.
 339 GCC_CHECK_UNWIND_GETIPINFO
 340
 341 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 342
 343 GCC_HEADER_STDINT(include/gstdint.h)
 344
 345 GLIBCXX_ENABLE_SYMVERS([yes])
 346 AC_SUBST(libtool_VERSION)
 347
 348 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 349
 350 ac_ldbl_compat=no
 351 case "$target" in
 352   powerpc*-*-linux* | \
 353   sparc*-*-linux* | \
 354   s390*-*-linux* | \
 355   alpha*-*-linux*)
 356   AC_TRY_COMPILE(, [
 357 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 358 #error no need for long double compatibility
 359 #endif
 360   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 361   if test "$ac_ldbl_compat" = yes; then
 362     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 363               [Define if compatibility should be provided for -mlong-double-64.])
 364     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 365   fi
 366 esac
 367 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 368
 369 # Check if assembler supports disabling hardware capability support.
 370 GLIBCXX_CHECK_ASSEMBLER_HWCAP
 371
 372 # Check if assembler supports rdrand opcode.
 373 GLIBCXX_CHECK_X86_RDRAND
 374
 375 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 376 GLIBCXX_CONFIGURE_TESTSUITE
 377
 378 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 379 GLIBCXX_CHECK_GTHREADS
 380
 381 # Define documentation rules conditionally.
 382
 383 # See if makeinfo has been installed and is modern enough
 384 # that we can use it.
 385 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 386                    [GNU texinfo.* \([0-9][0-9.]*\)],
 387                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 388 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 389
 390 # Check for doxygen
 391 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 392 AC_CHECK_PROG([DOT], dot, yes, no)
 393
 394 # Check for docbook
 395 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 396 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 397 GLIBCXX_CONFIGURE_DOCBOOK
 398
 399 # Check for xml/html dependencies.
 400 AM_CONDITIONAL(BUILD_XML,
 401                test $ac_cv_prog_DOXYGEN = "yes" &&
 402                test $ac_cv_prog_DOT = "yes" &&
 403                test $ac_cv_prog_XSLTPROC = "yes" &&
 404                test $ac_cv_prog_XMLLINT = "yes" &&
 405                test $glibcxx_stylesheets = "yes")
 406
 407 AM_CONDITIONAL(BUILD_HTML,
 408                test $ac_cv_prog_DOXYGEN = "yes" &&
 409                test $ac_cv_prog_DOT = "yes" &&
 410                test $ac_cv_prog_XSLTPROC = "yes" &&
 411                test $ac_cv_prog_XMLLINT = "yes" &&
 412                test $glibcxx_stylesheets = "yes")
 413
 414 # Check for man dependencies.
 415 AM_CONDITIONAL(BUILD_MAN,
 416                test $ac_cv_prog_DOXYGEN = "yes" &&
 417                test $ac_cv_prog_DOT = "yes")
 418
 419 # Check for pdf dependencies.
 420 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 421 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 422 AM_CONDITIONAL(BUILD_PDF,
 423                test $ac_cv_prog_DBLATEX = "yes" &&
 424                test $ac_cv_prog_PDFLATEX = "yes")
 425
 426
 427 # Propagate the target-specific source directories through the build chain.
 428 ATOMICITY_SRCDIR=config/${atomicity_dir}
 429 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 430 ATOMIC_FLAGS=${atomic_flags}
 431 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 432 OS_INC_SRCDIR=config/${os_include_dir}
 433 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 434 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 435 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 436 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 437 AC_SUBST(ATOMICITY_SRCDIR)
 438 AC_SUBST(ATOMIC_WORD_SRCDIR)
 439 AC_SUBST(ATOMIC_FLAGS)
 440 AC_SUBST(CPU_DEFINES_SRCDIR)
 441 AC_SUBST(ABI_TWEAKS_SRCDIR)
 442 AC_SUBST(OS_INC_SRCDIR)
 443 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 444 AC_SUBST(CPU_OPT_EXT_RANDOM)
 445 AC_SUBST(CPU_OPT_BITS_RANDOM)
 446
 447
 448 # Determine cross-compile flags and AM_CONDITIONALs.
 449 #AC_SUBST(GLIBCXX_IS_NATIVE)
 450 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 451 GLIBCXX_EVALUATE_CONDITIONALS
 452
 453 AC_CACHE_SAVE
 454
 455 if test ${multilib} = yes; then
 456   multilib_arg="--enable-multilib"
 457 else
 458   multilib_arg=
 459 fi
 460
 461 # Export all the install information.
 462 GLIBCXX_EXPORT_INSTALL_INFO
 463
 464 # Export all the include and flag information to Makefiles.
 465 GLIBCXX_EXPORT_INCLUDES
 466 GLIBCXX_EXPORT_FLAGS
 467
 468 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 469 dnl which can all be called multiple times as needed, plus one (different)
 470 dnl AC_OUTPUT macro.  This one lists the files to be created:
 471 AC_CONFIG_FILES(Makefile)
 472 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 473 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 474 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 475
 476 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 477 # that multilib installs will end up installed in the correct place.
 478 # The testsuite needs it for multilib-aware ABI baseline files.
 479 # To work around this not being passed down from config-ml.in ->
 480 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 481 # append it here.  Only modify Makefiles that have just been created.
 482 #
 483 # Also, get rid of this simulated-VPATH thing that automake does.
 484 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 485   [cat > vpsed$$ << \_EOF
 486 s!`test -f '$<' || echo '$(srcdir)/'`!!
 487 _EOF
 488    sed -f vpsed$$ $ac_file > tmp$$
 489    mv tmp$$ $ac_file
 490    rm vpsed$$
 491    echo 'MULTISUBDIR =' >> $ac_file
 492    ml_norecursion=yes
 493    . ${multi_basedir}/config-ml.in
 494    AS_UNSET([ml_norecursion])
 495 ])
 496
 497 AC_CONFIG_COMMANDS([generate-headers],
 498   [(cd include && ${MAKE-make} pch_build= )])
 499
 500 dnl And this actually makes things happen:
 501 AC_OUTPUT