gcc/ada/a-cgaaso.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --              ADA.CONTAINERS.GENERIC_ANONYMOUS_ARRAY_SORT                 --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- This unit was originally developed by Matthew J Heaney.                  --
  30 ------------------------------------------------------------------------------
  31
  32 --  This algorithm was adapted from GNAT.Heap_Sort (see g-heasor.ad[sb])
  33
  34 with System;
  35
  36 procedure Ada.Containers.Generic_Anonymous_Array_Sort
  37   (First, Last : Index_Type'Base)
  38 is
  39    type T is range System.Min_Int .. System.Max_Int;
  40
  41    function To_Index (J : T) return Index_Type;
  42    pragma Inline (To_Index);
  43
  44    function Lt (J, K : T) return Boolean;
  45    pragma Inline (Lt);
  46
  47    procedure Xchg (J, K : T);
  48    pragma Inline (Xchg);
  49
  50    procedure Sift (S : T);
  51
  52    --------------
  53    -- To_Index --
  54    --------------
  55
  56    function To_Index (J : T) return Index_Type is
  57       K : constant T'Base := Index_Type'Pos (First) + J - T'(1);
  58    begin
  59       return Index_Type'Val (K);
  60    end To_Index;
  61
  62    --------
  63    -- Lt --
  64    --------
  65
  66    function Lt (J, K : T) return Boolean is
  67    begin
  68       return Less (To_Index (J), To_Index (K));
  69    end Lt;
  70
  71    ----------
  72    -- Xchg --
  73    ----------
  74
  75    procedure Xchg (J, K : T) is
  76    begin
  77       Swap (To_Index (J), To_Index (K));
  78    end Xchg;
  79
  80    Max : T := Index_Type'Pos (Last) - Index_Type'Pos (First) + T'(1);
  81
  82    ----------
  83    -- Sift --
  84    ----------
  85
  86    procedure Sift (S : T) is
  87       C      : T := S;
  88       Son    : T;
  89       Father : T;
  90
  91    begin
  92       loop
  93          Son := C + C;
  94
  95          if Son < Max then
  96             if Lt (Son, Son + 1) then
  97                Son := Son + 1;
  98             end if;
  99          elsif Son > Max then
 100             exit;
 101          end if;
 102
 103          Xchg (Son, C);
 104          C := Son;
 105       end loop;
 106
 107       while C /= S loop
 108          Father := C / 2;
 109
 110          if Lt (Father, C) then
 111             Xchg (Father, C);
 112             C := Father;
 113          else
 114             exit;
 115          end if;
 116       end loop;
 117    end Sift;
 118
 119 --  Start of processing for Generic_Anonymous_Array_Sort
 120
 121 begin
 122    for J in reverse 1 .. Max / 2 loop
 123       Sift (J);
 124    end loop;
 125
 126    while Max > 1 loop
 127       Xchg (1, Max);
 128       Max := Max - 1;
 129       Sift (1);
 130    end loop;
 131 end Ada.Containers.Generic_Anonymous_Array_Sort;