gcc/ada/a-direio.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --                        A D A . D I R E C T _ I O                         --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-1998 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This is the generic template for Direct_IO, i.e. the code that gets
  35 --  duplicated. We absolutely minimize this code by either calling routines
  36 --  in System.File_IO (for common file functions), or in System.Direct_IO
  37 --  (for specialized Direct_IO functions)
  38
  39 with Interfaces.C_Streams; use Interfaces.C_Streams;
  40 with System;               use System;
  41 with System.File_Control_Block;
  42 with System.File_IO;
  43 with System.Direct_IO;
  44 with System.Storage_Elements;
  45 with Unchecked_Conversion;
  46
  47 use type System.Direct_IO.Count;
  48
  49 package body Ada.Direct_IO is
  50
  51    Zeroes : System.Storage_Elements.Storage_Array :=
  52               (1 .. System.Storage_Elements.Storage_Offset (Bytes) => 0);
  53    --  Buffer used to fill out partial records.
  54
  55    package FCB renames System.File_Control_Block;
  56    package FIO renames System.File_IO;
  57    package DIO renames System.Direct_IO;
  58
  59    SU : constant := System.Storage_Unit;
  60
  61    subtype AP      is FCB.AFCB_Ptr;
  62    subtype FP      is DIO.File_Type;
  63    subtype DCount  is DIO.Count;
  64    subtype DPCount is DIO.Positive_Count;
  65
  66    function To_FCB is new Unchecked_Conversion (File_Mode, FCB.File_Mode);
  67    function To_DIO is new Unchecked_Conversion (FCB.File_Mode, File_Mode);
  68
  69    -----------
  70    -- Close --
  71    -----------
  72
  73    procedure Close (File : in out File_Type) is
  74    begin
  75       FIO.Close (AP (File));
  76    end Close;
  77
  78    ------------
  79    -- Create --
  80    ------------
  81
  82    procedure Create
  83      (File : in out File_Type;
  84       Mode : in File_Mode := Inout_File;
  85       Name : in String := "";
  86       Form : in String := "")
  87    is
  88    begin
  89       DIO.Create (FP (File), To_FCB (Mode), Name, Form);
  90       File.Bytes := Bytes;
  91    end Create;
  92
  93    ------------
  94    -- Delete --
  95    ------------
  96
  97    procedure Delete (File : in out File_Type) is
  98    begin
  99       FIO.Delete (AP (File));
 100    end Delete;
 101
 102    -----------------
 103    -- End_Of_File --
 104    -----------------
 105
 106    function End_Of_File (File : in File_Type) return Boolean is
 107    begin
 108       return DIO.End_Of_File (FP (File));
 109    end End_Of_File;
 110
 111    ----------
 112    -- Form --
 113    ----------
 114
 115    function Form (File : in File_Type) return String is
 116    begin
 117       return FIO.Form (AP (File));
 118    end Form;
 119
 120    -----------
 121    -- Index --
 122    -----------
 123
 124    function Index (File : in File_Type) return Positive_Count is
 125    begin
 126       return Positive_Count (DIO.Index (FP (File)));
 127    end Index;
 128
 129    -------------
 130    -- Is_Open --
 131    -------------
 132
 133    function Is_Open (File : in File_Type) return Boolean is
 134    begin
 135       return FIO.Is_Open (AP (File));
 136    end Is_Open;
 137
 138    ----------
 139    -- Mode --
 140    ----------
 141
 142    function Mode (File : in File_Type) return File_Mode is
 143    begin
 144       return To_DIO (FIO.Mode (AP (File)));
 145    end Mode;
 146
 147    ----------
 148    -- Name --
 149    ----------
 150
 151    function Name (File : in File_Type) return String is
 152    begin
 153       return FIO.Name (AP (File));
 154    end Name;
 155
 156    ----------
 157    -- Open --
 158    ----------
 159
 160    procedure Open
 161      (File : in out File_Type;
 162       Mode : in File_Mode;
 163       Name : in String;
 164       Form : in String := "")
 165    is
 166    begin
 167       DIO.Open (FP (File), To_FCB (Mode), Name, Form);
 168       File.Bytes := Bytes;
 169    end Open;
 170
 171    ----------
 172    -- Read --
 173    ----------
 174
 175    procedure Read
 176      (File : in File_Type;
 177       Item : out Element_Type;
 178       From : in Positive_Count)
 179    is
 180    begin
 181       --  For a non-constrained variant record type, we read into an
 182       --  intermediate buffer, since we may have the case of discriminated
 183       --  records where a discriminant check is required, and we may need
 184       --  to assign only part of the record buffer originally written
 185
 186       if not Element_Type'Constrained then
 187          declare
 188             Buf : Element_Type;
 189
 190          begin
 191             DIO.Read (FP (File), Buf'Address, Bytes, DPCount (From));
 192             Item := Buf;
 193          end;
 194
 195       --  In the normal case, we can read straight into the buffer
 196
 197       else
 198          DIO.Read (FP (File), Item'Address, Bytes, DPCount (From));
 199       end if;
 200    end Read;
 201
 202    procedure Read (File : in File_Type; Item : out Element_Type) is
 203    begin
 204       --  Same processing for unconstrained case as above
 205
 206       if not Element_Type'Constrained then
 207          declare
 208             Buf : Element_Type;
 209
 210          begin
 211             DIO.Read (FP (File), Buf'Address, Bytes);
 212             Item := Buf;
 213          end;
 214
 215       else
 216          DIO.Read (FP (File), Item'Address, Bytes);
 217       end if;
 218    end Read;
 219
 220    -----------
 221    -- Reset --
 222    -----------
 223
 224    procedure Reset (File : in out File_Type; Mode : in File_Mode) is
 225    begin
 226       DIO.Reset (FP (File), To_FCB (Mode));
 227    end Reset;
 228
 229    procedure Reset (File : in out File_Type) is
 230    begin
 231       DIO.Reset (FP (File));
 232    end Reset;
 233
 234    ---------------
 235    -- Set_Index --
 236    ---------------
 237
 238    procedure Set_Index (File : in File_Type; To : in Positive_Count) is
 239    begin
 240       DIO.Set_Index (FP (File), DPCount (To));
 241    end Set_Index;
 242
 243    ----------
 244    -- Size --
 245    ----------
 246
 247    function Size (File : in File_Type) return Count is
 248    begin
 249       return Count (DIO.Size (FP (File)));
 250    end Size;
 251
 252    -----------
 253    -- Write --
 254    -----------
 255
 256    procedure Write
 257      (File : in File_Type;
 258       Item : in Element_Type;
 259       To   : in Positive_Count)
 260    is
 261    begin
 262       DIO.Set_Index (FP (File), DPCount (To));
 263       DIO.Write (FP (File), Item'Address, Item'Size / SU, Zeroes);
 264    end Write;
 265
 266    procedure Write (File : in File_Type; Item : in Element_Type) is
 267    begin
 268       DIO.Write (FP (File), Item'Address, Item'Size / SU, Zeroes);
 269    end Write;
 270
 271 end Ada.Direct_IO;