libatomic/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2 #  Copyright (C) 2012 Free Software Foundation, Inc.
   3 #
   4 #  This file is part of the GNU Atomic Library (libatomic).
   5 #
   6 #  Libatomic is free software; you can redistribute it and/or modify it
   7 #  under the terms of the GNU General Public License as published by
   8 #  the Free Software Foundation; either version 3 of the License, or
   9 #  (at your option) any later version.
  10 #
  11 #  Libatomic is distributed in the hope that it will be useful, but WITHOUT ANY
  12 #  WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  13 #  FOR A PARTICULAR PURPOSE.  See the GNU General Public License for
  14 #  more details.
  15 #
  16 #  Under Section 7 of GPL version 3, you are granted additional
  17 #  permissions described in the GCC Runtime Library Exception, version
  18 #  3.1, as published by the Free Software Foundation.
  19 #
  20 #  You should have received a copy of the GNU General Public License and
  21 #  a copy of the GCC Runtime Library Exception along with this program;
  22 #  see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see
  23 #  <http://www.gnu.org/licenses/>.
  24
  25 AC_PREREQ(2.59)
  26 AC_INIT([GNU Atomic Library], 1.0,,[libatomic])
  27 AC_CONFIG_HEADER(auto-config.h)
  28
  29 # -------
  30 # Options
  31 # -------
  32
  33 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  34 LIBAT_ENABLE(version-specific-runtime-libs, no, ,
  35    [Specify that runtime libraries should be installed in a compiler-specific directory],
  36    permit yes|no)
  37 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  38
  39 # We would like our source tree to be readonly. However when releases or
  40 # pre-releases are generated, the flex/bison generated files as well as the
  41 # various formats of manuals need to be included along with the rest of the
  42 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  43 # just that.
  44 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  45 LIBAT_ENABLE(generated-files-in-srcdir, no, ,
  46    [put copies of generated files in source dir intended for creating source
  47     tarballs for users without texinfo bison or flex.],
  48    permit yes|no)
  49 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  50 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  51
  52
  53 # -------
  54
  55 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  56 #
  57 # You will slowly go insane if you do not grok the following fact:  when
  58 # building this library, the top-level /target/ becomes the library's /host/.
  59 #
  60 # configure then causes --target to default to --host, exactly like any
  61 # other package using autoconf.  Therefore, 'target' and 'host' will
  62 # always be the same.  This makes sense both for native and cross compilers
  63 # just think about it for a little while.  :-)
  64 #
  65 # Also, if this library is being configured as part of a cross compiler, the
  66 # top-level configure script will pass the "real" host as $with_cross_host.
  67 #
  68 # Do not delete or change the following two lines.  For why, see
  69 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  70 AC_CANONICAL_SYSTEM
  71 target_alias=${target_alias-$host_alias}
  72
  73 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  74 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  75 #  1.9.0:  minimum required version
  76 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  77 #              of other PACKAGE_* variables will, however, and there's nothing
  78 #              we can do about that; they come from AC_INIT).
  79 #  no-dist:  we don't want 'dist' and related rules.
  80 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  81 #            file in the top srcdir, etc, etc), so stop complaining.
  82 #  -Wall:  turns on all automake warnings...
  83 #  -Wno-portability:  ...except this one, since GNU make is required.
  84 #  -Wno-override: ... and this one, since we do want this in testsuite.
  85 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  86 AM_ENABLE_MULTILIB(, ..)
  87
  88 # Calculate toolexeclibdir
  89 # Also toolexecdir, though it's only used in toolexeclibdir
  90 case ${enable_version_specific_runtime_libs} in
  91   yes)
  92     # Need the gcc compiler version to know where to install libraries
  93     # and header files if --enable-version-specific-runtime-libs option
  94     # is selected.
  95     toolexecdir='$(libdir)/gcc/$(target_alias)'
  96     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  97     ;;
  98   no)
  99     if test -n "$with_cross_host" &&
 100        test x"$with_cross_host" != x"no"; then
 101       # Install a library built with a cross compiler in tooldir, not libdir.
 102       toolexecdir='$(exec_prefix)/$(target_alias)'
 103       toolexeclibdir='$(toolexecdir)/lib'
 104     else
 105       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 106       toolexeclibdir='$(libdir)'
 107     fi
 108     multi_os_directory=`$CC -print-multi-os-directory`
 109     case $multi_os_directory in
 110       .) ;; # Avoid trailing /.
 111       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 112     esac
 113     ;;
 114 esac
 115 AC_SUBST(toolexecdir)
 116 AC_SUBST(toolexeclibdir)
 117
 118 # Check the compiler.
 119 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 120 # We must force CC to /not/ be precious variables; otherwise
 121 # the wrong, non-multilib-adjusted value will be used in multilibs.
 122 # As a side effect, we have to subst CFLAGS ourselves.
 123
 124 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 125 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 126 AC_PROG_CC
 127 AM_PROG_AS
 128 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 129
 130 AC_SUBST(CFLAGS)
 131
 132 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 133 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 134 # in both places for now and restore CFLAGS at the end of config.
 135 save_CFLAGS="$CFLAGS"
 136
 137 # Find other programs we need.
 138 AC_CHECK_TOOL(AR, ar)
 139 AC_CHECK_TOOL(NM, nm)
 140 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 141 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 142 AC_PROG_INSTALL
 143
 144 # Configure libtool
 145 AM_PROG_LIBTOOL
 146 AC_SUBST(enable_shared)
 147 AC_SUBST(enable_static)
 148 AM_MAINTAINER_MODE
 149
 150 # For libtool versioning info, format is CURRENT:REVISION:AGE
 151 libtool_VERSION=1:0:0
 152 AC_SUBST(libtool_VERSION)
 153
 154 # Get target configury.
 155 . ${srcdir}/configure.tgt
 156 if test -n "$UNSUPPORTED"; then
 157   AC_MSG_ERROR([Configuration ${target} is unsupported.])
 158 fi
 159
 160 # Disable fallbacks to __sync routines from libgcc.  Otherwise we'll
 161 # make silly decisions about what the cpu can do.
 162 CFLAGS="$save_CFLAGS -fno-sync-libcalls $XCFLAGS"
 163
 164 # Check header files.
 165 AC_STDC_HEADERS
 166 ACX_HEADER_STRING
 167 GCC_HEADER_STDINT(gstdint.h)
 168
 169 # Check for common type sizes
 170 LIBAT_FORALL_MODES([LIBAT_HAVE_INT_MODE])
 171
 172 # Check for compiler builtins of atomic operations.
 173 LIBAT_TEST_ATOMIC_INIT
 174 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_LOADSTORE])
 175 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_TAS])
 176 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_EXCHANGE])
 177 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_CAS])
 178 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_FETCH_ADD])
 179 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_FETCH_OP])
 180
 181 AC_C_BIGENDIAN
 182 # I don't like the default behaviour of WORDS_BIGENDIAN undefined for LE.
 183 AH_BOTTOM(
 184 [#ifndef WORDS_BIGENDIAN
 185 #define WORDS_BIGENDIAN 0
 186 #endif])
 187
 188 LIBAT_WORDSIZE
 189
 190 # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 191 # In case the pthread.h system header is not found, this test will fail.
 192 case " $config_path " in
 193  *" posix "*)
 194   XPCFLAGS=""
 195   CFLAGS="$CFLAGS -pthread"
 196   AC_LINK_IFELSE(
 197     [AC_LANG_PROGRAM(
 198      [#include <pthread.h>
 199       void *g(void *d) { return NULL; }],
 200      [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 201     [XPCFLAGS=" -pthread"],
 202     [CFLAGS="$save_CFLAGS $XCFLAGS" LIBS="-lpthread $LIBS"
 203      AC_LINK_IFELSE(
 204       [AC_LANG_PROGRAM(
 205        [#include <pthread.h>
 206         void *g(void *d) { return NULL; }],
 207        [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 208       [],
 209       [AC_MSG_ERROR([Pthreads are required to build libatomic])])])
 210   CFLAGS="$save_CFLAGS $XPCFLAGS"
 211   ;;
 212 esac
 213
 214 # See what sort of export controls are available.
 215 LIBAT_CHECK_ATTRIBUTE_VISIBILITY
 216 LIBAT_CHECK_ATTRIBUTE_DLLEXPORT
 217 LIBAT_CHECK_ATTRIBUTE_ALIAS
 218 if test x$try_ifunc = xyes; then
 219   LIBAT_CHECK_IFUNC
 220 fi
 221
 222 # Check linker support.
 223 LIBAT_ENABLE_SYMVERS
 224
 225 # Cleanup and exit.
 226 CFLAGS="$save_CFLAGS"
 227 AC_CACHE_SAVE
 228
 229 # Add -Wall -Werror if we are using GCC.
 230 if test "x$GCC" = "xyes"; then
 231   XCFLAGS="$XCFLAGS -Wall -Werror"
 232 fi
 233
 234 XCFLAGS="$XCFLAGS $XPCFLAGS"
 235
 236 AC_SUBST(config_path)
 237 AC_SUBST(XCFLAGS)
 238 AC_SUBST(XLDFLAGS)
 239 AC_SUBST(LIBS)
 240 AC_SUBST(SIZES)
 241
 242 AM_CONDITIONAL(HAVE_IFUNC, test x$libat_cv_have_ifunc = xyes)
 243 AM_CONDITIONAL(ARCH_ARM_LINUX,
 244                [expr "$config_path" : ".* linux/arm .*" > /dev/null])
 245 AM_CONDITIONAL(ARCH_I386,
 246                [test "$ARCH" = x86 && test x$libat_cv_wordsize = x4])
 247 AM_CONDITIONAL(ARCH_X86_64,
 248                [test "$ARCH" = x86 && test x$libat_cv_wordsize = x8])
 249
 250 if test ${multilib} = yes; then
 251   multilib_arg="--enable-multilib"
 252 else
 253   multilib_arg=
 254 fi
 255
 256 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 257 AC_OUTPUT