libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  27   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  28 ])
  29
  30 dnl
  31 dnl Initialize the rest of the library configury.  At this point we have
  32 dnl variables like $host.
  33 dnl
  34 dnl Sets:
  35 dnl  gcc_version          (x.y.z format)
  36 dnl  SUBDIRS
  37 dnl Substs:
  38 dnl  glibcxx_builddir     (absolute path)
  39 dnl  glibcxx_srcdir       (absolute path)
  40 dnl  toplevel_srcdir      (absolute path)
  41 dnl  with_cross_host
  42 dnl  with_newlib
  43 dnl  with_target_subdir
  44 dnl plus
  45 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  46 dnl  - default settings for all AM_CONFITIONAL test variables
  47 dnl  - lots of tools, like CC and CXX
  48 dnl
  49 AC_DEFUN([GLIBCXX_CONFIGURE], [
  50   # Keep these sync'd with the list in Makefile.am.  The first provides an
  51   # expandable list at autoconf time; the second provides an expandable list
  52   # (i.e., shell variable) at configure time.
  53   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  54   SUBDIRS='glibcxx_SUBDIRS'
  55
  56   # These need to be absolute paths, yet at the same time need to
  57   # canonicalize only relative paths, because then amd will not unmount
  58   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  59   glibcxx_builddir=`${PWDCMD-pwd}`
  60   case $srcdir in
  61     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  62     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  63   esac
  64   toplevel_srcdir=${glibcxx_srcdir}/..
  65   AC_SUBST(glibcxx_builddir)
  66   AC_SUBST(glibcxx_srcdir)
  67   AC_SUBST(toplevel_srcdir)
  68
  69   # We use these options to decide which functions to include.  They are
  70   # set from the top level.
  71   AC_ARG_WITH([target-subdir],
  72     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  73                    [configuring in a subdirectory]))
  74
  75   AC_ARG_WITH([cross-host],
  76     AC_HELP_STRING([--with-cross-host=HOST],
  77                    [configuring with a cross compiler]))
  78
  79   AC_ARG_WITH([newlib],
  80     AC_HELP_STRING([--with-newlib],
  81                    [assume newlib as a system C library]))
  82
  83   # We're almost certainly being configured before anything else which uses
  84   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
  85   # we not cache the value of CXX that we "discover" here, because it's set
  86   # to something unique for us and libjava.  Other target libraries need to
  87   # find CXX for themselves.  We yank the rug out from under the normal AC_*
  88   # process by sneakily renaming the cache variable.  This also lets us debug
  89   # the value of "our" CXX in postmortems.
  90   #
  91   # We must also force CXX to /not/ be a precious variable, otherwise the
  92   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
  93   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
  94   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
  95   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
  96   #
  97   # -fno-builtin must be present here so that a non-conflicting form of
  98   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  99
 100   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103   save_CXXFLAGS="$CXXFLAGS"
 104   CXXFLAGS="$CXXFLAGS -fno-builtin"
 105   AC_PROG_CC
 106   AC_PROG_CXX
 107   CXXFLAGS="$save_CXXFLAGS"
 108   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109   AC_SUBST(CFLAGS)
 110   AC_SUBST(CXXFLAGS)
 111
 112   # For directory versioning (e.g., headers) and other variables.
 113   AC_MSG_CHECKING([for GCC version number])
 114   gcc_version=`$CXX -dumpversion`
 115   AC_MSG_RESULT($gcc_version)
 116
 117   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 118   # available).  Uncomment the next line to force a particular method.
 119   AC_PROG_LN_S
 120   #LN_S='cp -p'
 121
 122   AC_CHECK_TOOL(AS, as)
 123   AC_CHECK_TOOL(AR, ar)
 124   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 125
 126   AM_MAINTAINER_MODE
 127
 128   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 129   # which are themselves conditionally expanded.
 130   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 131   ## other macros from doing the same.  This should be automated.)  -pme
 132   need_libmath=no
 133   enable_wchar_t=no
 134   #enable_libstdcxx_debug=no
 135   #enable_libstdcxx_pch=no
 136   #enable_cheaders=c
 137   #c_compatibility=no
 138   #enable_abi_check=no
 139   #enable_symvers=no
 140   #enable_hosted_libstdcxx=yes
 141
 142   # Find platform-specific directories containing configuration info.
 143   # Also possibly modify flags used elsewhere, as needed by the platform.
 144   GLIBCXX_CHECK_HOST
 145 ])
 146
 147
 148 m4_include([linkage.m4])
 149 m4_include([../config/no-executables.m4])
 150
 151
 152 dnl
 153 dnl Tests for newer compiler features, or features that are present in newer
 154 dnl compiler versions but not older compiler versions still in use, should
 155 dnl be placed here.
 156 dnl
 157 dnl Defines:
 158 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 159 dnl   new inlining code or the new system_header pragma will die on -Werror.
 160 dnl   Leave it out by default and use maint-mode to use it.
 161 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 162 dnl   compiler supports it and the user has not requested debug mode.
 163 dnl
 164 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 165   # All these tests are for C++; save the language and the compiler flags.
 166   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 167   # found in GLIBCXX_CONFIGURE.
 168   AC_LANG_SAVE
 169   AC_LANG_CPLUSPLUS
 170   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 171   ac_save_CXXFLAGS="$CXXFLAGS"
 172
 173   # Check for maintainer-mode bits.
 174   if test x"$USE_MAINTAINER_MODE" = xno; then
 175     WERROR=''
 176   else
 177     WERROR='-Werror'
 178   fi
 179
 180   # Check for -ffunction-sections -fdata-sections
 181   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 182   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 183   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 184   if test "$ac_test_CXXFLAGS" = set; then
 185     CXXFLAGS="$ac_save_CXXFLAGS"
 186   else
 187     # this is the suspicious part
 188     CXXFLAGS=''
 189   fi
 190   if test x"$ac_fdsections" = x"yes"; then
 191     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 192   fi
 193   AC_MSG_RESULT($ac_fdsections)
 194
 195   AC_LANG_RESTORE
 196   AC_SUBST(WERROR)
 197   AC_SUBST(SECTION_FLAGS)
 198 ])
 199
 200
 201 dnl
 202 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 203 dnl the native linker is in use, all variables will be defined to something
 204 dnl safe (like an empty string).
 205 dnl
 206 dnl Defines:
 207 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 208 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 209 dnl  LD (as a side effect of testing)
 210 dnl Sets:
 211 dnl  with_gnu_ld
 212 dnl  glibcxx_gnu_ld_version (possibly)
 213 dnl
 214 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 215 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 216 dnl
 217 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 218   # If we're not using GNU ld, then there's no point in even trying these
 219   # tests.  Check for that first.  We should have already tested for gld
 220   # by now (in libtool), but require it now just to be safe...
 221   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 222   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 223   AC_REQUIRE([AC_PROG_LD])
 224   AC_REQUIRE([AC_PROG_AWK])
 225
 226   # The name set by libtool depends on the version of libtool.  Shame on us
 227   # for depending on an impl detail, but c'est la vie.  Older versions used
 228   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 229   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 230   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 231   # set (hence we're using an older libtool), then set it.
 232   if test x${with_gnu_ld+set} != xset; then
 233     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 234       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 235       with_gnu_ld=no
 236     else
 237       with_gnu_ld=$ac_cv_prog_gnu_ld
 238     fi
 239   fi
 240
 241   # Start by getting the version number.  I think the libtool test already
 242   # does some of this, but throws away the result.
 243   changequote(,)
 244   ldver=`$LD --version 2>/dev/null | head -1 | \
 245          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 246   changequote([,])
 247   glibcxx_gnu_ld_version=`echo $ldver | \
 248          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 249
 250   # Set --gc-sections.
 251   if test "$with_gnu_ld" = "notbroken"; then
 252     # GNU ld it is!  Joy and bunny rabbits!
 253
 254     # All these tests are for C++; save the language and the compiler flags.
 255     # Need to do this so that g++ won't try to link in libstdc++
 256     ac_test_CFLAGS="${CFLAGS+set}"
 257     ac_save_CFLAGS="$CFLAGS"
 258     CFLAGS='-x c++  -Wl,--gc-sections'
 259
 260     # Check for -Wl,--gc-sections
 261     # XXX This test is broken at the moment, as symbols required for linking
 262     # are now in libsupc++ (not built yet).  In addition, this test has
 263     # cored on solaris in the past.  In addition, --gc-sections doesn't
 264     # really work at the moment (keeps on discarding used sections, first
 265     # .eh_frame and now some of the glibc sections for iconv).
 266     # Bzzzzt.  Thanks for playing, maybe next time.
 267     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 268     AC_TRY_RUN([
 269      int main(void)
 270      {
 271        try { throw 1; }
 272        catch (...) { };
 273        return 0;
 274      }
 275     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 276     if test "$ac_test_CFLAGS" = set; then
 277       CFLAGS="$ac_save_CFLAGS"
 278     else
 279       # this is the suspicious part
 280       CFLAGS=''
 281     fi
 282     if test "$ac_sectionLDflags" = "yes"; then
 283       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 284     fi
 285     AC_MSG_RESULT($ac_sectionLDflags)
 286   fi
 287
 288   # Set linker optimization flags.
 289   if test x"$with_gnu_ld" = x"yes"; then
 290     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 291   fi
 292
 293   AC_SUBST(SECTION_LDFLAGS)
 294   AC_SUBST(OPT_LDFLAGS)
 295 ])
 296
 297
 298 dnl
 299 dnl Check to see if this target can enable the wchar_t parts.
 300 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 301 dnl must have been previously checked.)  By default, wide characters are
 302 dnl disabled.
 303 dnl
 304 dnl Defines:
 305 dnl  HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 306 dnl  _GLIBCXX_USE_WCHAR_T if all the bits are found.
 307 dnl Substs:
 308 dnl  LIBICONV to a -l string containing the iconv library, if needed.
 309 dnl
 310 AC_DEFUN([GLIBCXX_CHECK_WCHAR_T_SUPPORT], [
 311   # Test wchar.h for mbstate_t, which is needed for char_traits and
 312   # others even if wchar_t support is not on.
 313   AC_MSG_CHECKING([for mbstate_t])
 314   AC_TRY_COMPILE([#include <wchar.h>],
 315   [mbstate_t teststate;],
 316   have_mbstate_t=yes, have_mbstate_t=no)
 317   AC_MSG_RESULT($have_mbstate_t)
 318   if test x"$have_mbstate_t" = xyes; then
 319     AC_DEFINE(HAVE_MBSTATE_T)
 320   fi
 321
 322   # Sanity check for existence of ISO C99 headers for extended encoding.
 323   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 324   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 325
 326   # Only continue checking if the ISO C99 headers exist and support is on.
 327   if test x"$ac_has_wchar_h" = xyes &&
 328      test x"$ac_has_wctype_h" = xyes &&
 329      test x"$enable_c_mbchar" != xno; then
 330
 331     # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 332     # numeric_limits can instantiate type_traits<wchar_t>
 333     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 334     AC_TRY_COMPILE([#include <wchar.h>],
 335     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 336     has_wchar_minmax=yes, has_wchar_minmax=no)
 337     AC_MSG_RESULT($has_wchar_minmax)
 338
 339     # Test wchar.h for WEOF, which is what we use to determine whether
 340     # to specialize for char_traits<wchar_t> or not.
 341     AC_MSG_CHECKING([for WEOF])
 342     AC_TRY_COMPILE([
 343       #include <wchar.h>
 344       #include <stddef.h>],
 345     [wint_t i = WEOF;],
 346     has_weof=yes, has_weof=no)
 347     AC_MSG_RESULT($has_weof)
 348
 349     # Tests for wide character functions used in char_traits<wchar_t>.
 350     ac_wfuncs=yes
 351     AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
 352     [],[ac_wfuncs=no])
 353
 354     # Checks for names injected into std:: by the c_std headers.
 355     AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
 356     fwprintf fwscanf swprintf swscanf vfwprintf vswprintf \
 357     vwprintf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 358     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstol \
 359     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 360     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
 361     [],[ac_wfuncs=no])
 362
 363     # Checks for wide character functions that are not required
 364     # for basic wchar_t support.  Don't disable support if they are missing.
 365     # Injection of these is wrapped with guard macros.
 366     AC_CHECK_FUNCS([vfwscanf vswscanf vwscanf wcstof iswblank],[],[])
 367
 368     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 369     if test x"$has_weof" = xyes &&
 370        test x"$has_wchar_minmax" = xyes &&
 371        test x"$ac_wfuncs" = xyes;
 372     then
 373       ac_isoC99_wchar_t=yes
 374     else
 375       ac_isoC99_wchar_t=no
 376     fi
 377     AC_MSG_RESULT($ac_isoC99_wchar_t)
 378
 379     # Use iconv for wchar_t to char conversions. As such, check for
 380     # X/Open Portability Guide, version 2 features (XPG2).
 381     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 382     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 383
 384     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 385     AC_CHECK_LIB(iconv, iconv, LIBICONV="-liconv")
 386     ac_save_LIBS="$LIBS"
 387     LIBS="$LIBS $LIBICONV"
 388     AC_SUBST(LIBICONV)
 389
 390     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 391     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 392
 393     LIBS="$ac_save_LIBS"
 394
 395     AC_MSG_CHECKING([for XPG2 wchar_t support])
 396     if test x"$ac_has_iconv_h" = xyes &&
 397        test x"$ac_has_langinfo_h" = xyes &&
 398        test x"$ac_XPG2funcs" = xyes;
 399     then
 400       ac_XPG2_wchar_t=yes
 401     else
 402       ac_XPG2_wchar_t=no
 403     fi
 404     AC_MSG_RESULT($ac_XPG2_wchar_t)
 405
 406     # At the moment, only enable wchar_t specializations if all the
 407     # above support is present.
 408     if test x"$ac_isoC99_wchar_t" = xyes &&
 409        test x"$ac_XPG2_wchar_t" = xyes;
 410     then
 411       AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
 412       enable_wchar_t=yes
 413     fi
 414   fi
 415   AC_MSG_CHECKING([for enabled wchar_t specializations])
 416   AC_MSG_RESULT($enable_wchar_t)
 417 ])
 418
 419
 420 dnl
 421 dnl Check for headers for, and arguments to, the setrlimit() function.
 422 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 423 dnl
 424 dnl Defines:
 425 dnl  _GLIBCXX_RES_LIMITS if we can set artificial resource limits
 426 dnl  various HAVE_LIMIT_* for individual limit names
 427 dnl
 428 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 429   AC_TRY_COMPILE(
 430     [#include <unistd.h>
 431      #include <sys/time.h>
 432      #include <sys/resource.h>
 433     ],
 434     [ int f = RLIMIT_$1 ; ],
 435     [glibcxx_mresult=1], [glibcxx_mresult=0])
 436   AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
 437                      [Only used in build directory testsuite_hooks.h.])
 438 ])
 439
 440 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 441   setrlimit_have_headers=yes
 442   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 443                    [],
 444                    [setrlimit_have_headers=no])
 445   # If don't have the headers, then we can't run the tests now, and we
 446   # won't be seeing any of these during testsuite compilation.
 447   if test $setrlimit_have_headers = yes; then
 448     # Can't do these in a loop, else the resulting syntax is wrong.
 449     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 450     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 451     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 452     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 453     GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
 454
 455     # Check for rlimit, setrlimit.
 456     AC_CACHE_VAL(ac_setrlimit, [
 457       AC_TRY_COMPILE(
 458         [#include <unistd.h>
 459          #include <sys/time.h>
 460          #include <sys/resource.h>
 461         ],
 462         [struct rlimit r;
 463          setrlimit(0, &r);],
 464         [ac_setrlimit=yes], [ac_setrlimit=no])
 465     ])
 466   fi
 467
 468   AC_MSG_CHECKING([for testsuite resource limits support])
 469   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 470     ac_res_limits=yes
 471     AC_DEFINE(_GLIBCXX_RES_LIMITS)
 472   else
 473     ac_res_limits=no
 474   fi
 475   AC_MSG_RESULT($ac_res_limits)
 476 ])
 477
 478
 479 dnl
 480 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 481 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 482 dnl
 483 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 484   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 485     AC_TRY_LINK(
 486       [#include <sys/stat.h>],
 487       [struct stat buffer;
 488        fstat(0, &buffer);
 489        S_ISREG(buffer.st_mode);],
 490       [glibcxx_cv_S_ISREG=yes],
 491       [glibcxx_cv_S_ISREG=no])
 492   ])
 493   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 494     AC_TRY_LINK(
 495       [#include <sys/stat.h>],
 496       [struct stat buffer;
 497        fstat(0, &buffer);
 498        S_IFREG & buffer.st_mode;],
 499       [glibcxx_cv_S_IFREG=yes],
 500       [glibcxx_cv_S_IFREG=no])
 501   ])
 502   if test $glibcxx_cv_S_ISREG = yes; then
 503     AC_DEFINE(HAVE_S_ISREG)
 504   elif test $glibcxx_cv_S_IFREG = yes; then
 505     AC_DEFINE(HAVE_S_IFREG)
 506   fi
 507 ])
 508
 509
 510 dnl
 511 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 512 dnl
 513 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 514   AC_CACHE_VAL(glibcxx_cv_POLL, [
 515     AC_TRY_LINK(
 516       [#include <poll.h>],
 517       [struct pollfd pfd[1];
 518        pfd[0].events = POLLIN;
 519        poll(pfd, 1, 0);],
 520       [glibcxx_cv_POLL=yes],
 521       [glibcxx_cv_POLL=no])
 522   ])
 523   if test $glibcxx_cv_POLL = yes; then
 524     AC_DEFINE(HAVE_POLL)
 525   fi
 526 ])
 527
 528
 529 dnl
 530 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 531 dnl
 532 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 533   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 534     AC_TRY_LINK(
 535       [#include <sys/uio.h>],
 536       [struct iovec iov[2];
 537        writev(0, iov, 0);],
 538       [glibcxx_cv_WRITEV=yes],
 539       [glibcxx_cv_WRITEV=no])
 540   ])
 541   if test $glibcxx_cv_WRITEV = yes; then
 542     AC_DEFINE(HAVE_WRITEV)
 543   fi
 544 ])
 545
 546
 547 dnl
 548 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 549 dnl
 550 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 551   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 552     AC_TRY_COMPILE(
 553       [#include <stdint.h>],
 554       [int64_t var;],
 555       [glibcxx_cv_INT64_T=yes],
 556       [glibcxx_cv_INT64_T=no])
 557   ])
 558   if test $glibcxx_cv_INT64_T = yes; then
 559     AC_DEFINE(HAVE_INT64_T)
 560   fi
 561 ])
 562
 563
 564 dnl
 565 dnl Check whether LFS support is available.
 566 dnl
 567 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 568   AC_LANG_SAVE
 569   AC_LANG_CPLUSPLUS
 570   ac_save_CXXFLAGS="$CXXFLAGS"
 571   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 572   AC_CACHE_VAL(glibcxx_cv_LFS, [
 573     AC_TRY_LINK(
 574       [#include <unistd.h>
 575        #include <stdio.h>
 576        #include <sys/stat.h>
 577       ],
 578       [FILE* fp;
 579        fopen64("t", "w");
 580        fseeko64(fp, 0, SEEK_CUR);
 581        ftello64(fp);
 582        lseek64(1, 0, SEEK_CUR);
 583        struct stat64 buf;
 584        fstat64(1, &buf);],
 585       [glibcxx_cv_LFS=yes],
 586       [glibcxx_cv_LFS=no])
 587   ])
 588   if test $glibcxx_cv_LFS = yes; then
 589     AC_DEFINE(_GLIBCXX_USE_LFS)
 590   fi
 591   CXXFLAGS="$ac_save_CXXFLAGS"
 592   AC_LANG_RESTORE
 593 ])
 594
 595
 596 dnl
 597 dnl Check for whether a fully dynamic basic_string implementation should
 598 dnl be turned on, that does not put empty objects in per-process static
 599 dnl memory (mostly useful together with shared memory allocators, see PR
 600 dnl libstdc++/16612 for details).
 601 dnl
 602 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING
 603 dnl --disable-fully-dynamic-string leaves _GLIBCXX_FULLY_DYNAMIC_STRING undefined
 604 dnl  +  Usage:  GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
 605 dnl       Where DEFAULT is either `yes' or `no'.
 606 dnl
 607 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
 608   GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
 609   if test $enable_fully_dynamic_string = yes; then
 610     AC_DEFINE(_GLIBCXX_FULLY_DYNAMIC_STRING)
 611   fi
 612 ])
 613
 614
 615 dnl
 616 dnl Does any necessary configuration of the testsuite directory.  Generates
 617 dnl the testsuite_hooks.h header.
 618 dnl
 619 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 620 dnl
 621 dnl Sets:
 622 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 623 dnl Substs:
 624 dnl  baseline_dir
 625 dnl
 626 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 627   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
 628     # Do checks for resource limit functions.
 629     GLIBCXX_CHECK_SETRLIMIT
 630
 631     # Look for setenv, so that extended locale tests can be performed.
 632     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 633
 634     if test $enable_symvers = no; then
 635       enable_abi_check=no
 636     else
 637       case "$host" in
 638         *-*-cygwin*)
 639           enable_abi_check=no ;;
 640         *)
 641           enable_abi_check=yes ;;
 642       esac
 643     fi
 644   else
 645     # Only build this as native, since automake does not understand
 646     # CXX_FOR_BUILD.
 647     enable_abi_check=no
 648   fi
 649
 650   # Export file names for ABI checking.
 651   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 652   AC_SUBST(baseline_dir)
 653
 654   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 655   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 656 ])
 657
 658
 659 dnl
 660 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 661 dnl
 662 dnl Substs:
 663 dnl  GLIBCXX_INCLUDES
 664 dnl  TOPLEVEL_INCLUDES
 665 dnl
 666 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 667   # Used for every C++ compile we perform.
 668   GLIBCXX_INCLUDES="\
 669 -I$glibcxx_builddir/include/$host_alias \
 670 -I$glibcxx_builddir/include \
 671 -I$glibcxx_srcdir/libsupc++"
 672
 673   # For Canadian crosses, pick this up too.
 674   if test $CANADIAN = yes; then
 675     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 676   fi
 677
 678   # Stuff in the actual top level.  Currently only used by libsupc++ to
 679   # get unwind* headers from the gcc dir.
 680   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 681   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 682
 683   # Now, export this to all the little Makefiles....
 684   AC_SUBST(GLIBCXX_INCLUDES)
 685   AC_SUBST(TOPLEVEL_INCLUDES)
 686 ])
 687
 688
 689 dnl
 690 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 691 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 692 dnl
 693 dnl Substs:
 694 dnl  OPTIMIZE_CXXFLAGS
 695 dnl  WARN_FLAGS
 696 dnl
 697 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 698   # Optimization flags that are probably a good idea for thrill-seekers. Just
 699   # uncomment the lines below and make, everything else is ready to go...
 700   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 701   OPTIMIZE_CXXFLAGS=
 702   AC_SUBST(OPTIMIZE_CXXFLAGS)
 703
 704   WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
 705   AC_SUBST(WARN_FLAGS)
 706 ])
 707
 708
 709 dnl
 710 dnl All installation directory information is determined here.
 711 dnl
 712 dnl Substs:
 713 dnl  gxx_install_dir
 714 dnl  glibcxx_prefixdir
 715 dnl  glibcxx_toolexecdir
 716 dnl  glibcxx_toolexeclibdir
 717 dnl
 718 dnl Assumes cross_compiling bits already done, and with_cross_host in
 719 dnl particular.
 720 dnl
 721 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 722   glibcxx_toolexecdir=no
 723   glibcxx_toolexeclibdir=no
 724   glibcxx_prefixdir=$prefix
 725
 726   AC_MSG_CHECKING([for gxx-include-dir])
 727   AC_ARG_WITH([gxx-include-dir],
 728     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 729                    [installation directory for include files]),
 730     [case "$withval" in
 731       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 732       no)  gxx_include_dir=no ;;
 733       *)   gxx_include_dir=$withval ;;
 734      esac],
 735     [gxx_include_dir=no])
 736   AC_MSG_RESULT($gxx_include_dir)
 737
 738   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 739   AC_ARG_ENABLE([version-specific-runtime-libs],
 740     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 741                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 742     [case "$enableval" in
 743       yes) version_specific_libs=yes ;;
 744       no)  version_specific_libs=no ;;
 745       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 746      esac],
 747     [version_specific_libs=no])
 748   AC_MSG_RESULT($version_specific_libs)
 749
 750   # Default case for install directory for include files.
 751   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 752     gxx_include_dir='${prefix}'/include/c++/${gcc_version}
 753   fi
 754
 755   # Version-specific runtime libs processing.
 756   if test $version_specific_libs = yes; then
 757     # Need the gcc compiler version to know where to install libraries
 758     # and header files if --enable-version-specific-runtime-libs option
 759     # is selected.  FIXME: these variables are misnamed, there are
 760     # no executables installed in _toolexecdir or _toolexeclibdir.
 761     if test x"$gxx_include_dir" = x"no"; then
 762       gxx_include_dir='${libdir}/gcc/${host_alias}/'$gcc_version/include/c++
 763     fi
 764     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 765     glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
 766   fi
 767
 768   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 769   # Install a library built with a cross compiler in tooldir, not libdir.
 770   if test x"$glibcxx_toolexecdir" = x"no"; then
 771     if test -n "$with_cross_host" &&
 772        test x"$with_cross_host" != x"no"; then
 773       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 774       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 775     else
 776       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 777       glibcxx_toolexeclibdir='${libdir}'
 778     fi
 779     multi_os_directory=`$CXX -print-multi-os-directory`
 780     case $multi_os_directory in
 781       .) ;; # Avoid trailing /.
 782       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 783     esac
 784   fi
 785
 786   AC_MSG_CHECKING([for install location])
 787   AC_MSG_RESULT($gxx_include_dir)
 788
 789   AC_SUBST(glibcxx_prefixdir)
 790   AC_SUBST(gxx_include_dir)
 791   AC_SUBST(glibcxx_toolexecdir)
 792   AC_SUBST(glibcxx_toolexeclibdir)
 793 ])
 794
 795
 796 dnl
 797 dnl GLIBCXX_ENABLE
 798 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 799 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 800 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 801 dnl
 802 dnl See docs/html/17_intro/configury.html#enable for documentation.
 803 dnl
 804 m4_define([GLIBCXX_ENABLE],[dnl
 805 m4_define([_g_switch],[--enable-$1])dnl
 806 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 807  AC_ARG_ENABLE($1,_g_help,
 808   m4_bmatch([$5],
 809    [^permit ],
 810      [[
 811       case "$enableval" in
 812        m4_bpatsubst([$5],[permit ])) ;;
 813        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 814           dnl Idea for future:  generate a URL pointing to
 815           dnl "onlinedocs/configopts.html#whatever"
 816       esac
 817      ]],
 818    [^$],
 819      [[
 820       case "$enableval" in
 821        yes|no) ;;
 822        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 823       esac
 824      ]],
 825    [[$5]]),
 826   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 827 m4_undefine([_g_switch])dnl
 828 m4_undefine([_g_help])dnl
 829 ])
 830
 831
 832 dnl
 833 dnl Check for ISO/IEC 9899:1999 "C99" support.
 834 dnl
 835 dnl --enable-c99 defines _GLIBCXX_USE_C99
 836 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 837 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 838 dnl       Where DEFAULT is either `yes' or `no'.
 839 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 840 dnl
 841 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 842   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 843
 844   AC_LANG_SAVE
 845   AC_LANG_CPLUSPLUS
 846
 847   # Check for the existence of <math.h> functions used if C99 is enabled.
 848   ac_c99_math=yes;
 849   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 850   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
 851   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
 852   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
 853   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
 854   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
 855   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
 856   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
 857   AC_TRY_COMPILE([#include <math.h>],
 858                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
 859   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
 860   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
 861   AC_TRY_COMPILE([#include <math.h>],
 862                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
 863   AC_TRY_COMPILE([#include <math.h>],
 864                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
 865   AC_MSG_RESULT($ac_c99_math)
 866
 867   if test x"$ac_c99_math" = x"yes"; then
 868     AC_DEFINE(_GLIBCXX_USE_C99_MATH)
 869   fi
 870
 871   # Check for the existence in <stdio.h> of vscanf, et. al.
 872   ac_c99_stdio=yes;
 873   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 874   AC_TRY_COMPILE([#include <stdio.h>],
 875                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
 876   AC_TRY_COMPILE([#include <stdio.h>
 877                   #include <stdarg.h>
 878                   void foo(char* fmt, ...)
 879                   {va_list args; va_start(args, fmt);
 880                   vfscanf(stderr, "%i", args);}],
 881                   [],, [ac_c99_stdio=no])
 882   AC_TRY_COMPILE([#include <stdio.h>
 883                   #include <stdarg.h>
 884                   void foo(char* fmt, ...)
 885                   {va_list args; va_start(args, fmt);
 886                   vscanf("%i", args);}],
 887                   [],, [ac_c99_stdio=no])
 888   AC_TRY_COMPILE([#include <stdio.h>
 889                   #include <stdarg.h>
 890                   void foo(char* fmt, ...)
 891                   {va_list args; va_start(args, fmt);
 892                   vsnprintf(fmt, 0, "%i", args);}],
 893                   [],, [ac_c99_stdio=no])
 894   AC_TRY_COMPILE([#include <stdio.h>
 895                   #include <stdarg.h>
 896                   void foo(char* fmt, ...)
 897                   {va_list args; va_start(args, fmt);
 898                   vsscanf(fmt, "%i", args);}],
 899                   [],, [ac_c99_stdio=no])
 900   AC_MSG_RESULT($ac_c99_stdio)
 901
 902   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 903   ac_c99_stdlib=yes;
 904   AC_MSG_CHECKING([for lldiv_t declaration])
 905   AC_CACHE_VAL(ac_c99_lldiv_t, [
 906   AC_TRY_COMPILE([#include <stdlib.h>],
 907                    [ lldiv_t mydivt;],
 908                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
 909   ])
 910   AC_MSG_RESULT($ac_c99_lldiv_t)
 911
 912   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 913   AC_TRY_COMPILE([#include <stdlib.h>],
 914                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
 915   AC_TRY_COMPILE([#include <stdlib.h>],
 916                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
 917   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
 918   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
 919   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
 920   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
 921   if test x"$ac_c99_lldiv_t" = x"no"; then
 922     ac_c99_stdlib=no;
 923   fi;
 924   AC_MSG_RESULT($ac_c99_stdlib)
 925
 926   # Check for the existence of <wchar.h> functions used if C99 is enabled.
 927   # XXX the wchar.h checks should be rolled into the general C99 bits.
 928   ac_c99_wchar=yes;
 929   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
 930   AC_TRY_COMPILE([#include <wchar.h>],
 931                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
 932   AC_TRY_COMPILE([#include <wchar.h>],
 933                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
 934   AC_TRY_COMPILE([#include <wchar.h>],
 935                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
 936   AC_MSG_RESULT($ac_c99_wchar)
 937
 938   AC_MSG_CHECKING([for enabled ISO C99 support])
 939   if test x"$ac_c99_math" = x"no" ||
 940      test x"$ac_c99_stdio" = x"no" ||
 941      test x"$ac_c99_stdlib" = x"no" ||
 942      test x"$ac_c99_wchar" = x"no"; then
 943     enable_c99=no;
 944   fi;
 945   AC_MSG_RESULT($enable_c99)
 946
 947   if test x"$ac_99_math" = x"yes"; then
 948     AC_DEFINE(_GLIBCXX_USE_C99_MATH)
 949   fi
 950
 951   # Option parsed, now set things appropriately
 952   if test x"$enable_c99" = x"yes"; then
 953     AC_DEFINE(_GLIBCXX_USE_C99)
 954   fi
 955
 956   AC_LANG_RESTORE
 957 ])
 958
 959
 960 dnl
 961 dnl Check for what type of C headers to use.
 962 dnl
 963 dnl --enable-cheaders= [does stuff].
 964 dnl --disable-cheaders [does not do anything, really].
 965 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
 966 dnl       Where DEFAULT is either `c' or `c_std'.
 967 dnl
 968 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
 969   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
 970     [construct "C" headers for g++], [permit c|c_std])
 971   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
 972
 973   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
 974
 975   AC_SUBST(C_INCLUDE_DIR)
 976   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
 977   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
 978   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
 979 ])
 980
 981
 982 dnl
 983 dnl Check for which locale library to use.  The choice is mapped to
 984 dnl a subdirectory of config/locale.
 985 dnl
 986 dnl Default is generic.
 987 dnl
 988 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
 989   AC_MSG_CHECKING([for C locale to use])
 990   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
 991     [use MODEL for target locale package],
 992     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
 993
 994   # If they didn't use this option switch, or if they specified --enable
 995   # with no specific model, we'll have to look for one.  If they
 996   # specified --disable (???), do likewise.
 997   if test $enable_clocale = no || test $enable_clocale = yes; then
 998      enable_clocale=auto
 999   fi
1000
1001   # Either a known package, or "auto"
1002   enable_clocale_flag=$enable_clocale
1003
1004   # Probe for locale support if no specific model is specified.
1005   # Default to "generic".
1006   if test $enable_clocale_flag = auto; then
1007     case ${target_os} in
1008       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1009         AC_EGREP_CPP([_GLIBCXX_ok], [
1010         #include <features.h>
1011         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1012           _GLIBCXX_ok
1013         #endif
1014         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1015
1016         # Test for bugs early in glibc-2.2.x series
1017           if test $enable_clocale_flag = gnu; then
1018           AC_TRY_RUN([
1019           #define _GNU_SOURCE 1
1020           #include <locale.h>
1021           #include <string.h>
1022           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1023           extern __typeof(newlocale) __newlocale;
1024           extern __typeof(duplocale) __duplocale;
1025           extern __typeof(strcoll_l) __strcoll_l;
1026           #endif
1027           int main()
1028           {
1029               const char __one[] = "Äuglein Augmen";
1030               const char __two[] = "Äuglein";
1031               int i;
1032               int j;
1033               __locale_t        loc;
1034                __locale_t        loc_dup;
1035               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1036               loc_dup = __duplocale(loc);
1037               i = __strcoll_l(__one, __two, loc);
1038               j = __strcoll_l(__one, __two, loc_dup);
1039               return 0;
1040           }
1041           ],
1042           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1043           [enable_clocale_flag=generic])
1044           fi
1045
1046         # ... at some point put __strxfrm_l tests in as well.
1047         ;;
1048       *)
1049         enable_clocale_flag=generic
1050         ;;
1051     esac
1052   fi
1053
1054   # Deal with gettext issues.  Default to not using it (=no) until we detect
1055   # support for it later.  Let the user turn it off via --e/d, but let that
1056   # default to on for easier handling.
1057   USE_NLS=no
1058   AC_ARG_ENABLE(nls,
1059     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1060     [],
1061     [enable_nls=yes])
1062
1063   # Set configure bits for specified locale package
1064   case ${enable_clocale_flag} in
1065     generic)
1066       AC_MSG_RESULT(generic)
1067
1068       CLOCALE_H=config/locale/generic/c_locale.h
1069       CLOCALE_CC=config/locale/generic/c_locale.cc
1070       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1071       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1072       CCOLLATE_CC=config/locale/generic/collate_members.cc
1073       CCTYPE_CC=config/locale/generic/ctype_members.cc
1074       CMESSAGES_H=config/locale/generic/messages_members.h
1075       CMESSAGES_CC=config/locale/generic/messages_members.cc
1076       CMONEY_CC=config/locale/generic/monetary_members.cc
1077       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1078       CTIME_H=config/locale/generic/time_members.h
1079       CTIME_CC=config/locale/generic/time_members.cc
1080       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1081       ;;
1082     gnu)
1083       AC_MSG_RESULT(gnu)
1084
1085       # Declare intention to use gettext, and add support for specific
1086       # languages.
1087       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1088       ALL_LINGUAS="de fr"
1089
1090       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1091       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1092       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1093         USE_NLS=yes
1094       fi
1095       # Export the build objects.
1096       for ling in $ALL_LINGUAS; do \
1097         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1098         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1099       done
1100       AC_SUBST(glibcxx_MOFILES)
1101       AC_SUBST(glibcxx_POFILES)
1102
1103       CLOCALE_H=config/locale/gnu/c_locale.h
1104       CLOCALE_CC=config/locale/gnu/c_locale.cc
1105       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1106       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1107       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1108       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1109       CMESSAGES_H=config/locale/gnu/messages_members.h
1110       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1111       CMONEY_CC=config/locale/gnu/monetary_members.cc
1112       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1113       CTIME_H=config/locale/gnu/time_members.h
1114       CTIME_CC=config/locale/gnu/time_members.cc
1115       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1116       ;;
1117     ieee_1003.1-2001)
1118       AC_MSG_RESULT(IEEE 1003.1)
1119
1120       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1121       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1122       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1123       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1124       CCOLLATE_CC=config/locale/generic/collate_members.cc
1125       CCTYPE_CC=config/locale/generic/ctype_members.cc
1126       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1127       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1128       CMONEY_CC=config/locale/generic/monetary_members.cc
1129       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1130       CTIME_H=config/locale/generic/time_members.h
1131       CTIME_CC=config/locale/generic/time_members.cc
1132       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1133       ;;
1134   esac
1135
1136   # This is where the testsuite looks for locale catalogs, using the
1137   # -DLOCALEDIR define during testsuite compilation.
1138   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1139   AC_SUBST(glibcxx_localedir)
1140
1141   # A standalone libintl (e.g., GNU libintl) may be in use.
1142   if test $USE_NLS = yes; then
1143     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1144     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1145   fi
1146   if test $USE_NLS = yes; then
1147     AC_DEFINE(_GLIBCXX_USE_NLS)
1148   fi
1149
1150   AC_SUBST(USE_NLS)
1151   AC_SUBST(CLOCALE_H)
1152   AC_SUBST(CCODECVT_H)
1153   AC_SUBST(CMESSAGES_H)
1154   AC_SUBST(CCODECVT_CC)
1155   AC_SUBST(CCOLLATE_CC)
1156   AC_SUBST(CCTYPE_CC)
1157   AC_SUBST(CMESSAGES_CC)
1158   AC_SUBST(CMONEY_CC)
1159   AC_SUBST(CNUMERIC_CC)
1160   AC_SUBST(CTIME_H)
1161   AC_SUBST(CTIME_CC)
1162   AC_SUBST(CLOCALE_CC)
1163   AC_SUBST(CLOCALE_INTERNAL_H)
1164 ])
1165
1166
1167 dnl
1168 dnl Check for which std::allocator base class to use.  The choice is
1169 dnl mapped from a subdirectory of include/ext.
1170 dnl
1171 dnl Default is new.
1172 dnl
1173 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
1174   AC_MSG_CHECKING([for std::allocator base class to use])
1175   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[=KIND],
1176     [use KIND for target std::allocator base],
1177     [permit new|malloc|mt|bitmap|pool|yes|no|auto])
1178
1179   # If they didn't use this option switch, or if they specified --enable
1180   # with no specific model, we'll have to look for one.  If they
1181   # specified --disable (???), do likewise.
1182   if test $enable_libstdcxx_allocator = no ||
1183      test $enable_libstdcxx_allocator = yes;
1184   then
1185      enable_libstdcxx_allocator=auto
1186   fi
1187
1188   # Either a known package, or "auto". Auto implies the default choice
1189   # for a particular platform.
1190   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
1191
1192   # Probe for host-specific support if no specific model is specified.
1193   # Default to "new".
1194   if test $enable_libstdcxx_allocator_flag = auto; then
1195     case ${target_os} in
1196       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1197         enable_libstdcxx_allocator_flag=mt
1198         ;;
1199       *)
1200         enable_libstdcxx_allocator_flag=new
1201         ;;
1202     esac
1203   fi
1204   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
1205
1206
1207   # Set configure bits for specified locale package
1208   case ${enable_libstdcxx_allocator_flag} in
1209     bitmap)
1210       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
1211       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
1212       ;;
1213     malloc)
1214       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
1215       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
1216       ;;
1217     mt)
1218       ALLOCATOR_H=config/allocator/mt_allocator_base.h
1219       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
1220       ;;
1221     new)
1222       ALLOCATOR_H=config/allocator/new_allocator_base.h
1223       ALLOCATOR_NAME=__gnu_cxx::new_allocator
1224       ;;
1225     pool)
1226       ALLOCATOR_H=config/allocator/pool_allocator_base.h
1227       ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
1228       ;;
1229   esac
1230
1231   AC_SUBST(ALLOCATOR_H)
1232   AC_SUBST(ALLOCATOR_NAME)
1233 ])
1234
1235
1236 dnl
1237 dnl Check for whether the Boost-derived checks should be turned on.
1238 dnl
1239 dnl --enable-concept-checks turns them on.
1240 dnl --disable-concept-checks leaves them off.
1241 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1242 dnl       Where DEFAULT is either `yes' or `no'.
1243 dnl
1244 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
1245   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1246   if test $enable_concept_checks = yes; then
1247     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1248   fi
1249 ])
1250
1251
1252 dnl
1253 dnl Check for which I/O library to use:  stdio, or something specific.
1254 dnl
1255 dnl Default is stdio.
1256 dnl
1257 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
1258   AC_MSG_CHECKING([for underlying I/O to use])
1259   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1260     [use target-specific I/O package], [permit stdio])
1261
1262   # Now that libio has been removed, you can have any color you want as long
1263   # as it's black.  This is one big no-op until other packages are added, but
1264   # showing the framework never hurts.
1265   case ${enable_cstdio} in
1266     stdio)
1267       CSTDIO_H=config/io/c_io_stdio.h
1268       BASIC_FILE_H=config/io/basic_file_stdio.h
1269       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1270       AC_MSG_RESULT(stdio)
1271       ;;
1272   esac
1273
1274   AC_SUBST(CSTDIO_H)
1275   AC_SUBST(BASIC_FILE_H)
1276   AC_SUBST(BASIC_FILE_CC)
1277 ])
1278
1279
1280 dnl
1281 dnl Check for "unusual" flags to pass to the compiler while building.
1282 dnl
1283 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1284 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1285 dnl --disable-cxx-flags passes nothing.
1286 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1287 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1288 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1289 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1290 dnl       If "default flags" is an empty string, the effect is the same
1291 dnl       as --disable or --enable=no.
1292 dnl
1293 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
1294   AC_MSG_CHECKING([for extra compiler flags for building])
1295   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1296     [pass compiler FLAGS when building library],
1297     [case "x$enable_cxx_flags" in
1298       xno | x)   enable_cxx_flags= ;;
1299       x-*)       ;;
1300       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1301      esac])
1302
1303   # Run through flags (either default or command-line) and set anything
1304   # extra (e.g., #defines) that must accompany particular g++ options.
1305   if test -n "$enable_cxx_flags"; then
1306     for f in $enable_cxx_flags; do
1307       case "$f" in
1308         -fhonor-std)  ;;
1309         -*)  ;;
1310         *)   # and we're trying to pass /what/ exactly?
1311              AC_MSG_ERROR([compiler flags start with a -]) ;;
1312       esac
1313     done
1314   fi
1315
1316   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1317   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1318   AC_SUBST(EXTRA_CXX_FLAGS)
1319 ])
1320
1321
1322 dnl
1323 dnl Check for wide character support.  Has the same effect as the option
1324 dnl in gcc's configure, but in a form that autoconf can mess with.
1325 dnl
1326 dnl --enable-c-mbchar requests all the wchar_t stuff.
1327 dnl --disable-c-mbchar doesn't.
1328 dnl  +  Usage:  GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1329 dnl       Where DEFAULT is either `yes' or `no'.
1330 dnl
1331 AC_DEFUN([GLIBCXX_ENABLE_C_MBCHAR], [
1332   GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1333   # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1334 ])
1335
1336
1337 dnl
1338 dnl Check to see if debugging libraries are to be built.
1339 dnl
1340 dnl --enable-libstdcxx-debug
1341 dnl builds a separate set of debugging libraries in addition to the
1342 dnl normal (shared, static) libstdc++ binaries.
1343 dnl
1344 dnl --disable-libstdcxx-debug
1345 dnl builds only one (non-debug) version of libstdc++.
1346 dnl
1347 dnl --enable-libstdcxx-debug-flags=FLAGS
1348 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1349 dnl
1350 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1351 dnl       Where DEFAULT is either `yes' or `no'.
1352 dnl
1353 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
1354   AC_MSG_CHECKING([for additional debug build])
1355   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1356   AC_MSG_RESULT($enable_libstdcxx_debug)
1357   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1358 ])
1359
1360
1361 dnl
1362 dnl Check for explicit debug flags.
1363 dnl
1364 dnl --enable-libstdcxx-debug-flags='-O1'
1365 dnl is a general method for passing flags to be used when
1366 dnl building debug libraries with --enable-debug.
1367 dnl
1368 dnl --disable-libstdcxx-debug-flags does nothing.
1369 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1370 dnl       If "default flags" is an empty string, the effect is the same
1371 dnl       as --disable or --enable=no.
1372 dnl
1373 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
1374   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1375     [pass compiler FLAGS when building debug library],
1376     [case "x$enable_libstdcxx_debug_flags" in
1377       xno | x)    enable_libstdcxx_debug_flags= ;;
1378       x-*)        ;;
1379       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1380      esac])
1381
1382   # Option parsed, now set things appropriately
1383   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1384   AC_SUBST(DEBUG_FLAGS)
1385
1386   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1387 ])
1388
1389
1390 dnl
1391 dnl Check if the user only wants a freestanding library implementation.
1392 dnl
1393 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1394 dnl installing only the headers required by [17.4.1.3] and the language
1395 dnl support library.  More than that will be built (to keep the Makefiles
1396 dnl conveniently clean), but not installed.
1397 dnl
1398 dnl Sets:
1399 dnl  is_hosted  (yes/no)
1400 dnl
1401 dnl Defines:
1402 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1403 dnl
1404 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
1405   AC_ARG_ENABLE([hosted-libstdcxx],
1406     AC_HELP_STRING([--disable-hosted-libstdcxx],
1407                    [only build freestanding C++ runtime support]),,
1408     [case "$host" in
1409         arm*-*-symbianelf*)
1410             enable_hosted_libstdcxx=no
1411             ;;
1412         *)
1413             enable_hosted_libstdcxx=yes
1414             ;;
1415      esac])
1416   if test "$enable_hosted_libstdcxx" = no; then
1417     AC_MSG_NOTICE([Only freestanding libraries will be built])
1418     is_hosted=no
1419     hosted_define=0
1420     enable_abi_check=no
1421     enable_libstdcxx_pch=no
1422   else
1423     is_hosted=yes
1424     hosted_define=1
1425   fi
1426   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1427   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1428     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1429 ])
1430
1431
1432 dnl
1433 dnl Check for template specializations for the 'long long' type extension.
1434 dnl The result determines only whether 'long long' I/O is enabled; things
1435 dnl like numeric_limits<> specializations are always available.
1436 dnl
1437 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1438 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1439 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1440 dnl       Where DEFAULT is either `yes' or `no'.
1441 dnl
1442 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
1443   GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1444   if test $enable_long_long = yes; then
1445     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1446   fi
1447 ])
1448
1449
1450 dnl
1451 dnl Check to see if building and using a C++ precompiled header can be done.
1452 dnl
1453 dnl --enable-libstdcxx-pch=yes
1454 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1455 dnl may work, after some light-hearted attempts to puzzle out compiler
1456 dnl support, flip bits on in include/Makefile.am
1457 dnl
1458 dnl --disable-libstdcxx-pch
1459 dnl turns off attempts to use or build stdc++.h.gch.
1460 dnl
1461 dnl Substs:
1462 dnl  glibcxx_PCHFLAGS
1463 dnl
1464 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
1465   AC_MSG_CHECKING([for enabled PCH])
1466   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1467   AC_MSG_RESULT([$enable_libstdcxx_pch])
1468
1469   if test $enable_libstdcxx_pch = yes; then
1470     AC_CACHE_CHECK([for compiler with PCH support],
1471       [glibcxx_cv_prog_CXX_pch],
1472       [ac_save_CXXFLAGS="$CXXFLAGS"
1473        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1474        AC_LANG_SAVE
1475        AC_LANG_CPLUSPLUS
1476        echo '#include <math.h>' > conftest.h
1477        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1478                           -o conftest.h.gch 1>&5 2>&1 &&
1479                 echo '#error "pch failed"' > conftest.h &&
1480           echo '#include "conftest.h"' > conftest.cc &&
1481                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1482        then
1483          glibcxx_cv_prog_CXX_pch=yes
1484        else
1485          glibcxx_cv_prog_CXX_pch=no
1486        fi
1487        rm -f conftest*
1488        CXXFLAGS=$ac_save_CXXFLAGS
1489        AC_LANG_RESTORE
1490       ])
1491     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1492   fi
1493
1494   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1495   if test $enable_libstdcxx_pch = yes; then
1496     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1497   else
1498     glibcxx_PCHFLAGS=""
1499   fi
1500   AC_SUBST(glibcxx_PCHFLAGS)
1501 ])
1502
1503
1504 dnl
1505 dnl Check for exception handling support.  If an explicit enable/disable
1506 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1507 dnl target may or may not support call frame exceptions.
1508 dnl
1509 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1510 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1511 dnl Neither one forces an attempt at detection.
1512 dnl
1513 dnl Defines:
1514 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1515 dnl
1516 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
1517   AC_MSG_CHECKING([for exception model to use])
1518   AC_LANG_SAVE
1519   AC_LANG_CPLUSPLUS
1520   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1521     [force use of builtin_setjmp for exceptions],
1522     [permit yes|no|auto])
1523
1524   if test $enable_sjlj_exceptions = auto; then
1525     # Botheration.  Now we've got to detect the exception model.  Link tests
1526     # against libgcc.a are problematic since we've not been given proper -L
1527     # bits for single-tree newlib and libgloss.
1528     #
1529     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1530     cat > conftest.$ac_ext << EOF
1531 [#]line __oline__ "configure"
1532 struct S { ~S(); };
1533 void bar();
1534 void foo()
1535 {
1536   S s;
1537   bar();
1538 }
1539 EOF
1540     old_CXXFLAGS="$CXXFLAGS"
1541     CXXFLAGS=-S
1542     if AC_TRY_EVAL(ac_compile); then
1543       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1544         enable_sjlj_exceptions=yes
1545       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1546         enable_sjlj_exceptions=no
1547       fi
1548     fi
1549     CXXFLAGS="$old_CXXFLAGS"
1550     rm -f conftest*
1551   fi
1552
1553   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1554   # to two different models.
1555   case $enable_sjlj_exceptions in
1556     yes)
1557       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1558         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1559       ac_exception_model_name=sjlj
1560       ;;
1561     no)
1562       ac_exception_model_name="call frame"
1563       ;;
1564     *)
1565       AC_MSG_ERROR([unable to detect exception model])
1566       ;;
1567   esac
1568  AC_LANG_RESTORE
1569  AC_MSG_RESULT($ac_exception_model_name)
1570 ])
1571
1572
1573 dnl
1574 dnl Add version tags to symbols in shared library (or not), additionally
1575 dnl marking other symbols as private/local (or not).
1576 dnl
1577 dnl --enable-symvers=style adds a version script to the linker call when
1578 dnl       creating the shared library.  The choice of version script is
1579 dnl       controlled by 'style'.
1580 dnl --disable-symvers does not.
1581 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1582 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1583 dnl       choose a default style based on linker characteristics.  Passing
1584 dnl       'no' disables versioning.
1585 dnl
1586 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
1587
1588 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1589   [enables symbol versioning of the shared library],
1590   [permit yes|no|gnu])
1591
1592 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1593 # don't know enough about $LD to do tricks...
1594 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1595 # FIXME  The following test is too strict, in theory.
1596 if test $enable_shared = no ||
1597         test "x$LD" = x ||
1598         test x$glibcxx_gnu_ld_version = x; then
1599   enable_symvers=no
1600 fi
1601
1602 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1603 if test $enable_symvers != no; then
1604   AC_MSG_CHECKING([for shared libgcc])
1605   ac_save_CFLAGS="$CFLAGS"
1606   CFLAGS=' -lgcc_s'
1607   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1608   CFLAGS="$ac_save_CFLAGS"
1609   if test $glibcxx_shared_libgcc = no; then
1610     cat > conftest.c <<EOF
1611 int main (void) { return 0; }
1612 EOF
1613 changequote(,)dnl
1614     glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1615                              -shared -shared-libgcc -o conftest.so \
1616                              conftest.c -v 2>&1 >/dev/null \
1617                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1618 changequote([,])dnl
1619     rm -f conftest.c conftest.so
1620     if test x${glibcxx_libgcc_s_suffix+set} = xset; then
1621       CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
1622       AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
1623       CFLAGS="$ac_save_CFLAGS"
1624     fi
1625   fi
1626   AC_MSG_RESULT($glibcxx_shared_libgcc)
1627 fi
1628
1629 # For GNU ld, we need at least this version.  The format is described in
1630 # GLIBCXX_CHECK_LINKER_FEATURES above.
1631 glibcxx_min_gnu_ld_version=21400
1632 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1633
1634 # Check to see if unspecified "yes" value can win, given results above.
1635 # Change "yes" into either "no" or a style name.
1636 if test $enable_symvers = yes; then
1637   if test $with_gnu_ld = yes &&
1638      test $glibcxx_shared_libgcc = yes;
1639   then
1640     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1641       enable_symvers=gnu
1642     else
1643       # The right tools, the right setup, but too old.  Fallbacks?
1644       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1645       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1646       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1647       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1648       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1649         # Globbing fix is present, proper block support is not.
1650         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1651         dnl enable_symvers=???
1652         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1653         enable_symvers=no
1654       else
1655         # 2.11 or older.
1656         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1657         enable_symvers=no
1658       fi
1659     fi
1660   else
1661     # just fail for now
1662     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1663     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1664     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1665     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1666     enable_symvers=no
1667   fi
1668 fi
1669
1670 # Everything parsed; figure out what file to use.
1671 case $enable_symvers in
1672   no)
1673     SYMVER_MAP=config/linker-map.dummy
1674     ;;
1675   gnu)
1676     SYMVER_MAP=config/linker-map.gnu
1677     AC_DEFINE(_GLIBCXX_SYMVER)
1678     ;;
1679 esac
1680
1681 AC_SUBST(SYMVER_MAP)
1682 AC_SUBST(port_specific_symbol_files)
1683 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1684 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1685 ])
1686
1687
1688 dnl
1689 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1690 dnl We must stage the required headers so that they will be installed
1691 dnl with the library (unlike libgcc, the STL implementation is provided
1692 dnl solely within headers).  Since we must not inject random user-space
1693 dnl macro names into user-provided C++ code, we first stage into <file>-in
1694 dnl and process to <file> with an output command.  The reason for a two-
1695 dnl stage process here is to correctly handle $srcdir!=$objdir without
1696 dnl having to write complex code (the sed commands to clean the macro
1697 dnl namespace are complex and fragile enough as it is).  We must also
1698 dnl add a relative path so that -I- is supported properly.
1699 dnl
1700 dnl Substs:
1701 dnl  glibcxx_thread_h
1702 dnl
1703 dnl Defines:
1704 dnl  HAVE_GTHR_DEFAULT
1705 dnl
1706 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
1707   AC_MSG_CHECKING([for thread model used by GCC])
1708   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1709   AC_MSG_RESULT([$target_thread_file])
1710
1711   if test $target_thread_file != single; then
1712     AC_DEFINE(HAVE_GTHR_DEFAULT)
1713   fi
1714
1715   glibcxx_thread_h=gthr-$target_thread_file.h
1716   AC_SUBST(glibcxx_thread_h)
1717 ])
1718
1719
1720 # Check whether LC_MESSAGES is available in <locale.h>.
1721 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1722 #
1723 # This file file be copied and used freely without restrictions.  It can
1724 # be used in projects which are not available under the GNU Public License
1725 # but which still want to provide support for the GNU gettext functionality.
1726 # Please note that the actual code is *not* freely available.
1727
1728 # serial 1
1729 AC_DEFUN([AC_LC_MESSAGES], [
1730   AC_CHECK_HEADER(locale.h, [
1731     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1732       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1733        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1734     if test $ac_cv_val_LC_MESSAGES = yes; then
1735       AC_DEFINE(HAVE_LC_MESSAGES)
1736     fi
1737   ])
1738 ])
1739
1740
1741 sinclude([../libtool.m4])
1742 dnl The lines below arrange for aclocal not to bring an installed
1743 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1744 dnl add a definition of LIBTOOL to Makefile.in.
1745 ifelse(,,,[AC_SUBST(LIBTOOL)
1746 AC_DEFUN([AM_PROG_LIBTOOL])
1747 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1748 AC_DEFUN([AC_PROG_LD])
1749 ])
1750
1751 dnl vim:et:ts=2:sw=2