gcc/ada/g-dyntab.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                   G N A T . D Y N A M I C _ T A B L E S                  --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                            $Revision: 1.4 $
  10 --                                                                          --
  11 --           Copyright (C) 2000-2001 Ada Core Technologies, Inc.            --
  12 --                                                                          --
  13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- As a special exception,  if other files  instantiate  generics from this --
  25 -- unit, or you link  this unit with other files  to produce an executable, --
  26 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27 -- covered  by the  GNU  General  Public  License.  This exception does not --
  28 -- however invalidate  any other reasons why  the executable file  might be --
  29 -- covered by the  GNU Public License.                                      --
  30 --                                                                          --
  31 -- GNAT is maintained by Ada Core Technologies Inc (http://www.gnat.com).   --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 with System; use System;
  36
  37 package body GNAT.Dynamic_Tables is
  38
  39    Min : constant Integer := Integer (Table_Low_Bound);
  40    --  Subscript of the minimum entry in the currently allocated table
  41
  42    type size_t is new Integer;
  43
  44    -----------------------
  45    -- Local Subprograms --
  46    -----------------------
  47
  48    procedure Reallocate (T : in out Instance);
  49    --  Reallocate the existing table according to the current value stored
  50    --  in Max. Works correctly to do an initial allocation if the table
  51    --  is currently null.
  52
  53    --------------
  54    -- Allocate --
  55    --------------
  56
  57    procedure Allocate
  58      (T   : in out Instance;
  59       Num : Integer := 1)
  60    is
  61    begin
  62       T.P.Last_Val := T.P.Last_Val + Num;
  63
  64       if T.P.Last_Val > T.P.Max then
  65          Reallocate (T);
  66       end if;
  67    end Allocate;
  68
  69    ------------
  70    -- Append --
  71    ------------
  72
  73    procedure Append (T : in out Instance; New_Val : Table_Component_Type) is
  74    begin
  75       Increment_Last (T);
  76       T.Table (Table_Index_Type (T.P.Last_Val)) := New_Val;
  77    end Append;
  78
  79    --------------------
  80    -- Decrement_Last --
  81    --------------------
  82
  83    procedure Decrement_Last (T : in out Instance) is
  84    begin
  85       T.P.Last_Val := T.P.Last_Val - 1;
  86    end Decrement_Last;
  87
  88    ----------
  89    -- Free --
  90    ----------
  91
  92    procedure Free (T : in out Instance) is
  93       procedure free (T : Table_Ptr);
  94       pragma Import (C, free);
  95
  96    begin
  97       free (T.Table);
  98       T.Table := null;
  99       T.P.Length := 0;
 100    end Free;
 101
 102    --------------------
 103    -- Increment_Last --
 104    --------------------
 105
 106    procedure Increment_Last (T : in out Instance) is
 107    begin
 108       T.P.Last_Val := T.P.Last_Val + 1;
 109
 110       if T.P.Last_Val > T.P.Max then
 111          Reallocate (T);
 112       end if;
 113    end Increment_Last;
 114
 115    ----------
 116    -- Init --
 117    ----------
 118
 119    procedure Init (T : in out Instance) is
 120       Old_Length : constant Integer := T.P.Length;
 121
 122    begin
 123       T.P.Last_Val := Min - 1;
 124       T.P.Max      := Min + Table_Initial - 1;
 125       T.P.Length   := T.P.Max - Min + 1;
 126
 127       --  If table is same size as before (happens when table is never
 128       --  expanded which is a common case), then simply reuse it. Note
 129       --  that this also means that an explicit Init call right after
 130       --  the implicit one in the package body is harmless.
 131
 132       if Old_Length = T.P.Length then
 133          return;
 134
 135       --  Otherwise we can use Reallocate to get a table of the right size.
 136       --  Note that Reallocate works fine to allocate a table of the right
 137       --  initial size when it is first allocated.
 138
 139       else
 140          Reallocate (T);
 141       end if;
 142    end Init;
 143
 144    ----------
 145    -- Last --
 146    ----------
 147
 148    function Last (T : in Instance) return Table_Index_Type is
 149    begin
 150       return Table_Index_Type (T.P.Last_Val);
 151    end Last;
 152
 153    ----------------
 154    -- Reallocate --
 155    ----------------
 156
 157    procedure Reallocate (T : in out Instance) is
 158
 159       function realloc
 160         (memblock : Table_Ptr;
 161          size     : size_t)
 162          return     Table_Ptr;
 163       pragma Import (C, realloc);
 164
 165       function malloc
 166         (size     : size_t)
 167          return     Table_Ptr;
 168       pragma Import (C, malloc);
 169
 170       New_Size : size_t;
 171
 172    begin
 173       if T.P.Max < T.P.Last_Val then
 174          while T.P.Max < T.P.Last_Val loop
 175             T.P.Length := T.P.Length * (100 + Table_Increment) / 100;
 176             T.P.Max := Min + T.P.Length - 1;
 177          end loop;
 178       end if;
 179
 180       New_Size :=
 181         size_t ((T.P.Max - Min + 1) *
 182                 (Table_Type'Component_Size / Storage_Unit));
 183
 184       if T.Table = null then
 185          T.Table := malloc (New_Size);
 186
 187       elsif New_Size > 0 then
 188          T.Table :=
 189            realloc
 190              (memblock => T.Table,
 191               size     => New_Size);
 192       end if;
 193
 194       if T.P.Length /= 0 and then T.Table = null then
 195          raise Storage_Error;
 196       end if;
 197
 198    end Reallocate;
 199
 200    -------------
 201    -- Release --
 202    -------------
 203
 204    procedure Release (T : in out Instance) is
 205    begin
 206       T.P.Length := T.P.Last_Val - Integer (Table_Low_Bound) + 1;
 207       T.P.Max    := T.P.Last_Val;
 208       Reallocate (T);
 209    end Release;
 210
 211    --------------
 212    -- Set_Item --
 213    --------------
 214
 215    procedure Set_Item
 216      (T     : in out Instance;
 217       Index : Table_Index_Type;
 218       Item  : Table_Component_Type)
 219    is
 220    begin
 221       if Integer (Index) > T.P.Max then
 222          Set_Last (T, Index);
 223       end if;
 224
 225       T.Table (Index) := Item;
 226    end Set_Item;
 227
 228    --------------
 229    -- Set_Last --
 230    --------------
 231
 232    procedure Set_Last (T : in out Instance; New_Val : Table_Index_Type) is
 233    begin
 234       if Integer (New_Val) < T.P.Last_Val then
 235          T.P.Last_Val := Integer (New_Val);
 236
 237       else
 238          T.P.Last_Val := Integer (New_Val);
 239
 240          if T.P.Last_Val > T.P.Max then
 241             Reallocate (T);
 242          end if;
 243       end if;
 244    end Set_Last;
 245
 246 end GNAT.Dynamic_Tables;