gcc/ada/s-osinte-android.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --                   S Y S T E M . O S _ I N T E R F A C E                  --
   6 --                                                                          --
   7 --                                   B o d y                                --
   8 --                                                                          --
   9 --                     Copyright (C) 1995-2014, AdaCore                     --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNARL was developed by the GNARL team at Florida State University.       --
  28 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This is an Android version of this package.
  33
  34 pragma Polling (Off);
  35 --  Turn off polling, we do not want ATC polling to take place during
  36 --  tasking operations. It causes infinite loops and other problems.
  37
  38 --  This package encapsulates all direct interfaces to OS services
  39 --  that are needed by children of System.
  40
  41 with Interfaces.C;            use Interfaces.C;
  42 with Interfaces.C.Extensions; use Interfaces.C.Extensions;
  43
  44 package body System.OS_Interface is
  45
  46    -----------------
  47    -- To_Duration --
  48    -----------------
  49
  50    function To_Duration (TS : timespec) return Duration is
  51    begin
  52       return Duration (TS.tv_sec) + Duration (TS.tv_nsec) / 10#1#E9;
  53    end To_Duration;
  54
  55    -----------------
  56    -- To_Timespec --
  57    -----------------
  58
  59    function To_Timespec (D : Duration) return timespec is
  60       S : time_t;
  61       F : Duration;
  62
  63    begin
  64       S := time_t (Long_Long_Integer (D));
  65       F := D - Duration (S);
  66
  67       --  If F has negative value due to a round-up, adjust for positive F
  68       --  value.
  69
  70       if F < 0.0 then
  71          S := S - 1;
  72          F := F + 1.0;
  73       end if;
  74
  75       return timespec'(tv_sec => S,
  76                        tv_nsec => long (Long_Long_Integer (F * 10#1#E9)));
  77    end To_Timespec;
  78
  79    -------------------
  80    -- clock_gettime --
  81    -------------------
  82
  83    function clock_gettime
  84      (clock_id : clockid_t;
  85       tp       : access timespec) return int
  86    is
  87       pragma Unreferenced (clock_id);
  88
  89       --  Android/Linux don't have clock_gettime, so use gettimeofday
  90
  91       use Interfaces;
  92
  93       type timeval is array (1 .. 3) of C.long;
  94       --  The timeval array is sized to contain long_long sec and long usec.
  95       --  If long_long'Size = long'Size then it will be overly large but that
  96       --  won't effect the implementation since it's not accessed directly.
  97
  98       procedure timeval_to_duration
  99         (T    : not null access timeval;
 100          sec  : not null access C.Extensions.long_long;
 101          usec : not null access C.long);
 102       pragma Import (C, timeval_to_duration, "__gnat_timeval_to_duration");
 103
 104       Micro  : constant := 10**6;
 105       sec    : aliased C.Extensions.long_long;
 106       usec   : aliased C.long;
 107       TV     : aliased timeval;
 108       Result : int;
 109
 110       function gettimeofday
 111         (Tv : access timeval;
 112          Tz : System.Address := System.Null_Address) return int;
 113       pragma Import (C, gettimeofday, "gettimeofday");
 114
 115    begin
 116       Result := gettimeofday (TV'Access, System.Null_Address);
 117       pragma Assert (Result = 0);
 118       timeval_to_duration (TV'Access, sec'Access, usec'Access);
 119       tp.all := To_Timespec (Duration (sec) + Duration (usec) / Micro);
 120       return Result;
 121    end clock_gettime;
 122
 123 end System.OS_Interface;