gcc/ada/a-chtgbk.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --              ADA.CONTAINERS.HASH_TABLES.GENERIC_BOUNDED_KEYS             --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- This unit was originally developed by Matthew J Heaney.                  --
  28 ------------------------------------------------------------------------------
  29
  30 --  Hash_Table_Type is used to implement hashed containers. This package
  31 --  declares hash-table operations that depend on keys.
  32
  33 generic
  34    with package HT_Types is
  35      new Generic_Bounded_Hash_Table_Types (<>);
  36
  37    use HT_Types;
  38
  39    with function Next (Node : Node_Type) return Count_Type;
  40
  41    with procedure Set_Next
  42      (Node : in out Node_Type;
  43       Next : Count_Type);
  44
  45    type Key_Type (<>) is limited private;
  46
  47    with function Hash (Key : Key_Type) return Hash_Type;
  48
  49    with function Equivalent_Keys
  50      (Key  : Key_Type;
  51       Node : Node_Type) return Boolean;
  52
  53 package Ada.Containers.Hash_Tables.Generic_Bounded_Keys is
  54    pragma Pure;
  55
  56    function Index
  57      (HT  : Hash_Table_Type'Class;
  58       Key : Key_Type) return Hash_Type;
  59    pragma Inline (Index);
  60    --  Returns the bucket number (array index value) for the given key
  61
  62    procedure Delete_Key_Sans_Free
  63      (HT  : in out Hash_Table_Type'Class;
  64       Key : Key_Type;
  65       X   : out Count_Type);
  66    --  Removes the node (if any) with the given key from the hash table,
  67    --  without deallocating it. Program_Error is raised if the hash
  68    --  table is busy.
  69
  70    function Find
  71      (HT  : Hash_Table_Type'Class;
  72       Key : Key_Type) return Count_Type;
  73    --  Returns the node (if any) corresponding to the given key
  74
  75    generic
  76       with function New_Node return Count_Type;
  77    procedure Generic_Conditional_Insert
  78      (HT       : in out Hash_Table_Type'Class;
  79       Key      : Key_Type;
  80       Node     : out Count_Type;
  81       Inserted : out Boolean);
  82    --  Attempts to insert a new node with the given key into the hash table.
  83    --  If a node with that key already exists in the table, then that node
  84    --  is returned and Inserted returns False. Otherwise New_Node is called
  85    --  to allocate a new node, and Inserted returns True. Program_Error is
  86    --  raised if the hash table is busy.
  87
  88    generic
  89       with function Hash (Node : Node_Type) return Hash_Type;
  90       with procedure Assign (Node : in out Node_Type; Key : Key_Type);
  91    procedure Generic_Replace_Element
  92      (HT   : in out Hash_Table_Type'Class;
  93       Node : Count_Type;
  94       Key  : Key_Type);
  95    --  Assigns Key to Node, possibly changing its equivalence class. If Node
  96    --  is in the same equivalence class as Key (that is, it's already in the
  97    --  bucket implied by Key), then if the hash table is locked then
  98    --  Program_Error is raised; otherwise Assign is called to assign Key to
  99    --  Node. If Node is in a different bucket from Key, then Program_Error is
 100    --  raised if the hash table is busy. Otherwise it Assigns Key to Node and
 101    --  moves the Node from its current bucket to the bucket implied by Key.
 102    --  Note that it is never proper to assign to Node a key value already
 103    --  in the map, and so if Key is equivalent to some other node then
 104    --  Program_Error is raised.
 105
 106 end Ada.Containers.Hash_Tables.Generic_Bounded_Keys;