configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libhsail-rt \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libmpx \
 161                 target-libssp \
 162                 target-libquadmath \
 163                 target-libgfortran \
 164                 target-libffi \
 165                 target-libobjc \
 166                 target-libada \
 167                 target-libgo"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # some tools are so dependent upon X11 that if we're not building with X,
 251 # it's not even worth trying to configure, much less build, that tool.
 252
 253 case ${with_x} in
 254   yes | "") ;; # the default value for this tree is that X11 is available
 255   no)
 256     skipdirs="${skipdirs} tk itcl libgui"
 257     # We won't be able to build gdbtk without X.
 258     enable_gdbtk=no
 259     ;;
 260   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 261 esac
 262
 263 # Some are only suitable for cross toolchains.
 264 # Remove these if host=target.
 265 cross_only="target-libgloss target-newlib target-opcodes"
 266
 267 case $is_cross_compiler in
 268   no) skipdirs="${skipdirs} ${cross_only}" ;;
 269 esac
 270
 271 # If both --with-headers and --with-libs are specified, default to
 272 # --without-newlib.
 273 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 274    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 275   if test x"${with_newlib}" = x ; then
 276     with_newlib=no
 277   fi
 278 fi
 279
 280 # Recognize --with-newlib/--without-newlib.
 281 case ${with_newlib} in
 282   no) skipdirs="${skipdirs} target-newlib" ;;
 283   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 284 esac
 285
 286 AC_ARG_ENABLE(as-accelerator-for,
 287 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 288                 [build as offload target compiler.
 289                 Specify offload host triple by ARG])])
 290
 291 AC_ARG_ENABLE(offload-targets,
 292 [AS_HELP_STRING([--enable-offload-targets=LIST],
 293                 [enable offloading to devices from comma-separated LIST of
 294                 TARGET[=DIR]. Use optional path to find offload target compiler
 295                 during the build])],
 296 [
 297   if test x"$enable_offload_targets" = x; then
 298     AC_MSG_ERROR([no offload targets specified])
 299   fi
 300 ], [enable_offload_targets=])
 301
 302 # Handle --enable-gold, --enable-ld.
 303 # --disable-gold [--enable-ld]
 304 #     Build only ld.  Default option.
 305 # --enable-gold [--enable-ld]
 306 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 307 #     as "ld.bfd" and "ld".
 308 # --enable-gold=default [--enable-ld]
 309 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 310 #     install ld as "ld.bfd".
 311 # --enable-gold[=default] --disable-ld
 312 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 313 # --enable-gold --enable-ld=default
 314 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 315 #     and ld.bfd).
 316 #     In other words, ld is default
 317 # --enable-gold=default --enable-ld=default
 318 #     Error.
 319
 320 default_ld=
 321 AC_ARG_ENABLE(gold,
 322 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 323                 [build gold @<:@ARG={default,yes,no}@:>@])],
 324 ENABLE_GOLD=$enableval,
 325 ENABLE_GOLD=no)
 326 case "${ENABLE_GOLD}" in
 327   yes|default)
 328     # Check for ELF target.
 329     is_elf=no
 330     case "${target}" in
 331       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 332       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 333       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 334       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 335         case "${target}" in
 336           *-*-linux*aout* | *-*-linux*oldld*)
 337             ;;
 338           *)
 339             is_elf=yes
 340             ;;
 341         esac
 342     esac
 343
 344     if test "$is_elf" = "yes"; then
 345       # Check for target supported by gold.
 346       case "${target}" in
 347         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 348         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 349           configdirs="$configdirs gold"
 350           if test x${ENABLE_GOLD} = xdefault; then
 351             default_ld=gold
 352           fi
 353           ENABLE_GOLD=yes
 354           ;;
 355       esac
 356     fi
 357     ;;
 358   no)
 359     ;;
 360   *)
 361     AC_MSG_ERROR([invalid --enable-gold argument])
 362     ;;
 363 esac
 364
 365 AC_ARG_ENABLE(ld,
 366 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 367                 [build ld @<:@ARG={default,yes,no}@:>@])],
 368 ENABLE_LD=$enableval,
 369 ENABLE_LD=yes)
 370
 371 case "${ENABLE_LD}" in
 372   default)
 373     if test x${default_ld} != x; then
 374       AC_MSG_ERROR([either gold or ld can be the default ld])
 375     fi
 376     ;;
 377   yes)
 378     ;;
 379   no)
 380     if test x${ENABLE_GOLD} != xyes; then
 381       AC_MSG_WARN([neither ld nor gold are enabled])
 382     fi
 383     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 384     ;;
 385   *)
 386     AC_MSG_ERROR([invalid --enable-ld argument])
 387     ;;
 388 esac
 389
 390 # PR gas/19109
 391 # Decide the default method for compressing debug sections.
 392 # Provide a configure time option to override our default.
 393 AC_ARG_ENABLE(compressed_debug_sections,
 394 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 395                 [Enable compressed debug sections for gas, gold or ld by
 396                  default])],
 397 [
 398   if test x"$enable_compressed_debug_sections" = xyes; then
 399     AC_MSG_ERROR([no program with compressed debug sections specified])
 400   fi
 401 ], [enable_compressed_debug_sections=])
 402
 403 # Configure extra directories which are host specific
 404
 405 case "${host}" in
 406   *-cygwin*)
 407     configdirs="$configdirs libtermcap" ;;
 408 esac
 409
 410 # A target can indicate whether a language isn't supported for some reason.
 411 # Only spaces may be used in this macro; not newlines or tabs.
 412 unsupported_languages=
 413
 414 # Remove more programs from consideration, based on the host or
 415 # target this usually means that a port of the program doesn't
 416 # exist yet.
 417
 418 case "${host}" in
 419   i[[3456789]]86-*-msdosdjgpp*)
 420     noconfigdirs="$noconfigdirs tcl tk itcl"
 421     ;;
 422 esac
 423
 424
 425 AC_ARG_ENABLE(libquadmath,
 426 AS_HELP_STRING([--disable-libquadmath],
 427   [do not build libquadmath directory]),
 428 ENABLE_LIBQUADMATH=$enableval,
 429 ENABLE_LIBQUADMATH=yes)
 430 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 431   noconfigdirs="$noconfigdirs target-libquadmath"
 432 fi
 433
 434
 435 AC_ARG_ENABLE(libquadmath-support,
 436 AS_HELP_STRING([--disable-libquadmath-support],
 437   [disable libquadmath support for Fortran]),
 438 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 439 ENABLE_LIBQUADMATH_SUPPORT=yes)
 440 enable_libquadmath_support=
 441 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 442   enable_libquadmath_support=no
 443 fi
 444
 445
 446 AC_ARG_ENABLE(libada,
 447 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 448 ENABLE_LIBADA=$enableval,
 449 ENABLE_LIBADA=yes)
 450 if test "${ENABLE_LIBADA}" != "yes" ; then
 451   noconfigdirs="$noconfigdirs gnattools"
 452 fi
 453
 454 AC_ARG_ENABLE(libssp,
 455 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 456 ENABLE_LIBSSP=$enableval,
 457 ENABLE_LIBSSP=yes)
 458
 459 AC_ARG_ENABLE(libstdcxx,
 460 AS_HELP_STRING([--disable-libstdcxx],
 461   [do not build libstdc++-v3 directory]),
 462 ENABLE_LIBSTDCXX=$enableval,
 463 ENABLE_LIBSTDCXX=default)
 464 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 465   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 466 fi]
 467
 468 # If this is accelerator compiler and its target is intelmic we enable
 469 # target liboffloadmic by default.  If this is compiler with offloading
 470 # for intelmic we enable host liboffloadmic by default.  Otherwise
 471 # liboffloadmic is disabled by default.
 472 AC_ARG_ENABLE([liboffloadmic],
 473 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 474                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 475 [case "$enableval" in
 476   no | host | target)
 477     enable_liboffloadmic=$enableval ;;
 478   *)
 479     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 480 esac],
 481 [if test x"$enable_as_accelerator_for" != x; then
 482   case "${target}" in
 483     *-intelmic-* | *-intelmicemul-*)
 484       enable_liboffloadmic=target
 485       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 486       ;;
 487     *)
 488       enable_liboffloadmic=no
 489       ;;
 490   esac
 491 else
 492   case "${enable_offload_targets}" in
 493     *-intelmic-* | *-intelmicemul-*)
 494       enable_liboffloadmic=host
 495       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 496       ;;
 497     *)
 498       enable_liboffloadmic=no
 499       ;;
 500     esac
 501 fi])
 502 AC_SUBST(extra_liboffloadmic_configure_flags)
 503
 504 # Enable libgomp by default on hosted POSIX systems, and a few others.
 505 if test x$enable_libgomp = x ; then
 506     case "${target}" in
 507     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 508         ;;
 509     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 510         ;;
 511     *-*-solaris2* | *-*-hpux11*)
 512         ;;
 513     *-*-darwin* | *-*-aix*)
 514         ;;
 515     nvptx*-*-*)
 516         ;;
 517     *)
 518         noconfigdirs="$noconfigdirs target-libgomp"
 519         ;;
 520     esac
 521 fi
 522
 523 # Disable libatomic on unsupported systems.
 524 if test -d ${srcdir}/libatomic; then
 525     if test x$enable_libatomic = x; then
 526         AC_MSG_CHECKING([for libatomic support])
 527         if (srcdir=${srcdir}/libatomic; \
 528                 . ${srcdir}/configure.tgt; \
 529                 test -n "$UNSUPPORTED")
 530         then
 531             AC_MSG_RESULT([no])
 532             noconfigdirs="$noconfigdirs target-libatomic"
 533         else
 534             AC_MSG_RESULT([yes])
 535         fi
 536     fi
 537 fi
 538
 539 # Disable liboffloadmic on unsupported systems.
 540 if test -d ${srcdir}/liboffloadmic; then
 541     if test x$enable_liboffloadmic != xno; then
 542         AC_MSG_CHECKING([for liboffloadmic support])
 543         if (srcdir=${srcdir}/liboffloadmic; \
 544                 . ${srcdir}/configure.tgt; \
 545                 test -n "$UNSUPPORTED")
 546         then
 547             AC_MSG_RESULT([no])
 548             noconfigdirs="$noconfigdirs target-liboffloadmic"
 549         else
 550             AC_MSG_RESULT([yes])
 551         fi
 552     fi
 553 fi
 554
 555 # Disable libitm on unsupported systems.
 556 if test -d ${srcdir}/libitm; then
 557     if test x$enable_libitm = x; then
 558         AC_MSG_CHECKING([for libitm support])
 559         if (srcdir=${srcdir}/libitm; \
 560                 . ${srcdir}/configure.tgt; \
 561                 test -n "$UNSUPPORTED")
 562         then
 563             AC_MSG_RESULT([no])
 564             noconfigdirs="$noconfigdirs target-libitm"
 565         else
 566             AC_MSG_RESULT([yes])
 567         fi
 568     fi
 569 fi
 570
 571 # Disable libsanitizer on unsupported systems.
 572 if test -d ${srcdir}/libsanitizer; then
 573     if test x$enable_libsanitizer = x; then
 574         AC_MSG_CHECKING([for libsanitizer support])
 575         if (srcdir=${srcdir}/libsanitizer; \
 576                 . ${srcdir}/configure.tgt; \
 577                 test -n "$UNSUPPORTED")
 578         then
 579             AC_MSG_RESULT([no])
 580             noconfigdirs="$noconfigdirs target-libsanitizer"
 581         else
 582             AC_MSG_RESULT([yes])
 583         fi
 584     fi
 585 fi
 586
 587 # Disable libvtv on unsupported systems.
 588 if test -d ${srcdir}/libvtv; then
 589     if test x$enable_libvtv = x; then
 590         AC_MSG_CHECKING([for libvtv support])
 591         if (srcdir=${srcdir}/libvtv; \
 592                 . ${srcdir}/configure.tgt; \
 593                 test "$VTV_SUPPORTED" != "yes")
 594         then
 595             AC_MSG_RESULT([no])
 596             noconfigdirs="$noconfigdirs target-libvtv"
 597         else
 598             AC_MSG_RESULT([yes])
 599         fi
 600     fi
 601 fi
 602
 603
 604 # Enable libmpx on supported systems by request.
 605 if test -d ${srcdir}/libmpx; then
 606     if test x$enable_libmpx = x; then
 607        AC_MSG_CHECKING([for libmpx support])
 608        if (srcdir=${srcdir}/libmpx; \
 609                . ${srcdir}/configure.tgt; \
 610                test "$LIBMPX_SUPPORTED" != "yes")
 611        then
 612            AC_MSG_RESULT([no])
 613            noconfigdirs="$noconfigdirs target-libmpx"
 614        else
 615            AC_MSG_RESULT([yes])
 616        fi
 617     fi
 618 fi
 619
 620 # Disable libhsail-rt on unsupported systems.
 621 if test -d ${srcdir}/libhsail-rt; then
 622     if test x$enable_libhsail_rt = x; then
 623         AC_MSG_CHECKING([for libhsail-rt support])
 624         if (srcdir=${srcdir}/libhsail-rt; \
 625                 . ${srcdir}/configure.tgt; \
 626                 test -n "$UNSUPPORTED")
 627         then
 628             AC_MSG_RESULT([no])
 629             unsupported_languages="$unsupported_languages brig"
 630             # This implicitly disables also target-libhsail-rt as it won't
 631             # get added to the build without BRIG FE.
 632         else
 633             AC_MSG_RESULT([yes])
 634         fi
 635     fi
 636 fi
 637
 638
 639 # Disable libquadmath for some systems.
 640 case "${target}" in
 641   avr-*-*)
 642     noconfigdirs="$noconfigdirs target-libquadmath"
 643     ;;
 644   # libquadmath is unused on AIX and libquadmath build process use of
 645   # LD_LIBRARY_PATH can break AIX bootstrap.
 646   powerpc-*-aix* | rs6000-*-aix*)
 647     noconfigdirs="$noconfigdirs target-libquadmath"
 648     ;;
 649 esac
 650
 651 # Disable libssp for some systems.
 652 case "${target}" in
 653   avr-*-*)
 654     # No hosted I/O support.
 655     noconfigdirs="$noconfigdirs target-libssp"
 656     ;;
 657   powerpc-*-aix* | rs6000-*-aix*)
 658     noconfigdirs="$noconfigdirs target-libssp"
 659     ;;
 660   rl78-*-*)
 661     # libssp uses a misaligned load to trigger a fault, but the RL78
 662     # doesn't fault for those - instead, it gives a build-time error
 663     # for explicit misaligned loads.
 664     noconfigdirs="$noconfigdirs target-libssp"
 665     ;;
 666   visium-*-*)
 667     # No hosted I/O support.
 668     noconfigdirs="$noconfigdirs target-libssp"
 669     ;;
 670 esac
 671
 672 # Disable libstdc++-v3 for some systems.
 673 # Allow user to override this if they pass --enable-libstdc++-v3
 674 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 675   case "${target}" in
 676     *-*-vxworks*)
 677       # VxWorks uses the Dinkumware C++ library.
 678       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 679       ;;
 680     arm*-wince-pe*)
 681       # the C++ libraries don't build on top of CE's C libraries
 682       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 683       ;;
 684     avr-*-*)
 685       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 686       ;;
 687     ft32-*-*)
 688       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 689       ;;
 690   esac
 691 fi
 692
 693 # Disable Fortran for some systems.
 694 case "${target}" in
 695   mmix-*-*)
 696     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 697     unsupported_languages="$unsupported_languages fortran"
 698     ;;
 699 esac
 700
 701 # Disable libffi for some systems.
 702 case "${target}" in
 703   powerpc-*-darwin*)
 704     ;;
 705   i[[3456789]]86-*-darwin*)
 706     ;;
 707   x86_64-*-darwin[[912]]*)
 708     ;;
 709   *-*-darwin*)
 710     noconfigdirs="$noconfigdirs target-libffi"
 711     ;;
 712   *-*-netware*)
 713     noconfigdirs="$noconfigdirs target-libffi"
 714     ;;
 715   *-*-phoenix*)
 716     noconfigdirs="$noconfigdirs target-libffi"
 717     ;;
 718   *-*-rtems*)
 719     noconfigdirs="$noconfigdirs target-libffi"
 720     ;;
 721   *-*-tpf*)
 722     noconfigdirs="$noconfigdirs target-libffi"
 723     ;;
 724   *-*-uclinux*)
 725     noconfigdirs="$noconfigdirs target-libffi"
 726     ;;
 727   *-*-vxworks*)
 728     noconfigdirs="$noconfigdirs target-libffi"
 729     ;;
 730   aarch64*-*-freebsd*)
 731     noconfigdirs="$noconfigdirs target-libffi"
 732     ;;
 733   alpha*-*-*vms*)
 734     noconfigdirs="$noconfigdirs target-libffi"
 735     ;;
 736   arm*-*-freebsd*)
 737     noconfigdirs="$noconfigdirs target-libffi"
 738     ;;
 739   arm-wince-pe)
 740     noconfigdirs="$noconfigdirs target-libffi"
 741     ;;
 742   arm*-*-symbianelf*)
 743     noconfigdirs="$noconfigdirs target-libffi"
 744     ;;
 745   cris-*-* | crisv32-*-*)
 746     case "${target}" in
 747       *-*-linux*)
 748         ;;
 749       *) # See PR46792 regarding target-libffi.
 750         noconfigdirs="$noconfigdirs target-libffi";;
 751     esac
 752     ;;
 753   hppa*64*-*-hpux*)
 754     noconfigdirs="$noconfigdirs target-libffi"
 755     ;;
 756   hppa*-hp-hpux11*)
 757     ;;
 758   hppa*-*-hpux*)
 759     noconfigdirs="$noconfigdirs target-libffi"
 760     ;;
 761   ia64*-*-*vms*)
 762     noconfigdirs="$noconfigdirs target-libffi"
 763     ;;
 764   i[[3456789]]86-w64-mingw*)
 765     noconfigdirs="$noconfigdirs target-libffi"
 766     ;;
 767   i[[3456789]]86-*-mingw*)
 768     noconfigdirs="$noconfigdirs target-libffi"
 769     ;;
 770   x86_64-*-mingw*)
 771     noconfigdirs="$noconfigdirs target-libffi"
 772     ;;
 773   mmix-*-*)
 774     noconfigdirs="$noconfigdirs target-libffi"
 775     ;;
 776   powerpc-*-aix*)
 777     ;;
 778   rs6000-*-aix*)
 779     ;;
 780   ft32-*-*)
 781     noconfigdirs="$noconfigdirs target-libffi"
 782     ;;
 783   *-*-lynxos*)
 784     noconfigdirs="$noconfigdirs target-libffi"
 785     ;;
 786 esac
 787
 788 # Disable the go frontend on systems where it is known to not work. Please keep
 789 # this in sync with contrib/config-list.mk.
 790 case "${target}" in
 791 *-*-darwin* | *-*-cygwin* | *-*-mingw*)
 792     unsupported_languages="$unsupported_languages go"
 793     ;;
 794 esac
 795
 796 # Disable libgo for some systems where it is known to not work.
 797 # For testing, you can easily override this with --enable-libgo.
 798 if test x$enable_libgo = x; then
 799     case "${target}" in
 800     *-*-darwin*)
 801         # PR 46986
 802         noconfigdirs="$noconfigdirs target-libgo"
 803         ;;
 804     *-*-cygwin* | *-*-mingw*)
 805         noconfigdirs="$noconfigdirs target-libgo"
 806         ;;
 807     esac
 808 fi
 809
 810 # Default libgloss CPU subdirectory.
 811 libgloss_dir="$target_cpu"
 812
 813 case "${target}" in
 814   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 815     libgloss_dir=wince
 816     ;;
 817   aarch64*-*-* )
 818     libgloss_dir=aarch64
 819     ;;
 820   arm*-*-*)
 821     libgloss_dir=arm
 822     ;;
 823   cris-*-* | crisv32-*-*)
 824     libgloss_dir=cris
 825     ;;
 826   hppa*-*-*)
 827     libgloss_dir=pa
 828     ;;
 829   i[[3456789]]86-*-*)
 830     libgloss_dir=i386
 831     ;;
 832   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 833     libgloss_dir=m68hc11
 834     ;;
 835   m68*-*-* | fido-*-*)
 836     libgloss_dir=m68k
 837     ;;
 838   mips*-*-*)
 839     libgloss_dir=mips
 840     ;;
 841   powerpc*-*-*)
 842     libgloss_dir=rs6000
 843     ;;
 844   sparc*-*-*)
 845     libgloss_dir=sparc
 846     ;;
 847 esac
 848
 849 # Disable newlib and libgloss for various target OSes.
 850 case "${target}" in
 851   alpha*-dec-osf*)
 852     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 853     ;;
 854   i[[3456789]]86-*-linux*)
 855     # This section makes it possible to build newlib natively on linux.
 856     # If we are using a cross compiler then don't configure newlib.
 857     if test x${is_cross_compiler} != xno ; then
 858       noconfigdirs="$noconfigdirs target-newlib"
 859     fi
 860     noconfigdirs="$noconfigdirs target-libgloss"
 861     # If we are not using a cross compiler, do configure newlib.
 862     # Note however, that newlib will only be configured in this situation
 863     # if the --with-newlib option has been given, because otherwise
 864     # 'target-newlib' will appear in skipdirs.
 865     ;;
 866   i[[3456789]]86-*-rdos*)
 867     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 868     ;;
 869   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 870     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 871     ;;
 872   sparc-*-sunos4*)
 873     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 874     ;;
 875   *-*-aix*)
 876     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 877     ;;
 878   *-*-beos*)
 879     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 880     ;;
 881   *-*-chorusos)
 882     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 883     ;;
 884   *-*-dragonfly*)
 885     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 886     ;;
 887   *-*-freebsd*)
 888     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 889     ;;
 890   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 891     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 892     ;;
 893   *-*-lynxos*)
 894     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 895     ;;
 896   *-*-mingw*)
 897     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 898     ;;
 899   *-*-netbsd*)
 900     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 901     ;;
 902   *-*-netware*)
 903     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 904     ;;
 905   *-*-tpf*)
 906     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 907     ;;
 908   *-*-uclinux*)
 909     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 910     ;;
 911   *-*-vxworks*)
 912     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 913     ;;
 914 esac
 915
 916 case "${target}" in
 917   *-*-chorusos)
 918     ;;
 919   aarch64-*-darwin*)
 920     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 921     noconfigdirs="$noconfigdirs sim target-rda"
 922     ;;
 923   arm-*-darwin*)
 924     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 925     noconfigdirs="$noconfigdirs sim target-rda"
 926     ;;
 927   powerpc-*-darwin*)
 928     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 929     noconfigdirs="$noconfigdirs sim target-rda"
 930     ;;
 931   i[[3456789]]86-*-darwin*)
 932     noconfigdirs="$noconfigdirs ld gprof"
 933     noconfigdirs="$noconfigdirs sim target-rda"
 934     ;;
 935   x86_64-*-darwin[[912]]*)
 936     noconfigdirs="$noconfigdirs ld gas gprof"
 937     noconfigdirs="$noconfigdirs sim target-rda"
 938     ;;
 939   *-*-darwin*)
 940     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 941     noconfigdirs="$noconfigdirs sim target-rda"
 942     ;;
 943   *-*-dragonfly*)
 944     ;;
 945   *-*-freebsd*)
 946     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 947         && test -f /usr/local/include/gmp.h; then
 948       with_gmp=/usr/local
 949     fi
 950     ;;
 951   *-*-kaos*)
 952     # Remove unsupported stuff on all kaOS configurations.
 953     noconfigdirs="$noconfigdirs target-libgloss"
 954     ;;
 955   *-*-netbsd*)
 956     ;;
 957   *-*-netware*)
 958     ;;
 959   *-*-phoenix*)
 960     noconfigdirs="$noconfigdirs target-libgloss"
 961     ;;
 962   *-*-rtems*)
 963     noconfigdirs="$noconfigdirs target-libgloss"
 964     ;;
 965     # The tpf target doesn't support gdb yet.
 966   *-*-tpf*)
 967     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 968     ;;
 969   *-*-uclinux*)
 970     noconfigdirs="$noconfigdirs target-rda"
 971     ;;
 972   *-*-vxworks*)
 973     ;;
 974   alpha*-dec-osf*)
 975     # ld works, but does not support shared libraries.
 976     # gas doesn't generate exception information.
 977     noconfigdirs="$noconfigdirs gas ld"
 978     ;;
 979   alpha*-*-*vms*)
 980     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 981     ;;
 982   alpha*-*-*)
 983     # newlib is not 64 bit ready
 984     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 985     ;;
 986   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 987     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 988     ;;
 989   arc*-*-*)
 990     noconfigdirs="$noconfigdirs sim"
 991     ;;
 992   arm-*-pe*)
 993     noconfigdirs="$noconfigdirs target-libgloss"
 994     ;;
 995   arm-*-riscix*)
 996     noconfigdirs="$noconfigdirs ld target-libgloss"
 997     ;;
 998   avr-*-*)
 999     if test x${with_avrlibc} != xno; then
