libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_INIT(package-unused, version-unused,, libgo)
  10 AC_CONFIG_SRCDIR(Makefile.am)
  11 AC_CONFIG_HEADER(config.h)
  12
  13 libtool_VERSION=16:0:0
  14 AC_SUBST(libtool_VERSION)
  15
  16 AM_ENABLE_MULTILIB(, ..)
  17
  18 AC_CANONICAL_SYSTEM
  19 target_alias=${target_alias-$host_alias}
  20
  21 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist subdir-objects -Wall -Wno-portability -Wno-override])
  22 AH_TEMPLATE(PACKAGE, [Name of package])
  23 AH_TEMPLATE(VERSION, [Version number of package])
  24
  25 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  26 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  27 AC_PROG_CC
  28 AC_PROG_GO
  29 AM_PROG_AS
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 case ${host} in
  35   *-*-aix*)
  36     # static hash tables crashes on AIX when libgo is built with O2
  37     CFLAGS="$CFLAGS -fno-section-anchors"
  38     GOCFLAGS="$GOCFLAGS -fno-section-anchors"
  39     ;;
  40 esac
  41
  42 AM_MAINTAINER_MODE
  43
  44 AC_PROG_LD
  45 AC_PROG_RANLIB
  46 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  47
  48 AC_LIBTOOL_DLOPEN
  49 AM_PROG_LIBTOOL
  50 AC_SUBST(enable_shared)
  51 AC_SUBST(enable_static)
  52
  53 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  54 AC_SUBST(CC_FOR_BUILD)
  55
  56 AC_PROG_AWK
  57
  58 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  59 AC_SUBST(WARN_FLAGS)
  60
  61 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  62                                       [turns on -Werror @<:@default=yes@:>@])])
  63 if test "x$enable_werror" != "xno"; then
  64   WERROR="-Werror"
  65 fi
  66 AC_SUBST(WERROR)
  67
  68 glibgo_toolexecdir=no
  69 glibgo_toolexeclibdir=no
  70
  71 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  72 AC_ARG_ENABLE([version-specific-runtime-libs],
  73   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  74                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  75   [case "$enableval" in
  76     yes) version_specific_libs=yes ;;
  77     no)  version_specific_libs=no ;;
  78     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  79    esac],
  80   [version_specific_libs=no])
  81 AC_MSG_RESULT($version_specific_libs)
  82
  83 # Version-specific runtime libs processing.
  84 if test $version_specific_libs = yes; then
  85   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  86   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  87 fi
  88
  89 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  90 # Install a library built with a cross compiler in tooldir, not libdir.
  91 if test -n "$with_cross_host" &&
  92    test x"$with_cross_host" != x"no"; then
  93   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  94   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  95 else
  96   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  97   nover_glibgo_toolexeclibdir='${libdir}'
  98 fi
  99 multi_os_directory=`$GOC -print-multi-os-directory`
 100 case $multi_os_directory in
 101   .) ;; # Avoid trailing /.
 102   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
 103 esac
 104
 105 if test x"$glibgo_toolexecdir" = x"no"; then
 106   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
 107   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 108 fi
 109
 110 AC_SUBST(glibgo_toolexecdir)
 111 AC_SUBST(glibgo_toolexeclibdir)
 112 AC_SUBST(nover_glibgo_toolexeclibdir)
 113
 114 # See if the user wants to configure without libffi.  Some
 115 # architectures don't support it.  FIXME: We should set a default
 116 # based on the host.
 117 AC_ARG_WITH(libffi,
 118   AS_HELP_STRING([--without-libffi],
 119                  [don't use libffi]),
 120   [:],
 121   [with_libffi=${with_libffi_default-yes}])
 122
 123 LIBFFI=
 124 LIBFFIINCS=
 125 if test "$with_libffi" != no; then
 126    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 127    LIBFFI=../libffi/libffi_convenience.la
 128    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 129 fi
 130 AC_SUBST(LIBFFI)
 131 AC_SUBST(LIBFFIINCS)
 132 AM_CONDITIONAL(USE_LIBFFI, test "$with_libffi" != "no")
 133
 134 # See if the user wants to configure without libatomic. This is useful if we are
 135 # on an architecture for which libgo does not need an atomic support library and
 136 # libatomic does not support our C compiler.
 137 AC_ARG_WITH(libatomic,
 138   AS_HELP_STRING([--without-libatomic],
 139                  [don't use libatomic]),
 140   [:],
 141   [with_libatomic=${with_libatomic_default-yes}])
 142
 143 LIBATOMIC=
 144 if test "$with_libatomic" != no; then
 145    LIBATOMIC=../libatomic/libatomic_convenience.la
 146 fi
 147 AC_SUBST(LIBATOMIC)
 148
 149 # Used to tell GNU make to include a file without telling automake to
 150 # include it.
 151 go_include="-include"
 152 AC_SUBST(go_include)
 153
 154 # All known GOOS values.  This is the union of all operating systems
 155 # supported by the gofrontend and all operating systems supported by
 156 # the gc toolchain.
 157 ALLGOOS="aix android darwin dragonfly freebsd hurd illumos irix js linux netbsd openbsd plan9 rtems solaris windows"
 158
 159 is_darwin=no
 160 is_freebsd=no
 161 is_irix=no
 162 is_linux=no
 163 is_netbsd=no
 164 is_openbsd=no
 165 is_dragonfly=no
 166 is_rtems=no
 167 is_solaris=no
 168 is_aix=no
 169 is_hurd=no
 170 GOOS=unknown
 171 case ${host} in
 172   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 173   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 174   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 175   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 176   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 177   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 178   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 179   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 180   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 181   *-*-aix*)      is_aix=yes;     GOOS=aix ;;
 182   *-*-gnu*)      is_hurd=yes;    GOOS=hurd ;;
 183 esac
 184 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 185 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 186 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 187 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 188 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 189 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 190 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 191 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 192 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 193 AM_CONDITIONAL(LIBGO_IS_AIX, test $is_aix = yes)
 194 AM_CONDITIONAL(LIBGO_IS_HURD, test $is_hurd = yes)
 195 AM_CONDITIONAL(LIBGO_IS_BSD, test $is_darwin = yes -o $is_dragonfly = yes -o $is_freebsd = yes -o $is_netbsd = yes -o $is_openbsd = yes)
 196 AC_SUBST(GOOS)
 197 AC_SUBST(ALLGOOS)
 198
 199 dnl Test whether we need to use DejaGNU or whether we can use the
 200 dnl simpler gotest approach.  We can only use gotest for a native
 201 dnl build.
 202 USE_DEJAGNU=no
 203 case ${host} in
 204   *-*-rtems*) USE_DEJAGNU=yes ;;
 205   ${build}) ;;
 206   *) USE_DEJAGNU=yes ;;
 207 esac
 208 AC_SUBST(USE_DEJAGNU)
 209
 210 # All known GOARCH values.  This is the union of all architectures
 211 # supported by the gofrontend and all architectures supported by the
 212 # gc toolchain.
 213 # To add a new architecture:
 214 # - add it to this list
 215 # - if appropriate, add an entry to ALLGOARCHFAMILY below
 216 # - add an entry to the case on ${host} below to set GOARCH
 217 # - update goarchList in libgo/go/go/build/syslist.go
 218 # - update goarch.sh to report the values for this architecture
 219 # - update go-set-goarch in gcc/testsuite/go.test/go-test.exp
 220 # - update ptrSizeMap and intSizeMap in libgo/go/cmd/cgo/main.go
 221 # - update arch lists in libgo/match.sh
 222 # - update arch lists in libgo/testsuite/gotest
 223 # - update +build lines in several places
 224 #   - libgo/go/runtime/lfstack_NNbit.go
 225 #   - libgo/go/runtime/hashNN.go
 226 #   - libgo/go/runtime/unalignedN.go
 227 #   - libgo/go/syscall/endian_XX.go
 228 #   - possibly others
 229 # - possibly update files in libgo/go/internal/syscall/unix
 230 ALLGOARCH="386 alpha amd64 amd64p32 arm armbe arm64 arm64be ia64 m68k mips mipsle mips64 mips64le mips64p32 mips64p32le nios2 ppc ppc64 ppc64le riscv riscv64 s390 s390x sh shbe sparc sparc64 wasm"
 231
 232 # All known GOARCH family values.
 233 ALLGOARCHFAMILY="I386 ALPHA AMD64 ARM ARM64 IA64 M68K MIPS MIPS64 NIOS2 PPC PPC64 RISCV RISCV64 S390 S390X SH SPARC SPARC64 WASM"
 234
 235 GOARCH=unknown
 236 case ${host} in
 237   alpha*-*-*)
 238     GOARCH=alpha
 239     ;;
 240   aarch64-*-*)
 241     GOARCH=arm64
 242     ;;
 243   aarch64_be-*-*)
 244     GOARCH=arm64be
 245     ;;
 246   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 247     GOARCH=arm
 248     case ${host} in
 249       arm*b*-*-*)
 250         GOARCH=armbe
 251         ;;
 252     esac
 253     ;;
 254 changequote(,)dnl
 255   i[34567]86-*-* | x86_64-*-*)
 256 changequote([,])dnl
 257     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 258 #ifdef __x86_64__
 259 #error 64-bit
 260 #endif
 261 ])],
 262         [GOARCH=386],
 263         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 264 #ifdef __ILP32__
 265 #error x32
 266 #endif
 267 ])],
 268         [GOARCH=amd64],
 269         [GOARCH=amd64p32]))
 270     ;;
 271   ia64-*-*)
 272     GOARCH=ia64
 273     ;;
 274   m68k*-*-*)
 275     GOARCH=m68k
 276     ;;
 277   mips*-*-*)
 278     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 279 #if _MIPS_SIM != _ABIO32
 280 #error not o32
 281 #endif
 282 ])],
 283 [mips_abi="o32"],
 284         [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 285 #if _MIPS_SIM != _ABIN32
 286 #error not n32
 287 #endif
 288 ])],
 289 [mips_abi="n32"],
 290         [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 291 #if _MIPS_SIM != _ABI64
 292 #error not n64
 293 #endif
 294 ])],
 295 [mips_abi="n64"],
 296         [AC_MSG_ERROR([unknown MIPS ABI])
 297 [mips_abi="n32"]])])])
 298     case "$mips_abi" in
 299     "o32") GOARCH=mips ;;
 300     "n32") GOARCH=mips64p32 ;;
 301     "n64") GOARCH=mips64 ;;
 302     esac
 303     case "${host}" in
 304     mips*el-*-*)
 305         GOARCH="${GOARCH}le"
 306         ;;
 307     esac
 308     ;;
 309   nios2-*-*)
 310     GOARCH=nios2
 311     ;;
 312   rs6000*-*-* | powerpc*-*-*)
 313     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 314 #ifdef _ARCH_PPC64
 315 #error 64-bit
 316 #endif
 317 ])],
 318 [GOARCH=ppc],
 319     [
 320 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 321 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 322 #error 64be
 323 #endif
 324 ])],
 325 [GOARCH=ppc64le],
 326 [GOARCH=ppc64])])
 327     ;;
 328   riscv64-*-*)
 329     GOARCH=riscv64
 330     ;;
 331   s390*-*-*)
 332     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 333 #if defined(__s390x__)
 334 #error 64-bit
 335 #endif
 336 ])],
 337 [GOARCH=s390],
 338 [GOARCH=s390x])
 339     ;;
 340   sh3eb*-*-* | sh4eb*-*-*)
 341     GOARCH=shbe
 342     ;;
 343   sh3*-*-* | sh4*-*-*)
 344     GOARCH=sh
 345     ;;
 346   sparc*-*-*)
 347     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 348 #if defined(__sparcv9) || defined(__arch64__)
 349 #error 64-bit
 350 #endif
 351 ])],
 352 [GOARCH=sparc],
 353 [GOARCH=sparc64])
 354     ;;
 355 esac
 356 AC_SUBST(GOARCH)
 357 AC_SUBST(ALLGOARCH)
 358 AC_SUBST(ALLGOARCHFAMILY)
 359
 360 AM_CONDITIONAL(LIBGO_IS_X86, test "$GOARCH" = "386" -o "$GOARCH" = "amd64" -o "$GOARCH" = "amd64p32")
 361
 362 FUNCTION_DESCRIPTORS=false
 363 case ${host} in
 364   rs6000*-*-* | powerpc*-*-*)
 365     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 366 #if _CALL_ELF == 1
 367 #error descriptors
 368 #endif
 369 ])],
 370         [FUNCTION_DESCRIPTORS=false],
 371         [FUNCTION_DESCRIPTORS=true])
 372     ;;
 373 esac
 374 AC_SUBST(FUNCTION_DESCRIPTORS)
 375
 376 dnl Some files are only present when needed for specific architectures.
 377 GO_LIBCALL_OS_FILE=
 378 GO_LIBCALL_OS_ARCH_FILE=
 379 GO_SYSCALL_OS_FILE=
 380 GO_SYSCALL_OS_ARCH_FILE=
 381 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 382   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 383 fi
 384 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 385   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 386 fi
 387 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 388   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 389 fi
 390 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 391   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 392 fi
 393 AC_SUBST(GO_LIBCALL_OS_FILE)
 394 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 395 AC_SUBST(GO_SYSCALL_OS_FILE)
 396 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 397
 398 dnl Special flags used to generate sysinfo.go.
 399 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 400 case "$target" in
 401     mips-sgi-irix6.5*)
 402         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 403         # msghdr in <sys/socket.h>.
 404         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 405         ;;
 406     *-*-solaris2.*)
 407         # Solaris 10+ needs this so struct msghdr gets the msg_control
 408         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 409         # above doesn't work with C99.
 410         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 411         ;;
 412 esac
 413 AC_SUBST(OSCFLAGS)
 414
 415 dnl Check if assembler supports disabling hardware capability support.
 416 GCC_CHECK_ASSEMBLER_HWCAP
 417
 418 dnl Use -fsplit-stack when compiling C code if available.
 419 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 420 [libgo_cv_c_split_stack_supported],
 421 [CFLAGS_hold=$CFLAGS
 422 CFLAGS="$CFLAGS -fsplit-stack"
 423 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 424 [libgo_cv_c_split_stack_supported=yes],
 425 [libgo_cv_c_split_stack_supported=no])
 426 CFLAGS=$CFLAGS_hold])
 427
 428 dnl Make sure the linker permits -fsplit-stack.  Old versions of gold will
 429 dnl reject split-stack code calling non-split-stack code on targets
 430 dnl they don't support.
 431 AC_CACHE_CHECK([whether linker supports split/non-split linked together],
 432 [libgo_cv_c_linker_split_non_split],
 433 [cat > conftest1.c << EOF
 434 extern void f();
 435 int main() { f(); return 0; }
 436 EOF
 437 cat > conftest2.c << EOF
 438 void f() {}
 439 EOF
 440 $CC -c -fsplit-stack $CFLAGS $CPPFLAGS conftest1.c >/dev/null 2>&1
 441 $CC -c $CFLAGS $CPPFLAGS conftest2.c > /dev/null 2>&1
 442 if $CC -o conftest conftest1.$ac_objext conftest2.$ac_objext > /dev/null 2>&1; then
 443   libgo_cv_c_linker_split_non_split=yes
 444 else
 445   libgo_cv_c_linker_split_non_split=no
 446 fi
 447 rm -f conftest1.* conftest2.* conftest])
 448
 449 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes; then
 450   SPLIT_STACK=-fsplit-stack
 451   AC_DEFINE(USING_SPLIT_STACK, 1,
 452                 [Define if the compiler supports -fsplit-stack])
 453 else
 454   SPLIT_STACK=
 455 fi
 456 AC_SUBST(SPLIT_STACK)
 457 AM_CONDITIONAL(USING_SPLIT_STACK,
 458         test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes)
 459
 460 dnl If the compiler supports split-stack but the linker does not, then
 461 dnl we need to explicitly disable split-stack for Go.
 462 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = no; then
 463   GO_SPLIT_STACK=-fno-split-stack
 464 else
 465   GO_SPLIT_STACK=
 466 fi
 467 AC_SUBST(GO_SPLIT_STACK)
 468
 469 dnl Check whether the linker does stack munging when calling from
 470 dnl split-stack into non-split-stack code.  We check this by looking
 471 dnl at the --help output.  FIXME: This is only half right: it's
 472 dnl possible for the linker to support this for some targets but not
 473 dnl others.
 474 dnl This is slightly different from the above check, which is whether
 475 dnl the linker permits the call at all.
 476 AC_CACHE_CHECK([whether linker supports split stack],
 477 [libgo_cv_c_linker_supports_split_stack],
 478 [libgo_cv_c_linker_supports_split_stack=no
 479 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 480   libgo_cv_c_linker_supports_split_stack=yes
 481 fi])
 482 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 483   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 484             [Define if the linker support split stack adjustments])
 485 fi
 486
 487 AC_CACHE_CHECK([whether compiler is llgo],
 488 [libgo_cv_c_goc_is_llgo],
 489 [libgo_cv_c_goc_is_llgo=no
 490 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 491   libgo_cv_c_goc_is_llgo=yes
 492 fi])
 493 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 494
 495 dnl Test for the -lm library.
 496 MATH_LIBS=
 497 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 498 AC_SUBST(MATH_LIBS)
 499
 500 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 501 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 502   [libgo_cv_lib_sockets=
 503    libgo_check_both=no
 504    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 505    if test "$libgo_check_socket" = "yes"; then
 506      unset ac_cv_func_connect
 507      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 508                   libgo_check_both=yes)
 509    fi
 510    if test "$libgo_check_both" = "yes"; then
 511      libgo_old_libs=$LIBS
 512      LIBS="$LIBS -lsocket -lnsl"
 513      unset ac_cv_func_accept
 514      AC_CHECK_FUNC(accept,
 515                    [libgo_check_nsl=no
 516                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 517      unset ac_cv_func_accept
 518      LIBS=$libgo_old_libs
 519    fi
 520    unset ac_cv_func_gethostbyname
 521    libgo_old_libs="$LIBS"
 522    AC_CHECK_FUNC(gethostbyname, ,
 523                  [AC_CHECK_LIB(nsl, main,
 524                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 525    unset ac_cv_func_gethostbyname
 526    AC_CHECK_FUNC(sendfile, ,
 527                  [AC_CHECK_LIB(sendfile, main,
 528                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lsendfile"])])
 529    LIBS=$libgo_old_libs
 530 ])
 531 NET_LIBS="$libgo_cv_lib_sockets"
 532 AC_SUBST(NET_LIBS)
 533
 534 dnl Test whether the compiler supports the -pthread option.
 535 AC_CACHE_CHECK([whether -pthread is supported],
 536 [libgo_cv_lib_pthread],
 537 [CFLAGS_hold=$CFLAGS
 538 CFLAGS="$CFLAGS -pthread -L../libatomic/.libs"
 539 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 540 [libgo_cv_lib_pthread=yes],
 541 [libgo_cv_lib_pthread=no])
 542 CFLAGS=$CFLAGS_hold])
 543 PTHREAD_CFLAGS=
 544 if test "$libgo_cv_lib_pthread" = yes; then
 545   # RISC-V apparently adds -latomic when using -pthread.
 546   PTHREAD_CFLAGS="-pthread -L../libatomic/.libs"
 547 fi
 548 AC_SUBST(PTHREAD_CFLAGS)
 549
 550 dnl Test for the -lpthread library.
 551 PTHREAD_LIBS=
 552 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 553 AC_SUBST(PTHREAD_LIBS)
 554
 555 dnl Test if -lrt is required for sched_yield or nanosleep or clock_gettime.
 556 AC_SEARCH_LIBS([sched_yield], [rt])
 557 AC_SEARCH_LIBS([nanosleep], [rt])
 558 AC_SEARCH_LIBS([clock_gettime], [rt])
 559
 560 AC_C_BIGENDIAN
 561
 562 GCC_CHECK_UNWIND_GETIPINFO
 563
 564 AC_CHECK_HEADERS(port.h sched.h semaphore.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/event.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/ptrace.h linux/reboot.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 565
 566 AC_CHECK_HEADERS([netinet/icmp6.h], [], [],
 567 [#include <netinet/in.h>
 568 ])
 569
 570 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 571 [#ifdef HAVE_SYS_SOCKET_H
 572 #include <sys/socket.h>
 573 #endif
 574 ])
 575
 576 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 577
 578 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr memmem)
 579 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 580 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 581
 582 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice syscall tee unlinkat unshare utimensat)
 583 AC_TYPE_OFF_T
 584 AC_CHECK_TYPES([loff_t])
 585
 586 LIBS_hold="$LIBS"
 587 LIBS="$LIBS -lm"
 588 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 589 LIBS="$LIBS_hold"
 590
 591 CFLAGS_hold="$CFLAGS"
 592 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 593 LIBS_hold="$LIBS"
 594 LIBS="$LIBS $PTHREAD_LIBS"
 595 AC_CHECK_FUNCS(sem_timedwait)
 596 CFLAGS="$CFLAGS_hold"
 597 LIBS="$LIBS_hold"
 598
 599 LIBS_hold="$LIBS"
 600 LIBS="$LIBS $MATH_LIBS"
 601 AC_CHECK_FUNCS(matherr)
 602 LIBS="$LIBS_hold"
 603
 604 dnl For x86 we want to use the -minline-all-stringops option to avoid
 605 dnl forcing a stack split when calling memcpy and friends.
 606 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 607 [libgo_cv_c_stringops],
 608 [CFLAGS_hold=$CFLAGS
 609 CFLAGS="$CFLAGS -minline-all-stringops"
 610 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 611 [libgo_cv_c_stringops=yes],
 612 [libgo_cv_c_stringops=no])
 613 CFLAGS=$CFLAGS_hold])
 614 STRINGOPS_FLAG=
 615 if test "$libgo_cv_c_stringops" = yes; then
 616   STRINGOPS_FLAG=-minline-all-stringops
 617 fi
 618 AC_SUBST(STRINGOPS_FLAG)
 619
 620 dnl For x86 we want to compile the math library with -mfancy-math-387
 621 dnl so that we can use the builtin instructions directly.
 622 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 623 [libgo_cv_c_fancymath],
 624 [CFLAGS_hold=$CFLAGS
 625 CFLAGS="$CFLAGS -mfancy-math-387"
 626 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 627 [libgo_cv_c_fancymath=yes],
 628 [libgo_cv_c_fancymath=no])
 629 CFLAGS=$CFLAGS_hold])
 630 MATH_FLAG=
 631 if test "$libgo_cv_c_fancymath" = yes; then
 632   MATH_FLAG="-mfancy-math-387"
 633 fi
 634 MATH_FLAG="${MATH_FLAG} -ffp-contract=off -fno-math-errno -fno-trapping-math"
 635 AC_SUBST(MATH_FLAG)
 636
 637 CFLAGS_hold=$CFLAGS
 638 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 639 AC_CHECK_TYPES([off64_t])
 640 CFLAGS=$CFLAGS_hold
 641
 642 dnl Work out the size of the epoll_events struct on GNU/Linux.
 643 AC_CACHE_CHECK([epoll_event size],
 644 [libgo_cv_c_epoll_event_size],
 645 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 646 [sizeof (struct epoll_event)],
 647 [#include <sys/epoll.h>],
 648 [libgo_cv_c_epoll_event_size=0])])
 649 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 650 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 651
 652 dnl Work out the offset of the fd field in the epoll_events struct on
 653 dnl GNU/Linux.
 654 AC_CACHE_CHECK([epoll_event data.fd offset],
 655 [libgo_cv_c_epoll_event_fd_offset],
 656 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 657 [offsetof (struct epoll_event, data.fd)],
 658 [#include <stddef.h>
 659 #include <sys/epoll.h>],
 660 [libgo_cv_c_epoll_event_fd_offset=0])])
 661 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 662 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 663
 664 dnl Check if <sys/stat.h> uses timespec_t for st_?tim members.  Introduced
 665 dnl in Solaris 11.4 for XPG7 compatibility.
 666 AC_EGREP_HEADER([timespec_t.*st_atim], [sys/stat.h],
 667                 [have_stat_timespec=yes], [have_stat_timespec=no])
 668 AM_CONDITIONAL(HAVE_STAT_TIMESPEC, test $have_stat_timespec = yes)
 669
 670 dnl See if struct exception is defined in <math.h>.
 671 AC_CHECK_TYPE([struct exception],
 672 [libgo_has_struct_exception=yes],
 673 [libgo_has_struct_exception=no],
 674 [#include <math.h>])
 675 if test "$libgo_has_struct_exception" = "yes"; then
 676   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 677             [Define to 1 if <math.h> defines struct exception])
 678 fi
 679
 680 dnl See whether setcontext changes the value of TLS variables.
 681 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 682 [libgo_cv_lib_setcontext_clobbers_tls],
 683 [CFLAGS_hold="$CFLAGS"
 684 CFLAGS="$PTHREAD_CFLAGS"
 685 LIBS_hold="$LIBS"
 686 LIBS="$LIBS $PTHREAD_LIBS"
 687 AC_CHECK_SIZEOF([void *])
 688 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 689 AC_RUN_IFELSE(
 690   [AC_LANG_SOURCE([
 691 #include <pthread.h>
 692 #include <stdlib.h>
 693 #include <ucontext.h>
 694 #include <unistd.h>
 695
 696 __thread int tls;
 697
 698 static char stack[[10 * 1024 * 1024]];
 699 static ucontext_t c;
 700
 701 /* Called via makecontext/setcontext.  */
 702
 703 static void
 704 cfn (void)
 705 {
 706   exit (tls);
 707 }
 708
 709 /* Called via pthread_create.  */
 710
 711 static void *
 712 tfn (void *dummy)
 713 {
 714   /* The thread should still see this value after calling
 715      setcontext.  */
 716   tls = 0;
 717
 718   setcontext (&c);
 719
 720   /* The call to setcontext should not return.  */
 721   abort ();
 722 }
 723
 724 int
 725 main ()
 726 {
 727   pthread_t tid;
 728
 729   /* The thread should not see this value.  */
 730   tls = 1;
 731
 732   if (getcontext (&c) < 0)
 733     abort ();
 734
 735   c.uc_stack.ss_sp = stack;
 736 #ifdef MAKECONTEXT_STACK_TOP
 737   c.uc_stack.ss_sp += sizeof stack;
 738 #endif
 739   c.uc_stack.ss_flags = 0;
 740   c.uc_stack.ss_size = sizeof stack;
 741   c.uc_link = NULL;
 742   makecontext (&c, cfn, 0);
 743
 744   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 745     abort ();
 746
 747   if (pthread_join (tid, NULL) != 0)
 748     abort ();
 749
 750   /* The thread should have called exit.  */
 751   abort ();
 752 }
 753 ])],
 754 [libgo_cv_lib_setcontext_clobbers_tls=no],
 755 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 756 [case "$target:$ptr_type_size" in
 757   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 758     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 759   *)
 760     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 761  esac
 762 ])
 763 CFLAGS="$CFLAGS_hold"
 764 LIBS="$LIBS_hold"
 765 ])
 766 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 767   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 768             [Define if setcontext clobbers TLS variables])
 769 fi
 770
 771 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 772 libgo_cv_ro_eh_frame, [
 773 libgo_cv_ro_eh_frame=no
 774 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 775 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 776   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 777     libgo_cv_ro_eh_frame=yes
 778   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 779        | grep -v '#write' > /dev/null; then
 780     libgo_cv_ro_eh_frame=yes
 781   fi
 782 fi
 783 rm -f conftest.*
 784 ])
 785 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 786   AC_DEFINE(EH_FRAME_FLAGS, "a",
 787             [Define to the flags needed for the .section .eh_frame directive.])
 788 else
 789   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 790             [Define to the flags needed for the .section .eh_frame directive.])
 791 fi
 792
 793 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 794 [libgo_cv_c_unused_arguments],
 795 [CFLAGS_hold=$CFLAGS
 796 CFLAGS="$CFLAGS -Qunused-arguments"
 797 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 798 [libgo_cv_c_unused_arguments=yes],
 799 [libgo_cv_c_unused_arguments=no])
 800 CFLAGS=$CFLAGS_hold])
 801
 802 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 803 libgo_cv_as_comdat_gnu, [
 804 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 805 CFLAGS_hold=$CFLAGS
 806 if test "$libgo_cv_c_unused_arguments" = yes; then
 807   CFLAGS="$CFLAGS -Qunused-arguments"
 808 fi
 809 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 810   libgo_cv_as_comdat_gnu=yes
 811 else
 812   libgo_cv_as_comdat_gnu=no
 813 fi
 814 CFLAGS=$CFLAGS_hold
 815 ])
 816 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 817   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 818             [Define if your assembler supports GNU comdat group syntax.])
 819 fi
 820
 821 AC_CACHE_CHECK([assembler supports pc related relocs],
 822 libgo_cv_as_x86_pcrel, [
 823 libgo_cv_as_x86_pcrel=yes
 824 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 825 CFLAGS_hold=$CFLAGS
 826 if test "$libgo_cv_c_unused_arguments" = yes; then
 827   CFLAGS="$CFLAGS -Qunused-arguments"
 828 fi
 829 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 830     libgo_cv_as_x86_pcrel=no
 831 fi
 832 CFLAGS=$CFLAGS_hold
 833 ])
 834 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 835   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 836             [Define if your assembler supports PC relative relocs.])
 837 fi
 838
 839 AC_CACHE_CHECK([assembler supports unwind section type],
 840 libgo_cv_as_x86_64_unwind_section_type, [
 841 libgo_cv_as_x86_64_unwind_section_type=yes
 842 echo '.section .eh_frame,"a",@unwind' > conftest.s
 843 CFLAGS_hold=$CFLAGS
 844 if test "$libgo_cv_c_unused_arguments" = yes; then
 845   CFLAGS="$CFLAGS -Qunused-arguments"
 846 fi
 847 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 848     libgo_cv_as_x86_64_unwind_section_type=no
 849 fi
 850 CFLAGS=$CFLAGS_hold
 851 ])
 852 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 853   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 854             [Define if your assembler supports unwind section type.])
 855 fi
 856
 857 AC_CACHE_CHECK([assembler supports AES instructions],
 858 libgo_cv_as_x86_aes, [
 859 libgo_cv_as_x86_aes=yes
 860 echo 'aesenc %xmm0, %xmm1' > conftest.s
 861 CFLAGS_hold=$CFLAGS
 862 if test "$libgo_cv_c_unused_arguments" = yes; then
 863   CFLAGS="$CFLAGS -Qunused-arguments"
 864 fi
 865 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i error > /dev/null; then
 866     libgo_cv_as_x86_aes=no
 867 fi
 868 CFLAGS=$CFLAGS_hold
 869 ])
 870 if test "x$libgo_cv_as_x86_aes" = xyes; then
 871   AC_DEFINE(HAVE_AS_X86_AES, 1,
 872             [Define if your assembler supports AES instructions.])
 873 fi
 874
 875 AC_CACHE_SAVE
 876
 877 if test ${multilib} = yes; then
 878   multilib_arg="--enable-multilib"
 879 else
 880   multilib_arg=
 881 fi
 882
 883 AC_CONFIG_FILES(Makefile testsuite/Makefile testsuite/libgo-test-support.exp)
 884
 885 AC_CONFIG_COMMANDS([default],
 886 [if test -n "$CONFIG_FILES"; then
 887    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 888    # that multilib installs will end up installed in the correct place.
 889    # The testsuite needs it for multilib-aware ABI baseline files.
 890    # To work around this not being passed down from config-ml.in ->
 891    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 892    # append it here.  Only modify Makefiles that have just been created.
 893    #
 894    # Also, get rid of this simulated-VPATH thing that automake does.
 895    cat > vpsed << \_EOF
 896 s!`test -f '$<' || echo '$(srcdir)/'`!!
 897 _EOF
 898    for i in $SUBDIRS; do
 899     case $CONFIG_FILES in
 900      *${i}/Makefile*)
 901        #echo "Adding MULTISUBDIR to $i/Makefile"
 902        sed -f vpsed $i/Makefile > tmp
 903        grep '^MULTISUBDIR =' Makefile >> tmp
 904        mv tmp $i/Makefile
 905        ;;
 906     esac
 907    done
 908    rm vpsed
 909  fi
 910 ],
 911 [
 912 # Variables needed in config.status (file generation) which aren't already
 913 # passed by autoconf.
 914 SUBDIRS="$SUBDIRS"
 915 ])
 916
 917 AC_OUTPUT