gcc/ada/g-thread.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                         G N A T . T H R E A D S                          --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                     Copyright (C) 1998-2006 AdaCore                      --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Ada.Task_Identification; use Ada.Task_Identification;
  35 with System.Task_Primitives.Operations;
  36 with System.Tasking;
  37 with System.Tasking.Stages;   use System.Tasking.Stages;
  38 with System.OS_Interface;     use System.OS_Interface;
  39 with System.Soft_Links;       use System.Soft_Links;
  40 with Unchecked_Conversion;
  41
  42 package body GNAT.Threads is
  43
  44    use System;
  45
  46    package STPO renames System.Task_Primitives.Operations;
  47
  48    type Thread_Id_Ptr is access all Thread_Id;
  49
  50    pragma Warnings (Off);
  51    --  The following unchecked conversions are aliasing safe, since they
  52    --  are never used to create pointers to improperly aliased data.
  53
  54    function To_Addr is new Unchecked_Conversion (Task_Id, Address);
  55    function To_Id   is new Unchecked_Conversion (Address, Task_Id);
  56    function To_Id   is new Unchecked_Conversion (Address, Tasking.Task_Id);
  57    function To_Tid  is new Unchecked_Conversion
  58      (Address, Ada.Task_Identification.Task_Id);
  59    function To_Thread is new Unchecked_Conversion (Address, Thread_Id_Ptr);
  60
  61    pragma Warnings (On);
  62
  63    type Code_Proc is access procedure (Id : Address; Parm : Void_Ptr);
  64
  65    task type Thread
  66      (Stsz : Natural;
  67       Prio : Any_Priority;
  68       Parm : Void_Ptr;
  69       Code : Code_Proc)
  70    is
  71       pragma Priority (Prio);
  72       pragma Storage_Size (Stsz);
  73    end Thread;
  74
  75    task body Thread is
  76    begin
  77       Code.all (To_Addr (Current_Task), Parm);
  78    end Thread;
  79
  80    type Tptr is access Thread;
  81
  82    -------------------
  83    -- Create_Thread --
  84    -------------------
  85
  86    function Create_Thread
  87      (Code : Address;
  88       Parm : Void_Ptr;
  89       Size : Natural;
  90       Prio : Integer) return System.Address
  91    is
  92       TP : Tptr;
  93
  94       function To_CP is new Unchecked_Conversion (Address, Code_Proc);
  95
  96    begin
  97       TP := new Thread (Size, Prio, Parm, To_CP (Code));
  98       return To_Addr (TP'Identity);
  99    end Create_Thread;
 100
 101    ---------------------
 102    -- Register_Thread --
 103    ---------------------
 104
 105    function Register_Thread return System.Address is
 106    begin
 107       return Task_Primitives.Operations.Register_Foreign_Thread.all'Address;
 108    end Register_Thread;
 109
 110    -----------------------
 111    -- Unregister_Thread --
 112    -----------------------
 113
 114    procedure Unregister_Thread is
 115       Self_Id : constant Tasking.Task_Id := Task_Primitives.Operations.Self;
 116    begin
 117       Self_Id.Common.State := Tasking.Terminated;
 118       Destroy_TSD (Self_Id.Common.Compiler_Data);
 119       Free_Task (Self_Id);
 120    end Unregister_Thread;
 121
 122    --------------------------
 123    -- Unregister_Thread_Id --
 124    --------------------------
 125
 126    procedure Unregister_Thread_Id (Thread : System.Address) is
 127       Thr : constant Thread_Id := To_Thread (Thread).all;
 128       T   : Tasking.Task_Id;
 129
 130       use type Tasking.Task_Id;
 131       use type System.OS_Interface.Thread_Id;
 132
 133    begin
 134       STPO.Lock_RTS;
 135
 136       T := Tasking.All_Tasks_List;
 137       loop
 138          exit when T = null or else STPO.Get_Thread_Id (T) = Thr;
 139
 140          T := T.Common.All_Tasks_Link;
 141       end loop;
 142
 143       STPO.Unlock_RTS;
 144
 145       if T /= null then
 146          T.Common.State := Tasking.Terminated;
 147          Destroy_TSD (T.Common.Compiler_Data);
 148          Free_Task (T);
 149       end if;
 150    end Unregister_Thread_Id;
 151
 152    --------------------
 153    -- Destroy_Thread --
 154    --------------------
 155
 156    procedure Destroy_Thread (Id : Address) is
 157       Tid : constant Task_Id := To_Id (Id);
 158    begin
 159       Abort_Task (Tid);
 160    end Destroy_Thread;
 161
 162    ----------------
 163    -- Get_Thread --
 164    ----------------
 165
 166    procedure Get_Thread (Id : Address; Thread : Address) is
 167       Thr : constant Thread_Id_Ptr := To_Thread (Thread);
 168    begin
 169       Thr.all := Task_Primitives.Operations.Get_Thread_Id (To_Id (Id));
 170    end Get_Thread;
 171
 172    ----------------
 173    -- To_Task_Id --
 174    ----------------
 175
 176    function To_Task_Id
 177      (Id   : System.Address) return Ada.Task_Identification.Task_Id
 178    is
 179    begin
 180       return To_Tid (Id);
 181    end To_Task_Id;
 182
 183 end GNAT.Threads;