1000       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1001     fi
1002     ;;
1003   c4x-*-* | tic4x-*-*)
1004     noconfigdirs="$noconfigdirs target-libgloss"
1005     ;;
1006   tic54x-*-*)
1007     noconfigdirs="$noconfigdirs target-libgloss gdb"
1008     ;;
1009   d10v-*-*)
1010     noconfigdirs="$noconfigdirs target-libgloss"
1011     ;;
1012   d30v-*-*)
1013     noconfigdirs="$noconfigdirs gdb"
1014     ;;
1015   fr30-*-elf*)
1016     noconfigdirs="$noconfigdirs gdb"
1017     ;;
1018   ft32-*-*)
1019     noconfigdirs="$noconfigdirs target-rda gprof"
1020     ;;
1021   moxie-*-*)
1022     noconfigdirs="$noconfigdirs"
1023     ;;
1024   h8300*-*-*)
1025     noconfigdirs="$noconfigdirs target-libgloss"
1026     ;;
1027   h8500-*-*)
1028     noconfigdirs="$noconfigdirs target-libgloss"
1029     ;;
1030   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1031     ;;
1032   hppa*64*-*-hpux*)
1033     noconfigdirs="$noconfigdirs gdb"
1034     ;;
1035   hppa*-*-hpux11*)
1036     noconfigdirs="$noconfigdirs gdb ld"
1037     ;;
1038   hppa*64*-*-linux*)
1039     ;;
1040   hppa*-*-linux*)
1041     ;;
1042   hppa*-*-*elf* | \
1043   hppa*-*-lites* | \
1044   hppa*-*-openbsd* | \
1045   hppa*64*-*-*)
1046     ;;
1047   hppa*-*-pro*)
1048     ;;
1049   hppa*-*-*)
1050     noconfigdirs="$noconfigdirs ld"
1051     ;;
1052   i960-*-*)
1053     noconfigdirs="$noconfigdirs gdb"
1054     ;;
1055   ia64*-*-elf*)
1056     # No gdb support yet.
1057     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1058     ;;
1059   ia64*-**-hpux*)
1060     # No ld support yet.
1061     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1062     ;;
1063   ia64*-*-*vms*)
1064     # No ld support yet.
1065     noconfigdirs="$noconfigdirs libgui itcl ld"
1066     ;;
1067   i[[3456789]]86-w64-mingw*)
1068     ;;
1069   i[[3456789]]86-*-mingw*)
1070     target_configdirs="$target_configdirs target-winsup"
1071     ;;
1072   *-*-cygwin*)
1073     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1074     noconfigdirs="$noconfigdirs target-libgloss"
1075     # always build newlib if winsup directory is present.
1076     if test -d "$srcdir/winsup/cygwin"; then
1077       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1078     elif test -d "$srcdir/newlib"; then
1079       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1080     fi
1081     ;;
1082   i[[3456789]]86-*-pe)
1083     noconfigdirs="$noconfigdirs target-libgloss"
1084     ;;
1085   i[[3456789]]86-*-sco3.2v5*)
1086     # The linker does not yet know about weak symbols in COFF,
1087     # and is not configured to handle mixed ELF and COFF.
1088     noconfigdirs="$noconfigdirs ld target-libgloss"
1089     ;;
1090   i[[3456789]]86-*-sco*)
1091     noconfigdirs="$noconfigdirs gprof target-libgloss"
1092     ;;
1093   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1094     noconfigdirs="$noconfigdirs target-libgloss"
1095     ;;
1096   i[[3456789]]86-*-sysv4*)
1097     noconfigdirs="$noconfigdirs target-libgloss"
1098     ;;
1099   i[[3456789]]86-*-beos*)
1100     noconfigdirs="$noconfigdirs gdb"
1101     ;;
1102   i[[3456789]]86-*-rdos*)
1103     noconfigdirs="$noconfigdirs gdb"
1104     ;;
1105   mmix-*-*)
1106     noconfigdirs="$noconfigdirs gdb"
1107     ;;
1108   mt-*-*)
1109     noconfigdirs="$noconfigdirs sim"
1110     ;;
1111   powerpc-*-aix*)
1112     # copied from rs6000-*-* entry
1113     noconfigdirs="$noconfigdirs gprof"
1114     ;;
1115   powerpc*-*-winnt* | powerpc*-*-pe*)
1116     target_configdirs="$target_configdirs target-winsup"
1117     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1118     # always build newlib.
1119     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1120     ;;
1121     # This is temporary until we can link against shared libraries
1122   powerpcle-*-solaris*)
1123     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1124     ;;
1125   powerpc-*-beos*)
1126     noconfigdirs="$noconfigdirs gdb"
1127     ;;
1128   rs6000-*-lynxos*)
1129     noconfigdirs="$noconfigdirs gprof"
1130     ;;
1131   rs6000-*-aix*)
1132     noconfigdirs="$noconfigdirs gprof"
1133     ;;
1134   rs6000-*-*)
1135     noconfigdirs="$noconfigdirs gprof"
1136     ;;
1137   m68k-apollo-*)
1138     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1139     ;;
1140   microblaze*)
1141     noconfigdirs="$noconfigdirs gprof"
1142     ;;
1143   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1144     if test x$with_newlib = xyes; then
1145       noconfigdirs="$noconfigdirs gprof"
1146     fi
1147     ;;
1148   mips*-*-irix5*)
1149     noconfigdirs="$noconfigdirs gprof target-libgloss"
1150     ;;
1151   mips*-*-irix6*)
1152     noconfigdirs="$noconfigdirs gprof target-libgloss"
1153     ;;
1154   mips*-*-bsd*)
1155     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1156     ;;
1157   mips*-*-linux*)
1158     ;;
1159   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1160   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1161     noconfigdirs="$noconfigdirs ld gas gprof"
1162     ;;
1163   mips*-*-*)
1164     noconfigdirs="$noconfigdirs gprof"
1165     ;;
1166   nvptx*-*-*)
1167     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1168     ;;
1169   sh-*-*)
1170     case "${target}" in
1171       sh*-*-elf)
1172          ;;
1173       *)
1174          noconfigdirs="$noconfigdirs target-libgloss" ;;
1175     esac
1176     ;;
1177   sparc-*-sunos4*)
1178     if test x${is_cross_compiler} = xno ; then
1179            use_gnu_ld=no
1180     fi
1181     ;;
1182   tic6x-*-*)
1183     noconfigdirs="$noconfigdirs sim"
1184     ;;
1185   tilepro*-*-* | tilegx*-*-*)
1186     noconfigdirs="$noconfigdirs sim"
1187     ;;
1188   v810-*-*)
1189     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1190     ;;
1191   vax-*-*)
1192     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1193     ;;
1194 esac
1195
1196 # If we aren't building newlib, then don't build libgloss, since libgloss
1197 # depends upon some newlib header files.
1198 case "${noconfigdirs}" in
1199   *target-libgloss*) ;;
1200   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1201 esac
1202
1203 # Work in distributions that contain no compiler tools, like Autoconf.
1204 host_makefile_frag=/dev/null
1205 if test -d ${srcdir}/config ; then
1206 case "${host}" in
1207   i[[3456789]]86-*-msdosdjgpp*)
1208     host_makefile_frag="config/mh-djgpp"
1209     ;;
1210   *-cygwin*)
1211     ACX_CHECK_CYGWIN_CAT_WORKS
1212     host_makefile_frag="config/mh-cygwin"
1213     ;;
1214   *-mingw*)
1215     host_makefile_frag="config/mh-mingw"
1216     ;;
1217   alpha*-linux*)
1218     host_makefile_frag="config/mh-alpha-linux"
1219     ;;
1220   hppa*-hp-hpux10*)
1221     host_makefile_frag="config/mh-pa-hpux10"
1222     ;;
1223   hppa*-hp-hpux*)
1224     host_makefile_frag="config/mh-pa"
1225     ;;
1226   hppa*-*)
1227     host_makefile_frag="config/mh-pa"
1228     ;;
1229   *-*-darwin*)
1230     host_makefile_frag="config/mh-darwin"
1231     ;;
1232   powerpc-*-aix*)
1233     host_makefile_frag="config/mh-ppc-aix"
1234     ;;
1235   rs6000-*-aix*)
1236     host_makefile_frag="config/mh-ppc-aix"
1237     ;;
1238 esac
1239 fi
1240
1241 if test "${build}" != "${host}" ; then
1242   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1243   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1244   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1245   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1246   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1247   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1248   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1249   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1250   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1251   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1252   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1253   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1254 else
1255   AR_FOR_BUILD="\$(AR)"
1256   AS_FOR_BUILD="\$(AS)"
1257   CC_FOR_BUILD="\$(CC)"
1258   CXX_FOR_BUILD="\$(CXX)"
1259   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1260   GOC_FOR_BUILD="\$(GOC)"
1261   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1262   LD_FOR_BUILD="\$(LD)"
1263   NM_FOR_BUILD="\$(NM)"
1264   RANLIB_FOR_BUILD="\$(RANLIB)"
1265   WINDRES_FOR_BUILD="\$(WINDRES)"
1266   WINDMC_FOR_BUILD="\$(WINDMC)"
1267 fi
1268
1269 AC_PROG_CC
1270 AC_PROG_CXX
1271
1272 # We must set the default linker to the linker used by gcc for the correct
1273 # operation of libtool.  If LD is not defined and we are using gcc, try to
1274 # set the LD default to the ld used by gcc.
1275 if test -z "$LD"; then
1276   if test "$GCC" = yes; then
1277     case $build in
1278     *-*-mingw*)
1279       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1280     *)
1281       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1282     esac
1283     case $gcc_prog_ld in
1284     # Accept absolute paths.
1285     [[\\/]* | [A-Za-z]:[\\/]*)]
1286       LD="$gcc_prog_ld" ;;
1287     esac
1288   fi
1289 fi
1290
1291 # Check whether -static-libstdc++ -static-libgcc is supported.
1292 have_static_libs=no
1293 if test "$GCC" = yes; then
1294   saved_LDFLAGS="$LDFLAGS"
1295
1296   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1297   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1298   AC_LANG_PUSH(C++)
1299   AC_LINK_IFELSE([
1300 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1301 #error -static-libstdc++ not implemented
1302 #endif
1303 int main() {}],
1304     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1305     [AC_MSG_RESULT([no])])
1306   AC_LANG_POP(C++)
1307
1308   LDFLAGS="$saved_LDFLAGS"
1309 fi
1310
1311 ACX_PROG_GNAT
1312 ACX_PROG_CMP_IGNORE_INITIAL
1313
1314 AC_ARG_ENABLE([bootstrap],
1315 [AS_HELP_STRING([--enable-bootstrap],
1316                 [enable bootstrapping @<:@yes if native build@:>@])],,
1317 enable_bootstrap=default)
1318
1319 # Issue errors and warnings for invalid/strange bootstrap combinations.
1320 if test -r $srcdir/gcc/configure; then
1321   have_compiler=yes
1322 else
1323   have_compiler=no
1324 fi
1325
1326 case "$have_compiler:$host:$target:$enable_bootstrap" in
1327   *:*:*:no) ;;
1328
1329   # Default behavior.  Enable bootstrap if we have a compiler
1330   # and we are in a native configuration.
1331   yes:$build:$build:default)
1332     enable_bootstrap=yes ;;
1333
1334   *:*:*:default)
1335     enable_bootstrap=no ;;
1336
1337   # We have a compiler and we are in a native configuration, bootstrap is ok
1338   yes:$build:$build:yes)
1339     ;;
1340
1341   # Other configurations, but we have a compiler.  Assume the user knows
1342   # what he's doing.
1343   yes:*:*:yes)
1344     AC_MSG_WARN([trying to bootstrap a cross compiler])
1345     ;;
1346
1347   # No compiler: if they passed --enable-bootstrap explicitly, fail
1348   no:*:*:yes)
1349     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1350
1351   # Fail if wrong command line
1352   *)
1353     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1354     ;;
1355 esac
1356
1357 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1358 # C++98 compiler can still start the bootstrap.
1359 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1360   CXX="$CXX -std=gnu++98"
1361 fi
1362
1363 # Used for setting $lt_cv_objdir
1364 _LT_CHECK_OBJDIR
1365
1366 # Check for GMP, MPFR and MPC
1367 gmplibs="-lmpc -lmpfr -lgmp"
1368 gmpinc=
1369 have_gmp=no
1370
1371 # Specify a location for mpc
1372 # check for this first so it ends up on the link line before mpfr.
1373 AC_ARG_WITH(mpc,
1374 [AS_HELP_STRING([--with-mpc=PATH],
1375                 [specify prefix directory for installed MPC package.
1376                  Equivalent to --with-mpc-include=PATH/include
1377                  plus --with-mpc-lib=PATH/lib])])
1378 AC_ARG_WITH(mpc-include,
1379 [AS_HELP_STRING([--with-mpc-include=PATH],
1380                 [specify directory for installed MPC include files])])
1381 AC_ARG_WITH(mpc-lib,
1382 [AS_HELP_STRING([--with-mpc-lib=PATH],
1383                 [specify directory for the installed MPC library])])
1384
1385 if test "x$with_mpc" != x; then
1386   gmplibs="-L$with_mpc/lib $gmplibs"
1387   gmpinc="-I$with_mpc/include $gmpinc"
1388 fi
1389 if test "x$with_mpc_include" != x; then
1390   gmpinc="-I$with_mpc_include $gmpinc"
1391 fi
1392 if test "x$with_mpc_lib" != x; then
1393   gmplibs="-L$with_mpc_lib $gmplibs"
1394 fi
1395 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1396   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1397   gmpinc='-I$$s/mpc/src '"$gmpinc"
1398   # Do not test the mpc version.  Assume that it is sufficient, since
1399   # it is in the source tree, and the library has not been built yet
1400   # but it would be included on the link line in the version check below
1401   # hence making the test fail.
1402   have_gmp=yes
1403 fi
1404
1405 # Specify a location for mpfr
1406 # check for this first so it ends up on the link line before gmp.
1407 AC_ARG_WITH(mpfr-dir,
1408 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1409 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1410 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1411
1412 AC_ARG_WITH(mpfr,
1413 [AS_HELP_STRING([--with-mpfr=PATH],
1414                 [specify prefix directory for installed MPFR package.
1415                  Equivalent to --with-mpfr-include=PATH/include
1416                  plus --with-mpfr-lib=PATH/lib])])
1417 AC_ARG_WITH(mpfr-include,
1418 [AS_HELP_STRING([--with-mpfr-include=PATH],
1419                 [specify directory for installed MPFR include files])])
1420 AC_ARG_WITH(mpfr-lib,
1421 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1422                 [specify directory for the installed MPFR library])])
1423
1424 if test "x$with_mpfr" != x; then
1425   gmplibs="-L$with_mpfr/lib $gmplibs"
1426   gmpinc="-I$with_mpfr/include $gmpinc"
1427 fi
1428 if test "x$with_mpfr_include" != x; then
1429   gmpinc="-I$with_mpfr_include $gmpinc"
1430 fi
1431 if test "x$with_mpfr_lib" != x; then
1432   gmplibs="-L$with_mpfr_lib $gmplibs"
1433 fi
1434 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1435   # MPFR v3.1.0 moved the sources into a src sub-directory.
1436   if ! test -d ${srcdir}/mpfr/src; then
1437     AC_MSG_ERROR([dnl
1438 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1439   fi
1440   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1441   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1442   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1443   # Do not test the mpfr version.  Assume that it is sufficient, since
1444   # it is in the source tree, and the library has not been built yet
1445   # but it would be included on the link line in the version check below
1446   # hence making the test fail.
1447   have_gmp=yes
1448 fi
1449
1450 # Specify a location for gmp
1451 AC_ARG_WITH(gmp-dir,
1452 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1453 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1454 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1455
1456 AC_ARG_WITH(gmp,
1457 [AS_HELP_STRING([--with-gmp=PATH],
1458                 [specify prefix directory for the installed GMP package.
1459                  Equivalent to --with-gmp-include=PATH/include
1460                  plus --with-gmp-lib=PATH/lib])])
1461 AC_ARG_WITH(gmp-include,
1462 [AS_HELP_STRING([--with-gmp-include=PATH],
1463                 [specify directory for installed GMP include files])])
1464 AC_ARG_WITH(gmp-lib,
1465 [AS_HELP_STRING([--with-gmp-lib=PATH],
1466                 [specify directory for the installed GMP library])])
1467
1468
1469 if test "x$with_gmp" != x; then
1470   gmplibs="-L$with_gmp/lib $gmplibs"
1471   gmpinc="-I$with_gmp/include $gmpinc"
1472 fi
1473 if test "x$with_gmp_include" != x; then
1474   gmpinc="-I$with_gmp_include $gmpinc"
1475 fi
1476 if test "x$with_gmp_lib" != x; then
1477   gmplibs="-L$with_gmp_lib $gmplibs"
1478 fi
1479 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1480   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1481   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1482   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1483   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1484   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1485   # Do not test the gmp version.  Assume that it is sufficient, since
1486   # it is in the source tree, and the library has not been built yet
1487   # but it would be included on the link line in the version check below
1488   # hence making the test fail.
1489   have_gmp=yes
1490 fi
1491
1492 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1493   have_gmp=yes
1494   saved_CFLAGS="$CFLAGS"
1495   CFLAGS="$CFLAGS $gmpinc"
1496   # Check for the recommended and required versions of GMP.
1497   AC_MSG_CHECKING([for the correct version of gmp.h])
1498   AC_TRY_COMPILE([#include "gmp.h"],[
1499   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1500   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1501   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1502   choke me
1503   #endif
1504   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1505   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1506   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1507   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1508   choke me
1509   #endif
1510   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1511    [AC_MSG_RESULT([no]); have_gmp=no])
1512
1513   # If we have GMP, check the MPFR version.
1514   if test x"$have_gmp" = xyes; then
1515     # Check for the recommended and required versions of MPFR.
1516     AC_MSG_CHECKING([for the correct version of mpfr.h])
1517     AC_TRY_COMPILE([#include <gmp.h>
1518     #include <mpfr.h>],[
1519     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1520     choke me
1521     #endif
1522     ], [AC_TRY_COMPILE([#include <gmp.h>
1523     #include <mpfr.h>],[
1524     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1525     choke me
1526     #endif
1527     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1528      [AC_MSG_RESULT([no]); have_gmp=no])
1529   fi
1530
1531   # Check for the MPC header version.
1532   if test x"$have_gmp" = xyes ; then
1533     # Check for the recommended and required versions of MPC.
1534     AC_MSG_CHECKING([for the correct version of mpc.h])
1535     AC_TRY_COMPILE([#include <mpc.h>],[
1536     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1537     choke me
1538     #endif
1539     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1540     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1541     choke me
1542     #endif
1543     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1544      [AC_MSG_RESULT([no]); have_gmp=no])
1545   fi
1546
1547   # Now check the MPFR library.
1548   if test x"$have_gmp" = xyes; then
1549     saved_LIBS="$LIBS"
1550     LIBS="$LIBS $gmplibs"
1551     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1552     AC_TRY_LINK([#include <mpc.h>],[
1553     mpfr_t n;
1554     mpfr_t x;
1555     mpc_t c;
1556     int t;
1557     mpfr_init (n);
1558     mpfr_init (x);
1559     mpfr_atan2 (n, n, x, GMP_RNDN);
1560     mpfr_erfc (n, x, GMP_RNDN);
1561     mpfr_subnormalize (x, t, GMP_RNDN);
1562     mpfr_clear(n);
1563     mpfr_clear(x);
1564     mpc_init2 (c, 53);
1565     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1566     mpc_cosh (c, c, MPC_RNDNN);
1567     mpc_pow (c, c, c, MPC_RNDNN);
1568     mpc_acosh (c, c, MPC_RNDNN);
1569     mpc_clear (c);
1570     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1571     LIBS="$saved_LIBS"
1572   fi
1573
1574   CFLAGS="$saved_CFLAGS"
1575
1576 # The library versions listed in the error message below should match
1577 # the HARD-minimums enforced above.
1578   if test x$have_gmp != xyes; then
1579     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1580 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1581 their locations.  Source code for these libraries can be found at
1582 their respective hosting sites as well as at
1583 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1584 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1585 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1586 make sure that you have installed both the libraries and the header
1587 files.  They may be located in separate packages.])
1588   fi
1589 fi
1590
1591 # Flags needed for both GMP, MPFR and/or MPC.
1592 AC_SUBST(gmplibs)
1593 AC_SUBST(gmpinc)
1594 AC_SUBST(extra_mpfr_configure_flags)
1595 AC_SUBST(extra_mpc_gmp_configure_flags)
1596 AC_SUBST(extra_mpc_mpfr_configure_flags)
1597 AC_SUBST(extra_isl_gmp_configure_flags)
1598
1599 # Libraries to use for stage1 or when not bootstrapping.
1600 AC_ARG_WITH(stage1-libs,
1601 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1602 [if test "$withval" = "no" -o "$withval" = "yes"; then
1603    stage1_libs=
1604  else
1605    stage1_libs=$withval
1606  fi],
1607 [stage1_libs=])
1608 AC_SUBST(stage1_libs)
1609
1610 # Linker flags to use for stage1 or when not bootstrapping.
1611 AC_ARG_WITH(stage1-ldflags,
1612 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1613 [if test "$withval" = "no" -o "$withval" = "yes"; then
1614    stage1_ldflags=
1615  else
1616    stage1_ldflags=$withval
1617  fi],
1618 [stage1_ldflags=
1619  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1620  # if supported.  But if the user explicitly specified the libraries to use,
1621  # trust that they are doing what they want.
1622  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1623    stage1_ldflags="-static-libstdc++ -static-libgcc"
1624  fi])
1625 AC_SUBST(stage1_ldflags)
1626
1627 # Libraries to use for stage2 and later builds.
1628 AC_ARG_WITH(boot-libs,
1629 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1630 [if test "$withval" = "no" -o "$withval" = "yes"; then
1631    poststage1_libs=
1632  else
1633    poststage1_libs=$withval
1634  fi],
1635 [poststage1_libs=])
1636 AC_SUBST(poststage1_libs)
1637
1638 # Linker flags to use for stage2 and later builds.
1639 AC_ARG_WITH(boot-ldflags,
1640 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1641                 [linker flags for stage2 and later])],
1642 [if test "$withval" = "no" -o "$withval" = "yes"; then
1643    poststage1_ldflags=
1644  else
1645    poststage1_ldflags=$withval
1646  fi],
1647 [poststage1_ldflags=
1648  # In stages 2 and 3, default to linking libstdc++ and libgcc
1649  # statically.  But if the user explicitly specified the libraries to
1650  # use, trust that they are doing what they want.
1651  if test "$poststage1_libs" = ""; then
1652    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1653  fi])
1654 AC_SUBST(poststage1_ldflags)
1655
1656 # GCC GRAPHITE dependency isl.
1657 # Basic setup is inlined here, actual checks are in config/isl.m4
1658
1659 AC_ARG_WITH(isl,
1660   [AS_HELP_STRING(
1661    [--with-isl=PATH],
1662    [Specify prefix directory for the installed isl package.
1663     Equivalent to --with-isl-include=PATH/include
1664     plus --with-isl-lib=PATH/lib])])
1665
1666 # Treat --without-isl as a request to disable
1667 # GRAPHITE support and skip all following checks.
1668 if test "x$with_isl" != "xno"; then
1669   # Check for isl
1670   dnl Provide configure switches and initialize islinc & isllibs
1671   dnl with user input.
1672   ISL_INIT_FLAGS
1673   dnl The versions of isl that work for Graphite
1674   ISL_CHECK_VERSION()
1675   dnl Only execute fail-action, if isl has been requested.
1676   ISL_IF_FAILED([
1677     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1678 fi
1679
1680 # If the isl check failed, disable builds of in-tree variant of isl
1681 if test "x$with_isl" = xno ||
1682    test "x$gcc_cv_isl" = xno; then
1683   noconfigdirs="$noconfigdirs isl"
1684   islinc=
1685 fi
1686
1687 AC_SUBST(isllibs)
1688 AC_SUBST(islinc)
1689
1690 # Check for LTO support.
1691 AC_ARG_ENABLE(lto,
1692 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1693 enable_lto=$enableval,
1694 enable_lto=yes; default_enable_lto=yes)
1695
1696 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1697   build_lto_plugin=yes
1698 ],[if test x"$default_enable_lto" = x"yes" ; then
1699     case $target in
1700       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1701       # On other non-ELF platforms, LTO has yet to be validated.
1702       *) enable_lto=no ;;
1703     esac
1704   else
1705   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1706   # It would also be nice to check the binutils support, but we don't
1707   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1708   # warn during gcc/ subconfigure; unless you're bootstrapping with
1709   # -flto it won't be needed until after installation anyway.
1710     case $target in
1711       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1712       *) if test x"$enable_lto" = x"yes"; then
1713         AC_MSG_ERROR([LTO support is not enabled for this target.])
1714         fi
1715       ;;
1716     esac
1717   fi
1718   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1719   # Build it unless LTO was explicitly disabled.
1720   case $target in
1721     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1722     *) ;;
1723   esac
1724 ])
1725
1726 AC_ARG_ENABLE(linker-plugin-configure-flags,
1727   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1728     [additional flags for configuring linker plugins @<:@none@:>@])],
1729   extra_linker_plugin_configure_flags=$enableval,
1730   extra_linker_plugin_configure_flags=)
1731 AC_SUBST(extra_linker_plugin_configure_flags)
1732 AC_ARG_ENABLE(linker-plugin-flags,
1733   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1734     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1735   extra_linker_plugin_flags=$enableval,
1736   extra_linker_plugin_flags=)
1737 AC_SUBST(extra_linker_plugin_flags)
1738
1739 # Enable --enable-host-shared.
1740 # Checked early to determine whether jit is an 'all' language
1741 AC_ARG_ENABLE(host-shared,
1742 [AS_HELP_STRING([--enable-host-shared],
1743                 [build host code as shared libraries])],
1744 [host_shared=$enableval], [host_shared=no])
1745 AC_SUBST(host_shared)
1746
1747 # By default, C and C++ are the only stage 1 languages.
1748 stage1_languages=,c,
1749
1750 # Target libraries that we bootstrap.
1751 bootstrap_target_libs=,target-libgcc,
1752
1753 # Figure out what language subdirectories are present.
1754 # Look if the user specified --enable-languages="..."; if not, use
1755 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1756 # go away some day.
1757 # NB:  embedded tabs in this IF block -- do not untabify
1758 if test -d ${srcdir}/gcc; then
1759   if test x"${enable_languages+set}" != xset; then
1760     if test x"${LANGUAGES+set}" = xset; then
1761       enable_languages="${LANGUAGES}"
1762         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1763     else
1764       enable_languages=default
1765     fi
1766   else
1767     if test x"${enable_languages}" = x ||
1768        test x"${enable_languages}" = xyes;
1769        then
1770       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1771       exit 1
1772     fi
1773   fi
1774   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1775
1776   # 'f95' is the old name for the 'fortran' language. We issue a warning
1777   # and make the substitution.
1778   case ,${enable_languages}, in
1779     *,f95,*)
1780       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1781       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1782       ;;
1783   esac
1784
1785   # If bootstrapping, C++ must be enabled.
1786   case ",$enable_languages,:$enable_bootstrap" in
1787     *,c++,*:*) ;;
1788     *:yes)
1789       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1790         enable_languages="${enable_languages},c++"
1791       else
1792         AC_MSG_ERROR([bootstrapping requires c++ sources])
1793       fi
1794       ;;
1795   esac
1796
1797   # First scan to see if an enabled language requires some other language.
1798   # We assume that a given config-lang.in will list all the language
1799   # front ends it requires, even if some are required indirectly.
1800   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1801     case ${lang_frag} in
1802       ..) ;;
1803       # The odd quoting in the next line works around
1804       # an apparent bug in bash 1.12 on linux.
1805       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1806       *)
1807         # From the config-lang.in, get $language, $lang_requires, and
1808         # $lang_requires_boot_languages.
1809         language=
1810         lang_requires=
1811         lang_requires_boot_languages=
1812         # set srcdir during sourcing lang_frag to the gcc dir.
1813         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1814         # polutes this shell
1815         saved_srcdir=${srcdir}
1816         srcdir=${srcdir}/gcc . ${lang_frag}
1817         srcdir=${saved_srcdir}
1818         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1819           case ,${enable_languages}, in
1820             *,$other,*) ;;
1821             *,default,*) ;;
1822             *,all,*) ;;
1823             *,$language,*)
1824               echo " \`$other' language required by \`$language'; enabling" 1>&2
1825               enable_languages="${enable_languages},${other}"
1826               ;;
1827           esac
1828         done
1829         for other in ${lang_requires_boot_languages} ; do
1830           if test "$other" != "c"; then
1831             case ,${enable_stage1_languages}, in
1832               *,$other,*) ;;
1833               *,default,*) ;;
1834               *,all,*) ;;
1835               *)
1836                 case ,${enable_languages}, in
1837                   *,$language,*)
1838                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1839                     enable_stage1_languages="$enable_stage1_languages,${other}"
1840                     ;;
1841                 esac
1842                 ;;
1843             esac
1844           fi
1845         done
1846         ;;
1847     esac
1848   done
1849
1850   new_enable_languages=,c,
1851
1852   # If LTO is enabled, add the LTO front end.
1853   if test "$enable_lto" = "yes" ; then
1854     case ,${enable_languages}, in
1855       *,lto,*) ;;
1856       *) enable_languages="${enable_languages},lto" ;;
1857     esac
1858     if test "${build_lto_plugin}" = "yes" ; then
1859       configdirs="$configdirs lto-plugin"
1860     fi
1861   fi
1862
1863   # If we're building an offloading compiler, add the LTO front end.
1864   if test x"$enable_as_accelerator_for" != x ; then
1865     case ,${enable_languages}, in
1866       *,lto,*) ;;
1867       *) enable_languages="${enable_languages},lto" ;;
1868     esac
1869   fi
1870
1871   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1872   potential_languages=,c,
1873
1874   enabled_target_libs=
1875   disabled_target_libs=
1876
1877   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1878     case ${lang_frag} in
1879       ..) ;;
1880       # The odd quoting in the next line works around
1881       # an apparent bug in bash 1.12 on linux.
1882       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1883       *)
1884         # From the config-lang.in, get $language, $target_libs,
1885         # $lang_dirs, $boot_language, and $build_by_default
1886         language=
1887         target_libs=
1888         lang_dirs=
1889         subdir_requires=
1890         boot_language=no
1891         build_by_default=yes
1892         # set srcdir during sourcing.  See above about save & restore
1893         saved_srcdir=${srcdir}
1894         srcdir=${srcdir}/gcc . ${lang_frag}
1895         srcdir=${saved_srcdir}
1896         if test x${language} = x; then
1897           echo "${lang_frag} doesn't set \$language." 1>&2
1898           exit 1
1899         fi
1900
1901         if test "$language" = "c++"; then
1902           boot_language=yes
1903         fi
1904
1905         add_this_lang=no
1906         # C is always enabled, so no need to add it again
1907         if test "$language" != "c"; then
1908           case ,${enable_languages}, in
1909             *,${language},*)
1910               # Language was explicitly selected; include it
1911               add_this_lang=yes
1912               ;;
1913             *,all,*)
1914               # All languages are enabled
1915               add_this_lang=all
1916               ;;
1917             *,default,*)
1918               # 'default' was selected, select it if it is a default language
1919               add_this_lang=${build_by_default}
1920               ;;
1921           esac
1922         fi
1923
1924         # Disable languages that need other directories if these aren't available.
1925         for i in $subdir_requires; do
1926           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1927           case ${add_this_lang} in
1928             yes)
1929               # Specifically requested language; tell them.
1930               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1931               ;;
1932             all)
1933               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
1934               add_this_lang=unsupported
1935               ;;
1936             *)
1937               # Silently disable.
1938               add_this_lang=unsupported
1939               ;;
1940           esac
1941         done
1942
1943         # Disable Ada if no preexisting GNAT is available.
1944         case ${add_this_lang}:${language}:${have_gnat} in
1945           yes:ada:no)
1946             # Specifically requested language; tell them.
1947             AC_MSG_ERROR([GNAT is required to build $language])
1948             ;;
1949           all:ada:no)
1950             AC_MSG_WARN([GNAT is required to build $language])
1951             add_this_lang=unsupported
1952             ;;
1953           *:ada:no)
1954             # Silently disable.
1955             add_this_lang=unsupported
1956             ;;
1957         esac
1958
1959         # Disable jit if -enable-host-shared not specified
1960         case ${add_this_lang}:${language}:${host_shared} in
1961           yes:jit:no)
1962             # PR jit/64780: explicitly specify --enable-host-shared
1963             AC_MSG_ERROR([
1964 Enabling language "jit" requires --enable-host-shared.
1965
1966 --enable-host-shared typically slows the rest of the compiler down by
1967 a few %, so you must explicitly enable it.
1968
1969 If you want to build both the jit and the regular compiler, it is often
1970 best to do this via two separate configure/builds, in separate
1971 directories, to avoid imposing the performance cost of
1972 --enable-host-shared on the regular compiler.])
1973             ;;
1974           all:jit:no)
1975             AC_MSG_WARN([--enable-host-shared required to build $language])
1976             add_this_lang=unsupported
1977             ;;
1978           *:jit:no)
1979             # Silently disable.
1980             add_this_lang=unsupported
1981             ;;
1982         esac
1983
1984         # Disable a language that is unsupported by the target.
1985         case "${add_this_lang}: $unsupported_languages " in
1986           no:*) ;;
1987           unsupported:*) ;;
1988           *:*" $language "*)
1989             AC_MSG_WARN([${language} not supported for this target])
1990             add_this_lang=unsupported
1991             ;;
1992         esac
1993
1994         case $add_this_lang in
1995           unsupported)
1996             # Remove language-dependent dirs.
1997             disabled_target_libs="$disabled_target_libs $target_libs"
1998             noconfigdirs="$noconfigdirs $lang_dirs"
1999             ;;
2000           no)
2001             # Remove language-dependent dirs; still show language as supported.
2002             disabled_target_libs="$disabled_target_libs $target_libs"
2003             noconfigdirs="$noconfigdirs $lang_dirs"
2004             potential_languages="${potential_languages}${language},"
2005             ;;
2006           all|yes)
2007             new_enable_languages="${new_enable_languages}${language},"
2008             potential_languages="${potential_languages}${language},"
2009             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2010             enabled_target_libs="$enabled_target_libs $target_libs"
2011             case "${boot_language}:,$enable_stage1_languages," in
2012               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2013                 # Add to (comma-separated) list of stage 1 languages.
2014                 case ",$stage1_languages," in
2015                   *,$language,* | ,yes, | ,all,) ;;
2016                   *) stage1_languages="${stage1_languages}${language}," ;;
2017                 esac
2018                 # We need to bootstrap any supporting libraries.
2019                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2020                 ;;
2021             esac
2022             ;;
2023         esac
2024         ;;
2025     esac
2026   done
2027
2028   # Add target libraries which are only needed for disabled languages
2029   # to noconfigdirs.
2030   if test -n "$disabled_target_libs"; then
2031     for dir in $disabled_target_libs; do
2032       case " $enabled_target_libs " in
2033       *" ${dir} "*) ;;
2034       *) noconfigdirs="$noconfigdirs $dir" ;;
2035       esac
2036     done
2037   fi
2038
2039   AC_ARG_ENABLE(stage1-languages,
2040   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2041                   [choose additional languages to build during
2042                   stage1.  Mostly useful for compiler development])],
2043   [case ,${enable_stage1_languages}, in
2044     ,no,|,,)
2045       # Set it to something that will have no effect in the loop below
2046       enable_stage1_languages=c ;;
2047     ,yes,)
2048       enable_stage1_languages=`echo $new_enable_languages | \
2049         sed -e "s/^,//" -e "s/,$//" ` ;;
2050     *,all,*)
2051       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2052         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2053   esac
2054
2055   # Add "good" languages from enable_stage1_languages to stage1_languages,
2056   # while "bad" languages go in missing_languages.  Leave no duplicates.
2057   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2058     case $potential_languages in
2059       *,$i,*)
2060         case $stage1_languages in
2061           *,$i,*) ;;
2062           *) stage1_languages="$stage1_languages$i," ;;
2063         esac ;;
2064       *)
2065         case $missing_languages in
2066           *,$i,*) ;;
2067           *) missing_languages="$missing_languages$i," ;;
2068         esac ;;
2069      esac
2070   done])
2071
2072   # Remove leading/trailing commas that were added for simplicity
2073   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2074   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2075   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2076   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2077
2078   if test "x$missing_languages" != x; then
2079     AC_MSG_ERROR([
2080 The following requested languages could not be built: ${missing_languages}
2081 Supported languages are: ${potential_languages}])
2082   fi
2083   if test "x$new_enable_languages" != "x$enable_languages"; then
2084     echo The following languages will be built: ${new_enable_languages}
2085     enable_languages="$new_enable_languages"
2086   fi
2087
2088   AC_SUBST(stage1_languages)
2089   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2090 fi
2091
2092 # Handle --disable-<component> generically.
2093 for dir in $configdirs $build_configdirs $target_configdirs ; do
2094   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2095   varname=`echo $dirname | sed -e s/+/_/g`
2096   if eval test x\${enable_${varname}} "=" xno ; then
2097     noconfigdirs="$noconfigdirs $dir"
2098   fi
2099 done
2100
2101 # Check for Boehm's garbage collector
2102 AC_ARG_ENABLE(objc-gc,
2103 [AS_HELP_STRING([--enable-objc-gc],
2104                 [enable use of Boehm's garbage collector with the
2105                  GNU Objective-C runtime])])
2106 AC_ARG_WITH([target-bdw-gc],
2107 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2108                 [specify prefix directory for installed bdw-gc package.
2109                  Equivalent to --with-target-bdw-gc-include=PATH/include
2110                  plus --with-target-bdw-gc-lib=PATH/lib])])
2111 AC_ARG_WITH([target-bdw-gc-include],
2112 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2113                 [specify directories for installed bdw-gc include files])])
2114 AC_ARG_WITH([target-bdw-gc-lib],
2115 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2116                 [specify directories for installed bdw-gc library])])
2117
2118 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2119   AC_MSG_CHECKING([for bdw garbage collector])
2120   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2121     dnl no bdw-gw options, assume default locations
2122     AC_MSG_RESULT([using bdw-gc in default locations])
2123   else
2124     dnl bdw-gw options, first error checking, complete checking in libobjc
2125     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2126       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2127     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2128       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2129     else
2130       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2131     fi
2132   fi
2133 esac
2134
2135 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2136 case ,${enable_languages}, in
2137   *,c++,*)
2138     # Disable libitm, libsanitizer if we're not building libstdc++
2139     case "${noconfigdirs}" in
2140       *target-libstdc++-v3*)
2141         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2142         ;;
2143       *) ;;
2144     esac
2145     ;;
2146   *)
2147     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2148     ;;
2149 esac
2150
2151 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2152 # $build_configdirs and $target_configdirs.
2153 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2154
2155 notsupp=""
2156 for dir in . $skipdirs $noconfigdirs ; do
2157   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2158   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2159     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2160     if test -r $srcdir/$dirname/configure ; then
2161       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2162         true
2163       else
2164         notsupp="$notsupp $dir"
2165       fi
2166     fi
2167   fi
2168   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2169     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2170     if test -r $srcdir/$dirname/configure ; then
2171       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2172         true
2173       else
2174         notsupp="$notsupp $dir"
2175       fi
2176     fi
2177   fi
2178   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2179     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2180     if test -r $srcdir/$dirname/configure ; then
2181       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2182         true
2183       else
2184         notsupp="$notsupp $dir"
2185       fi
2186     fi
2187   fi
2188 done
2189
2190 # Quietly strip out all directories which aren't configurable in this tree.
2191 # This relies on all configurable subdirectories being autoconfiscated, which
2192 # is now the case.
2193 build_configdirs_all="$build_configdirs"
2194 build_configdirs=
2195 for i in ${build_configdirs_all} ; do
2196   j=`echo $i | sed -e s/build-//g`
2197   if test -f ${srcdir}/$j/configure ; then
2198     build_configdirs="${build_configdirs} $i"
2199   fi
2200 done
2201
2202 configdirs_all="$configdirs"
2203 configdirs=
2204 for i in ${configdirs_all} ; do
2205   if test -f ${srcdir}/$i/configure ; then
2206     configdirs="${configdirs} $i"
2207   fi
2208 done
2209
2210 target_configdirs_all="$target_configdirs"
2211 target_configdirs=
2212 for i in ${target_configdirs_all} ; do
2213   j=`echo $i | sed -e s/target-//g`
2214   if test -f ${srcdir}/$j/configure ; then
2215     target_configdirs="${target_configdirs} $i"
2216   fi
2217 done
2218
2219 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2220 # so we have to add it after the preceding checks.
2221 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2222 then
2223   case " $configdirs " in
2224     *" libiberty "*)
2225       # If we can build libiberty, we can also build libiberty-linker-plugin.
2226       configdirs="$configdirs libiberty-linker-plugin"
2227       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2228         --with-libiberty=../libiberty-linker-plugin";;
2229     *)
2230       AC_MSG_ERROR([libiberty missing]);;
2231   esac
2232 fi
2233
2234 # Sometimes we have special requirements for the host libiberty.
2235 extra_host_libiberty_configure_flags=
2236 extra_host_zlib_configure_flags=
2237 case " $configdirs " in
2238   *" lto-plugin "* | *" libcc1 "*)
2239     # When these are to be built as shared libraries, the same applies to
2240     # libiberty.
2241     extra_host_libiberty_configure_flags=--enable-shared
2242     ;;
2243   *" bfd "*)
2244     # When bfd is to be built as a shared library, the same applies to
2245     # zlib.
2246     if test "$enable_shared" = "yes"; then
2247       extra_host_zlib_configure_flags=--enable-host-shared
2248     fi
2249     ;;
2250 esac
2251 AC_SUBST(extra_host_libiberty_configure_flags)
2252 AC_SUBST(extra_host_zlib_configure_flags)
2253
2254 # Produce a warning message for the subdirs we can't configure.
2255 # This isn't especially interesting in the Cygnus tree, but in the individual
2256 # FSF releases, it's important to let people know when their machine isn't
2257 # supported by the one or two programs in a package.
2258
2259 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2260   # If $appdirs is non-empty, at least one of those directories must still
2261   # be configured, or we error out.  (E.g., if the gas release supports a
2262   # specified target in some subdirs but not the gas subdir, we shouldn't
2263   # pretend that all is well.)
2264   if test -n "$appdirs" ; then
2265     for dir in $appdirs ; do
2266       if test -r $dir/Makefile.in ; then
2267         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2268           appdirs=""
2269           break
2270         fi
2271         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2272           appdirs=""
2273           break
2274         fi
2275       fi
2276     done
2277     if test -n "$appdirs" ; then
2278       echo "*** This configuration is not supported by this package." 1>&2
2279       exit 1
2280     fi
2281   fi
2282   # Okay, some application will build, or we don't care to check.  Still
2283   # notify of subdirs not getting built.
2284   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2285   echo "    ${notsupp}" 1>&2
2286   echo "    (Any other directories should still work fine.)" 1>&2
2287 fi
2288
2289 case "$host" in
2290   *msdosdjgpp*)
2291     enable_gdbtk=no ;;
2292 esac
2293
2294 # To find our prefix, in gcc_cv_tool_prefix.
2295 ACX_TOOL_DIRS
2296
2297 copy_dirs=
2298
2299 AC_ARG_WITH([build-sysroot],
2300   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2301                   [use sysroot as the system root during the build])],
2302   [if test x"$withval" != x ; then
2303      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2304    fi],
2305   [SYSROOT_CFLAGS_FOR_TARGET=])
2306 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2307
2308 AC_ARG_WITH([debug-prefix-map],
2309   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2310                   [map A to B, C to D ... in debug information])],
2311   [if test x"$withval" != x; then
2312      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2313      for debug_map in $withval; do
2314        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2315      done
2316    fi],
2317   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2318 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2319
2320 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2321 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2322 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2323 # We want to ensure that TARGET libraries (which we know are built with
2324 # gcc) are built with "-O2 -g", so include those options when setting
2325 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2326 if test "x$CFLAGS_FOR_TARGET" = x; then
2327   if test "x${is_cross_compiler}" = xyes; then
2328     CFLAGS_FOR_TARGET="-g -O2"
2329   else
2330     CFLAGS_FOR_TARGET=$CFLAGS
2331     case " $CFLAGS " in
2332       *" -O2 "*) ;;
2333       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2334     esac
2335     case " $CFLAGS " in
2336       *" -g "* | *" -g3 "*) ;;
2337       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2338     esac
2339   fi
2340 fi
2341 AC_SUBST(CFLAGS_FOR_TARGET)
2342
2343 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2344   if test "x${is_cross_compiler}" = xyes; then
2345     CXXFLAGS_FOR_TARGET="-g -O2"
2346   else
2347     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2348     case " $CXXFLAGS " in
2349       *" -O2 "*) ;;
2350       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2351     esac
2352     case " $CXXFLAGS " in
2353       *" -g "* | *" -g3 "*) ;;
2354       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2355     esac
2356   fi
2357 fi
2358 AC_SUBST(CXXFLAGS_FOR_TARGET)
2359
2360 AC_SUBST(LDFLAGS_FOR_TARGET)
2361
2362 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2363 # the named directory are copied to $(tooldir)/sys-include.
2364 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2365   if test x${is_cross_compiler} = xno ; then
2366     echo 1>&2 '***' --with-headers is only supported when cross compiling
2367     exit 1
2368   fi
2369   if test x"${with_headers}" != xyes ; then
2370     x=${gcc_cv_tool_prefix}
2371     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2372   fi
2373 fi
2374
2375 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2376 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2377 # are permitted.
2378 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2379   if test x${is_cross_compiler} = xno ; then
2380     echo 1>&2 '***' --with-libs is only supported when cross compiling
2381     exit 1
2382   fi
2383   if test x"${with_libs}" != xyes ; then
2384     # Copy the libraries in reverse order, so that files in the first named
2385     # library override files in subsequent libraries.
2386     x=${gcc_cv_tool_prefix}
2387     for l in ${with_libs}; do
2388       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2389     done
2390   fi
2391 fi
2392
2393 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2394 #
2395 # This is done by determining whether or not the appropriate directory
2396 # is available, and by checking whether or not specific configurations
2397 # have requested that this magic not happen.
2398 #
2399 # The command line options always override the explicit settings in
2400 # configure.ac, and the settings in configure.ac override this magic.
2401 #
2402 # If the default for a toolchain is to use GNU as and ld, and you don't
2403 # want to do that, then you should use the --without-gnu-as and
2404 # --without-gnu-ld options for the configure script.  Similarly, if
2405 # the default is to use the included zlib and you don't want to do that,
2406 # you should use the --with-system-zlib option for the configure script.
2407
2408 if test x${use_gnu_as} = x &&
2409    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2410   with_gnu_as=yes
2411   extra_host_args="$extra_host_args --with-gnu-as"
2412 fi
2413
2414 if test x${use_gnu_ld} = x &&
2415    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2416   with_gnu_ld=yes
2417   extra_host_args="$extra_host_args --with-gnu-ld"
2418 fi
2419
2420 if test x${use_included_zlib} = x &&
2421    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2422   :
2423 else
2424   with_system_zlib=yes
2425   extra_host_args="$extra_host_args --with-system-zlib"
2426 fi
2427
2428 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2429 # can detect this case.
2430
2431 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2432   with_newlib=yes
2433   extra_host_args="$extra_host_args --with-newlib"
2434 fi
2435
2436 # Handle ${copy_dirs}
2437 set fnord ${copy_dirs}
2438 shift
2439 while test $# != 0 ; do
2440   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2441     :
2442   else
2443     echo Copying $1 to $2
2444
2445     # Use the install script to create the directory and all required
2446     # parent directories.
2447     if test -d $2 ; then
2448       :
2449     else
2450       echo >config.temp
2451       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2452     fi
2453
2454     # Copy the directory, assuming we have tar.
2455     # FIXME: Should we use B in the second tar?  Not all systems support it.
2456     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2457
2458     # It is the responsibility of the user to correctly adjust all
2459     # symlinks.  If somebody can figure out how to handle them correctly
2460     # here, feel free to add the code.
2461
2462     echo $1 > $2/COPIED
2463   fi
2464   shift; shift
2465 done
2466
2467 # Determine a target-dependent exec_prefix that the installed
2468 # gcc will search in.  Keep this list sorted by triplet, with
2469 # the *-*-osname triplets last.
2470 md_exec_prefix=
2471 case "${target}" in
2472   i[[34567]]86-pc-msdosdjgpp*)
2473     md_exec_prefix=/dev/env/DJDIR/bin
2474     ;;
2475   *-*-hpux* | \
2476   *-*-nto-qnx* | \
2477   *-*-solaris2*)
2478     md_exec_prefix=/usr/ccs/bin
2479     ;;
2480 esac
2481
2482 extra_arflags_for_target=
2483 extra_nmflags_for_target=
2484 extra_ranlibflags_for_target=
2485 target_makefile_frag=/dev/null
2486 case "${target}" in
2487   spu-*-*)
2488     target_makefile_frag="config/mt-spu"
2489     ;;
2490   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2491     target_makefile_frag="config/mt-sde"
2492     ;;
2493   mipsisa*-*-elfoabi*)
2494     target_makefile_frag="config/mt-mips-elfoabi"
2495     ;;
2496   mips*-*-*linux* | mips*-*-gnu*)
2497     target_makefile_frag="config/mt-mips-gnu"
2498     ;;
2499   nios2-*-elf*)
2500     target_makefile_frag="config/mt-nios2-elf"
2501     ;;
2502   *-*-linux-android*)
2503     target_makefile_frag="config/mt-android"
2504     ;;
2505   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2506     target_makefile_frag="config/mt-gnu"
2507     ;;
2508   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2509     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2510     # commands to handle both 32-bit and 64-bit objects.  These flags are
2511     # harmless if we're using GNU nm or ar.
2512     extra_arflags_for_target=" -X32_64"
2513     extra_nmflags_for_target=" -B -X32_64"
2514     ;;
2515 esac
2516
2517 alphaieee_frag=/dev/null
2518 case $target in
2519   alpha*-*-*)
2520     # This just makes sure to use the -mieee option to build target libs.
2521     # This should probably be set individually by each library.
2522     alphaieee_frag="config/mt-alphaieee"
2523     ;;
2524 esac
2525
2526 # If --enable-target-optspace always use -Os instead of -O2 to build
2527 # the target libraries, similarly if it is not specified, use -Os
2528 # on selected platforms.
2529 ospace_frag=/dev/null
2530 case "${enable_target_optspace}:${target}" in
2531   yes:*)
2532     ospace_frag="config/mt-ospace"
2533     ;;
2534   :d30v-*)
2535     ospace_frag="config/mt-d30v"
2536     ;;
2537   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2538     ospace_frag="config/mt-ospace"
2539     ;;
2540   no:* | :*)
2541     ;;
2542   *)
2543     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2544     ;;
2545 esac
2546
2547 # Some systems (e.g., one of the i386-aix systems the gas testers are
2548 # using) don't handle "\$" correctly, so don't use it here.
2549 tooldir='${exec_prefix}'/${target_noncanonical}
2550 build_tooldir=${tooldir}
2551
2552 # Create a .gdbinit file which runs the one in srcdir
2553 # and tells GDB to look there for source files.
2554
2555 if test -r ${srcdir}/.gdbinit ; then
2556   case ${srcdir} in
2557     .) ;;
2558     *) cat > ./.gdbinit <<EOF
2559 # ${NO_EDIT}
2560 dir ${srcdir}
2561 dir .
2562 source ${srcdir}/.gdbinit
2563 EOF
2564     ;;
2565   esac
2566 fi
2567
2568 # Make sure that the compiler is able to generate an executable.  If it
2569 # can't, we are probably in trouble.  We don't care whether we can run the
2570 # executable--we might be using a cross compiler--we only care whether it
2571 # can be created.  At this point the main configure script has set CC.
2572 we_are_ok=no
2573 echo "int main () { return 0; }" > conftest.c
2574 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2575 if test $? = 0 ; then
2576   if test -s conftest || test -s conftest.exe ; then
2577     we_are_ok=yes
2578   fi
2579 fi
2580 case $we_are_ok in
2581   no)
2582     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2583     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2584     rm -f conftest*
2585     exit 1
2586     ;;
2587 esac
2588 rm -f conftest*
2589
2590 # Decide which environment variable is used to find dynamic libraries.
2591 case "${host}" in
2592   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2593   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2594   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2595   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2596 esac
2597
2598 # On systems where the dynamic library environment variable is PATH,
2599 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2600 # built executables to PATH.
2601 if test "$RPATH_ENVVAR" = PATH; then
2602   GCC_SHLIB_SUBDIR=/shlib
2603 else
2604   GCC_SHLIB_SUBDIR=
2605 fi
2606
2607 # Adjust the toplevel makefile according to whether bootstrap was selected.
2608 case $enable_bootstrap in
2609   yes)
2610     bootstrap_suffix=bootstrap
2611     BUILD_CONFIG=bootstrap-debug
2612     ;;
2613   no)
2614     bootstrap_suffix=no-bootstrap
2615     BUILD_CONFIG=
2616     ;;
2617 esac
2618
2619 AC_MSG_CHECKING(for default BUILD_CONFIG)
2620
2621 AC_ARG_WITH([build-config],
2622   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2623                   [use config/NAME.mk build configuration])],
2624   [case $with_build_config in
2625    yes) with_build_config= ;;
2626    no) with_build_config= BUILD_CONFIG= ;;
2627    esac])
2628
2629 if test "x${with_build_config}" != x; then
2630   BUILD_CONFIG=$with_build_config
2631 else
2632   case $BUILD_CONFIG in
2633   bootstrap-debug)
2634     if echo "int f (void) { return 0; }" > conftest.c &&
2635        ${CC} -c conftest.c &&
2636        mv conftest.o conftest.o.g0 &&
2637        ${CC} -c -g conftest.c &&
2638        mv conftest.o conftest.o.g &&
2639        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2640       :
2641     else
2642       BUILD_CONFIG=
2643     fi
2644     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2645     ;;
2646   esac
2647 fi
2648 AC_MSG_RESULT($BUILD_CONFIG)
2649 AC_SUBST(BUILD_CONFIG)
2650
2651 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2652 AC_MSG_CHECKING([for --enable-vtable-verify])
2653 AC_ARG_ENABLE(vtable-verify,
2654 [AS_HELP_STRING([--enable-vtable-verify],
2655                 [Enable vtable verification feature])],
2656 [case "$enableval" in
2657  yes) enable_vtable_verify=yes ;;
2658  no)  enable_vtable_verify=no ;;
2659  *)   enable_vtable_verify=no;;
2660  esac],
2661 [enable_vtable_verify=no])
2662 AC_MSG_RESULT($enable_vtable_verify)
2663
2664 # Record target_configdirs and the configure arguments for target and
2665 # build configuration in Makefile.
2666 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2667 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2668 bootstrap_fixincludes=no
2669
2670 # If we are building libgomp, bootstrap it.
2671 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2672   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2673 fi
2674
2675 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2676 # or bootstrap-ubsan, bootstrap it.
2677 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2678   case "$BUILD_CONFIG" in
2679     *bootstrap-asan* | *bootstrap-ubsan* )
2680       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2681       bootstrap_fixincludes=yes
2682       ;;
2683   esac
2684 fi
2685
2686 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2687 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2688    test "$enable_vtable_verify" != no; then
2689   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2690 fi
2691
2692 # If we are building libmpx and $BUILD_CONFIG contains bootstrap-mpx,
2693 # bootstrap it.
2694 if echo " ${target_configdirs} " | grep " libmpx " > /dev/null 2>&1; then
2695   case "$BUILD_CONFIG" in
2696     *bootstrap-mpx* )
2697       bootstrap_target_libs=${bootstrap_target_libs}target-libmpx,
2698       ;;
2699   esac
2700 fi
2701
2702 # Determine whether gdb needs tk/tcl or not.
2703 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2704 # and in that case we want gdb to be built without tk.  Ugh!
2705 # In fact I believe gdb is the *only* package directly dependent on tk,
2706 # so we should be able to put the 'maybe's in unconditionally and
2707 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2708 # 100% sure that that's safe though.
2709
2710 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2711 case "$enable_gdbtk" in
2712   no)
2713     GDB_TK="" ;;
2714   yes)
2715     GDB_TK="${gdb_tk}" ;;
2716   *)
2717     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2718     # distro.  Eventually someone will fix this and move Insight, nee
2719     # gdbtk to a separate directory.
2720     if test -d ${srcdir}/gdb/gdbtk ; then
2721       GDB_TK="${gdb_tk}"
2722     else
2723       GDB_TK=""
2724     fi
2725     ;;
2726 esac
2727 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2728 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2729
2730 # Strip out unwanted targets.
2731
2732 # While at that, we remove Makefiles if we were started for recursive
2733 # configuration, so that the top-level Makefile reconfigures them,
2734 # like we used to do when configure itself was recursive.
2735
2736 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2737 # but now we're fixing up the Makefile ourselves with the additional
2738 # commands passed to AC_CONFIG_FILES.  Use separate variables
2739 # extrasub-{build,host,target} not because there is any reason to split
2740 # the substitutions up that way, but only to remain below the limit of
2741 # 99 commands in a script, for HP-UX sed.
2742 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2743
2744 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2745   yes:yes:*\ gold\ *:*,c++,*) ;;
2746   yes:yes:*\ gold\ *:*)
2747     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2748     ;;
2749 esac
2750
2751 extrasub_build=
2752 for module in ${build_configdirs} ; do
2753   if test -z "${no_recursion}" \
2754      && test -f ${build_subdir}/${module}/Makefile; then
2755     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2756     rm -f ${build_subdir}/${module}/Makefile
2757   fi
2758   extrasub_build="$extrasub_build
2759 /^@if build-$module\$/d
2760 /^@endif build-$module\$/d
2761 /^@if build-$module-$bootstrap_suffix\$/d
2762 /^@endif build-$module-$bootstrap_suffix\$/d"
2763 done
2764 extrasub_host=
2765 for module in ${configdirs} ; do
2766   if test -z "${no_recursion}"; then
2767     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2768       if test -f ${file}; then
2769         echo 1>&2 "*** removing ${file} to force reconfigure"
2770         rm -f ${file}
2771       fi
2772     done
2773   fi
2774   case ${module},${bootstrap_fixincludes} in
2775     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2776     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2777   esac
2778   extrasub_host="$extrasub_host
2779 /^@if $module\$/d
2780 /^@endif $module\$/d
2781 /^@if $module-$host_bootstrap_suffix\$/d
2782 /^@endif $module-$host_bootstrap_suffix\$/d"
2783 done
2784 extrasub_target=
2785 for module in ${target_configdirs} ; do
2786   if test -z "${no_recursion}" \
2787      && test -f ${target_subdir}/${module}/Makefile; then
2788     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2789     rm -f ${target_subdir}/${module}/Makefile
2790   fi
2791
2792   # We only bootstrap target libraries listed in bootstrap_target_libs.
2793   case $bootstrap_target_libs in
2794     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2795     *) target_bootstrap_suffix=no-bootstrap ;;
2796   esac
2797
2798   extrasub_target="$extrasub_target
2799 /^@if target-$module\$/d
2800 /^@endif target-$module\$/d
2801 /^@if target-$module-$target_bootstrap_suffix\$/d
2802 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2803 done
2804
2805 # Do the final fixup along with target modules.
2806 extrasub_target="$extrasub_target
2807 /^@if /,/^@endif /d"
2808
2809 # Create the serialization dependencies.  This uses a temporary file.
2810
2811 AC_ARG_ENABLE([serial-configure],
2812 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2813                 [force sequential configuration of
2814                  sub-packages for the host, target or build
2815                  machine, or all sub-packages])])
2816
2817 case ${enable_serial_configure} in
2818   yes)
2819     enable_serial_build_configure=yes
2820     enable_serial_host_configure=yes
2821     enable_serial_target_configure=yes
2822     ;;
2823 esac
2824
2825 # These force 'configure's to be done one at a time, to avoid problems
2826 # with contention over a shared config.cache.
2827 rm -f serdep.tmp
2828 echo '# serdep.tmp' > serdep.tmp
2829 olditem=
2830 test "x${enable_serial_build_configure}" = xyes &&
2831 for item in ${build_configdirs} ; do
2832   case ${olditem} in
2833     "") ;;
2834     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2835   esac
2836   olditem=${item}
2837 done
2838 olditem=
2839 test "x${enable_serial_host_configure}" = xyes &&
2840 for item in ${configdirs} ; do
2841   case ${olditem} in
2842     "") ;;
2843     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2844   esac
2845   olditem=${item}
2846 done
2847 olditem=
2848 test "x${enable_serial_target_configure}" = xyes &&
2849 for item in ${target_configdirs} ; do
2850   case ${olditem} in
2851     "") ;;
2852     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2853   esac
2854   olditem=${item}
2855 done
2856 serialization_dependencies=serdep.tmp
2857 AC_SUBST_FILE(serialization_dependencies)
2858
2859 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2860 # target, nonopt, and variable assignments.  These are the ones we
2861 # might not want to pass down to subconfigures.  The exception being
2862 # --cache-file=/dev/null, which is used to turn off the use of cache
2863 # files altogether, and which should be passed on to subconfigures.
2864 # Also strip program-prefix, program-suffix, and program-transform-name,
2865 # so that we can pass down a consistent program-transform-name.
2866 baseargs=
2867 tbaseargs=
2868 keep_next=no
2869 skip_next=no
2870 eval "set -- $ac_configure_args"
2871 for ac_arg
2872 do
2873   if test X"$skip_next" = X"yes"; then
2874     skip_next=no
2875     continue
2876   fi
2877   if test X"$keep_next" = X"yes"; then
2878     case $ac_arg in
2879       *\'*)
2880         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2881     esac
2882     baseargs="$baseargs '$ac_arg'"
2883     tbaseargs="$tbaseargs '$ac_arg'"
2884     keep_next=no
2885     continue
2886   fi
2887
2888   # Handle separated arguments.  Based on the logic generated by
2889   # autoconf 2.59.
2890   case $ac_arg in
2891     *=* | --config-cache | -C | -disable-* | --disable-* \
2892       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2893       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2894       | -with-* | --with-* | -without-* | --without-* | --x)
2895       separate_arg=no
2896       ;;
2897     -*)
2898       separate_arg=yes
2899       ;;
2900     *)
2901       separate_arg=no
2902       ;;
2903   esac
2904
2905   skip_targ=no
2906   case $ac_arg in
2907 changequote(,)
2908   --with-* | --without-*)
2909     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2910
2911     case $libopt in
2912     *[-_]include)
2913       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2914       ;;
2915     *[-_]lib)
2916       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2917       ;;
2918     *)
2919       lib=$libopt
2920       ;;
2921     esac
2922 changequote([,])
2923
2924     case $lib in
2925     mpc | mpfr | gmp | isl)
2926       # If we're processing --with-$lib, --with-$lib-include or
2927       # --with-$lib-lib, for one of the libs above, and target is
2928       # different from host, don't pass the current argument to any
2929       # target library's configure.
2930       if test x$is_cross_compiler = xyes; then
2931         skip_targ=yes
2932       fi
2933       ;;
2934     esac
2935     ;;
2936   esac
2937
2938   case "$ac_arg" in
2939     --cache-file=/dev/null | \
2940     -cache-file=/dev/null )
2941       # Handled here to avoid the test to skip args below.
2942       baseargs="$baseargs '$ac_arg'"
2943       tbaseargs="$tbaseargs '$ac_arg'"
2944       # Assert: $separate_arg should always be no.
2945       keep_next=$separate_arg
2946       ;;
2947     --no*)
2948       continue
2949       ;;
2950     --c* | \
2951     --sr* | \
2952     --ho* | \
2953     --bu* | \
2954     --t* | \
2955     --program-* | \
2956     -cache_file* | \
2957     -srcdir* | \
2958     -host* | \
2959     -build* | \
2960     -target* | \
2961     -program-prefix* | \
2962     -program-suffix* | \
2963     -program-transform-name* )
2964       skip_next=$separate_arg
2965       continue
2966       ;;
2967     -*)
2968       # An option.  Add it.
2969       case $ac_arg in
2970         *\'*)
2971           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2972       esac
2973       baseargs="$baseargs '$ac_arg'"
2974       if test X"$skip_targ" = Xno; then
2975         tbaseargs="$tbaseargs '$ac_arg'"
2976       fi
2977       keep_next=$separate_arg
2978       ;;
2979     *)
2980       # Either a variable assignment, or a nonopt (triplet).  Don't
2981       # pass it down; let the Makefile handle this.
2982       continue
2983       ;;
2984   esac
2985 done
2986 # Remove the initial space we just introduced and, as these will be
2987 # expanded by make, quote '$'.
2988 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2989
2990 # Add in --program-transform-name, after --program-prefix and
2991 # --program-suffix have been applied to it.  Autoconf has already
2992 # doubled dollar signs and backslashes in program_transform_name; we want
2993 # the backslashes un-doubled, and then the entire thing wrapped in single
2994 # quotes, because this will be expanded first by make and then by the shell.
2995 # Also, because we want to override the logic in subdir configure scripts to
2996 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2997 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2998 ${program_transform_name}
2999 EOF_SED
3000 gcc_transform_name=`cat conftestsed.out`
3001 rm -f conftestsed.out
3002 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3003 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3004 if test "$silent" = yes; then
3005   baseargs="$baseargs --silent"
3006   tbaseargs="$tbaseargs --silent"
3007 fi
3008 baseargs="$baseargs --disable-option-checking"
3009 tbaseargs="$tbaseargs --disable-option-checking"
3010
3011 # Record and document user additions to sub configure arguments.
3012 AC_ARG_VAR([build_configargs],
3013            [additional configure arguments for build directories])
3014 AC_ARG_VAR([host_configargs],
3015            [additional configure arguments for host directories])
3016 AC_ARG_VAR([target_configargs],
3017            [additional configure arguments for target directories])
3018
3019 # For the build-side libraries, we just need to pretend we're native,
3020 # and not use the same cache file.  Multilibs are neither needed nor
3021 # desired.  We can't even use the same cache file for all build-side
3022 # libraries, as they're compiled differently; some with C, some with
3023 # C++ or with different feature-enabling options.
3024 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3025
3026 # For host modules, accept cache file option, or specification as blank.
3027 case "${cache_file}" in
3028 "") # empty
3029   cache_file_option="" ;;
3030 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3031   cache_file_option="--cache-file=${cache_file}" ;;
3032 *) # relative path
3033   cache_file_option="--cache-file=../${cache_file}" ;;
3034 esac
3035
3036 # Host dirs don't like to share a cache file either, horribly enough.
3037 # This seems to be due to autoconf 2.5x stupidity.
3038 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3039
3040 target_configargs="$target_configargs ${tbaseargs}"
3041
3042 # Passing a --with-cross-host argument lets the target libraries know
3043 # whether they are being built with a cross-compiler or being built
3044 # native.  However, it would be better to use other mechanisms to make the
3045 # sorts of decisions they want to make on this basis.  Please consider
3046 # this option to be deprecated.  FIXME.
3047 if test x${is_cross_compiler} = xyes ; then
3048   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3049 fi
3050
3051 # Special user-friendly check for native x86_64-linux build, if
3052 # multilib is not explicitly enabled.
3053 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3054   x86_64-*linux*:yes:$build:$build:)
3055     # Make sure we have a development environment that handles 32-bit
3056     dev64=no
3057     echo "int main () { return 0; }" > conftest.c
3058     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3059     if test $? = 0 ; then
3060       if test -s conftest || test -s conftest.exe ; then
3061         dev64=yes
3062       fi
3063     fi
3064     rm -f conftest*
3065     if test x${dev64} != xyes ; then
3066       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3067     fi
3068     ;;
3069 esac
3070
3071 # Default to --enable-multilib.
3072 if test x${enable_multilib} = x ; then
3073   target_configargs="--enable-multilib ${target_configargs}"
3074 fi
3075
3076 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3077 # changed from the earlier setting of with_newlib.
3078 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3079   target_configargs="--with-newlib ${target_configargs}"
3080 fi
3081
3082 # Different target subdirs use different values of certain variables
3083 # (notably CXX).  Worse, multilibs use *lots* of different values.
3084 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3085 # it doesn't automatically accept command-line overrides of them.
3086 # This means it's not safe for target subdirs to share a cache file,
3087 # which is disgusting, but there you have it.  Hopefully this can be
3088 # fixed in future.  It's still worthwhile to use a cache file for each
3089 # directory.  I think.
3090
3091 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3092 # We need to pass --target, as newer autoconf's requires consistency
3093 # for target_alias and gcc doesn't manage it consistently.
3094 target_configargs="--cache-file=./config.cache ${target_configargs}"
3095
3096 FLAGS_FOR_TARGET=
3097 case " $target_configdirs " in
3098  *" newlib "*)
3099   case " $target_configargs " in
3100   *" --with-newlib "*)
3101    case "$target" in
3102     *-cygwin*)
3103       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3104       ;;
3105    esac
3106
3107    # If we're not building GCC, don't discard standard headers.
3108    if test -d ${srcdir}/gcc; then
3109      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3110
3111      if test "${build}" != "${host}"; then
3112        # On Canadian crosses, CC_FOR_TARGET will have already been set
3113        # by `configure', so we won't have an opportunity to add -Bgcc/
3114        # to it.  This is right: we don't want to search that directory
3115        # for binaries, but we want the header files in there, so add
3116        # them explicitly.
3117        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3118
3119        # Someone might think of using the pre-installed headers on
3120        # Canadian crosses, in case the installed compiler is not fully
3121        # compatible with the compiler being built.  In this case, it
3122        # would be better to flag an error than risking having
3123        # incompatible object files being constructed.  We can't
3124        # guarantee that an error will be flagged, but let's hope the
3125        # compiler will do it, when presented with incompatible header
3126        # files.
3127      fi
3128    fi
3129
3130    case "${target}-${is_cross_compiler}" in
3131    i[[3456789]]86-*-linux*-no)
3132       # Here host == target, so we don't need to build gcc,
3133       # so we don't want to discard standard headers.
3134       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3135       ;;
3136    *)
3137       # If we're building newlib, use its generic headers last, but search
3138       # for any libc-related directories first (so make it the last -B
3139       # switch).
3140       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3141
3142       # If we're building libgloss, find the startup file, simulator library
3143       # and linker script.
3144       case " $target_configdirs " in
3145         *" libgloss "*)
3146         # Look for startup file, simulator library and maybe linker script.
3147         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3148         # Look for libnosys.a in case the target needs it.
3149         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3150         # Most targets have the linker script in the source directory.
3151         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3152         ;;
3153       esac
3154       ;;
3155    esac
3156    ;;
3157   esac
3158   ;;
3159 esac
3160
3161 case "$target" in
3162   x86_64-*mingw* | *-w64-mingw*)
3163   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3164   # however, use a symlink named 'mingw' in ${prefix} .
3165     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3166     ;;
3167   *-mingw*)
3168   # MinGW can't be handled as Cygwin above since it does not use newlib.
3169     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3170     ;;
3171 esac
3172
3173 # Allow the user to override the flags for
3174 # our build compiler if desired.
3175 if test x"${build}" = x"${host}" ; then
3176   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3177   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3178   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3179 fi
3180
3181 # On Canadian crosses, we'll be searching the right directories for
3182 # the previously-installed cross compiler, so don't bother to add
3183 # flags for directories within the install tree of the compiler
3184 # being built; programs in there won't even run.
3185 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3186   # Search for pre-installed headers if nothing else fits.
3187   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3188 fi
3189
3190 if test "x${use_gnu_ld}" = x &&
3191    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3192   # Arrange for us to find uninstalled linker scripts.
3193   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3194 fi
3195
3196 # Search for other target-specific linker scripts and such.
3197 case "${target}" in
3198   mep*)
3199     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3200     ;;
3201 esac
3202
3203 # Makefile fragments.
3204 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3205 do
3206   eval fragval=\$$frag
3207   if test $fragval != /dev/null; then
3208     eval $frag=${srcdir}/$fragval
3209   fi
3210 done
3211 AC_SUBST_FILE(host_makefile_frag)
3212 AC_SUBST_FILE(target_makefile_frag)
3213 AC_SUBST_FILE(alphaieee_frag)
3214 AC_SUBST_FILE(ospace_frag)
3215
3216 # Miscellanea: directories, flags, etc.
3217 AC_SUBST(RPATH_ENVVAR)
3218 AC_SUBST(GCC_SHLIB_SUBDIR)
3219 AC_SUBST(tooldir)
3220 AC_SUBST(build_tooldir)
3221 AC_SUBST(CONFIGURE_GDB_TK)
3222 AC_SUBST(GDB_TK)
3223 AC_SUBST(INSTALL_GDB_TK)
3224
3225 # Build module lists & subconfigure args.
3226 AC_SUBST(build_configargs)
3227 AC_SUBST(build_configdirs)
3228
3229 # Host module lists & subconfigure args.
3230 AC_SUBST(host_configargs)
3231 AC_SUBST(configdirs)
3232 AC_SUBST(target_configdirs)
3233
3234 # Target module lists & subconfigure args.
3235 AC_SUBST(target_configargs)
3236
3237
3238 # Build tools.
3239 AC_SUBST(AR_FOR_BUILD)
3240 AC_SUBST(AS_FOR_BUILD)
3241 AC_SUBST(CC_FOR_BUILD)
3242 AC_SUBST(CFLAGS_FOR_BUILD)
3243 AC_SUBST(CXXFLAGS_FOR_BUILD)
3244 AC_SUBST(CXX_FOR_BUILD)
3245 AC_SUBST(DLLTOOL_FOR_BUILD)
3246 AC_SUBST(GFORTRAN_FOR_BUILD)
3247 AC_SUBST(GOC_FOR_BUILD)
3248 AC_SUBST(LDFLAGS_FOR_BUILD)
3249 AC_SUBST(LD_FOR_BUILD)
3250 AC_SUBST(NM_FOR_BUILD)
3251 AC_SUBST(RANLIB_FOR_BUILD)
3252 AC_SUBST(WINDMC_FOR_BUILD)
3253 AC_SUBST(WINDRES_FOR_BUILD)
3254
3255 # Generate default definitions for YACC, M4, LEX and other programs that run
3256 # on the build machine.  These are used if the Makefile can't locate these
3257 # programs in objdir.
3258 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3259
3260 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3261 case " $build_configdirs " in
3262   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3263 esac
3264
3265 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3266 case " $build_configdirs " in
3267   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3268 esac
3269
3270 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3271 case " $build_configdirs " in
3272   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3273 esac
3274
3275 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3276 case " $build_configdirs " in
3277   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3278   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3279 esac
3280
3281 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3282 case " $build_configdirs " in
3283   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3284 esac
3285
3286 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3287 case " $build_configdirs " in
3288   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3289   *)
3290 changequote(,)
3291     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3292     # higher, else we use the "missing" dummy.
3293     if ${MAKEINFO} --version \
3294        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3295       :
3296     else
3297       MAKEINFO="$MISSING makeinfo"
3298     fi
3299     ;;
3300 changequote([,])
3301 esac
3302
3303 # FIXME: expect and dejagnu may become build tools?
3304
3305 AC_CHECK_PROGS(EXPECT, expect, expect)
3306 case " $configdirs " in
3307   *" expect "*)
3308     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3309     ;;
3310 esac
3311
3312 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3313 case " $configdirs " in
3314   *" dejagnu "*)
3315     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3316     ;;
3317 esac
3318
3319
3320 # Host tools.
3321 NCN_STRICT_CHECK_TOOLS(AR, ar)
3322 NCN_STRICT_CHECK_TOOLS(AS, as)
3323 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3324 NCN_STRICT_CHECK_TOOLS(LD, ld)
3325 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3326 NCN_STRICT_CHECK_TOOLS(NM, nm)
3327 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3328 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3329 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3330 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3331 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3332 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3333 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3334 AC_SUBST(CC)
3335 AC_SUBST(CXX)
3336 AC_SUBST(CFLAGS)
3337 AC_SUBST(CXXFLAGS)
3338
3339 # Target tools.
3340 AC_ARG_WITH([build-time-tools],
3341   [AS_HELP_STRING([--with-build-time-tools=PATH],
3342                   [use given path to find target tools during the build])],
3343   [case x"$withval" in
3344      x/*) ;;
3345      *)
3346        with_build_time_tools=
3347        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3348        ;;
3349    esac],
3350   [with_build_time_tools=])
3351
3352 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3353 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3354 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3355 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3356 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3357
3358 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3359 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3360 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3361 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3362 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3363 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3364 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3365 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3366 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3367 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3368 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3369 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3370 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3371
3372 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3373
3374 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3375 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3376 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3377 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3378 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3379                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3380                 c++)
3381 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3382                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3383                 c++)
3384 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3385 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3386 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3387                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3388 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3389                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3390 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3391 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3392 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3393 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3394 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3395 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3396 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3397 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3398 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3399 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3400
3401 AC_SUBST(FLAGS_FOR_TARGET)
3402 AC_SUBST(RAW_CXX_FOR_TARGET)
3403
3404 # Certain tools may need extra flags.
3405 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3406 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3407 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3408
3409 # When building target libraries, except in a Canadian cross, we use
3410 # the same toolchain as the compiler we just built.
3411 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3412 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3413 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3414 if test $host = $build; then
3415   case " $configdirs " in
3416     *" gcc "*)
3417       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3418       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3419       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3420       ;;
3421   esac
3422 fi
3423
3424 AC_SUBST(COMPILER_AS_FOR_TARGET)
3425 AC_SUBST(COMPILER_LD_FOR_TARGET)
3426 AC_SUBST(COMPILER_NM_FOR_TARGET)
3427
3428 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3429 AC_ARG_ENABLE(maintainer-mode,
3430 [AS_HELP_STRING([--enable-maintainer-mode],
3431                 [enable make rules and dependencies not useful
3432                  (and sometimes confusing) to the casual installer])],
3433       USE_MAINTAINER_MODE=$enableval,
3434       USE_MAINTAINER_MODE=no)
3435 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3436 AC_SUBST(MAINTAINER_MODE_TRUE)
3437 AC_SUBST(MAINTAINER_MODE_FALSE)
3438 if test "$USE_MAINTAINER_MODE" = yes; then
3439   MAINTAINER_MODE_TRUE=
3440   MAINTAINER_MODE_FALSE='#'
3441 else
3442   MAINTAINER_MODE_TRUE='#'
3443   MAINTAINER_MODE_FALSE=
3444 fi
3445 MAINT=$MAINTAINER_MODE_TRUE
3446 AC_SUBST(MAINT)dnl
3447
3448 # ---------------------
3449 # GCC bootstrap support
3450 # ---------------------
3451
3452 # Stage specific cflags for build.
3453 stage1_cflags="-g"
3454 case $build in
3455   vax-*-*)
3456     case ${GCC} in
3457       yes) stage1_cflags="-g -Wa,-J" ;;
3458       *) stage1_cflags="-g -J" ;;
3459     esac ;;
3460 esac
3461
3462 AC_SUBST(stage1_cflags)
3463
3464 # Enable --enable-checking in stage1 of the compiler.
3465 AC_ARG_ENABLE(stage1-checking,
3466 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3467                 [choose additional checking for stage1 of the compiler])],
3468 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3469 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3470   # For --disable-checking or implicit --enable-checking=release, avoid
3471   # setting --enable-checking=gc in the default stage1 checking for LTO
3472   # bootstraps.  See PR62077.
3473   case $BUILD_CONFIG in
3474     *lto*)
3475       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3476     *)
3477       stage1_checking=--enable-checking=yes,types;;
3478   esac
3479   if test "x$enable_checking" = x && \
3480      test -d ${srcdir}/gcc && \
3481      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3482     stage1_checking=--enable-checking=yes,types,extra
3483   fi
3484 else
3485   stage1_checking=--enable-checking=$enable_checking,types
3486 fi])
3487 AC_SUBST(stage1_checking)
3488
3489 # Enable -Werror in bootstrap stage2 and later.
3490 AC_ARG_ENABLE(werror,
3491 [AS_HELP_STRING([--enable-werror],
3492                 [enable -Werror in bootstrap stage2 and later])],
3493 [
3494 case ${enable_werror} in
3495   yes) stage2_werror_flag="--enable-werror-always" ;;
3496   *) stage2_werror_flag="" ;;
3497 esac
3498 ],
3499 [
3500 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3501   case $BUILD_CONFIG in
3502   bootstrap-debug)
3503       stage2_werror_flag="--enable-werror-always" ;;
3504   "")
3505       stage2_werror_flag="--enable-werror-always" ;;
3506   esac
3507 fi
3508 ])
3509
3510 AC_SUBST(stage2_werror_flag)
3511
3512 # Specify what files to not compare during bootstrap.
3513
3514 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3515 case "$target" in
3516   hppa*64*-*-hpux*) ;;
3517   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/* | gcc/function-tests.o" ;;
3518   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3519 esac
3520 AC_SUBST(compare_exclusions)
3521
3522 AC_CONFIG_FILES([Makefile],
3523   [sed "$extrasub_build" Makefile |
3524    sed "$extrasub_host" |
3525    sed "$extrasub_target" > mf$$
3526    mv -f mf$$ Makefile],
3527   [extrasub_build="$extrasub_build"
3528    extrasub_host="$extrasub_host"
3529    extrasub_target="$extrasub_target"])
3530 AC_OUTPUT