gcc/ada/s-ficobl.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --              S Y S T E M . F I L E _ C O N T R O L _ B L O C K           --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --            Copyright (C) 1992-2004 Free Software Foundation, Inc.        --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This package contains the declaration of the basic file control block
  35 --  shared between Text_IO, Sequential_IO, Direct_IO and Streams.Stream_IO.
  36 --  The actual control blocks are derived from this block by extension. The
  37 --  control block is itself derived from Ada.Streams.Root_Stream_Type which
  38 --  facilitates implementation of Stream_IO.Stream and Text_Streams.Stream.
  39
  40 with Ada.Streams;
  41 with Interfaces.C_Streams;
  42
  43 package System.File_Control_Block is
  44
  45    ----------------------------
  46    -- Ada File Control Block --
  47    ----------------------------
  48
  49    --  The Ada file control block is an abstract extension of the root
  50    --  stream type. This allows a file to be treated directly as a stream
  51    --  for the purposes of Stream_IO, or stream operations on a text file.
  52    --  The individual I/O packages extend this type with package specific
  53    --  fields to create the concrete types to which the routines in this
  54    --  package can be applied.
  55
  56    --  The type File_Type in the individual packages is an access to the
  57    --  extended file control block. The value is null if the file is not
  58    --  open, and a pointer to the control block if the file is open.
  59
  60    type Pstring is access all String;
  61    --  Used to hold name and form strings
  62
  63    type File_Mode is (In_File, Inout_File, Out_File, Append_File);
  64    --  File mode (union of file modes permitted by individual packages,
  65    --  the types File_Mode in the individual packages are declared to
  66    --  allow easy conversion to and from this general type.
  67
  68    type Shared_Status_Type is (Yes, No, None);
  69    --  This type is used to define the sharing status of a file. The default
  70    --  setting of None is used if no "shared=xxx" appears in the form string
  71    --  when a file is created or opened. For a file with Shared_Status set to
  72    --  None, Use_Error will be raised if any other file is opened or created
  73    --  with the same full name. Yes/No are set in response to the presence
  74    --  of "shared=yes" or "shared=no" in the form string. In either case it
  75    --  is permissible to have multiple files opened with the same full name.
  76    --  All files opened simultaneously with "shared=yes" will share the same
  77    --  stream with the semantics specified in the RM for file sharing. All
  78    --  files opened with "shared=no" will have their own stream.
  79
  80    type AFCB;
  81    type AFCB_Ptr is access all AFCB'Class;
  82
  83    type AFCB is abstract new Ada.Streams.Root_Stream_Type with record
  84
  85       Stream : Interfaces.C_Streams.FILEs;
  86       --  The file descriptor
  87
  88       Name : Pstring;
  89       --  A pointer to the file name. The file name is null for temporary
  90       --  files, and also for standard files (stdin, stdout, stderr). The
  91       --  name is always null-terminated if it is non-null.
  92
  93       Form : Pstring;
  94       --  A pointer to the form string. This is the string used in the
  95       --  fopen call, and must be supplied by the caller (there are no
  96       --  defaults at this level). The string is always null-terminated.
  97
  98       Mode : File_Mode;
  99       --  The file mode. No checks are made that the mode is consistent
 100       --  with the form used to fopen the file.
 101
 102       Is_Regular_File : Boolean;
 103       --  A flag indicating if the file is a regular file
 104
 105       Is_Temporary_File : Boolean;
 106       --  A flag set only for temporary files (i.e. files created using the
 107       --  Create function with a null name parameter, using tmpfile). This
 108       --  is currently not used since temporary files are deleted by the
 109       --  operating system, but it is set properly in case some systems
 110       --  need this information in the future.
 111
 112       Is_System_File : Boolean;
 113       --  A flag set only for system files (stdin, stdout, stderr)
 114
 115       Is_Text_File : Boolean;
 116       --  A flag set if the file was opened in text mode
 117
 118       Shared_Status : Shared_Status_Type;
 119       --  Indicates sharing status of file, see description of type above
 120
 121       Access_Method : Character;
 122       --  Set to 'Q', 'S', 'T, 'D' for Sequential_IO, Stream_IO, Text_IO
 123       --  Direct_IO file (used to validate file sharing request).
 124
 125       Next : AFCB_Ptr;
 126       Prev : AFCB_Ptr;
 127       --  All open files are kept on a doubly linked chain, with these
 128       --  pointers used to maintain the next and previous pointers.
 129
 130    end record;
 131
 132    ----------------------------------
 133    -- Primitive Operations of AFCB --
 134    ----------------------------------
 135
 136    --  Note that we inherit the abstract operations Read and Write from
 137    --  the base type. These must be overridden by the individual file
 138    --  access methods to provide Stream Read/Write access.
 139
 140    function AFCB_Allocate (Control_Block : AFCB) return AFCB_Ptr is abstract;
 141    --  Given a control block, allocate space for a control block of the same
 142    --  type on the heap, and return the pointer to this allocated block. Note
 143    --  that the argument Control_Block is not used other than as the argument
 144    --  that controls which version of AFCB_Allocate is called.
 145
 146    procedure AFCB_Close (File : access AFCB) is abstract;
 147    --  Performs any specialized close actions on a file before the file is
 148    --  actually closed at the system level. This is called by Close, and
 149    --  the reason we need the primitive operation is for the automatic
 150    --  close operations done as part of finalization.
 151
 152    procedure AFCB_Free (File : access AFCB) is abstract;
 153    --  Frees the AFCB referenced by the given parameter. It is not necessary
 154    --  to free the strings referenced by the Form and Name fields, but if the
 155    --  extension has any other heap objects, they must be freed as well. This
 156    --  procedure must be overridden by each individual file package.
 157
 158 end System.File_Control_Block;