gcc/ada/a-coboho.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --       A D A . C O N T A I N E R S . B O U N D E D _ H O L D E R S        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --            Copyright (C) 2014, Free Software Foundation, Inc.            --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 ------------------------------------------------------------------------------
  27
  28 with Unchecked_Conversion;
  29 with Ada.Assertions; use Ada.Assertions;
  30
  31 package body Ada.Containers.Bounded_Holders is
  32
  33    function Size_In_Storage_Elements (Element : Element_Type) return Natural is
  34      (Element'Size / System.Storage_Unit)
  35        with Pre =>
  36        (Element'Size mod System.Storage_Unit = 0 or else
  37           raise Assertion_Error with "Size must be a multiple of Storage_Unit")
  38        and then
  39          (Element'Size / System.Storage_Unit <= Max_Size_In_Storage_Elements
  40             or else raise Assertion_Error with "Size is too big");
  41    --  This returns the size of Element in storage units. It raises an
  42    --  exception if the size is not a multiple of Storage_Unit, or if the size
  43    --  is too big.
  44
  45    function Cast is new
  46      Unchecked_Conversion (System.Address, Element_Access);
  47
  48    ---------
  49    -- "=" --
  50    ---------
  51
  52    function "=" (Left, Right : Holder) return Boolean is
  53    begin
  54       return Get (Left) = Get (Right);
  55    end "=";
  56
  57    -------------
  58    -- Element --
  59    -------------
  60
  61    function Get (Container : Holder) return Element_Type is
  62    begin
  63       return Cast (Container'Address).all;
  64    end Get;
  65
  66    ---------------------
  67    -- Replace_Element --
  68    ---------------------
  69
  70    procedure Set (Container : in out Holder; New_Item  : Element_Type) is
  71       Storage : Storage_Array
  72         (1 .. Size_In_Storage_Elements (New_Item)) with
  73           Address => New_Item'Address;
  74    begin
  75       Container.Data (Storage'Range) := Storage;
  76    end Set;
  77
  78    ---------------
  79    -- To_Holder --
  80    ---------------
  81
  82    function To_Holder (New_Item : Element_Type) return Holder is
  83    begin
  84       return Result : Holder do
  85          Set (Result, New_Item);
  86       end return;
  87    end To_Holder;
  88
  89 end Ada.Containers.Bounded_Holders;