gcc/ada/a-swuwti.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                  ADA.STRINGS.WIDE_UNBOUNDED.WIDE_TEXT_IO                 --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1997-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Ada.Wide_Text_IO; use Ada.Wide_Text_IO;
  35
  36 package body Ada.Strings.Wide_Unbounded.Wide_Text_IO is
  37
  38    --------------
  39    -- Get_Line --
  40    --------------
  41
  42    function Get_Line return Unbounded_Wide_String is
  43       Buffer : Wide_String (1 .. 1000);
  44       Last   : Natural;
  45       Str1   : Wide_String_Access;
  46       Str2   : Wide_String_Access;
  47       Result : Unbounded_Wide_String;
  48
  49    begin
  50       Get_Line (Buffer, Last);
  51       Str1 := new Wide_String'(Buffer (1 .. Last));
  52       while Last = Buffer'Last loop
  53          Get_Line (Buffer, Last);
  54          Str2 := new Wide_String (1 .. Str1'Last + Last);
  55          Str2 (Str1'Range) := Str1.all;
  56          Str2 (Str1'Last + 1 .. Str2'Last) := Buffer (1 .. Last);
  57          Free (Str1);
  58          Str1 := Str2;
  59       end loop;
  60
  61       Result.Reference := Str1;
  62       Result.Last      := Str1'Length;
  63       return Result;
  64    end Get_Line;
  65
  66    function Get_Line
  67      (File : Ada.Wide_Text_IO.File_Type) return Unbounded_Wide_String
  68    is
  69       Buffer : Wide_String (1 .. 1000);
  70       Last   : Natural;
  71       Str1   : Wide_String_Access;
  72       Str2   : Wide_String_Access;
  73       Result : Unbounded_Wide_String;
  74
  75    begin
  76       Get_Line (File, Buffer, Last);
  77       Str1 := new Wide_String'(Buffer (1 .. Last));
  78       while Last = Buffer'Last loop
  79          Get_Line (File, Buffer, Last);
  80          Str2 := new Wide_String (1 .. Str1'Last + Last);
  81          Str2 (Str1'Range) := Str1.all;
  82          Str2 (Str1'Last + 1 .. Str2'Last) := Buffer (1 .. Last);
  83          Free (Str1);
  84          Str1 := Str2;
  85       end loop;
  86
  87       Result.Reference := Str1;
  88       Result.Last      := Str1'Length;
  89       return Result;
  90    end Get_Line;
  91
  92    procedure Get_Line (Item : out Unbounded_Wide_String) is
  93    begin
  94       Get_Line (Current_Input, Item);
  95    end Get_Line;
  96
  97    procedure Get_Line
  98      (File : Ada.Wide_Text_IO.File_Type;
  99       Item : out Unbounded_Wide_String)
 100    is
 101    begin
 102       --  We are going to read into the string that is already there and
 103       --  allocated. Hopefully it is big enough now, if not, we will extend
 104       --  it in the usual manner using Realloc_For_Chunk.
 105
 106       --  Make sure we start with at least 80 characters
 107
 108       if Item.Reference'Last < 80 then
 109          Realloc_For_Chunk (Item, 80);
 110       end if;
 111
 112       --  Loop to read data, filling current string as far as possible.
 113       --  Item.Last holds the number of characters read so far.
 114
 115       Item.Last := 0;
 116       loop
 117          Get_Line
 118            (File,
 119             Item.Reference (Item.Last + 1 .. Item.Reference'Last),
 120             Item.Last);
 121
 122          --  If we hit the end of the line before the end of the buffer, then
 123          --  we are all done, and the result length is properly set.
 124
 125          if Item.Last < Item.Reference'Last then
 126             return;
 127          end if;
 128
 129          --  If not enough room, double it and keep reading
 130
 131          Realloc_For_Chunk (Item, Item.Last);
 132       end loop;
 133    end Get_Line;
 134
 135    ---------
 136    -- Put --
 137    ---------
 138
 139    procedure Put (U : Unbounded_Wide_String) is
 140    begin
 141       Put (U.Reference (1 .. U.Last));
 142    end Put;
 143
 144    procedure Put (File : File_Type; U : Unbounded_Wide_String) is
 145    begin
 146       Put (File, U.Reference (1 .. U.Last));
 147    end Put;
 148
 149    --------------
 150    -- Put_Line --
 151    --------------
 152
 153    procedure Put_Line (U : Unbounded_Wide_String) is
 154    begin
 155       Put_Line (U.Reference (1 .. U.Last));
 156    end Put_Line;
 157
 158    procedure Put_Line (File : File_Type; U : Unbounded_Wide_String) is
 159    begin
 160       Put_Line (File, U.Reference (1 .. U.Last));
 161    end Put_Line;
 162
 163 end Ada.Strings.Wide_Unbounded.Wide_Text_IO;