libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=7:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  54                                       [turns on -Werror @<:@default=yes@:>@])])
  55 if test "x$enable_werror" != "xno"; then
  56   WERROR="-Werror"
  57 fi
  58 AC_SUBST(WERROR)
  59
  60 glibgo_toolexecdir=no
  61 glibgo_toolexeclibdir=no
  62
  63 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  64 AC_ARG_ENABLE([version-specific-runtime-libs],
  65   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  67   [case "$enableval" in
  68     yes) version_specific_libs=yes ;;
  69     no)  version_specific_libs=no ;;
  70     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71    esac],
  72   [version_specific_libs=no])
  73 AC_MSG_RESULT($version_specific_libs)
  74
  75 # Version-specific runtime libs processing.
  76 if test $version_specific_libs = yes; then
  77   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  78   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  79 fi
  80
  81 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  82 # Install a library built with a cross compiler in tooldir, not libdir.
  83 if test -n "$with_cross_host" &&
  84    test x"$with_cross_host" != x"no"; then
  85   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  86   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  87 else
  88   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  89   nover_glibgo_toolexeclibdir='${libdir}'
  90 fi
  91 multi_os_directory=`$GOC -print-multi-os-directory`
  92 case $multi_os_directory in
  93   .) ;; # Avoid trailing /.
  94   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
  95 esac
  96
  97 if test x"$glibgo_toolexecdir" = x"no"; then
  98   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
  99   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 100 fi
 101
 102 AC_SUBST(glibgo_toolexecdir)
 103 AC_SUBST(glibgo_toolexeclibdir)
 104 AC_SUBST(nover_glibgo_toolexeclibdir)
 105
 106 # See if the user wants to configure without libffi.  Some
 107 # architectures don't support it.  FIXME: We should set a default
 108 # based on the host.
 109 AC_ARG_WITH(libffi,
 110   AS_HELP_STRING([--without-libffi],
 111                  [don't use libffi]),
 112   [:],
 113   [with_libffi=${with_libffi_default-yes}])
 114
 115 LIBFFI=
 116 LIBFFIINCS=
 117 if test "$with_libffi" != no; then
 118    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 119    LIBFFI=../libffi/libffi_convenience.la
 120    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 121 fi
 122 AC_SUBST(LIBFFI)
 123 AC_SUBST(LIBFFIINCS)
 124
 125 # See if the user wants to configure without libatomic. This is useful if we are
 126 # on an architecture for which libgo does not need an atomic support library and
 127 # libatomic does not support our C compiler.
 128 AC_ARG_WITH(libatomic,
 129   AS_HELP_STRING([--without-libatomic],
 130                  [don't use libatomic]),
 131   [:],
 132   [with_libatomic=${with_libatomic_default-yes}])
 133
 134 LIBATOMIC=
 135 if test "$with_libatomic" != no; then
 136    LIBATOMIC=../libatomic/libatomic_convenience.la
 137 fi
 138 AC_SUBST(LIBATOMIC)
 139
 140 # Used to tell GNU make to include a file without telling automake to
 141 # include it.
 142 go_include="-include"
 143 AC_SUBST(go_include)
 144
 145 is_darwin=no
 146 is_freebsd=no
 147 is_irix=no
 148 is_linux=no
 149 is_netbsd=no
 150 is_openbsd=no
 151 is_dragonfly=no
 152 is_rtems=no
 153 is_solaris=no
 154 GOOS=unknown
 155 case ${host} in
 156   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 157   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 158   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 159   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 160   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 161   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 162   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 163   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 164   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 165 esac
 166 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 167 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 168 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 169 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 170 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 171 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 172 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 173 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 174 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 175 AC_SUBST(GOOS)
 176
 177 dnl Test whether we need to use DejaGNU or whether we can use the
 178 dnl simpler gotest approach.  We can only use gotest for a native
 179 dnl build.
 180 USE_DEJAGNU=no
 181 case ${host} in
 182   *-*-rtems*) USE_DEJAGNU=yes ;;
 183   ${build}) ;;
 184   *) USE_DEJAGNU=yes ;;
 185 esac
 186 AC_SUBST(USE_DEJAGNU)
 187
 188 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 189 is_386=no
 190 is_alpha=no
 191 is_arm=no
 192 is_arm64=no
 193 is_m68k=no
 194 mips_abi=unknown
 195 is_ppc=no
 196 is_ppc64=no
 197 is_ppc64le=no
 198 is_s390=no
 199 is_s390x=no
 200 is_sparc=no
 201 is_sparc64=no
 202 is_x86_64=no
 203 GOARCH=unknown
 204 case ${host} in
 205   alpha*-*-*)
 206     is_alpha=yes
 207     GOARCH=alpha
 208     ;;
 209   aarch64-*-*)
 210     is_arm64=yes
 211     GOARCH=arm64
 212     ;;
 213   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 214     is_arm=yes
 215     GOARCH=arm
 216     ;;
 217 changequote(,)dnl
 218   i[34567]86-*-* | x86_64-*-*)
 219 changequote([,])dnl
 220     AC_COMPILE_IFELSE([
 221 #ifdef __x86_64__
 222 #error 64-bit
 223 #endif],
 224 [is_386=yes], [is_x86_64=yes])
 225     if test "$is_386" = "yes"; then
 226       GOARCH=386
 227     else
 228       GOARCH=amd64
 229     fi
 230     ;;
 231   m68k*-*-*)
 232     is_m68k=yes
 233     GOARCH=m68k
 234     ;;
 235   mips*-*-*)
 236     AC_COMPILE_IFELSE([
 237 #if _MIPS_SIM != _ABIO32
 238 #error not o32
 239 #endif],
 240 [mips_abi="o32"],
 241         [AC_COMPILE_IFELSE([
 242 #if _MIPS_SIM != _ABIN32
 243 #error not n32
 244 #endif],
 245 [mips_abi="n32"],
 246         [AC_COMPILE_IFELSE([
 247 #if _MIPS_SIM != _ABI64
 248 #error not n64
 249 #endif],
 250 [mips_abi="n64"],
 251         [AC_COMPILE_IFELSE([
 252 #if _MIPS_SIM != _ABIO64
 253 #error not o64
 254 #endif],
 255 [mips_abi="o64"],
 256         [AC_MSG_ERROR([unknown MIPS ABI])
 257 [mips_abi="n32"]])])])])
 258     case "$mips_abi" in
 259     "o32") GOARCH=mipso32 ;;
 260     "n32") GOARCH=mipsn32 ;;
 261     "n64") GOARCH=mipsn64 ;;
 262     "o64") GOARCH=mipso64 ;;
 263     esac
 264     ;;
 265   rs6000*-*-* | powerpc*-*-*)
 266     AC_COMPILE_IFELSE([
 267 #ifdef _ARCH_PPC64
 268 #error 64-bit
 269 #endif],
 270 [is_ppc=yes],
 271     [AC_COMPILE_IFELSE([
 272 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 273 #error 64be
 274 #endif],
 275 [is_ppc64le=yes],[is_ppc64=yes])])
 276     if test "$is_ppc" = "yes"; then
 277       GOARCH=ppc
 278     elif test "$is_ppc64" = "yes"; then
 279       GOARCH=ppc64
 280     else
 281       GOARCH=ppc64le
 282     fi
 283     ;;
 284   s390*-*-*)
 285     AC_COMPILE_IFELSE([
 286 #if defined(__s390x__)
 287 #error 64-bit
 288 #endif],
 289 [is_s390=yes], [is_s390x=yes])
 290     if test "$is_s390" = "yes"; then
 291       GOARCH=s390
 292     else
 293       GOARCH=s390x
 294     fi
 295     ;;
 296   sparc*-*-*)
 297     AC_COMPILE_IFELSE([
 298 #if defined(__sparcv9) || defined(__arch64__)
 299 #error 64-bit
 300 #endif],
 301 [is_sparc=yes], [is_sparc64=yes])
 302     if test "$is_sparc" = "yes"; then
 303       GOARCH=sparc
 304     else
 305       GOARCH=sparc64
 306     fi
 307     ;;
 308 esac
 309 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 310 AM_CONDITIONAL(LIBGO_IS_ALPHA, test $is_alpha = yes)
 311 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 312 AM_CONDITIONAL(LIBGO_IS_ARM64, test $is_arm64 = yes)
 313 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 314 AM_CONDITIONAL(LIBGO_IS_MIPS, test $mips_abi != unknown)
 315 AM_CONDITIONAL(LIBGO_IS_MIPSO32, test $mips_abi = o32)
 316 AM_CONDITIONAL(LIBGO_IS_MIPSN32, test $mips_abi = n32)
 317 AM_CONDITIONAL(LIBGO_IS_MIPSN64, test $mips_abi = n64)
 318 AM_CONDITIONAL(LIBGO_IS_MIPSO64, test $mips_abi = o64)
 319 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 320 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 321 AM_CONDITIONAL(LIBGO_IS_PPC64LE, test $is_ppc64le = yes)
 322 AM_CONDITIONAL(LIBGO_IS_S390, test $is_s390 = yes)
 323 AM_CONDITIONAL(LIBGO_IS_S390X, test $is_s390x = yes)
 324 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 325 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 326 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 327 AC_SUBST(GOARCH)
 328
 329 dnl Some files are only present when needed for specific architectures.
 330 GO_LIBCALL_OS_FILE=
 331 GO_LIBCALL_OS_ARCH_FILE=
 332 GO_SYSCALL_OS_FILE=
 333 GO_SYSCALL_OS_ARCH_FILE=
 334 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 335   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 336 fi
 337 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 338   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 339 fi
 340 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 341   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 342 fi
 343 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 344   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 345 fi
 346 AC_SUBST(GO_LIBCALL_OS_FILE)
 347 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 348 AC_SUBST(GO_SYSCALL_OS_FILE)
 349 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 350
 351 dnl Special flags used to generate sysinfo.go.
 352 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 353 case "$target" in
 354     mips-sgi-irix6.5*)
 355         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 356         # msghdr in <sys/socket.h>.
 357         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 358         ;;
 359     *-*-solaris2.1[[01]])
 360         # Solaris 10+ needs this so struct msghdr gets the msg_control
 361         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 362         # above doesn't work with C99.
 363         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 364         ;;
 365 esac
 366 AC_SUBST(OSCFLAGS)
 367
 368 dnl Use -fsplit-stack when compiling C code if available.
 369 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 370 [libgo_cv_c_split_stack_supported],
 371 [CFLAGS_hold=$CFLAGS
 372 CFLAGS="$CFLAGS -fsplit-stack"
 373 AC_COMPILE_IFELSE([[int i;]],
 374 [libgo_cv_c_split_stack_supported=yes],
 375 [libgo_cv_c_split_stack_supported=no])
 376 CFLAGS=$CFLAGS_hold])
 377 if test "$libgo_cv_c_split_stack_supported" = yes; then
 378   SPLIT_STACK=-fsplit-stack
 379   AC_DEFINE(USING_SPLIT_STACK, 1,
 380                 [Define if the compiler supports -fsplit-stack])
 381 else
 382   SPLIT_STACK=
 383 fi
 384 AC_SUBST(SPLIT_STACK)
 385 AM_CONDITIONAL(USING_SPLIT_STACK,
 386         test "$libgo_cv_c_split_stack_supported" = yes)
 387
 388 dnl Check whether the linker does stack munging when calling from
 389 dnl split-stack into non-split-stack code.  We check this by looking
 390 dnl at the --help output.  FIXME: This is only half right: it's
 391 dnl possible for the linker to support this for some targets but not
 392 dnl others.
 393 AC_CACHE_CHECK([whether linker supports split stack],
 394 [libgo_cv_c_linker_supports_split_stack],
 395 [libgo_cv_c_linker_supports_split_stack=no
 396 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 397   libgo_cv_c_linker_supports_split_stack=yes
 398 fi])
 399 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 400   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 401             [Define if the linker support split stack adjustments])
 402 fi
 403
 404 AC_CACHE_CHECK([whether compiler is llgo],
 405 [libgo_cv_c_goc_is_llgo],
 406 [libgo_cv_c_goc_is_llgo=no
 407 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 408   libgo_cv_c_goc_is_llgo=yes
 409 fi])
 410 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 411
 412 dnl Test for the -lm library.
 413 MATH_LIBS=
 414 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 415 AC_SUBST(MATH_LIBS)
 416
 417 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 418 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 419   [libgo_cv_lib_sockets=
 420    libgo_check_both=no
 421    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 422    if test "$libgo_check_socket" = "yes"; then
 423      unset ac_cv_func_connect
 424      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 425                   libgo_check_both=yes)
 426    fi
 427    if test "$libgo_check_both" = "yes"; then
 428      libgo_old_libs=$LIBS
 429      LIBS="$LIBS -lsocket -lnsl"
 430      unset ac_cv_func_accept
 431      AC_CHECK_FUNC(accept,
 432                    [libgo_check_nsl=no
 433                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 434      unset ac_cv_func_accept
 435      LIBS=$libgo_old_libs
 436    fi
 437    unset ac_cv_func_gethostbyname
 438    libgo_old_libs="$LIBS"
 439    AC_CHECK_FUNC(gethostbyname, ,
 440                  [AC_CHECK_LIB(nsl, main,
 441                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 442    unset ac_cv_func_gethostbyname
 443    LIBS=$libgo_old_libs
 444 ])
 445 NET_LIBS="$libgo_cv_lib_sockets"
 446 AC_SUBST(NET_LIBS)
 447
 448 dnl Test whether the compiler supports the -pthread option.
 449 AC_CACHE_CHECK([whether -pthread is supported],
 450 [libgo_cv_lib_pthread],
 451 [CFLAGS_hold=$CFLAGS
 452 CFLAGS="$CFLAGS -pthread"
 453 AC_COMPILE_IFELSE([[int i;]],
 454 [libgo_cv_lib_pthread=yes],
 455 [libgo_cv_lib_pthread=no])
 456 CFLAGS=$CFLAGS_hold])
 457 PTHREAD_CFLAGS=
 458 if test "$libgo_cv_lib_pthread" = yes; then
 459   PTHREAD_CFLAGS=-pthread
 460 fi
 461 AC_SUBST(PTHREAD_CFLAGS)
 462
 463 dnl Test for the -lpthread library.
 464 PTHREAD_LIBS=
 465 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 466 AC_SUBST(PTHREAD_LIBS)
 467
 468 dnl Test if -lrt is required for sched_yield and/or nanosleep.
 469 AC_SEARCH_LIBS([sched_yield], [rt])
 470 AC_SEARCH_LIBS([nanosleep], [rt])
 471
 472 AC_C_BIGENDIAN
 473
 474 GCC_CHECK_UNWIND_GETIPINFO
 475
 476 AC_CHECK_HEADERS(sched.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/reboot.h netinet/icmp6.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 477
 478 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 479 [#ifdef HAVE_SYS_SOCKET_H
 480 #include <sys/socket.h>
 481 #endif
 482 ])
 483
 484 AC_CACHE_CHECK([whether <ustat.h> can be used],
 485 [libgo_cv_c_ustat_h],
 486 [CFLAGS_hold=$CFLAGS
 487 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 488 AC_COMPILE_IFELSE(
 489 [AC_LANG_SOURCE([
 490 #include <sys/types.h>
 491 #ifdef HAVE_LINUX_FILTER_H
 492 #include <linux/filter.h>
 493 #endif
 494 #include <ustat.h>
 495 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 496 CFLAGS=$CFLAGS_hold])
 497 if test $libgo_cv_c_ustat_h = yes; then
 498   AC_DEFINE(HAVE_USTAT_H, 1,
 499     [Define to 1 if you have the <ustat.h> header file and it works.])
 500 fi
 501
 502 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 503
 504 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr)
 505 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 506 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 507
 508 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice tee unlinkat unshare utimensat)
 509 AC_TYPE_OFF_T
 510 AC_CHECK_TYPES([loff_t])
 511
 512 LIBS_hold="$LIBS"
 513 LIBS="$LIBS -lm"
 514 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 515 LIBS="$LIBS_hold"
 516
 517 CFLAGS_hold="$CFLAGS"
 518 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 519 LIBS_hold="$LIBS"
 520 LIBS="$LIBS $PTHREAD_LIBS"
 521 AC_CHECK_FUNCS(sem_timedwait)
 522 CFLAGS="$CFLAGS_hold"
 523 LIBS="$LIBS_hold"
 524
 525 LIBS_hold="$LIBS"
 526 LIBS="$LIBS $MATH_LIBS"
 527 AC_CHECK_FUNCS(matherr)
 528 LIBS="$LIBS_hold"
 529
 530 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 531 [libgo_cv_func___sync_bool_compare_and_swap_4],
 532 [AC_LINK_IFELSE([
 533 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 534 uint32 i;
 535 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 536 ],
 537 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 538 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 539 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 540   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 541     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 542 fi
 543
 544 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 545 [libgo_cv_func___sync_bool_compare_and_swap_8],
 546 [AC_LINK_IFELSE([
 547 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 548 uint64 i;
 549 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 550 ],
 551 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 552 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 553 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 554   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 555     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 556 fi
 557
 558 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 559 [libgo_cv_func___sync_fetch_and_add_4],
 560 [AC_LINK_IFELSE([
 561 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 562 uint32 i;
 563 int main() { return __sync_fetch_and_add (&i, 1); }
 564 ],
 565 [libgo_cv_func___sync_fetch_and_add_4=yes],
 566 [libgo_cv_func___sync_fetch_and_add_4=no])])
 567 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 568   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 569     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 570 fi
 571
 572 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 573 [libgo_cv_func___sync_add_and_fetch_8],
 574 [AC_LINK_IFELSE([
 575 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 576 uint64 i;
 577 int main() { return __sync_add_and_fetch (&i, 1); }
 578 ],
 579 [libgo_cv_func___sync_add_and_fetch_8=yes],
 580 [libgo_cv_func___sync_add_and_fetch_8=no])])
 581 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 582   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 583     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 584 fi
 585
 586 dnl For x86 we want to use the -minline-all-stringops option to avoid
 587 dnl forcing a stack split when calling memcpy and friends.
 588 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 589 [libgo_cv_c_stringops],
 590 [CFLAGS_hold=$CFLAGS
 591 CFLAGS="$CFLAGS -minline-all-stringops"
 592 AC_COMPILE_IFELSE([int i;],
 593 [libgo_cv_c_stringops=yes],
 594 [libgo_cv_c_stringops=no])
 595 CFLAGS=$CFLAGS_hold])
 596 STRINGOPS_FLAG=
 597 if test "$libgo_cv_c_stringops" = yes; then
 598   STRINGOPS_FLAG=-minline-all-stringops
 599 fi
 600 AC_SUBST(STRINGOPS_FLAG)
 601
 602 dnl For x86 we want to compile the math library with -mfancy-math-387
 603 dnl -funsafe-math-optimizations so that we can use the builtin
 604 dnl instructions directly.
 605 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 606 [libgo_cv_c_fancymath],
 607 [CFLAGS_hold=$CFLAGS
 608 CFLAGS="$CFLAGS -mfancy-math-387"
 609 AC_COMPILE_IFELSE([int i;],
 610 [libgo_cv_c_fancymath=yes],
 611 [libgo_cv_c_fancymath=no])
 612 CFLAGS=$CFLAGS_hold])
 613 MATH_FLAG=
 614 if test "$libgo_cv_c_fancymath" = yes; then
 615   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations"
 616 else
 617   MATH_FLAG="-ffp-contract=off"
 618 fi
 619 AC_SUBST(MATH_FLAG)
 620
 621 CFLAGS_hold=$CFLAGS
 622 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 623 AC_CHECK_TYPES([off64_t])
 624 CFLAGS=$CFLAGS_hold
 625
 626 dnl Work out the size of the epoll_events struct on GNU/Linux.
 627 AC_CACHE_CHECK([epoll_event size],
 628 [libgo_cv_c_epoll_event_size],
 629 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 630 [sizeof (struct epoll_event)],
 631 [#include <sys/epoll.h>],
 632 [libgo_cv_c_epoll_event_size=0])])
 633 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 634 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 635
 636 dnl Work out the offset of the fd field in the epoll_events struct on
 637 dnl GNU/Linux.
 638 AC_CACHE_CHECK([epoll_event data.fd offset],
 639 [libgo_cv_c_epoll_event_fd_offset],
 640 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 641 [offsetof (struct epoll_event, data.fd)],
 642 [#include <stddef.h>
 643 #include <sys/epoll.h>],
 644 [libgo_cv_c_epoll_event_fd_offset=0])])
 645 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 646 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 647
 648 dnl See if struct exception is defined in <math.h>.
 649 AC_CHECK_TYPE([struct exception],
 650 [libgo_has_struct_exception=yes],
 651 [libgo_has_struct_exception=no],
 652 [#include <math.h>])
 653 if test "$libgo_has_struct_exception" = "yes"; then
 654   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 655             [Define to 1 if <math.h> defines struct exception])
 656 fi
 657
 658 dnl See whether setcontext changes the value of TLS variables.
 659 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 660 [libgo_cv_lib_setcontext_clobbers_tls],
 661 [CFLAGS_hold="$CFLAGS"
 662 CFLAGS="$PTHREAD_CFLAGS"
 663 LIBS_hold="$LIBS"
 664 LIBS="$LIBS $PTHREAD_LIBS"
 665 AC_CHECK_SIZEOF([void *])
 666 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 667 AC_RUN_IFELSE(
 668   [AC_LANG_SOURCE([
 669 #include <pthread.h>
 670 #include <stdlib.h>
 671 #include <ucontext.h>
 672 #include <unistd.h>
 673
 674 __thread int tls;
 675
 676 static char stack[[10 * 1024 * 1024]];
 677 static ucontext_t c;
 678
 679 /* Called via makecontext/setcontext.  */
 680
 681 static void
 682 cfn (void)
 683 {
 684   exit (tls);
 685 }
 686
 687 /* Called via pthread_create.  */
 688
 689 static void *
 690 tfn (void *dummy)
 691 {
 692   /* The thread should still see this value after calling
 693      setcontext.  */
 694   tls = 0;
 695
 696   setcontext (&c);
 697
 698   /* The call to setcontext should not return.  */
 699   abort ();
 700 }
 701
 702 int
 703 main ()
 704 {
 705   pthread_t tid;
 706
 707   /* The thread should not see this value.  */
 708   tls = 1;
 709
 710   if (getcontext (&c) < 0)
 711     abort ();
 712
 713   c.uc_stack.ss_sp = stack;
 714 #ifdef MAKECONTEXT_STACK_TOP
 715   c.uc_stack.ss_sp += sizeof stack;
 716 #endif
 717   c.uc_stack.ss_flags = 0;
 718   c.uc_stack.ss_size = sizeof stack;
 719   c.uc_link = NULL;
 720   makecontext (&c, cfn, 0);
 721
 722   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 723     abort ();
 724
 725   if (pthread_join (tid, NULL) != 0)
 726     abort ();
 727
 728   /* The thread should have called exit.  */
 729   abort ();
 730 }
 731 ])],
 732 [libgo_cv_lib_setcontext_clobbers_tls=no],
 733 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 734 [case "$target:$ptr_type_size" in
 735   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 736     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 737   *)
 738     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 739  esac
 740 ])
 741 CFLAGS="$CFLAGS_hold"
 742 LIBS="$LIBS_hold"
 743 ])
 744 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 745   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 746             [Define if setcontext clobbers TLS variables])
 747 fi
 748
 749 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 750 libgo_cv_ro_eh_frame, [
 751 libgo_cv_ro_eh_frame=no
 752 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 753 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 754   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 755     libgo_cv_ro_eh_frame=yes
 756   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 757        | grep -v '#write' > /dev/null; then
 758     libgo_cv_ro_eh_frame=yes
 759   fi
 760 fi
 761 rm -f conftest.*
 762 ])
 763 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 764   AC_DEFINE(EH_FRAME_FLAGS, "a",
 765             [Define to the flags needed for the .section .eh_frame directive.])
 766 else
 767   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 768             [Define to the flags needed for the .section .eh_frame directive.])
 769 fi
 770
 771 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 772 [libgo_cv_c_unused_arguments],
 773 [CFLAGS_hold=$CFLAGS
 774 CFLAGS="$CFLAGS -Qunused-arguments"
 775 AC_COMPILE_IFELSE([[int i;]],
 776 [libgo_cv_c_unused_arguments=yes],
 777 [libgo_cv_c_unused_arguments=no])
 778 CFLAGS=$CFLAGS_hold])
 779
 780 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 781 libgo_cv_as_comdat_gnu, [
 782 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 783 CFLAGS_hold=$CFLAGS
 784 if test "$libgo_cv_c_unused_arguments" = yes; then
 785   CFLAGS="$CFLAGS -Qunused-arguments"
 786 fi
 787 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 788   libgo_cv_as_comdat_gnu=yes
 789 else
 790   libgo_cv_as_comdat_gnu=no
 791 fi
 792 CFLAGS=$CFLAGS_hold
 793 ])
 794 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 795   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 796             [Define if your assembler supports GNU comdat group syntax.])
 797 fi
 798
 799 AC_CACHE_CHECK([assembler supports pc related relocs],
 800 libgo_cv_as_x86_pcrel, [
 801 libgo_cv_as_x86_pcrel=yes
 802 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 803 CFLAGS_hold=$CFLAGS
 804 if test "$libgo_cv_c_unused_arguments" = yes; then
 805   CFLAGS="$CFLAGS -Qunused-arguments"
 806 fi
 807 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 808     libgo_cv_as_x86_pcrel=no
 809 fi
 810 CFLAGS=$CFLAGS_hold
 811 ])
 812 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 813   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 814             [Define if your assembler supports PC relative relocs.])
 815 fi
 816
 817 AC_CACHE_CHECK([assembler supports unwind section type],
 818 libgo_cv_as_x86_64_unwind_section_type, [
 819 libgo_cv_as_x86_64_unwind_section_type=yes
 820 echo '.section .eh_frame,"a",@unwind' > conftest.s
 821 CFLAGS_hold=$CFLAGS
 822 if test "$libgo_cv_c_unused_arguments" = yes; then
 823   CFLAGS="$CFLAGS -Qunused-arguments"
 824 fi
 825 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 826     libgo_cv_as_x86_64_unwind_section_type=no
 827 fi
 828 CFLAGS=$CFLAGS_hold
 829 ])
 830 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 831   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 832             [Define if your assembler supports unwind section type.])
 833 fi
 834
 835 AC_CACHE_SAVE
 836
 837 if test ${multilib} = yes; then
 838   multilib_arg="--enable-multilib"
 839 else
 840   multilib_arg=
 841 fi
 842
 843 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 844
 845 AC_CONFIG_COMMANDS([default],
 846 [if test -n "$CONFIG_FILES"; then
 847    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 848    # that multilib installs will end up installed in the correct place.
 849    # The testsuite needs it for multilib-aware ABI baseline files.
 850    # To work around this not being passed down from config-ml.in ->
 851    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 852    # append it here.  Only modify Makefiles that have just been created.
 853    #
 854    # Also, get rid of this simulated-VPATH thing that automake does.
 855    cat > vpsed << \_EOF
 856 s!`test -f '$<' || echo '$(srcdir)/'`!!
 857 _EOF
 858    for i in $SUBDIRS; do
 859     case $CONFIG_FILES in
 860      *${i}/Makefile*)
 861        #echo "Adding MULTISUBDIR to $i/Makefile"
 862        sed -f vpsed $i/Makefile > tmp
 863        grep '^MULTISUBDIR =' Makefile >> tmp
 864        mv tmp $i/Makefile
 865        ;;
 866     esac
 867    done
 868    rm vpsed
 869  fi
 870 ],
 871 [
 872 # Variables needed in config.status (file generation) which aren't already
 873 # passed by autoconf.
 874 SUBDIRS="$SUBDIRS"
 875 ])
 876
 877 AC_OUTPUT