gcc/ada/a-cusyqu.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --               ADA.CONTAINERS.UNBOUNDED_SYNCHRONIZED_QUEUES               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --            Copyright (C) 2011, Free Software Foundation, Inc.            --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 --                                                                          --
  31 -- This unit was originally developed by Matthew J Heaney.                  --
  32 ------------------------------------------------------------------------------
  33
  34 with System;
  35 with Ada.Containers.Synchronized_Queue_Interfaces;
  36 with Ada.Finalization;
  37
  38 generic
  39    with package Queue_Interfaces is
  40      new Ada.Containers.Synchronized_Queue_Interfaces (<>);
  41
  42    Default_Ceiling : System.Any_Priority := System.Priority'Last;
  43
  44 package Ada.Containers.Unbounded_Synchronized_Queues is
  45    pragma Preelaborate;
  46
  47    package Implementation is
  48
  49       --  All identifiers in this unit are implementation defined
  50
  51       pragma Implementation_Defined;
  52
  53       type List_Type is tagged limited private;
  54
  55       procedure Enqueue
  56         (List     : in out List_Type;
  57          New_Item : Queue_Interfaces.Element_Type);
  58
  59       procedure Dequeue
  60         (List    : in out List_Type;
  61          Element : out Queue_Interfaces.Element_Type);
  62
  63       function Length (List : List_Type) return Count_Type;
  64
  65       function Max_Length (List : List_Type) return Count_Type;
  66
  67    private
  68
  69       type Node_Type;
  70       type Node_Access is access Node_Type;
  71
  72       type Node_Type is limited record
  73          Element : Queue_Interfaces.Element_Type;
  74          Next    : Node_Access;
  75       end record;
  76
  77       type List_Type is new Ada.Finalization.Limited_Controlled with record
  78          First, Last : Node_Access;
  79          Length      : Count_Type := 0;
  80          Max_Length  : Count_Type := 0;
  81       end record;
  82
  83       overriding
  84       procedure Finalize (List : in out List_Type);
  85
  86    end Implementation;
  87
  88    protected type Queue (Ceiling : System.Any_Priority := Default_Ceiling)
  89      with Priority => Ceiling is new Queue_Interfaces.Queue with
  90
  91       overriding
  92       entry Enqueue (New_Item : Queue_Interfaces.Element_Type);
  93
  94       overriding
  95       entry Dequeue (Element : out Queue_Interfaces.Element_Type);
  96
  97       overriding
  98       function Current_Use return Count_Type;
  99
 100       overriding
 101       function Peak_Use return Count_Type;
 102
 103    private
 104
 105       List : Implementation.List_Type;
 106
 107    end Queue;
 108
 109 end Ada.Containers.Unbounded_Synchronized_Queues;