libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:6:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  -Wall:  turns on all automake warnings...
  76 #  -Wno-portability:  ...except this one, since GNU make is now required.
  77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
  78 AH_TEMPLATE(PACKAGE, [Name of package])
  79 AH_TEMPLATE(VERSION, [Version number of package])
  80
  81 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  82 # up critical shell variables.
  83 GLIBCXX_CONFIGURE
  84
  85 AC_LIBTOOL_DLOPEN
  86 AM_PROG_LIBTOOL
  87 AC_SUBST(enable_shared)
  88 AC_SUBST(enable_static)
  89
  90 # Possibly disable most of the library.
  91 ## TODO: Consider skipping unncessary tests altogether in this case, rather
  92 ## than just ignoring the results.  Faster /and/ more correct, win win.
  93 GLIBCXX_ENABLE_HOSTED
  94
  95 # Check for compiler support that doesn't require linking.
  96 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  97 GLIBCXX_ENABLE_PCH($is_hosted)
  98
  99 # Enable all the variable C++ runtime options.
 100 GLIBCXX_ENABLE_CSTDIO
 101 GLIBCXX_ENABLE_CLOCALE
 102 GLIBCXX_ENABLE_ALLOCATOR
 103 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 104 GLIBCXX_ENABLE_C99([yes])
 105 GLIBCXX_ENABLE_LONG_LONG([yes])
 106 GLIBCXX_ENABLE_WCHAR_T([yes])
 107 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 108 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 109 GLIBCXX_ENABLE_DEBUG([no])
 110 GLIBCXX_ENABLE_CXX_FLAGS
 111 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 112
 113 # No surprises, no surprises...
 114 GLIBCXX_ENABLE_THREADS
 115 if test $atomicity_dir = cpu/generic ; then
 116   AC_MSG_WARN([No native atomic operations are provided for this platform.])
 117   if test $target_thread_file = single; then
 118     AC_MSG_WARN([They cannot be faked when thread support is disabled.])
 119     AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
 120   else
 121     AC_MSG_WARN([They will be faked using a mutex.])
 122     AC_MSG_WARN([Performance of certain classes will degrade as a result.])
 123   fi
 124 fi
 125
 126
 127 if $GLIBCXX_IS_NATIVE; then
 128
 129   # We can do more elaborate tests that assume a working linker.
 130   CANADIAN=no
 131
 132   # Check for available headers.
 133   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 134   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h \
 135   sys/types.h sys/ipc.h sys/sem.h])
 136
 137   GLIBCXX_CHECK_COMPILER_FEATURES
 138   GLIBCXX_CHECK_LINKER_FEATURES
 139   GLIBCXX_CHECK_MATH_SUPPORT
 140   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 141   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 142   GLIBCXX_CHECK_ICONV_SUPPORT
 143   GLIBCXX_CHECK_STDLIB_SUPPORT
 144
 145   # For showmanyc_helper().
 146   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 147   GLIBCXX_CHECK_POLL
 148   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 149
 150   # For xsputn_2().
 151   AC_CHECK_HEADERS(sys/uio.h)
 152   GLIBCXX_CHECK_WRITEV
 153
 154   # For the __streamoff_base_type typedef.
 155   GLIBCXX_CHECK_INT64_T
 156
 157   # For LFS support.
 158   GLIBCXX_CHECK_LFS
 159
 160   AC_LC_MESSAGES
 161
 162   AC_TRY_COMPILE(
 163     [#include <setjmp.h>],
 164     [sigjmp_buf env;
 165      while (! sigsetjmp (env, 1))
 166        siglongjmp (env, 1);
 167     ],
 168     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
 169
 170   AC_FUNC_MMAP
 171
 172 else
 173
 174   # This lets us hard-code the functionality we know we'll have in the cross
 175   # target environment.  "Let" is a sugar-coated word placed on an especially
 176   # dull and tedious hack, actually.
 177   #
 178   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 179   # that involve linking, can't be used:
 180   #    "cannot open sim-crt0.o"
 181   #    "cannot open crt0.o"
 182   # etc.  All this is because there currently exists no unified, consistent
 183   # way for top level CC information to be passed down to target directories:
 184   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 185   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 186   # crosses can be removed.
 187
 188   # If Canadian cross, then don't pick up tools from the build directory.
 189   # Used only in GLIBCXX_EXPORT_INCLUDES.
 190   if test -n "$with_cross_host" &&
 191      test x"$build_alias" != x"$with_cross_host" &&
 192      test x"$build" != x"$target";
 193   then
 194     CANADIAN=yes
 195   else
 196     CANADIAN=no
 197   fi
 198
 199   # Construct crosses by hand, eliminating bits that need ld...
 200   # GLIBCXX_CHECK_COMPILER_FEATURES
 201   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 202   # GLIBCXX_CHECK_MATH_SUPPORT
 203
 204   # First, test for "known" system libraries.  We may be using newlib even
 205   # on a hosted environment.
 206   if test "x${with_newlib}" = "xyes"; then
 207     os_include_dir="os/newlib"
 208     AC_DEFINE(HAVE_HYPOT)
 209
 210     # GLIBCXX_CHECK_STDLIB_SUPPORT
 211     AC_DEFINE(HAVE_STRTOF)
 212     # AC_FUNC_MMAP
 213     AC_DEFINE(HAVE_MMAP)
 214
 215     AC_DEFINE(HAVE_ACOSF)
 216     AC_DEFINE(HAVE_ASINF)
 217     AC_DEFINE(HAVE_ATAN2F)
 218     AC_DEFINE(HAVE_ATANF)
 219     AC_DEFINE(HAVE_CEILF)
 220     AC_DEFINE(HAVE_COPYSIGN)
 221     AC_DEFINE(HAVE_COPYSIGNF)
 222     AC_DEFINE(HAVE_COSF)
 223     AC_DEFINE(HAVE_COSHF)
 224     AC_DEFINE(HAVE_EXPF)
 225     AC_DEFINE(HAVE_FABSF)
 226     AC_DEFINE(HAVE_FLOORF)
 227     AC_DEFINE(HAVE_FMODF)
 228     AC_DEFINE(HAVE_FREXPF)
 229     AC_DEFINE(HAVE_LDEXPF)
 230     AC_DEFINE(HAVE_LOG10F)
 231     AC_DEFINE(HAVE_LOGF)
 232     AC_DEFINE(HAVE_MODFF)
 233     AC_DEFINE(HAVE_POWF)
 234     AC_DEFINE(HAVE_SINF)
 235     AC_DEFINE(HAVE_SINHF)
 236     AC_DEFINE(HAVE_SQRTF)
 237     AC_DEFINE(HAVE_TANF)
 238     AC_DEFINE(HAVE_TANHF)
 239
 240     AC_DEFINE(HAVE_S_ISREG)
 241     AC_DEFINE(HAVE_S_IFREG)
 242   else
 243     GLIBCXX_CROSSCONFIG
 244   fi
 245
 246   # At some point, we should differentiate between architectures
 247   # like x86, which have long double versions, and alpha/powerpc/etc.,
 248   # which don't. For the time being, punt.
 249   if test x"long_double_math_on_this_cpu" = x"yes"; then
 250     AC_DEFINE(HAVE_ACOSL)
 251     AC_DEFINE(HAVE_ASINL)
 252     AC_DEFINE(HAVE_ATAN2L)
 253     AC_DEFINE(HAVE_ATANL)
 254     AC_DEFINE(HAVE_CEILL)
 255     AC_DEFINE(HAVE_COPYSIGNL)
 256     AC_DEFINE(HAVE_COSL)
 257     AC_DEFINE(HAVE_COSHL)
 258     AC_DEFINE(HAVE_EXPL)
 259     AC_DEFINE(HAVE_FABSL)
 260     AC_DEFINE(HAVE_FLOORL)
 261     AC_DEFINE(HAVE_FMODL)
 262     AC_DEFINE(HAVE_FREXPL)
 263     AC_DEFINE(HAVE_LDEXPL)
 264     AC_DEFINE(HAVE_LOG10L)
 265     AC_DEFINE(HAVE_LOGL)
 266     AC_DEFINE(HAVE_MODFL)
 267     AC_DEFINE(HAVE_POWL)
 268     AC_DEFINE(HAVE_SINCOSL)
 269     AC_DEFINE(HAVE_SINL)
 270     AC_DEFINE(HAVE_SINHL)
 271     AC_DEFINE(HAVE_SQRTL)
 272     AC_DEFINE(HAVE_TANL)
 273     AC_DEFINE(HAVE_TANHL)
 274   fi
 275
 276 fi
 277
 278 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 279 GLIBCXX_ENABLE_SYMVERS([yes])
 280
 281 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 282 GLIBCXX_CONFIGURE_TESTSUITE
 283
 284 # Propagate the target-specific source directories through the build chain.
 285 ATOMICITY_SRCDIR=config/${atomicity_dir}
 286 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 287 OS_INC_SRCDIR=config/${os_include_dir}
 288 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 289 AC_SUBST(ATOMICITY_SRCDIR)
 290 AC_SUBST(ATOMIC_WORD_SRCDIR)
 291 AC_SUBST(ABI_TWEAKS_SRCDIR)
 292 AC_SUBST(OS_INC_SRCDIR)
 293
 294 # Determine cross-compile flags and AM_CONDITIONALs.
 295 #AC_SUBST(GLIBCXX_IS_NATIVE)
 296 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 297 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 298 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 299 GLIBCXX_EVALUATE_CONDITIONALS
 300
 301 AC_CACHE_SAVE
 302
 303 if test ${multilib} = yes; then
 304   multilib_arg="--enable-multilib"
 305 else
 306   multilib_arg=
 307 fi
 308
 309 # Export all the install information.
 310 GLIBCXX_EXPORT_INSTALL_INFO
 311
 312 # Export all the include and flag information to Makefiles.
 313 GLIBCXX_EXPORT_INCLUDES
 314 GLIBCXX_EXPORT_FLAGS
 315
 316 if ${CONFIG_SHELL-/bin/sh} ./libtool --tag CXX --features |
 317    grep "enable shared" > /dev/null;
 318 then
 319   LIBSUPCXX_PICFLAGS=-prefer-pic
 320 else
 321   LIBSUPCXX_PICFLAGS=
 322 fi
 323 AC_SUBST(LIBSUPCXX_PICFLAGS)
 324
 325 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 326 dnl which can all be called multiple times as needed, plus one (different)
 327 dnl AC_OUTPUT macro.  This one lists the files to be created:
 328 AC_CONFIG_FILES( \
 329   Makefile \
 330   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
 331   )
 332 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 333
 334 dnl These commands are run at the end of config.status:
 335 AC_CONFIG_COMMANDS([default],
 336 [if test -n "$CONFIG_FILES"; then
 337    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 338    # that multilib installs will end up installed in the correct place.
 339    # The testsuite needs it for multilib-aware ABI baseline files.
 340    # To work around this not being passed down from config-ml.in ->
 341    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 342    # append it here.  Only modify Makefiles that have just been created.
 343    #
 344    # Also, get rid of this simulated-VPATH thing that automake does.
 345    cat > vpsed << \_EOF
 346 s!`test -f '$<' || echo '$(srcdir)/'`!!
 347 _EOF
 348    for i in $SUBDIRS; do
 349     case $CONFIG_FILES in
 350      *${i}/Makefile*)
 351        #echo "Adding MULTISUBDIR to $i/Makefile"
 352        sed -f vpsed $i/Makefile > tmp
 353        grep '^MULTISUBDIR =' Makefile >> tmp
 354        mv tmp $i/Makefile
 355        ;;
 356     esac
 357    done
 358    rm vpsed
 359  fi
 360  (cd include && ${MAKE-make})
 361 ],
 362 [
 363 # Variables needed in config.status (file generation) which aren't already
 364 # passed by autoconf.
 365 SUBDIRS="$SUBDIRS"
 366 ])
 367
 368 dnl And this actually makes things happen:
 369 AC_OUTPUT