libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([GNU OpenMP Runtime Library], 1.0,,[libgomp])
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # -------
   9 # Options
  10 # -------
  11
  12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  13 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  14    [Specify that runtime libraries should be installed in a compiler-specific directory],
  15    permit yes|no)
  16 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  17
  18 AC_MSG_CHECKING([for --enable-linux-futex])
  19 LIBGOMP_ENABLE(linux-futex, yes,
  20   [Use the Linux futex system call],
  21   permit yes|no)
  22 AC_MSG_RESULT($enable_linux_futex)
  23
  24 # -------
  25 # -------
  26
  27 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  28 #
  29 # You will slowly go insane if you do not grok the following fact:  when
  30 # building this library, the top-level /target/ becomes the library's /host/.
  31 #
  32 # configure then causes --target to default to --host, exactly like any
  33 # other package using autoconf.  Therefore, 'target' and 'host' will
  34 # always be the same.  This makes sense both for native and cross compilers
  35 # just think about it for a little while.  :-)
  36 #
  37 # Also, if this library is being configured as part of a cross compiler, the
  38 # top-level configure script will pass the "real" host as $with_cross_host.
  39 #
  40 # Do not delete or change the following two lines.  For why, see
  41 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  42 AC_CANONICAL_SYSTEM
  43 target_alias=${target_alias-$host_alias}
  44
  45 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  46 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  47 #  1.9.0:  minimum required version
  48 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  49 #              of other PACKAGE_* variables will, however, and there's nothing
  50 #              we can do about that; they come from AC_INIT).
  51 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  52 #            file in the top srcdir, etc, etc), so stop complaining.
  53 #  no-dependencies:  turns off auto dependency generation (just for now)
  54 #  -Wall:  turns on all automake warnings...
  55 #  -Wno-portability:  ...except this one, since GNU make is required.
  56 #  -Wno-override: ... and this one, since we do want this in testsuite.
  57 AM_INIT_AUTOMAKE([1.9.0 foreign -Wall -Wno-portability -Wno-override])
  58 AM_ENABLE_MULTILIB(, ..)
  59
  60 # Calculate toolexeclibdir
  61 # Also toolexecdir, though it's only used in toolexeclibdir
  62 case ${enable_version_specific_runtime_libs} in
  63   yes)
  64     # Need the gcc compiler version to know where to install libraries
  65     # and header files if --enable-version-specific-runtime-libs option
  66     # is selected.
  67     toolexecdir='$(libdir)/gcc/$(target_alias)'
  68     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  69     ;;
  70   no)
  71     if test -n "$with_cross_host" &&
  72        test x"$with_cross_host" != x"no"; then
  73       # Install a library built with a cross compiler in tooldir, not libdir.
  74       toolexecdir='$(exec_prefix)/$(target_alias)'
  75       toolexeclibdir='$(toolexecdir)/lib'
  76     else
  77       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  78       toolexeclibdir='$(libdir)'
  79     fi
  80     multi_os_directory=`$CC -print-multi-os-directory`
  81     case $multi_os_directory in
  82       .) ;; # Avoid trailing /.
  83       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  84     esac
  85     ;;
  86 esac
  87 AC_SUBST(toolexecdir)
  88 AC_SUBST(toolexeclibdir)
  89
  90 # Check the compiler.
  91 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  92 # We must force CC to /not/ be precious variables; otherwise
  93 # the wrong, non-multilib-adjusted value will be used in multilibs.
  94 # As a side effect, we have to subst CFLAGS ourselves.
  95
  96 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  97 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  98 AC_PROG_CC
  99 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 100
 101 AC_SUBST(CFLAGS)
 102
 103 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 104 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 105 # in both places for now and restore CFLAGS at the end of config.
 106 save_CFLAGS="$CFLAGS"
 107
 108 # Add -Wall -Werror if we are using GCC.
 109 if test "x$GCC" = "xyes"; then
 110   XCFLAGS="$XCFLAGS -Wall -Werror"
 111 fi
 112
 113 # Find other programs we need.
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 116 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 117 AC_PROG_MAKE_SET
 118 AC_PROG_INSTALL
 119
 120 # Configure libtool
 121 AM_PROG_LIBTOOL
 122 AC_SUBST(enable_shared)
 123 AC_SUBST(enable_static)
 124
 125 AM_MAINTAINER_MODE
 126
 127 # We need gfortran to compile parts of the library
 128 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 129 #AC_PROG_FC(gfortran)
 130 FC="$GFORTRAN"
 131 AC_PROG_FC(gfortran)
 132 FCFLAGS="$FCFLAGS -Wall"
 133
 134 # For libtool versioning info, format is CURRENT:REVISION:AGE
 135 libtool_VERSION=1:0:0
 136 AC_SUBST(libtool_VERSION)
 137
 138 # Check header files.
 139 AC_STDC_HEADERS
 140 AC_HEADER_TIME
 141 AC_CHECK_HEADERS(unistd.h semaphore.h sys/loadavg.h sys/time.h)
 142
 143 GCC_HEADER_STDINT(gstdint.h)
 144
 145 # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 146 # In case the pthread.h system header is not found, this test will fail.
 147 XPCFLAGS=""
 148 CFLAGS="$CFLAGS -pthread"
 149 AC_LINK_IFELSE(
 150  [AC_LANG_PROGRAM(
 151   [#include <pthread.h>
 152    void *g(void *d) { return NULL; }],
 153   [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 154  [XPCFLAGS=" -Wc,-pthread"],
 155  [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 156   AC_LINK_IFELSE(
 157    [AC_LANG_PROGRAM(
 158     [#include <pthread.h>
 159      void *g(void *d) { return NULL; }],
 160     [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 161    [],
 162    [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 163
 164 # Check for functions needed.
 165 AC_CHECK_FUNCS(getloadavg clock_gettime)
 166
 167 # At least for glibc, clock_gettime is in librt.  But don't pull that
 168 # in if it still doesn't give us the function we want.
 169 if test $ac_cv_func_clock_gettime = no; then
 170   AC_CHECK_LIB(rt, clock_gettime,
 171     [LIBS="-lrt $LIBS"
 172      AC_DEFINE(HAVE_CLOCK_GETTIME,
 173                [Define to 1 if you have the `clock_gettime' function.])])
 174 fi
 175
 176 # See if we support thread-local storage.
 177 LIBGOMP_CHECK_TLS
 178
 179 # See what sort of export controls are availible.
 180 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 181 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 182 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 183 LIBGOMP_ENABLE_SYMVERS
 184
 185 # Get target configury.
 186 . ${srcdir}/configure.tgt
 187 CFLAGS="$save_CFLAGS $XCFLAGS"
 188
 189 # Check for __sync_val_compare_and_swap, but only after the target has
 190 # had a chance to set XCFLAGS.
 191 LIBGOMP_CHECK_SYNC_BUILTINS
 192
 193 XCFLAGS="$XCFLAGS$XPCFLAGS"
 194
 195 AC_SUBST(config_path)
 196 AC_SUBST(XCFLAGS)
 197 AC_SUBST(XLDFLAGS)
 198
 199 # Cleanup and exit.
 200 CFLAGS="$save_CFLAGS"
 201 AC_CACHE_SAVE
 202
 203 if test ${multilib} = yes; then
 204   multilib_arg="--enable-multilib"
 205 else
 206   multilib_arg=
 207 fi
 208
 209 # Set up the set of libraries that we need to link against for libgomp.
 210 # Note that the GOMP_SELF_SPEC in gcc.c will force -pthread for -fopenmp,
 211 # which will force linkage against -lpthread (or equivalent for the system).
 212 # That's not 100% ideal, but about the best we can do easily.
 213 if test $enable_shared = yes; then
 214   link_gomp="-lgomp %{static: $LIBS}"
 215 else
 216   link_gomp="-lgomp $LIBS"
 217 fi
 218 AC_SUBST(link_gomp)
 219
 220 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 221
 222 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 223 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 224 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 225 # need to copy this macro to our acinclude.m4.
 226 save_CFLAGS="$CFLAGS"
 227 for i in $config_path; do
 228   if test -f $srcdir/config/$i/omp-lock.h; then
 229     CFLAGS="$CFLAGS -include $srcdir/config/$i/omp-lock.h"
 230     break
 231   fi
 232 done
 233
 234 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 235   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 236 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 237 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 238 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 239
 240 # If the lock fits in an integer, then arrange for Fortran to use that
 241 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 242 # Except that we don't have a way at present to multi-lib the installed
 243 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 244 # actual target.
 245 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 246 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 247 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 248   OMP_LOCK_KIND=8
 249 fi
 250 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 251   OMP_NEST_LOCK_KIND=8
 252 fi
 253
 254 AC_SUBST(OMP_LOCK_SIZE)
 255 AC_SUBST(OMP_LOCK_ALIGN)
 256 AC_SUBST(OMP_NEST_LOCK_SIZE)
 257 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 258 AC_SUBST(OMP_LOCK_KIND)
 259 AC_SUBST(OMP_NEST_LOCK_KIND)
 260 CFLAGS="$save_CFLAGS"
 261
 262 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 263 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 264 AC_OUTPUT