libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/lib-ld.m4)
   8 sinclude(../config/override.m4)
   9 sinclude(../config/picflag.m4)
  10 sinclude(../config/dfp.m4)
  11 sinclude(../config/unwind_ipinfo.m4)
  12 sinclude(../config/gthr.m4)
  13 sinclude(../config/sjlj.m4)
  14
  15 AC_PREREQ(2.64)
  16 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  17 AC_CONFIG_SRCDIR([static-object.mk])
  18
  19 # The libgcc should not depend on any header files
  20 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  21   [m4_divert_text([DEFAULTS],
  22     [ac_includes_default='/* none */'])])
  23
  24 AC_ARG_WITH(target-subdir,
  25 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  26 AC_ARG_WITH(cross-host,
  27 [  --with-cross-host=HOST           Configuring with a cross compiler])
  28 AC_ARG_WITH(ld,
  29 [  --with-ld               arrange to use the specified ld (full pathname)])
  30
  31 if test "${srcdir}" = "."; then
  32   if test -n "${with_build_subdir}"; then
  33     libgcc_topdir="${srcdir}/../.."
  34     with_target_subdir=
  35   elif test -z "${with_target_subdir}"; then
  36     libgcc_topdir="${srcdir}/.."
  37   else
  38     if test "${with_target_subdir}" != "."; then
  39       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  40     else
  41       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  42     fi
  43   fi
  44 else
  45   libgcc_topdir="${srcdir}/.."
  46 fi
  47 AC_SUBST(libgcc_topdir)
  48 AC_CONFIG_AUX_DIR($libgcc_topdir)
  49 AC_CONFIG_HEADER(auto-target.h:config.in)
  50
  51 AC_ARG_ENABLE(shared,
  52 [  --disable-shared        don't provide a shared libgcc],
  53 [
  54   case $enable_shared in
  55   yes | no) ;;
  56   *)
  57     enable_shared=no
  58     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  59     for pkg in $enableval; do
  60       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  61         enable_shared=yes
  62       fi
  63     done
  64     IFS="$ac_save_ifs"
  65     ;;
  66   esac
  67 ], [enable_shared=yes])
  68 AC_SUBST(enable_shared)
  69
  70 AC_ARG_ENABLE(vtable-verify,
  71 [  --enable-vtable-verify    Enable vtable verification feature ],
  72 [case "$enableval" in
  73  yes) enable_vtable_verify=yes ;;
  74  no)  enable_vtable_verify=no ;;
  75  *)   enable_vtable_verify=no;;
  76  esac],
  77 [enable_vtable_verify=no])
  78 AC_SUBST(enable_vtable_verify)
  79
  80 AC_ARG_WITH(aix-soname,
  81 [AS_HELP_STRING([--with-aix-soname=aix|svr4|both],
  82     [shared library versioning (aka "SONAME") variant to provide on AIX])],
  83 [case "${host}:${enable_shared}" in
  84  power*-*-aix[[5-9]]*:yes)
  85    AC_MSG_CHECKING([which variant of shared library versioning to provide for shared libgcc])
  86    case ${withval} in
  87      aix|svr4|both) ;;
  88      *) AC_MSG_ERROR([Unknown argument to --with-aix-soname]);;
  89    esac
  90    AC_MSG_RESULT($withval)
  91    ;;
  92  *) with_aix_soname=aix ;;
  93  esac
  94 ], [with_aix_soname=aix])
  95 AC_SUBST(with_aix_soname)
  96
  97 GCC_PICFLAG
  98 AC_SUBST(PICFLAG)
  99
 100 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 101 AC_ARG_ENABLE(version-specific-runtime-libs,
 102 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
 103 [case "$enableval" in
 104  yes) version_specific_libs=yes ;;
 105  no)  version_specific_libs=no ;;
 106  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 107  esac],
 108 [version_specific_libs=no])
 109 AC_MSG_RESULT($version_specific_libs)
 110
 111 AC_ARG_WITH(slibdir,
 112 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
 113 slibdir="$with_slibdir",
 114 if test "${version_specific_libs}" = yes; then
 115   slibdir='$(libsubdir)'
 116 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
 117   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
 118 else
 119   slibdir='$(libdir)'
 120 fi)
 121 AC_SUBST(slibdir)
 122
 123 # Command-line options.
 124 # Very limited version of AC_MAINTAINER_MODE.
 125 AC_ARG_ENABLE([maintainer-mode],
 126   [AC_HELP_STRING([--enable-maintainer-mode],
 127                  [enable make rules and dependencies not useful (and
 128                   sometimes confusing) to the casual installer])],
 129   [case ${enable_maintainer_mode} in
 130      yes) MAINT='' ;;
 131      no) MAINT='#' ;;
 132      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 133    esac
 134    maintainer_mode=${enableval}],
 135   [MAINT='#'])
 136 AC_SUBST([MAINT])dnl
 137
 138 AC_PROG_INSTALL
 139
 140 AC_PROG_AWK
 141 # We need awk; bail out if it's missing.
 142 case ${AWK} in
 143   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 144 esac
 145
 146 AC_CANONICAL_HOST
 147 ACX_NONCANONICAL_HOST
 148 ACX_NONCANONICAL_TARGET
 149 GCC_TOPLEV_SUBDIRS
 150
 151 # Calculate toolexeclibdir
 152 # Also toolexecdir, though it's only used in toolexeclibdir
 153 case ${version_specific_libs} in
 154   yes)
 155     # Need the gcc compiler version to know where to install libraries
 156     # and header files if --enable-version-specific-runtime-libs option
 157     # is selected.
 158     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 159     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 160     ;;
 161   no)
 162     if test -n "$with_cross_host" &&
 163        test x"$with_cross_host" != x"no"; then
 164       # Install a library built with a cross compiler in tooldir, not libdir.
 165       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 166       toolexeclibdir='$(toolexecdir)/lib'
 167     else
 168       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 169       toolexeclibdir='$(libdir)'
 170     fi
 171     multi_os_directory=`$CC -print-multi-os-directory`
 172     case $multi_os_directory in
 173       .) ;; # Avoid trailing /.
 174       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 175     esac
 176     ;;
 177 esac
 178 AC_SUBST(toolexecdir)
 179 AC_SUBST(toolexeclibdir)
 180
 181 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 182 dnl to call AC_CHECK_PROG.
 183 AC_CHECK_TOOL(AR, ar)
 184 AC_CHECK_TOOL(LIPO, lipo, :)
 185 AC_CHECK_TOOL(NM, nm)
 186 AC_CHECK_TOOL(RANLIB, ranlib, :)
 187 AC_CHECK_TOOL(STRIP, strip, :)
 188 AC_PROG_LN_S
 189
 190 GCC_NO_EXECUTABLES
 191 AC_PROG_CC
 192 AC_PROG_CPP_WERROR
 193
 194 AC_CHECK_SIZEOF([double])
 195 AC_CHECK_SIZEOF([long double])
 196 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 197 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 198 AC_SUBST(double_type_size)
 199 AC_SUBST(long_double_type_size)
 200
 201 AC_CHECK_HEADERS(inttypes.h stdint.h stdlib.h ftw.h \
 202         unistd.h sys/stat.h sys/types.h \
 203         string.h strings.h memory.h)
 204 AC_HEADER_STDC
 205
 206 # Check for decimal float support.
 207 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 208                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 209 #include <fenv.h>
 210 ]], [[
 211 _Decimal32 x;
 212 int fe_except =
 213   FE_INVALID|FE_DIVBYZERO|FE_OVERFLOW|FE_UNDERFLOW|FE_INEXACT;
 214 ]])],
 215                                   [libgcc_cv_dfp=yes],
 216                                   [libgcc_cv_dfp=no])])
 217 decimal_float=$libgcc_cv_dfp
 218 AC_SUBST(decimal_float)
 219
 220 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 221
 222 # Check for fixed-point support.
 223 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 224                [AC_COMPILE_IFELSE([_Sat _Fract x;], [libgcc_cv_fixed_point=yes],
 225                                   [libgcc_cv_fixed_point=no])])
 226 fixed_point=$libgcc_cv_fixed_point
 227 AC_SUBST(fixed_point)
 228
 229 # For platforms with the unwind ABI which includes an unwind library,
 230 # libunwind, we can choose to use the system libunwind.
 231 # config.gcc also contains tests of with_system_libunwind.
 232 GCC_CHECK_UNWIND_GETIPINFO
 233
 234 # Check if the compiler is configured for setjmp/longjmp exceptions.
 235 GCC_CHECK_SJLJ_EXCEPTIONS
 236
 237 AC_ARG_ENABLE([explicit-exception-frame-registration],
 238   [AC_HELP_STRING([--enable-explicit-exception-frame-registration],
 239      [register exception tables explicitly at module start, for use
 240       e.g. for compatibility with installations without PT_GNU_EH_FRAME support])],
 241 [
 242 force_explicit_eh_registry=
 243 if test "$enable_explicit_exception_frame_registration" = yes; then
 244   if test $ac_cv_sjlj_exceptions = yes; then
 245     AC_MSG_ERROR([Can't --enable-explicit-exception-frame-registration
 246                   with setjmp/longjmp exceptions])
 247   fi
 248   force_explicit_eh_registry=-DUSE_EH_FRAME_REGISTRY_ALWAYS
 249 fi
 250 ])
 251 AC_SUBST([force_explicit_eh_registry])
 252
 253 AC_LIB_PROG_LD_GNU
 254
 255 AC_MSG_CHECKING([for thread model used by GCC])
 256 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 257 AC_MSG_RESULT([$target_thread_file])
 258
 259 # Check for assembler CFI support.
 260 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 261                [AC_COMPILE_IFELSE(
 262 [asm("\n\
 263         .text\n\
 264         .cfi_startproc\n\
 265         .cfi_personality 0, symbol\n\
 266         .cfi_endproc");],
 267   [libgcc_cv_cfi=yes],
 268   [libgcc_cv_cfi=no])])
 269
 270 # Check 32bit or 64bit.  In the case of MIPS, this really determines the
 271 # word size rather than the address size.
 272 cat > conftest.c <<EOF
 273 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__)) \
 274     || defined(__mips64)
 275 host_address=64
 276 #else
 277 host_address=32
 278 #endif
 279 EOF
 280 eval `${CC-cc} -E conftest.c | grep host_address=`
 281 rm -f conftest.c
 282
 283 case ${host} in
 284 mips*-*-*)
 285   AC_CACHE_CHECK([whether the target is hard-float],
 286                  [libgcc_cv_mips_hard_float],
 287                  [AC_COMPILE_IFELSE(
 288     [#ifndef __mips_hard_float
 289      #error FOO
 290      #endif],
 291     [libgcc_cv_mips_hard_float=yes],
 292     [libgcc_cv_mips_hard_float=no])])
 293 esac
 294
 295 case ${host} in
 296 *-*-solaris2*)
 297   # Check for system-provided CRTs on Solaris 11.x and Solaris 12.
 298   AC_CACHE_CHECK([system-provided CRTs on Solaris],
 299                  [libgcc_cv_solaris_crts],
 300     [libgcc_cv_solaris_crts=no
 301      libgcc_sysroot="`${CC} -print-sysroot`"
 302      libgcc_libdir="$libgcc_sysroot/usr/lib"
 303      # At the time they were added, gcrt1.o became a symlink for backwards
 304      # compatibility on x86, while crt1.o was added on sparc, so check for that.
 305      case ${host} in
 306        i?86-*-solaris2* | x86_64-*-solaris2*)
 307          if test -h "$libgcc_libdir/gcrt1.o"; then libgcc_cv_solaris_crts=yes; fi
 308          ;;
 309        sparc*-*-solaris2*)
 310          if test -f "$libgcc_libdir/crt1.o"; then libgcc_cv_solaris_crts=yes; fi
 311          ;;
 312      esac])
 313   if test $libgcc_cv_solaris_crts = yes; then
 314     AC_DEFINE(HAVE_SOLARIS_CRTS, 1,
 315       [Define if the system-provided CRTs are present on Solaris.])
 316   fi
 317   ;;
 318 esac
 319
 320 # Determine the version of glibc, if any, used on the target.
 321 AC_MSG_CHECKING([for target glibc version])
 322 AC_ARG_WITH([glibc-version],
 323   [AS_HELP_STRING([--with-glibc-version=M.N],
 324     [assume GCC used with glibc version M.N or later])], [
 325 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
 326   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
 327   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
 328 else
 329   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
 330 fi], [
 331 AC_COMPUTE_INT([glibc_version_major], [__GLIBC__],
 332                                       [#include <features.h>],
 333                                       [glibc_version_major=0])
 334 AC_COMPUTE_INT([glibc_version_minor], [__GLIBC_MINOR__],
 335                                       [#include <features.h>],
 336                                       [glibc_version_minor=0])])
 337 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
 338
 339 # Determine floating-point type for powerpc*-*-linux*.
 340 # Single-precision-only FPRs are not a supported configuration for
 341 # this target, so are not allowed for in this test.
 342 case ${host} in
 343 powerpc*-*-linux*)
 344   cat > conftest.c <<EOF
 345 #ifdef __powerpc64__
 346 ppc_fp_type=64
 347 #elif defined _SOFT_FLOAT
 348 ppc_fp_type=soft
 349 #elif defined _SOFT_DOUBLE
 350 ppc_fp_type=e500v1
 351 #elif defined __NO_FPRS__
 352 ppc_fp_type=e500v2
 353 #else
 354 ppc_fp_type=hard
 355 #endif
 356 EOF
 357 eval `${CC-cc} -E conftest.c | grep ppc_fp_type=`
 358 rm -f conftest.c
 359 # glibc 2.19 and later provide all the soft-fp functions, with proper
 360 # interactions with <fenv.h> exception and rounding mode handling, so
 361 # make libgcc's versions into compat symbols if a recent enough glibc
 362 # version is being used.
 363 ppc_fp_compat=
 364 case ${ppc_fp_type} in
 365 soft|e500v1|e500v2)
 366   if test $glibc_version_major -gt 2 \
 367     || ( test $glibc_version_major -eq 2 \
 368         && test $glibc_version_minor -ge 19 ); then
 369     ppc_fp_compat="t-softfp-compat"
 370   fi
 371   ;;
 372 esac
 373 ;;
 374 esac
 375
 376 # Collect host-machine-specific information.
 377 . ${srcdir}/config.host
 378
 379 # Used for constructing correct paths for offload compilers.
 380 accel_dir_suffix=
 381 real_host_noncanonical=${host_noncanonical}
 382 if test x"$enable_as_accelerator_for" != x; then
 383   accel_dir_suffix=/accel/${target_noncanonical}
 384   real_host_noncanonical=${enable_as_accelerator_for}
 385 fi
 386 AC_SUBST(accel_dir_suffix)
 387 AC_SUBST(real_host_noncanonical)
 388
 389 if test x"$enable_offload_targets" != x; then
 390   extra_parts="${extra_parts} crtoffloadbegin.o crtoffloadend.o"
 391 fi
 392
 393 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 394 # This is after config.host so we can augment tmake_file.
 395 # Link with -nostartfiles -nodefaultlibs since neither are present while
 396 # building libgcc.
 397 case ${host} in
 398 i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 399   cat > conftest.s <<EOF
 400         .section        .eh_frame,"a",@unwind
 401         .zero   4
 402         .section        .jcr,"aw",@progbits
 403         .zero   8
 404 EOF
 405   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 406       tmake_file="${tmake_file} i386/t-crtstuff"
 407   fi
 408   ;;
 409 esac
 410
 411 # Check if xtensa target is configured for windowed ABI and thus needs to use
 412 # custom unwind code.
 413 # This is after config.host so we can augment tmake_file.
 414 case ${host} in
 415 xtensa*-*)
 416   cat > conftest.c <<EOF
 417         #ifdef __XTENSA_CALL0_ABI__
 418         #error
 419         #endif
 420 EOF
 421   if AC_TRY_COMMAND(${CC-cc} -E -o conftest.i conftest.c 1>&AS_MESSAGE_LOG_FD); then
 422       tmake_file="${tmake_file} xtensa/t-windowed"
 423   fi
 424   ;;
 425 esac
 426
 427 # Check for visibility support.  This is after config.host so that
 428 # we can check for asm_hidden_op.
 429 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 430     libgcc_cv_hidden_visibility_attribute, [
 431         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 432         libgcc_cv_hidden_visibility_attribute=no
 433         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 434             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 435                 libgcc_cv_hidden_visibility_attribute=yes
 436             fi
 437         fi
 438         rm -f conftest.*
 439     ])
 440
 441 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 442     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 443 else
 444     vis_hide=
 445 fi
 446 AC_SUBST(vis_hide)
 447
 448 # See if we have thread-local storage.  We can only test assembler
 449 # since link-time and run-time tests require the newly built
 450 # gcc, which can't be used to build executable due to that libgcc
 451 # is yet to be built here.
 452 GCC_CHECK_CC_TLS
 453 set_have_cc_tls=
 454 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 455   set_have_cc_tls="-DHAVE_CC_TLS"
 456 fi
 457 AC_SUBST(set_have_cc_tls)
 458
 459 # See if we have emulated thread-local storage.
 460 GCC_CHECK_EMUTLS
 461 set_use_emutls=
 462 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 463   set_use_emutls="-DUSE_EMUTLS"
 464 fi
 465 AC_SUBST(set_use_emutls)
 466
 467 AC_CACHE_CHECK(for init priority support, libgcc_cv_init_priority, [
 468 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,
 469   [[void ip (void) __attribute__ ((constructor (1)));]])],
 470   [libgcc_cv_init_priority=yes],[libgcc_cv_init_priority=no])])
 471 if test $libgcc_cv_init_priority = yes; then
 472   AC_DEFINE(HAVE_INIT_PRIORITY, 1,
 473   [Define if the compiler supports init priority.])
 474 fi
 475
 476 # Conditionalize the sfp-machine.h header for this target machine.
 477 if test -z "${sfp_machine_header}"; then
 478         sfp_machine_header=$cpu_type/sfp-machine.h
 479         if test -f ${srcdir}/config/${sfp_machine_header}; then
 480                 :
 481         else
 482                 sfp_machine_header=no-sfp-machine.h
 483         fi
 484 fi
 485 AC_SUBST(sfp_machine_header)
 486
 487 # Conditionalize the makefile for this target machine.
 488 tmake_file_=
 489 for f in ${tmake_file}
 490 do
 491         if test -f ${srcdir}/config/$f
 492         then
 493                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 494         fi
 495 done
 496 tmake_file="${tmake_file_}"
 497 AC_SUBST(tmake_file)
 498
 499 # Likewise export definitions for libgcc_tm.h
 500 tm_file_=
 501 for f in ${tm_file}
 502 do
 503         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 504 done
 505 tm_file="${tm_file_}"
 506 AC_SUBST(tm_file)
 507 AC_SUBST(tm_defines)
 508
 509 # Map from thread model to thread header.
 510 GCC_AC_THREAD_HEADER([$target_thread_file])
 511
 512 # Substitute configuration variables
 513 AC_SUBST(cpu_type)
 514 AC_SUBST(extra_parts)
 515 AC_SUBST(asm_hidden_op)
 516 AC_CONFIG_LINKS([enable-execute-stack.c:$enable_execute_stack])
 517 AC_CONFIG_LINKS([unwind.h:$unwind_header])
 518 AC_CONFIG_LINKS([md-unwind-support.h:config/$md_unwind_header])
 519 AC_CONFIG_LINKS([sfp-machine.h:config/$sfp_machine_header])
 520 AC_CONFIG_LINKS([gthr-default.h:$thread_header])
 521
 522 # We need multilib support.
 523 AC_CONFIG_FILES([Makefile])
 524 AC_CONFIG_COMMANDS([default],
 525   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 526 if test -n "$CONFIG_FILES"; then
 527   # FIXME: We shouldn't need to set ac_file
 528   ac_file=Makefile
 529   . ${libgcc_topdir}/config-ml.in
 530 fi]],
 531 [[srcdir=${srcdir}
 532 host=${host}
 533 with_target_subdir=${with_target_subdir}
 534 with_multisubdir=${with_multisubdir}
 535 ac_configure_args="--enable-multilib ${ac_configure_args}"
 536 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 537 libgcc_topdir=${libgcc_topdir}
 538 CC="${CC}"
 539 ]])
 540 AC_OUTPUT