gcc/ada/s-bitops.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                GNU ADA RUNTIME LIBRARY (GNARL) COMPONENTS                --
   4 --                                                                          --
   5 --                       S Y S T E M . B I T _ O P S                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --         Copyright (C) 1996-2004 Free Software Foundation, Inc.           --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with System;                 use System;
  35 with System.Pure_Exceptions; use System.Pure_Exceptions;
  36 with System.Unsigned_Types;  use System.Unsigned_Types;
  37
  38 with Unchecked_Conversion;
  39
  40 package body System.Bit_Ops is
  41
  42    subtype Bits_Array is System.Unsigned_Types.Packed_Bytes1 (Positive);
  43    --  Unconstrained array used to interprete the address values. We use the
  44    --  unaligned version always, since this will handle both the aligned and
  45    --  unaligned cases, and we always do these operations by bytes anyway.
  46    --  Note: we use a ones origin array here so that the computations of the
  47    --  length in bytes work correctly (give a non-negative value) for the
  48    --  case of zero length bit strings).
  49
  50    type Bits is access Bits_Array;
  51    --  This is the actual type into which address values are converted
  52
  53    function To_Bits is new Unchecked_Conversion (Address, Bits);
  54
  55    LE : constant := Standard'Default_Bit_Order;
  56    --  Static constant set to 0 for big-endian, 1 for little-endian
  57
  58    --  The following is an array of masks used to mask the final byte, either
  59    --  at the high end (big-endian case) or the low end (little-endian case).
  60
  61    Masks : constant array (1 .. 7) of Packed_Byte := (
  62      (1 - LE) * 2#1000_0000# + LE * 2#0000_0001#,
  63      (1 - LE) * 2#1100_0000# + LE * 2#0000_0011#,
  64      (1 - LE) * 2#1110_0000# + LE * 2#0000_0111#,
  65      (1 - LE) * 2#1111_0000# + LE * 2#0000_1111#,
  66      (1 - LE) * 2#1111_1000# + LE * 2#0001_1111#,
  67      (1 - LE) * 2#1111_1100# + LE * 2#0011_1111#,
  68      (1 - LE) * 2#1111_1110# + LE * 2#0111_1111#);
  69
  70    -----------------------
  71    -- Local Subprograms --
  72    -----------------------
  73
  74    procedure Raise_Error;
  75    --  Raise Constraint_Error, complaining about unequal lengths
  76
  77    -------------
  78    -- Bit_And --
  79    -------------
  80
  81    procedure Bit_And
  82      (Left   : Address;
  83       Llen   : Natural;
  84       Right  : Address;
  85       Rlen   : Natural;
  86       Result : Address)
  87    is
  88       LeftB   : constant Bits := To_Bits (Left);
  89       RightB  : constant Bits := To_Bits (Right);
  90       ResultB : constant Bits := To_Bits (Result);
  91
  92    begin
  93       if Llen /= Rlen then
  94          Raise_Error;
  95       end if;
  96
  97       for J in 1 .. (Rlen + 7) / 8 loop
  98          ResultB (J) := LeftB (J) and RightB (J);
  99       end loop;
 100    end Bit_And;
 101
 102    ------------
 103    -- Bit_Eq --
 104    ------------
 105
 106    function Bit_Eq
 107      (Left  : Address;
 108       Llen  : Natural;
 109       Right : Address;
 110       Rlen  : Natural)
 111       return  Boolean
 112    is
 113       LeftB  : constant Bits := To_Bits (Left);
 114       RightB : constant Bits := To_Bits (Right);
 115
 116    begin
 117       if Llen /= Rlen then
 118          return False;
 119
 120       else
 121          declare
 122             BLen : constant Natural := Llen / 8;
 123             Bitc : constant Natural := Llen mod 8;
 124
 125          begin
 126             if LeftB (1 .. BLen) /= RightB (1 .. BLen) then
 127                return False;
 128
 129             elsif Bitc /= 0 then
 130                return
 131                  ((LeftB (BLen + 1) xor RightB (BLen + 1))
 132                    and Masks (Bitc)) = 0;
 133
 134             else -- Bitc = 0
 135                return True;
 136             end if;
 137          end;
 138       end if;
 139    end Bit_Eq;
 140
 141    -------------
 142    -- Bit_Not --
 143    -------------
 144
 145    procedure Bit_Not
 146      (Opnd   : System.Address;
 147       Len    : Natural;
 148       Result : System.Address)
 149    is
 150       OpndB   : constant Bits := To_Bits (Opnd);
 151       ResultB : constant Bits := To_Bits (Result);
 152
 153    begin
 154       for J in 1 .. (Len + 7) / 8 loop
 155          ResultB (J) := not OpndB (J);
 156       end loop;
 157    end Bit_Not;
 158
 159    ------------
 160    -- Bit_Or --
 161    ------------
 162
 163    procedure Bit_Or
 164      (Left   : Address;
 165       Llen   : Natural;
 166       Right  : Address;
 167       Rlen   : Natural;
 168       Result : Address)
 169    is
 170       LeftB   : constant Bits := To_Bits (Left);
 171       RightB  : constant Bits := To_Bits (Right);
 172       ResultB : constant Bits := To_Bits (Result);
 173
 174    begin
 175       if Llen /= Rlen then
 176          Raise_Error;
 177       end if;
 178
 179       for J in 1 .. (Rlen + 7) / 8 loop
 180          ResultB (J) := LeftB (J) or RightB (J);
 181       end loop;
 182    end Bit_Or;
 183
 184    -------------
 185    -- Bit_Xor --
 186    -------------
 187
 188    procedure Bit_Xor
 189      (Left   : Address;
 190       Llen   : Natural;
 191       Right  : Address;
 192       Rlen   : Natural;
 193       Result : Address)
 194    is
 195       LeftB   : constant Bits := To_Bits (Left);
 196       RightB  : constant Bits := To_Bits (Right);
 197       ResultB : constant Bits := To_Bits (Result);
 198
 199    begin
 200       if Llen /= Rlen then
 201          Raise_Error;
 202       end if;
 203
 204       for J in 1 .. (Rlen + 7) / 8 loop
 205          ResultB (J) := LeftB (J) xor RightB (J);
 206       end loop;
 207    end Bit_Xor;
 208
 209    -----------------
 210    -- Raise_Error --
 211    -----------------
 212
 213    procedure Raise_Error is
 214    begin
 215       Raise_Exception (CE, "unequal lengths in logical operation");
 216    end Raise_Error;
 217
 218 end System.Bit_Ops;