configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2022 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libiconv libctf libsframe"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gm2tools gotools c++tools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-libatomic \
 154                 target-libitm \
 155                 target-libstdc++-v3 \
 156                 target-libsanitizer \
 157                 target-libvtv \
 158                 target-libssp \
 159                 target-libquadmath \
 160                 target-libgfortran \
 161                 target-libffi \
 162                 target-libobjc \
 163                 target-libada \
 164                 target-libgm2 \
 165                 target-libgo \
 166                 target-libphobos \
 167                 target-zlib"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 251 # is provided.
 252 if test x$with_system_readline = xyes ; then
 253   noconfigdirs="$noconfigdirs readline"
 254 fi
 255
 256 # some tools are so dependent upon X11 that if we're not building with X,
 257 # it's not even worth trying to configure, much less build, that tool.
 258
 259 case ${with_x} in
 260   yes | "") ;; # the default value for this tree is that X11 is available
 261   no)
 262     skipdirs="${skipdirs} tk itcl libgui"
 263     # We won't be able to build gdbtk without X.
 264     enable_gdbtk=no
 265     ;;
 266   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 267 esac
 268
 269 # Some are only suitable for cross toolchains.
 270 # Remove these if host=target.
 271 cross_only="target-libgloss target-newlib target-opcodes"
 272
 273 case $is_cross_compiler in
 274   no) skipdirs="${skipdirs} ${cross_only}" ;;
 275 esac
 276
 277 # If both --with-headers and --with-libs are specified, default to
 278 # --without-newlib.
 279 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 280    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 281   if test x"${with_newlib}" = x ; then
 282     with_newlib=no
 283   fi
 284 fi
 285
 286 # Recognize --with-newlib/--without-newlib.
 287 case ${with_newlib} in
 288   no) skipdirs="${skipdirs} target-newlib" ;;
 289   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 290 esac
 291
 292 AC_ARG_ENABLE(as-accelerator-for,
 293 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 294                 [build as offload target compiler.
 295                 Specify offload host triple by ARG])])
 296
 297 AC_ARG_ENABLE(offload-targets,
 298 [AS_HELP_STRING([--enable-offload-targets=LIST],
 299                 [enable offloading to devices from comma-separated LIST of
 300                 TARGET[=DIR]. Use optional path to find offload target compiler
 301                 during the build])],
 302 [
 303   if test x"$enable_offload_targets" = x; then
 304     AC_MSG_ERROR([no offload targets specified])
 305   fi
 306 ], [enable_offload_targets=])
 307
 308 AC_ARG_ENABLE(offload-defaulted,
 309 [AS_HELP_STRING([--enable-offload-defaulted]
 310                 [If enabled, configured but not installed offload compilers and
 311                 libgomp plugins are silently ignored.  Useful for distribution
 312                 compilers where those are in separate optional packages.])],
 313 [enable_offload_defaulted=$enableval],
 314 [enable_offload_defaulted=])
 315
 316 # Handle --enable-gold, --enable-ld.
 317 # --disable-gold [--enable-ld]
 318 #     Build only ld.  Default option.
 319 # --enable-gold [--enable-ld]
 320 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 321 #     as "ld.bfd" and "ld".
 322 # --enable-gold=default [--enable-ld]
 323 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 324 #     install ld as "ld.bfd".
 325 # --enable-gold[=default] --disable-ld
 326 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 327 # --enable-gold --enable-ld=default
 328 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 329 #     and ld.bfd).
 330 #     In other words, ld is default
 331 # --enable-gold=default --enable-ld=default
 332 #     Error.
 333
 334 default_ld=
 335 AC_ARG_ENABLE(gold,
 336 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 337                 [build gold @<:@ARG={default,yes,no}@:>@])],
 338 ENABLE_GOLD=$enableval,
 339 ENABLE_GOLD=no)
 340 case "${ENABLE_GOLD}" in
 341   yes|default)
 342     # Check for ELF target.
 343     is_elf=no
 344     case "${target}" in
 345       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 346       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 347       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 348       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 349         case "${target}" in
 350           *-*-linux*aout* | *-*-linux*oldld*)
 351             ;;
 352           *)
 353             is_elf=yes
 354             ;;
 355         esac
 356     esac
 357
 358     if test "$is_elf" = "yes"; then
 359       # Check for target supported by gold.
 360       case "${target}" in
 361         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 362         | aarch64*-*-* | mips*-*-* | s390*-*-* | loongarch*-*-*)
 363           configdirs="$configdirs gold"
 364           if test x${ENABLE_GOLD} = xdefault; then
 365             default_ld=gold
 366           fi
 367           ENABLE_GOLD=yes
 368           ;;
 369       esac
 370     fi
 371     ;;
 372   no)
 373     ;;
 374   *)
 375     AC_MSG_ERROR([invalid --enable-gold argument])
 376     ;;
 377 esac
 378
 379 AC_ARG_ENABLE(ld,
 380 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 381                 [build ld @<:@ARG={default,yes,no}@:>@])],
 382 ENABLE_LD=$enableval,
 383 ENABLE_LD=yes)
 384
 385 case "${ENABLE_LD}" in
 386   default)
 387     if test x${default_ld} != x; then
 388       AC_MSG_ERROR([either gold or ld can be the default ld])
 389     fi
 390     ;;
 391   yes)
 392     ;;
 393   no)
 394     if test x${ENABLE_GOLD} != xyes; then
 395       AC_MSG_WARN([neither ld nor gold are enabled])
 396     fi
 397     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 398     ;;
 399   *)
 400     AC_MSG_ERROR([invalid --enable-ld argument])
 401     ;;
 402 esac
 403
 404 # PR gas/19109
 405 # Decide the default method for compressing debug sections.
 406 # Provide a configure time option to override our default.
 407 AC_ARG_ENABLE(compressed_debug_sections,
 408 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 409                 [Enable compressed debug sections for gas, gold or ld by
 410                  default])],
 411 [
 412   if test x"$enable_compressed_debug_sections" = xyes; then
 413     AC_MSG_ERROR([no program with compressed debug sections specified])
 414   fi
 415 ], [enable_compressed_debug_sections=])
 416
 417 # Configure extra directories which are host specific
 418
 419 case "${host}" in
 420   *-cygwin*)
 421     configdirs="$configdirs libtermcap" ;;
 422 esac
 423
 424 # A target can indicate whether a language isn't supported for some reason.
 425 # Only spaces may be used in this macro; not newlines or tabs.
 426 unsupported_languages=
 427
 428 # Remove more programs from consideration, based on the host or
 429 # target this usually means that a port of the program doesn't
 430 # exist yet.
 431
 432 case "${host}" in
 433   i[[3456789]]86-*-msdosdjgpp*)
 434     noconfigdirs="$noconfigdirs tcl tk itcl"
 435     ;;
 436 esac
 437
 438
 439 AC_ARG_ENABLE(libquadmath,
 440 AS_HELP_STRING([--disable-libquadmath],
 441   [do not build libquadmath directory]),
 442 ENABLE_LIBQUADMATH=$enableval,
 443 ENABLE_LIBQUADMATH=yes)
 444 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 445   noconfigdirs="$noconfigdirs target-libquadmath"
 446 fi
 447
 448
 449 AC_ARG_ENABLE(libquadmath-support,
 450 AS_HELP_STRING([--disable-libquadmath-support],
 451   [disable libquadmath support for Fortran]),
 452 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 453 ENABLE_LIBQUADMATH_SUPPORT=yes)
 454 enable_libquadmath_support=
 455 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 456   enable_libquadmath_support=no
 457 fi
 458
 459
 460 AC_ARG_ENABLE(libada,
 461 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 462 ENABLE_LIBADA=$enableval,
 463 ENABLE_LIBADA=yes)
 464 if test "${ENABLE_LIBADA}" != "yes" ; then
 465   noconfigdirs="$noconfigdirs gnattools"
 466 fi
 467
 468 AC_ARG_ENABLE(libgm2,
 469 [AS_HELP_STRING([--enable-libgm2], [build libgm2 directory])],
 470 ENABLE_LIBGM2=$enableval,
 471 ENABLE_LIBGM2=no)
 472 if test "${ENABLE_LIBGM2}" != "yes" ; then
 473   noconfigdirs="$noconfigdirs gm2tools"
 474 fi
 475
 476 AC_ARG_ENABLE(libssp,
 477 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 478 ENABLE_LIBSSP=$enableval,
 479 ENABLE_LIBSSP=yes)
 480
 481 AC_ARG_ENABLE(libstdcxx,
 482 AS_HELP_STRING([--disable-libstdcxx],
 483   [do not build libstdc++-v3 directory]),
 484 ENABLE_LIBSTDCXX=$enableval,
 485 ENABLE_LIBSTDCXX=default)
 486 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 487   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 488 fi]
 489
 490 # Enable libgomp by default on hosted POSIX systems, and a few others.
 491 if test x$enable_libgomp = x ; then
 492     case "${target}" in
 493     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 494         ;;
 495     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 496         ;;
 497     *-*-solaris2* | *-*-hpux11*)
 498         ;;
 499     *-*-darwin* | *-*-aix*)
 500         ;;
 501     nvptx*-*-* | amdgcn*-*-*)
 502         ;;
 503     *)
 504         noconfigdirs="$noconfigdirs target-libgomp"
 505         ;;
 506     esac
 507 fi
 508
 509 # Disable libatomic on unsupported systems.
 510 if test -d ${srcdir}/libatomic; then
 511     if test x$enable_libatomic = x; then
 512         AC_MSG_CHECKING([for libatomic support])
 513         if (srcdir=${srcdir}/libatomic; \
 514                 . ${srcdir}/configure.tgt; \
 515                 test -n "$UNSUPPORTED")
 516         then
 517             AC_MSG_RESULT([no])
 518             noconfigdirs="$noconfigdirs target-libatomic"
 519         else
 520             AC_MSG_RESULT([yes])
 521         fi
 522     fi
 523 fi
 524
 525 # Disable libitm on unsupported systems.
 526 if test -d ${srcdir}/libitm; then
 527     if test x$enable_libitm = x; then
 528         AC_MSG_CHECKING([for libitm support])
 529         if (srcdir=${srcdir}/libitm; \
 530                 . ${srcdir}/configure.tgt; \
 531                 test -n "$UNSUPPORTED")
 532         then
 533             AC_MSG_RESULT([no])
 534             noconfigdirs="$noconfigdirs target-libitm"
 535         else
 536             AC_MSG_RESULT([yes])
 537         fi
 538     fi
 539 fi
 540
 541 # Disable libsanitizer on unsupported systems.
 542 if test -d ${srcdir}/libsanitizer; then
 543     if test x$enable_libsanitizer = x; then
 544         AC_MSG_CHECKING([for libsanitizer support])
 545         if (srcdir=${srcdir}/libsanitizer; \
 546                 . ${srcdir}/configure.tgt; \
 547                 test -n "$UNSUPPORTED")
 548         then
 549             AC_MSG_RESULT([no])
 550             noconfigdirs="$noconfigdirs target-libsanitizer"
 551         else
 552             AC_MSG_RESULT([yes])
 553         fi
 554     fi
 555 fi
 556
 557 # Disable libvtv on unsupported systems.
 558 if test -d ${srcdir}/libvtv; then
 559     if test x$enable_libvtv = x; then
 560         AC_MSG_CHECKING([for libvtv support])
 561         if (srcdir=${srcdir}/libvtv; \
 562                 . ${srcdir}/configure.tgt; \
 563                 test "$VTV_SUPPORTED" != "yes")
 564         then
 565             AC_MSG_RESULT([no])
 566             noconfigdirs="$noconfigdirs target-libvtv"
 567         else
 568             AC_MSG_RESULT([yes])
 569         fi
 570     fi
 571 fi
 572
 573 # Disable libquadmath for some systems.
 574 case "${target}" in
 575   avr-*-*)
 576     noconfigdirs="$noconfigdirs target-libquadmath"
 577     ;;
 578   # libquadmath is unused on AIX and libquadmath build process use of
 579   # LD_LIBRARY_PATH can break AIX bootstrap.
 580   powerpc-*-aix* | rs6000-*-aix*)
 581     noconfigdirs="$noconfigdirs target-libquadmath"
 582     ;;
 583 esac
 584
 585 # Disable libssp for some systems.
 586 case "${target}" in
 587   avr-*-*)
 588     # No hosted I/O support.
 589     noconfigdirs="$noconfigdirs target-libssp"
 590     ;;
 591   bpf-*-*)
 592     noconfigdirs="$noconfigdirs target-libssp"
 593     ;;
 594   powerpc-*-aix* | rs6000-*-aix*)
 595     noconfigdirs="$noconfigdirs target-libssp"
 596     ;;
 597   pru-*-*)
 598     # No hosted I/O support.
 599     noconfigdirs="$noconfigdirs target-libssp"
 600     ;;
 601   rl78-*-*)
 602     # libssp uses a misaligned load to trigger a fault, but the RL78
 603     # doesn't fault for those - instead, it gives a build-time error
 604     # for explicit misaligned loads.
 605     noconfigdirs="$noconfigdirs target-libssp"
 606     ;;
 607   visium-*-*)
 608     # No hosted I/O support.
 609     noconfigdirs="$noconfigdirs target-libssp"
 610     ;;
 611 esac
 612
 613 # Disable libstdc++-v3 for some systems.
 614 # Allow user to override this if they pass --enable-libstdcxx
 615 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 616   case "${target}" in
 617     *-*-vxworks*)
 618       # VxWorks uses the Dinkumware C++ library.
 619       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 620       ;;
 621     amdgcn*-*-*)
 622       # Not ported/fails to build when using newlib.
 623       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 624       ;;
 625     arm*-wince-pe*)
 626       # the C++ libraries don't build on top of CE's C libraries
 627       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 628       ;;
 629     avr-*-*)
 630       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 631       ;;
 632     bpf-*-*)
 633       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 634       ;;
 635     ft32-*-*)
 636       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 637       ;;
 638   esac
 639 fi
 640
 641 # Disable C++ on systems where it is known to not work.
 642 # For testing, you can override this with --enable-languages=c++.
 643 case ,${enable_languages}, in
 644   *,c++,*)
 645     ;;
 646   *)
 647       case "${target}" in
 648         bpf-*-*)
 649           unsupported_languages="$unsupported_languages c++"
 650           ;;
 651       esac
 652       ;;
 653 esac
 654
 655 # Disable Objc on systems where it is known to not work.
 656 # For testing, you can override this with --enable-languages=objc.
 657 case ,${enable_languages}, in
 658   *,objc,*)
 659     ;;
 660   *)
 661       case "${target}" in
 662         bpf-*-*)
 663           unsupported_languages="$unsupported_languages objc"
 664           ;;
 665       esac
 666       ;;
 667 esac
 668
 669 # Disable D on systems where it is known to not work.
 670 # For testing, you can override this with --enable-languages=d.
 671 case ,${enable_languages}, in
 672   *,d,*)
 673     ;;
 674   *)
 675     case "${target}" in
 676       bpf-*-*)
 677         unsupported_languages="$unsupported_languages d"
 678         ;;
 679     esac
 680     ;;
 681 esac
 682
 683 # Disable libphobos on unsupported systems.
 684 # For testing, you can override this with --enable-libphobos.
 685 if test -d ${srcdir}/libphobos; then
 686     if test x$enable_libphobos = x; then
 687         AC_MSG_CHECKING([for libphobos support])
 688         if (srcdir=${srcdir}/libphobos; \
 689                 . ${srcdir}/configure.tgt; \
 690                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 691         then
 692             AC_MSG_RESULT([no])
 693             noconfigdirs="$noconfigdirs target-libphobos"
 694         else
 695             AC_MSG_RESULT([yes])
 696         fi
 697     fi
 698 fi
 699
 700 # Disable Fortran for some systems.
 701 case "${target}" in
 702   mmix-*-*)
 703     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 704     unsupported_languages="$unsupported_languages fortran"
 705     ;;
 706   bpf-*-*)
 707     unsupported_languages="$unsupported_languages fortran"
 708     ;;
 709 esac
 710
 711 # Disable libffi for some systems.
 712 case "${target}" in
 713   powerpc-*-darwin*)
 714     ;;
 715   i[[3456789]]86-*-darwin*)
 716     ;;
 717   x86_64-*-darwin[[912]]*)
 718     ;;
 719   *-*-darwin*)
 720     noconfigdirs="$noconfigdirs target-libffi"
 721     ;;
 722   *-*-netware*)
 723     noconfigdirs="$noconfigdirs target-libffi"
 724     ;;
 725   *-*-phoenix*)
 726     noconfigdirs="$noconfigdirs target-libffi"
 727     ;;
 728   *-*-rtems*)
 729     noconfigdirs="$noconfigdirs target-libffi"
 730     ;;
 731   *-*-tpf*)
 732     noconfigdirs="$noconfigdirs target-libffi"
 733     ;;
 734   *-*-uclinux*)
 735     noconfigdirs="$noconfigdirs target-libffi"
 736     ;;
 737   *-*-vxworks*)
 738     noconfigdirs="$noconfigdirs target-libffi"
 739     ;;
 740   aarch64*-*-freebsd*)
 741     noconfigdirs="$noconfigdirs target-libffi"
 742     ;;
 743   alpha*-*-*vms*)
 744     noconfigdirs="$noconfigdirs target-libffi"
 745     ;;
 746   arm*-*-freebsd*)
 747     noconfigdirs="$noconfigdirs target-libffi"
 748     ;;
 749   arm-wince-pe)
 750     noconfigdirs="$noconfigdirs target-libffi"
 751     ;;
 752   arm*-*-symbianelf*)
 753     noconfigdirs="$noconfigdirs target-libffi"
 754     ;;
 755   bpf-*-*)
 756     noconfigdirs="$noconfigdirs target-libffi"
 757     ;;
 758   cris-*-* | crisv32-*-*)
 759     case "${target}" in
 760       *-*-linux*)
 761         ;;
 762       *) # See PR46792 regarding target-libffi.
 763         noconfigdirs="$noconfigdirs target-libffi";;
 764     esac
 765     ;;
 766   hppa*64*-*-hpux*)
 767     noconfigdirs="$noconfigdirs target-libffi"
 768     ;;
 769   ia64*-*-*vms*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772   i[[3456789]]86-w64-mingw*)
 773     noconfigdirs="$noconfigdirs target-libffi"
 774     ;;
 775   i[[3456789]]86-*-mingw*)
 776     noconfigdirs="$noconfigdirs target-libffi"
 777     ;;
 778   x86_64-*-mingw*)
 779     noconfigdirs="$noconfigdirs target-libffi"
 780     ;;
 781   mmix-*-*)
 782     noconfigdirs="$noconfigdirs target-libffi"
 783     ;;
 784   powerpc-*-aix*)
 785     ;;
 786   rs6000-*-aix*)
 787     ;;
 788   ft32-*-*)
 789     noconfigdirs="$noconfigdirs target-libffi"
 790     ;;
 791   *-*-lynxos*)
 792     noconfigdirs="$noconfigdirs target-libffi"
 793     ;;
 794 esac
 795
 796 # Disable the go frontend on systems where it is known to not work. Please keep
 797 # this in sync with contrib/config-list.mk.
 798 case "${target}" in
 799 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 800     unsupported_languages="$unsupported_languages go"
 801     ;;
 802 esac
 803
 804 # Only allow gdbserver on some systems.
 805 if test -d ${srcdir}/gdbserver; then
 806     if test x$enable_gdbserver = x; then
 807         AC_MSG_CHECKING([for gdbserver support])
 808         if (srcdir=${srcdir}/gdbserver; \
 809                 . ${srcdir}/configure.srv; \
 810                 test -n "$UNSUPPORTED")
 811         then
 812             AC_MSG_RESULT([no])
 813             noconfigdirs="$noconfigdirs gdbserver"
 814         else
 815             AC_MSG_RESULT([yes])
 816         fi
 817     fi
 818 fi
 819
 820 # Disable libgo for some systems where it is known to not work.
 821 # For testing, you can easily override this with --enable-libgo.
 822 if test x$enable_libgo = x; then
 823     case "${target}" in
 824     *-*-darwin*)
 825         # PR 46986
 826         noconfigdirs="$noconfigdirs target-libgo"
 827         ;;
 828     *-*-cygwin* | *-*-mingw*)
 829         noconfigdirs="$noconfigdirs target-libgo"
 830         ;;
 831     bpf-*-*)
 832         noconfigdirs="$noconfigdirs target-libgo"
 833         ;;
 834     esac
 835 fi
 836
 837 # Default libgloss CPU subdirectory.
 838 libgloss_dir="$target_cpu"
 839
 840 case "${target}" in
 841   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 842     libgloss_dir=wince
 843     ;;
 844   aarch64*-*-* )
 845     libgloss_dir=aarch64
 846     ;;
 847   arm*-*-*)
 848     libgloss_dir=arm
 849     ;;
 850   cris-*-* | crisv32-*-*)
 851     libgloss_dir=cris
 852     ;;
 853   hppa*-*-*)
 854     libgloss_dir=pa
 855     ;;
 856   i[[3456789]]86-*-*)
 857     libgloss_dir=i386
 858     ;;
 859   loongarch*-*-*)
 860     libgloss_dir=loongarch
 861     ;;
 862   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 863     libgloss_dir=m68hc11
 864     ;;
 865   m68*-*-* | fido-*-*)
 866     libgloss_dir=m68k
 867     ;;
 868   mips*-*-*)
 869     libgloss_dir=mips
 870     ;;
 871   powerpc*-*-*)
 872     libgloss_dir=rs6000
 873     ;;
 874   pru-*-*)
 875     libgloss_dir=pru
 876     ;;
 877   sparc*-*-*)
 878     libgloss_dir=sparc
 879     ;;
 880 esac
 881
 882 # Disable newlib and libgloss for various target OSes.
 883 case "${target}" in
 884   alpha*-dec-osf*)
 885     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 886     ;;
 887   i[[3456789]]86-*-linux*)
 888     # This section makes it possible to build newlib natively on linux.
 889     # If we are using a cross compiler then don't configure newlib.
 890     if test x${is_cross_compiler} != xno ; then
 891       noconfigdirs="$noconfigdirs target-newlib"
 892     fi
 893     noconfigdirs="$noconfigdirs target-libgloss"
 894     # If we are not using a cross compiler, do configure newlib.
 895     # Note however, that newlib will only be configured in this situation
 896     # if the --with-newlib option has been given, because otherwise
 897     # 'target-newlib' will appear in skipdirs.
 898     ;;
 899   i[[3456789]]86-*-rdos*)
 900     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 901     ;;
 902   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 903     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 904     ;;
 905   sparc-*-sunos4*)
 906     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 907     ;;
 908   bpf-*-*)
 909     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 910     ;;
 911   *-*-aix*)
 912     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 913     ;;
 914   *-*-beos*)
 915     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 916     ;;
 917   *-*-chorusos)
 918     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 919     ;;
 920   *-*-dragonfly*)
 921     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 922     ;;
 923   *-*-freebsd*)
 924     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 925     ;;
 926   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 927     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 928     ;;
 929   *-*-lynxos*)
 930     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 931     ;;
 932   *-*-mingw*)
 933     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 934     ;;
 935   *-*-netbsd*)
 936     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 937     ;;
 938   *-*-netware*)
 939     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 940     ;;
 941   *-*-tpf*)
 942     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 943     ;;
 944   *-*-uclinux*)
 945     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 946     ;;
 947   *-*-vxworks*)
 948     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 949     ;;
 950 esac
 951
 952 case "${target}" in
 953   *-*-chorusos)
 954     ;;
 955   aarch64-*-darwin*)
 956     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 957     noconfigdirs="$noconfigdirs sim target-rda"
 958     ;;
 959   amdgcn*-*-*)
 960     ;;
 961   arm-*-darwin*)
 962     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 963     noconfigdirs="$noconfigdirs sim target-rda"
 964     ;;
 965   powerpc-*-darwin*)
 966     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 967     noconfigdirs="$noconfigdirs sim target-rda"
 968     ;;
 969   i[[3456789]]86-*-darwin*)
 970     noconfigdirs="$noconfigdirs ld gprof"
 971     noconfigdirs="$noconfigdirs sim target-rda"
 972     ;;
 973   x86_64-*-darwin[[912]]*)
 974     noconfigdirs="$noconfigdirs ld gas gprof"
 975     noconfigdirs="$noconfigdirs sim target-rda"
 976     ;;
 977   *-*-darwin*)
 978     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 979     noconfigdirs="$noconfigdirs sim target-rda"
 980     ;;
 981   *-*-dragonfly*)
 982     ;;
 983   *-*-freebsd*)
 984     if test "x$with_gmp" = x \
 985         && ! test -d ${srcdir}/gmp \
 986         && test -f /usr/local/include/gmp.h; then
 987       with_gmp=/usr/local
 988     fi
 989     ;;
 990   *-*-kaos*)
 991     # Remove unsupported stuff on all kaOS configurations.
 992     noconfigdirs="$noconfigdirs target-libgloss"
 993     ;;
 994   *-*-netbsd*)
 995     ;;
 996   *-*-netware*)
 997     ;;
 998   *-*-phoenix*)
 999     noconfigdirs="$noconfigdirs target-libgloss"
1000     ;;
1001   *-*-rtems*)
1002     noconfigdirs="$noconfigdirs target-libgloss"
1003     ;;
1004     # The tpf target doesn't support gdb yet.
1005   *-*-tpf*)
1006     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1007     ;;
1008   *-*-uclinux*)
1009     noconfigdirs="$noconfigdirs target-rda"
1010     ;;
1011   *-*-vxworks*)
1012     ;;
1013   alpha*-dec-osf*)
1014     # ld works, but does not support shared libraries.
1015     # gas doesn't generate exception information.
1016     noconfigdirs="$noconfigdirs gas ld"
1017     ;;
1018   alpha*-*-*vms*)
1019     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1020     ;;
1021   alpha*-*-*)
1022     # newlib is not 64 bit ready
1023     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1024     ;;
1025   bpf-*-*)
1026     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1027     ;;
1028   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1029     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1030     ;;
1031   arc*-*-*)
1032     noconfigdirs="$noconfigdirs sim"
1033     ;;
1034   arm-*-pe*)
1035     noconfigdirs="$noconfigdirs target-libgloss"
1036     ;;
1037   arm-*-riscix*)
1038     noconfigdirs="$noconfigdirs ld target-libgloss"
1039     ;;
1040   avr-*-*)
1041     if test x${with_avrlibc} != xno; then
1042       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1043     fi
1044     ;;
1045   c4x-*-* | tic4x-*-*)
1046     noconfigdirs="$noconfigdirs target-libgloss"
1047     ;;
1048   tic54x-*-*)
1049     noconfigdirs="$noconfigdirs target-libgloss gdb"
1050     ;;
1051   d10v-*-*)
1052     noconfigdirs="$noconfigdirs target-libgloss"
1053     ;;
1054   d30v-*-*)
1055     noconfigdirs="$noconfigdirs gdb"
1056     ;;
1057   fr30-*-elf*)
1058     noconfigdirs="$noconfigdirs gdb"
1059     ;;
1060   ft32-*-*)
1061     noconfigdirs="$noconfigdirs target-rda gprof"
1062     ;;
1063   moxie-*-*)
1064     noconfigdirs="$noconfigdirs"
1065     ;;
1066   h8300*-*-*)
1067     noconfigdirs="$noconfigdirs target-libgloss"
1068     ;;
1069   h8500-*-*)
1070     noconfigdirs="$noconfigdirs target-libgloss"
1071     ;;
1072   hppa*64*-*-hpux*)
1073     noconfigdirs="$noconfigdirs gdb"
1074     ;;
1075   hppa*64*-*-linux*)
1076     ;;
1077   hppa*-*-linux*)
1078     ;;
1079   hppa*-*-*elf* | \
1080   hppa*-*-lites* | \
1081   hppa*-*-openbsd* | \
1082   hppa*64*-*-*)
1083     ;;
1084   hppa*-*-pro*)
1085     ;;
1086   hppa*-*-*)
1087     noconfigdirs="$noconfigdirs ld"
1088     ;;
1089   i960-*-*)
1090     noconfigdirs="$noconfigdirs gdb"
1091     ;;
1092   ia64*-*-elf*)
1093     # No gdb support yet.
1094     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1095     ;;
1096   ia64*-**-hpux*)
1097     # No ld support yet.
1098     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1099     ;;
1100   ia64*-*-*vms*)
1101     # No ld support yet.
1102     noconfigdirs="$noconfigdirs libgui itcl ld"
1103     ;;
1104   i[[3456789]]86-w64-mingw*)
1105     ;;
1106   i[[3456789]]86-*-mingw*)
1107     target_configdirs="$target_configdirs target-winsup"
1108     ;;
1109   *-*-cygwin*)
1110     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1111     noconfigdirs="$noconfigdirs target-libgloss"
1112     # always build newlib if winsup directory is present.
1113     if test -d "$srcdir/winsup/cygwin"; then
1114       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1115     elif test -d "$srcdir/newlib"; then
1116       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1117     fi
1118     ;;
1119   i[[3456789]]86-*-pe)
1120     noconfigdirs="$noconfigdirs target-libgloss"
1121     ;;
1122   i[[3456789]]86-*-sco3.2v5*)
1123     # The linker does not yet know about weak symbols in COFF,
1124     # and is not configured to handle mixed ELF and COFF.
1125     noconfigdirs="$noconfigdirs ld target-libgloss"
1126     ;;
1127   i[[3456789]]86-*-sco*)
1128     noconfigdirs="$noconfigdirs gprof target-libgloss"
1129     ;;
1130   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1131     noconfigdirs="$noconfigdirs target-libgloss"
1132     ;;
1133   i[[3456789]]86-*-sysv4*)
1134     noconfigdirs="$noconfigdirs target-libgloss"
1135     ;;
1136   i[[3456789]]86-*-beos*)
1137     noconfigdirs="$noconfigdirs gdb"
1138     ;;
1139   i[[3456789]]86-*-rdos*)
1140     noconfigdirs="$noconfigdirs gdb"
1141     ;;
1142   mmix-*-*)
1143     noconfigdirs="$noconfigdirs gdb"
1144     ;;
1145   mt-*-*)
1146     noconfigdirs="$noconfigdirs sim"
1147     ;;
1148   nfp-*-*)
1149     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1150     noconfigdirs="$noconfigdirs $target_libraries"
1151     ;;
1152   pdp11-*-*)
1153     noconfigdirs="$noconfigdirs gdb gprof"
1154     ;;
1155   powerpc-*-aix*)
1156     # copied from rs6000-*-* entry
1157     noconfigdirs="$noconfigdirs gprof"
1158     ;;
1159   powerpc*-*-winnt* | powerpc*-*-pe*)
1160     target_configdirs="$target_configdirs target-winsup"
1161     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1162     # always build newlib.
1163     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1164     ;;
1165     # This is temporary until we can link against shared libraries
1166   powerpcle-*-solaris*)
1167     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1168     ;;
1169   powerpc-*-beos*)
1170     noconfigdirs="$noconfigdirs gdb"
1171     ;;
1172   rs6000-*-lynxos*)
1173     noconfigdirs="$noconfigdirs gprof"
1174     ;;
1175   rs6000-*-aix*)
1176     noconfigdirs="$noconfigdirs gprof"
1177     ;;
1178   rs6000-*-*)
1179     noconfigdirs="$noconfigdirs gprof"
1180     ;;
1181   m68k-apollo-*)
1182     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1183     ;;
1184   microblaze*)
1185     noconfigdirs="$noconfigdirs gprof"
1186     ;;
1187   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1188     if test x$with_newlib = xyes; then
1189       noconfigdirs="$noconfigdirs gprof"
1190     fi
1191     ;;
1192   mips*-*-irix5*)
1193     noconfigdirs="$noconfigdirs gprof target-libgloss"
1194     ;;
1195   mips*-*-irix6*)
1196     noconfigdirs="$noconfigdirs gprof target-libgloss"
1197     ;;
1198   mips*-*-bsd*)
1199     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1200     ;;
1201   mips*-*-linux*)
1202     ;;
1203   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1204   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1205     noconfigdirs="$noconfigdirs ld gas gprof"
1206     ;;
1207   mips*-*-*)
1208     noconfigdirs="$noconfigdirs gprof"
1209     ;;
1210   nvptx*-*-*)
1211     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1212     ;;
1213   sh-*-*)
1214     case "${target}" in
1215       sh*-*-elf)
1216          ;;
1217       *)
1218          noconfigdirs="$noconfigdirs target-libgloss" ;;
1219     esac
1220     ;;
1221   sparc-*-sunos4*)
1222     if test x${is_cross_compiler} = xno ; then
1223            use_gnu_ld=no
1224     fi
1225     ;;
1226   tic6x-*-*)
1227     noconfigdirs="$noconfigdirs sim"
1228     ;;
1229   v810-*-*)
1230     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1231     ;;
1232   vax-*-*)
1233     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1234     ;;
1235   wasm32-*-*)
1236     noconfigdirs="$noconfigdirs ld"
1237     ;;
1238   loongarch*-*-linux*)
1239     ;;
1240   loongarch*-*-*)
1241     noconfigdirs="$noconfigdirs gprof"
1242     ;;
1243 esac
1244
1245 # If we aren't building newlib, then don't build libgloss, since libgloss
1246 # depends upon some newlib header files.
1247 case "${noconfigdirs}" in
1248   *target-libgloss*) ;;
1249   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1250 esac
1251
1252 # Work in distributions that contain no compiler tools, like Autoconf.
1253 host_makefile_frag=/dev/null
1254 if test -d ${srcdir}/config ; then
1255 case "${host}" in
1256   i[[3456789]]86-*-msdosdjgpp*)
1257     host_makefile_frag="config/mh-djgpp"
1258     ;;
1259   *-cygwin*)
1260     ACX_CHECK_CYGWIN_CAT_WORKS
1261     host_makefile_frag="config/mh-cygwin"
1262     ;;
1263   *-mingw*)
1264     host_makefile_frag="config/mh-mingw"
1265     ;;
1266   alpha*-linux*)
1267     host_makefile_frag="config/mh-alpha-linux"
1268     ;;
1269   hppa*-hp-hpux*)
1270     host_makefile_frag="config/mh-pa"
1271     ;;
1272   hppa*-*)
1273     host_makefile_frag="config/mh-pa"
1274     ;;
1275   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1276     host_makefile_frag="config/mh-darwin"
1277     ;;
1278   powerpc-*-aix*)
1279     host_makefile_frag="config/mh-ppc-aix"
1280     ;;
1281   rs6000-*-aix*)
1282     host_makefile_frag="config/mh-ppc-aix"
1283     ;;
1284 esac
1285 fi
1286
1287 if test "${build}" != "${host}" ; then
1288   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1289   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1290   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1291   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1292   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1293   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1294   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1295   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1296   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1297   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1298   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1299   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1300   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1301   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1302   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1303 else
1304   AR_FOR_BUILD="\$(AR)"
1305   AS_FOR_BUILD="\$(AS)"
1306   CC_FOR_BUILD="\$(CC)"
1307   CXX_FOR_BUILD="\$(CXX)"
1308   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1309   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1310   GOC_FOR_BUILD="\$(GOC)"
1311   GDC_FOR_BUILD="\$(GDC)"
1312   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1313   LD_FOR_BUILD="\$(LD)"
1314   NM_FOR_BUILD="\$(NM)"
1315   RANLIB_FOR_BUILD="\$(RANLIB)"
1316   WINDRES_FOR_BUILD="\$(WINDRES)"
1317   WINDMC_FOR_BUILD="\$(WINDMC)"
1318 fi
1319
1320 AC_PROG_CC_C99
1321 AC_PROG_CXX
1322
1323 # We must set the default linker to the linker used by gcc for the correct
1324 # operation of libtool.  If LD is not defined and we are using gcc, try to
1325 # set the LD default to the ld used by gcc.
1326 if test -z "$LD"; then
1327   if test "$GCC" = yes; then
1328     case $build in
1329     *-*-mingw*)
1330       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1331     *)
1332       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1333     esac
1334     case $gcc_prog_ld in
1335     # Accept absolute paths.
1336     [[\\/]* | [A-Za-z]:[\\/]*)]
1337       LD="$gcc_prog_ld" ;;
1338     esac
1339   fi
1340 fi
1341
1342 # Check whether -static-libstdc++ -static-libgcc is supported.
1343 have_static_libs=no
1344 if test "$GCC" = yes; then
1345   saved_LDFLAGS="$LDFLAGS"
1346
1347   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1348   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1349   AC_LANG_PUSH(C++)
1350   AC_LINK_IFELSE([AC_LANG_SOURCE([
1351 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1352 #error -static-libstdc++ not implemented
1353 #endif
1354 int main() {}])],
1355     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1356     [AC_MSG_RESULT([no])])
1357   AC_LANG_POP(C++)
1358
1359   LDFLAGS="$saved_LDFLAGS"
1360 fi
1361
1362 ACX_PROG_GNAT
1363 ACX_PROG_GDC
1364 ACX_PROG_CMP_IGNORE_INITIAL
1365
1366 AC_ARG_ENABLE([bootstrap],
1367 [AS_HELP_STRING([--enable-bootstrap],
1368                 [enable bootstrapping @<:@yes if native build@:>@])],,
1369 enable_bootstrap=default)
1370
1371 # Issue errors and warnings for invalid/strange bootstrap combinations.
1372 if test -r $srcdir/gcc/configure; then
1373   have_compiler=yes
1374 else
1375   have_compiler=no
1376 fi
1377
1378 case "$have_compiler:$host:$target:$enable_bootstrap" in
1379   *:*:*:no) ;;
1380
1381   # Default behavior.  Enable bootstrap if we have a compiler
1382   # and we are in a native configuration.
1383   yes:$build:$build:default)
1384     enable_bootstrap=yes ;;
1385
1386   *:*:*:default)
1387     enable_bootstrap=no ;;
1388
1389   # We have a compiler and we are in a native configuration, bootstrap is ok
1390   yes:$build:$build:yes)
1391     ;;
1392
1393   # Other configurations, but we have a compiler.  Assume the user knows
1394   # what he's doing.
1395   yes:*:*:yes)
1396     AC_MSG_WARN([trying to bootstrap a cross compiler])
1397     ;;
1398
1399   # No compiler: if they passed --enable-bootstrap explicitly, fail
1400   no:*:*:yes)
1401     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1402
1403   # Fail if wrong command line
1404   *)
1405     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1406     ;;
1407 esac
1408
1409 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1410 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1411 # require C++11 (or higher).
1412 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1413   CXX="$CXX -std=c++11"
1414 elif test "$have_compiler" = yes; then
1415   AX_CXX_COMPILE_STDCXX(11)
1416
1417   if test "${build}" != "${host}"; then
1418     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1419   fi
1420 fi
1421
1422 AC_ARG_ENABLE([pgo-build],
1423 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1424                 [enable the PGO build])],
1425 [enable_pgo_build=$enableval],
1426 [enable_pgo_build=no])
1427
1428 # Issue errors and warnings for invalid/strange PGO build combinations.
1429 case "$have_compiler:$host:$target:$enable_pgo_build" in
1430   *:*:*:no) ;;
1431
1432   # Allow the PGO build only if we aren't building a compiler and
1433   # we are in a native configuration.
1434   no:$build:$build:yes | no:$build:$build:lto) ;;
1435
1436   # Disallow the PGO bootstrap if we are building a compiler.
1437   yes:*:*:yes | yes:*:*:lto)
1438     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1439
1440   *)
1441     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1442     ;;
1443 esac
1444
1445 if test "$enable_pgo_build" != "no"; then
1446   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1447   old_CFLAGS="$CFLAGS"
1448   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1449   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1450   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1451                     [PGO_BUILD_GEN_CFLAGS=])
1452   CFLAGS="$old_CFLAGS"
1453   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1454     AC_MSG_RESULT([yes])
1455     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1456   else
1457     AC_MSG_RESULT([no])
1458     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1459   fi
1460
1461   if test "$enable_pgo_build" = "lto"; then
1462     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1463     old_CFLAGS="$CFLAGS"
1464     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1465     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1466     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1467                       [PGO_BUILD_LTO_CFLAGS=])
1468     CFLAGS="$old_CFLAGS"
1469     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1470       AC_MSG_RESULT([yes])
1471     else
1472       AC_MSG_RESULT([no])
1473       AC_MSG_WARN([LTO is disabled for the PGO build])
1474     fi
1475   fi
1476 fi
1477 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1478 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1479 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1480
1481 # Used for setting $lt_cv_objdir
1482 _LT_CHECK_OBJDIR
1483
1484 # Check for GMP, MPFR and MPC
1485 require_gmp=no
1486 require_mpc=no
1487 if test -d ${srcdir}/gcc ; then
1488   require_gmp=yes
1489   require_mpc=yes
1490 fi
1491 if test -d ${srcdir}/gdb ; then
1492   if test "x$enable_gdb" != xno; then
1493    require_gmp=yes
1494   fi
1495 fi
1496
1497 gmplibs="-lmpfr -lgmp"
1498 if test x"$require_mpc" = "xyes" ; then
1499   gmplibs="-lmpc $gmplibs"
1500 fi
1501 gmpinc=
1502 have_gmp=no
1503
1504 # Specify a location for mpc
1505 # check for this first so it ends up on the link line before mpfr.
1506 AC_ARG_WITH(mpc,
1507 [AS_HELP_STRING([--with-mpc=PATH],
1508                 [specify prefix directory for installed MPC package.
1509                  Equivalent to --with-mpc-include=PATH/include
1510                  plus --with-mpc-lib=PATH/lib])])
1511 AC_ARG_WITH(mpc-include,
1512 [AS_HELP_STRING([--with-mpc-include=PATH],
1513                 [specify directory for installed MPC include files])])
1514 AC_ARG_WITH(mpc-lib,
1515 [AS_HELP_STRING([--with-mpc-lib=PATH],
1516                 [specify directory for the installed MPC library])])
1517
1518 if test "x$with_mpc" != x; then
1519   gmplibs="-L$with_mpc/lib $gmplibs"
1520   gmpinc="-I$with_mpc/include $gmpinc"
1521 fi
1522 if test "x$with_mpc_include" != x; then
1523   gmpinc="-I$with_mpc_include $gmpinc"
1524 fi
1525 if test "x$with_mpc_lib" != x; then
1526   gmplibs="-L$with_mpc_lib $gmplibs"
1527 fi
1528 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1529   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1530   gmpinc='-I$$s/mpc/src '"$gmpinc"
1531   # Do not test the mpc version.  Assume that it is sufficient, since
1532   # it is in the source tree, and the library has not been built yet
1533   # but it would be included on the link line in the version check below
1534   # hence making the test fail.
1535   have_gmp=yes
1536 fi
1537
1538 # Specify a location for mpfr
1539 # check for this first so it ends up on the link line before gmp.
1540 AC_ARG_WITH(mpfr,
1541 [AS_HELP_STRING([--with-mpfr=PATH],
1542                 [specify prefix directory for installed MPFR package.
1543                  Equivalent to --with-mpfr-include=PATH/include
1544                  plus --with-mpfr-lib=PATH/lib])])
1545 AC_ARG_WITH(mpfr-include,
1546 [AS_HELP_STRING([--with-mpfr-include=PATH],
1547                 [specify directory for installed MPFR include files])])
1548 AC_ARG_WITH(mpfr-lib,
1549 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1550                 [specify directory for the installed MPFR library])])
1551
1552 if test "x$with_mpfr" != x; then
1553   gmplibs="-L$with_mpfr/lib $gmplibs"
1554   gmpinc="-I$with_mpfr/include $gmpinc"
1555 fi
1556 if test "x$with_mpfr_include" != x; then
1557   gmpinc="-I$with_mpfr_include $gmpinc"
1558 fi
1559 if test "x$with_mpfr_lib" != x; then
1560   gmplibs="-L$with_mpfr_lib $gmplibs"
1561 fi
1562 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1563   # MPFR v3.1.0 moved the sources into a src sub-directory.
1564   if ! test -d ${srcdir}/mpfr/src; then
1565     AC_MSG_ERROR([dnl
1566 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1567   fi
1568   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1569   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1570   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1571   # Do not test the mpfr version.  Assume that it is sufficient, since
1572   # it is in the source tree, and the library has not been built yet
1573   # but it would be included on the link line in the version check below
1574   # hence making the test fail.
1575   have_gmp=yes
1576 fi
1577
1578 # Specify a location for gmp
1579 AC_ARG_WITH(gmp,
1580 [AS_HELP_STRING([--with-gmp=PATH],
1581                 [specify prefix directory for the installed GMP package.
1582                  Equivalent to --with-gmp-include=PATH/include
1583                  plus --with-gmp-lib=PATH/lib])])
1584 AC_ARG_WITH(gmp-include,
1585 [AS_HELP_STRING([--with-gmp-include=PATH],
1586                 [specify directory for installed GMP include files])])
1587 AC_ARG_WITH(gmp-lib,
1588 [AS_HELP_STRING([--with-gmp-lib=PATH],
1589                 [specify directory for the installed GMP library])])
1590
1591
1592 if test "x$with_gmp" != x; then
1593   gmplibs="-L$with_gmp/lib $gmplibs"
1594   gmpinc="-I$with_gmp/include $gmpinc"
1595 fi
1596 if test "x$with_gmp_include" != x; then
1597   gmpinc="-I$with_gmp_include $gmpinc"
1598 fi
1599 if test "x$with_gmp_lib" != x; then
1600   gmplibs="-L$with_gmp_lib $gmplibs"
1601 fi
1602 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1603   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1604   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1605   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1606   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1607   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1608   # Do not test the gmp version.  Assume that it is sufficient, since
1609   # it is in the source tree, and the library has not been built yet
1610   # but it would be included on the link line in the version check below
1611   # hence making the test fail.
1612   have_gmp=yes
1613 fi
1614
1615 if test "x$require_gmp" = xyes && test "x$have_gmp" = xno; then
1616   have_gmp=yes
1617   saved_CFLAGS="$CFLAGS"
1618   CFLAGS="$CFLAGS $gmpinc"
1619   # Check for the recommended and required versions of GMP.
1620   AC_MSG_CHECKING([for the correct version of gmp.h])
1621   AC_TRY_COMPILE([#include "gmp.h"],[
1622   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1623   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1624   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1625   choke me
1626   #endif
1627   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1628   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1629   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1630   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1631   choke me
1632   #endif
1633   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1634    [AC_MSG_RESULT([no]); have_gmp=no])
1635
1636   # If we have GMP, check the MPFR version.
1637   if test x"$have_gmp" = xyes; then
1638     # Check for the recommended and required versions of MPFR.
1639     AC_MSG_CHECKING([for the correct version of mpfr.h])
1640     AC_TRY_COMPILE([#include <gmp.h>
1641     #include <mpfr.h>],[
1642     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1643     choke me
1644     #endif
1645     ], [AC_TRY_COMPILE([#include <gmp.h>
1646     #include <mpfr.h>],[
1647     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1648     choke me
1649     #endif
1650     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1651      [AC_MSG_RESULT([no]); have_gmp=no])
1652   fi
1653
1654   # Check for the MPC header version.
1655   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes ; then
1656     # Check for the recommended and required versions of MPC.
1657     AC_MSG_CHECKING([for the correct version of mpc.h])
1658     AC_TRY_COMPILE([#include <mpc.h>],[
1659     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1660     choke me
1661     #endif
1662     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1663     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1664     choke me
1665     #endif
1666     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1667      [AC_MSG_RESULT([no]); have_gmp=no])
1668   fi
1669
1670   # Now check the MPFR library.
1671   if test x"$have_gmp" = xyes; then
1672     saved_LIBS="$LIBS"
1673     LIBS="$LIBS $gmplibs"
1674     AC_MSG_CHECKING([for the correct version of the gmp/mpfr libraries])
1675     AC_TRY_LINK([#include <mpfr.h>],[
1676     mpfr_t n;
1677     mpfr_t x;
1678     int t;
1679     mpfr_init (n);
1680     mpfr_init (x);
1681     mpfr_atan2 (n, n, x, MPFR_RNDN);
1682     mpfr_erfc (n, x, MPFR_RNDN);
1683     mpfr_subnormalize (x, t, MPFR_RNDN);
1684     mpfr_clear(n);
1685     mpfr_clear(x);
1686     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1687     LIBS="$saved_LIBS"
1688   fi
1689
1690   # Now check the MPC library
1691   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes; then
1692     saved_LIBS="$LIBS"
1693     LIBS="$LIBS $gmplibs"
1694     AC_MSG_CHECKING([for the correct version of the mpc libraries])
1695     AC_TRY_LINK([#include <mpc.h>],[
1696     mpc_t c;
1697     mpc_init2 (c, 53);
1698     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1699     mpc_cosh (c, c, MPC_RNDNN);
1700     mpc_pow (c, c, c, MPC_RNDNN);
1701     mpc_acosh (c, c, MPC_RNDNN);
1702     mpc_clear (c);
1703     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1704     LIBS="$saved_LIBS"
1705   fi
1706
1707   CFLAGS="$saved_CFLAGS"
1708
1709 # The library versions listed in the error message below should match
1710 # the HARD-minimums enforced above.
1711   if test x$have_gmp != xyes; then
1712     if test -d ${srcdir}/gcc ; then
1713       AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1714 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1715 their locations.  Source code for these libraries can be found at
1716 their respective hosting sites as well as at
1717 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1718 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1719 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1720 make sure that you have installed both the libraries and the header
1721 files.  They may be located in separate packages.])
1722     else
1723       AC_MSG_ERROR([Building GDB requires GMP 4.2+, and MPFR 3.1.0+.
1724 Try the --with-gmp and/or --with-mpfr options to specify
1725 their locations.  If you obtained GMP and/or MPFR from a vendor
1726 distribution package, make sure that you have installed both the libraries
1727 and the header files.  They may be located in separate packages.])
1728     fi
1729   fi
1730 fi
1731
1732 # Flags needed for both GMP, MPFR and/or MPC.
1733 AC_SUBST(gmplibs)
1734 AC_SUBST(gmpinc)
1735 AC_SUBST(extra_mpfr_configure_flags)
1736 AC_SUBST(extra_mpc_gmp_configure_flags)
1737 AC_SUBST(extra_mpc_mpfr_configure_flags)
1738 AC_SUBST(extra_isl_gmp_configure_flags)
1739
1740 # Libraries to use for stage1 or when not bootstrapping.
1741 AC_ARG_WITH(stage1-libs,
1742 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1743 [if test "$withval" = "no" -o "$withval" = "yes"; then
1744    stage1_libs=
1745  else
1746    stage1_libs=$withval
1747  fi],
1748 [stage1_libs=])
1749 AC_SUBST(stage1_libs)
1750
1751 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1752 # default is yes if gcc is being built; no otherwise.  The reason for
1753 # this default is that gdb is sometimes linked against GNU Source
1754 # Highlight, which is a shared library that uses C++ exceptions.  In
1755 # this case, -static-libstdc++ will cause crashes.
1756 AC_ARG_WITH(static-standard-libraries,
1757 [AS_HELP_STRING([--with-static-standard-libraries],
1758                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1759 [], [with_static_standard_libraries=auto])
1760 if test "$with_static_standard_libraries" = auto; then
1761   with_static_standard_libraries=$have_compiler
1762 fi
1763
1764 # Linker flags to use for stage1 or when not bootstrapping.
1765 AC_ARG_WITH(stage1-ldflags,
1766 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1767 [if test "$withval" = "no" -o "$withval" = "yes"; then
1768    stage1_ldflags=
1769  else
1770    stage1_ldflags=$withval
1771  fi],
1772 [stage1_ldflags=
1773  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1774  # if supported.  But if the user explicitly specified the libraries to use,
1775  # trust that they are doing what they want.
1776  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1777      -a "$have_static_libs" = yes; then
1778    stage1_ldflags="-static-libstdc++ -static-libgcc"
1779  fi])
1780 AC_SUBST(stage1_ldflags)
1781
1782 # Libraries to use for stage2 and later builds.
1783 AC_ARG_WITH(boot-libs,
1784 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1785 [if test "$withval" = "no" -o "$withval" = "yes"; then
1786    poststage1_libs=
1787  else
1788    poststage1_libs=$withval
1789  fi],
1790 [poststage1_libs=])
1791 AC_SUBST(poststage1_libs)
1792
1793 # Linker flags to use for stage2 and later builds.
1794 AC_ARG_WITH(boot-ldflags,
1795 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1796                 [linker flags for stage2 and later])],
1797 [if test "$withval" = "no" -o "$withval" = "yes"; then
1798    poststage1_ldflags=
1799  else
1800    poststage1_ldflags=$withval
1801  fi],
1802 [poststage1_ldflags=
1803  # In stages 2 and 3, default to linking libstdc++ and libgcc
1804  # statically.  But if the user explicitly specified the libraries to
1805  # use, trust that they are doing what they want.
1806  if test "$poststage1_libs" = ""; then
1807    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1808  fi])
1809 AC_SUBST(poststage1_ldflags)
1810
1811 # GCC GRAPHITE dependency isl.
1812 # Basic setup is inlined here, actual checks are in config/isl.m4
1813
1814 AC_ARG_WITH(isl,
1815   [AS_HELP_STRING(
1816    [--with-isl=PATH],
1817    [Specify prefix directory for the installed isl package.
1818     Equivalent to --with-isl-include=PATH/include
1819     plus --with-isl-lib=PATH/lib])])
1820
1821 # Treat --without-isl as a request to disable
1822 # GRAPHITE support and skip all following checks.
1823 if test "x$with_isl" != "xno"; then
1824   # Check for isl
1825   dnl Provide configure switches and initialize islinc & isllibs
1826   dnl with user input.
1827   ISL_INIT_FLAGS
1828   dnl The versions of isl that work for Graphite
1829   ISL_CHECK_VERSION()
1830   dnl Only execute fail-action, if isl has been requested.
1831   ISL_IF_FAILED([
1832     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1833 fi
1834
1835 # If the isl check failed, disable builds of in-tree variant of isl
1836 if test "x$with_isl" = xno ||
1837    test "x$gcc_cv_isl" = xno; then
1838   noconfigdirs="$noconfigdirs isl"
1839   islinc=
1840 fi
1841
1842 AC_SUBST(isllibs)
1843 AC_SUBST(islinc)
1844
1845 # Check for LTO support.
1846 AC_ARG_ENABLE(lto,
1847 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1848 enable_lto=$enableval,
1849 enable_lto=yes; default_enable_lto=yes)
1850
1851 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1852   build_lto_plugin=yes
1853 ],[if test x"$default_enable_lto" = x"yes" ; then
1854     case $target in
1855       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1856       # On other non-ELF platforms, LTO has yet to be validated.
1857       *) enable_lto=no ;;
1858     esac
1859   else
1860   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1861   # It would also be nice to check the binutils support, but we don't
1862   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1863   # warn during gcc/ subconfigure; unless you're bootstrapping with
1864   # -flto it won't be needed until after installation anyway.
1865     case $target in
1866       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1867       *) if test x"$enable_lto" = x"yes"; then
1868         AC_MSG_ERROR([LTO support is not enabled for this target.])
1869         fi
1870       ;;
1871     esac
1872   fi
1873   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1874   # Build it unless LTO was explicitly disabled.
1875   case $target in
1876     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1877     *) ;;
1878   esac
1879 ])
1880
1881 AC_ARG_ENABLE(linker-plugin-configure-flags,
1882   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1883     [additional flags for configuring linker plugins @<:@none@:>@])],
1884   extra_linker_plugin_configure_flags=$enableval,
1885   extra_linker_plugin_configure_flags=)
1886 AC_SUBST(extra_linker_plugin_configure_flags)
1887 AC_ARG_ENABLE(linker-plugin-flags,
1888   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1889     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1890   extra_linker_plugin_flags=$enableval,
1891   extra_linker_plugin_flags=)
1892 AC_SUBST(extra_linker_plugin_flags)
1893
1894 # Enable --enable-host-pie.
1895 # Checked early to determine whether jit is an 'all' language
1896 AC_ARG_ENABLE(host-pie,
1897 [AS_HELP_STRING([--enable-host-pie],
1898                 [build position independent host executables])],
1899 [host_pie=$enableval
1900  case $host in
1901    x86_64-*-darwin* | aarch64-*-darwin*)
1902      if test x$host_pie != xyes ; then
1903        # PIC is the default, and actually cannot be switched off.
1904        echo configure.ac: warning: PIC code is required for the configured target, host-shared setting ignored. 1>&2
1905        host_pie=yes
1906      fi ;;
1907   *) ;;
1908  esac],
1909 [case $host in
1910   *-*-darwin2*) host_pie=yes ;;
1911   *) host_pie=no ;;
1912  esac])
1913
1914 AC_SUBST(host_pie)
1915
1916 # Enable --enable-host-shared.
1917 # Checked early to determine whether jit is an 'all' language
1918 AC_ARG_ENABLE(host-shared,
1919 [AS_HELP_STRING([--enable-host-shared],
1920                 [build host code as shared libraries])],
1921 [host_shared=$enableval
1922  case $host in
1923    x86_64-*-darwin* | aarch64-*-darwin*)
1924      if test x$host_shared != xyes ; then
1925        # PIC is the default, and actually cannot be switched off.
1926        echo configure.ac: warning: PIC code is required for the configured target, host-shared setting ignored. 1>&2
1927        host_shared=yes
1928      fi ;;
1929    *-*-darwin*)
1930      if test x$host_pie == xyes ; then
1931        echo configure.ac: warning: PIC code is required for PIE executables. 1>&2
1932        host_shared=yes
1933      fi ;;
1934   *) ;;
1935  esac],
1936 [case $host in
1937   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
1938   # Darwin needs PIC objects to link PIE executables.
1939   *-*-darwin*) host_shared=host_pie ;;
1940   *) host_shared=no;;
1941  esac])
1942
1943 AC_SUBST(host_shared)
1944
1945 if test x$host_shared = xyes; then
1946   PICFLAG=-fPIC
1947 elif test x$host_pie = xyes; then
1948   PICFLAG=-fPIE
1949 else
1950   PICFLAG=
1951 fi
1952
1953 AC_SUBST(PICFLAG)
1954
1955 # If we are building PIC/PIE host executables, and we are building dependent
1956 # libs (e.g. GMP) in-tree those libs need to be configured to generate PIC
1957 # code.
1958 host_libs_picflag=
1959 if test "$host_shared" = "yes" -o "$host_pie" = "yes"; then
1960 host_libs_picflag='--with-pic'
1961 fi
1962 AC_SUBST(host_libs_picflag)
1963
1964 # By default, C and C++ are the only stage 1 languages.
1965 stage1_languages=,c,
1966
1967 # Target libraries that we bootstrap.
1968 bootstrap_target_libs=,target-libgcc,
1969
1970 # Figure out what language subdirectories are present.
1971 # Look if the user specified --enable-languages="..."; if not, use
1972 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1973 # go away some day.
1974 # NB:  embedded tabs in this IF block -- do not untabify
1975 if test -d ${srcdir}/gcc; then
1976   if test x"${enable_languages+set}" != xset; then
1977     if test x"${LANGUAGES+set}" = xset; then
1978       enable_languages="${LANGUAGES}"
1979         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1980     else
1981       enable_languages=default
1982     fi
1983   else
1984     if test x"${enable_languages}" = x ||
1985        test x"${enable_languages}" = xyes;
1986        then
1987       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1988       exit 1
1989     fi
1990   fi
1991   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1992
1993   # 'f95' is the old name for the 'fortran' language. We issue a warning
1994   # and make the substitution.
1995   case ,${enable_languages}, in
1996     *,f95,*)
1997       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1998       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1999       ;;
2000   esac
2001
2002   # If bootstrapping, C++ must be enabled.
2003   case ",$enable_languages,:$enable_bootstrap" in
2004     *,c++,*:*) ;;
2005     *:yes)
2006       if test -f ${srcdir}/gcc/cp/config-lang.in; then
2007         enable_languages="${enable_languages},c++"
2008       else
2009         AC_MSG_ERROR([bootstrapping requires c++ sources])
2010       fi
2011       ;;
2012   esac
2013
2014   # First scan to see if an enabled language requires some other language.
2015   # We assume that a given config-lang.in will list all the language
2016   # front ends it requires, even if some are required indirectly.
2017   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2018     case ${lang_frag} in
2019       ..) ;;
2020       # The odd quoting in the next line works around
2021       # an apparent bug in bash 1.12 on linux.
2022       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2023       *)
2024         # From the config-lang.in, get $language, $lang_requires, and
2025         # $lang_requires_boot_languages.
2026         language=
2027         lang_requires=
2028         lang_requires_boot_languages=
2029         # set srcdir during sourcing lang_frag to the gcc dir.
2030         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
2031         # polutes this shell
2032         saved_srcdir=${srcdir}
2033         srcdir=${srcdir}/gcc . ${lang_frag}
2034         srcdir=${saved_srcdir}
2035         for other in ${lang_requires} ${lang_requires_boot_languages}; do
2036           case ,${enable_languages}, in
2037             *,$other,*) ;;
2038             *,default,*) ;;
2039             *,all,*) ;;
2040             *,$language,*)
2041               echo " \`$other' language required by \`$language'; enabling" 1>&2
2042               enable_languages="${enable_languages},${other}"
2043               ;;
2044           esac
2045         done
2046         for other in ${lang_requires_boot_languages} ; do
2047           if test "$other" != "c"; then
2048             case ,${enable_stage1_languages}, in
2049               *,$other,*) ;;
2050               *,default,*) ;;
2051               *,all,*) ;;
2052               *)
2053                 case ,${enable_languages}, in
2054                   *,$language,*)
2055                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
2056                     enable_stage1_languages="$enable_stage1_languages,${other}"
2057                     ;;
2058                 esac
2059                 ;;
2060             esac
2061           fi
2062         done
2063         ;;
2064     esac
2065   done
2066
2067   new_enable_languages=,c,
2068
2069   # If LTO is enabled, add the LTO front end.
2070   if test "$enable_lto" = "yes" ; then
2071     case ,${enable_languages}, in
2072       *,lto,*) ;;
2073       *) enable_languages="${enable_languages},lto" ;;
2074     esac
2075     if test "${build_lto_plugin}" = "yes" ; then
2076       configdirs="$configdirs lto-plugin"
2077     fi
2078   fi
2079
2080   # If we're building an offloading compiler, add the LTO front end.
2081   if test x"$enable_as_accelerator_for" != x ; then
2082     case ,${enable_languages}, in
2083       *,lto,*) ;;
2084       *) enable_languages="${enable_languages},lto" ;;
2085     esac
2086   fi
2087
2088   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2089   potential_languages=,c,
2090
2091   enabled_target_libs=
2092   disabled_target_libs=
2093
2094   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2095     case ${lang_frag} in
2096       ..) ;;
2097       # The odd quoting in the next line works around
2098       # an apparent bug in bash 1.12 on linux.
2099       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2100       *)
2101         # From the config-lang.in, get $language, $target_libs,
2102         # $lang_dirs, $boot_language, and $build_by_default
2103         language=
2104         target_libs=
2105         lang_dirs=
2106         subdir_requires=
2107         boot_language=no
2108         build_by_default=yes
2109         # set srcdir during sourcing.  See above about save & restore
2110         saved_srcdir=${srcdir}
2111         srcdir=${srcdir}/gcc . ${lang_frag}
2112         srcdir=${saved_srcdir}
2113         if test x${language} = x; then
2114           echo "${lang_frag} doesn't set \$language." 1>&2
2115           exit 1
2116         fi
2117
2118         if test "$language" = "c++"; then
2119           boot_language=yes
2120         fi
2121
2122         add_this_lang=no
2123         # C is always enabled, so no need to add it again
2124         if test "$language" != "c"; then
2125           case ,${enable_languages}, in
2126             *,${language},*)
2127               # Language was explicitly selected; include it
2128               add_this_lang=yes
2129               ;;
2130             *,all,*)
2131               # All languages are enabled
2132               add_this_lang=all
2133               ;;
2134             *,default,*)
2135               # 'default' was selected, select it if it is a default language
2136               add_this_lang=${build_by_default}
2137               ;;
2138           esac
2139         fi
2140
2141         # Disable languages that need other directories if these aren't available.
2142         for i in $subdir_requires; do
2143           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2144           case ${add_this_lang} in
2145             yes)
2146               # Specifically requested language; tell them.
2147               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2148               ;;
2149             all)
2150               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2151               add_this_lang=unsupported
2152               ;;
2153             *)
2154               # Silently disable.
2155               add_this_lang=unsupported
2156               ;;
2157           esac
2158         done
2159
2160         # Disable Ada if no preexisting GNAT is available.
2161         case ${add_this_lang}:${language}:${have_gnat} in
2162           yes:ada:no)
2163             # Specifically requested language; tell them.
2164             AC_MSG_ERROR([GNAT is required to build $language])
2165             ;;
2166           all:ada:no)
2167             AC_MSG_WARN([GNAT is required to build $language])
2168             add_this_lang=unsupported
2169             ;;
2170           *:ada:no)
2171             # Silently disable.
2172             add_this_lang=unsupported
2173             ;;
2174         esac
2175
2176         # Disable D if no preexisting GDC is available.
2177         case ${add_this_lang}:${language}:${have_gdc} in
2178           yes:d:no)
2179             # Specifically requested language; tell them.
2180             AC_MSG_ERROR([GDC is required to build $language])
2181            ;;
2182           all:d:no)
2183             AC_MSG_WARN([GDC is required to build $language])
2184             add_this_lang=unsupported
2185             ;;
2186           *:d:no)
2187             # Silently disable.
2188             add_this_lang=unsupported
2189             ;;
2190         esac
2191
2192         # Disable jit if -enable-host-shared not specified
2193         # but not if building for Mingw. All code in Windows
2194         # is position independent code (PIC).
2195         case $target in
2196           *mingw*) ;;
2197           *)
2198           case ${add_this_lang}:${language}:${host_shared} in
2199             yes:jit:no)
2200                    # PR jit/64780: explicitly specify --enable-host-shared
2201             AC_MSG_ERROR([
2202 Enabling language "jit" requires --enable-host-shared.
2203
2204 --enable-host-shared typically slows the rest of the compiler down by
2205 a few %, so you must explicitly enable it.
2206
2207 If you want to build both the jit and the regular compiler, it is often
2208 best to do this via two separate configure/builds, in separate
2209 directories, to avoid imposing the performance cost of
2210 --enable-host-shared on the regular compiler.])
2211                     ;;
2212             all:jit:no)
2213               AC_MSG_WARN([--enable-host-shared required to build $language])
2214               add_this_lang=unsupported
2215               ;;
2216             *:jit:no)
2217               # Silently disable.
2218               add_this_lang=unsupported
2219               ;;
2220                 esac
2221           ;;
2222         esac
2223
2224         # Disable a language that is unsupported by the target.
2225         case "${add_this_lang}: $unsupported_languages " in
2226           no:*) ;;
2227           unsupported:*) ;;
2228           *:*" $language "*)
2229             AC_MSG_WARN([${language} not supported for this target])
2230             add_this_lang=unsupported
2231             ;;
2232         esac
2233
2234         case $add_this_lang in
2235           unsupported)
2236             # Remove language-dependent dirs.
2237             disabled_target_libs="$disabled_target_libs $target_libs"
2238             noconfigdirs="$noconfigdirs $lang_dirs"
2239             ;;
2240           no)
2241             # Remove language-dependent dirs; still show language as supported.
2242             disabled_target_libs="$disabled_target_libs $target_libs"
2243             noconfigdirs="$noconfigdirs $lang_dirs"
2244             potential_languages="${potential_languages}${language},"
2245             ;;
2246           all|yes)
2247             new_enable_languages="${new_enable_languages}${language},"
2248             potential_languages="${potential_languages}${language},"
2249             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2250             enabled_target_libs="$enabled_target_libs $target_libs"
2251             case "${boot_language}:,$enable_stage1_languages," in
2252               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2253                 # Add to (comma-separated) list of stage 1 languages.
2254                 case ",$stage1_languages," in
2255                   *,$language,* | ,yes, | ,all,) ;;
2256                   *) stage1_languages="${stage1_languages}${language}," ;;
2257                 esac
2258                 # We need to bootstrap any supporting libraries.
2259                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2260                 ;;
2261             esac
2262             ;;
2263         esac
2264         ;;
2265     esac
2266   done
2267
2268   # Add target libraries which are only needed for disabled languages
2269   # to noconfigdirs.
2270   if test -n "$disabled_target_libs"; then
2271     for dir in $disabled_target_libs; do
2272       case " $enabled_target_libs " in
2273       *" ${dir} "*) ;;
2274       *) noconfigdirs="$noconfigdirs $dir" ;;
2275       esac
2276     done
2277   fi
2278
2279   AC_ARG_ENABLE(stage1-languages,
2280   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2281                   [choose additional languages to build during
2282                   stage1.  Mostly useful for compiler development])],
2283   [case ,${enable_stage1_languages}, in
2284     ,no,|,,)
2285       # Set it to something that will have no effect in the loop below
2286       enable_stage1_languages=c ;;
2287     ,yes,)
2288       enable_stage1_languages=`echo $new_enable_languages | \
2289         sed -e "s/^,//" -e "s/,$//" ` ;;
2290     *,all,*)
2291       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2292         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2293   esac
2294
2295   # Add "good" languages from enable_stage1_languages to stage1_languages,
2296   # while "bad" languages go in missing_languages.  Leave no duplicates.
2297   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2298     case $potential_languages in
2299       *,$i,*)
2300         case $stage1_languages in
2301           *,$i,*) ;;
2302           *) stage1_languages="$stage1_languages$i," ;;
2303         esac ;;
2304       *)
2305         case $missing_languages in
2306           *,$i,*) ;;
2307           *) missing_languages="$missing_languages$i," ;;
2308         esac ;;
2309      esac
2310   done])
2311
2312   # Remove leading/trailing commas that were added for simplicity
2313   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2314   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2315   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2316   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2317
2318   if test "x$missing_languages" != x; then
2319     AC_MSG_ERROR([
2320 The following requested languages could not be built: ${missing_languages}
2321 Supported languages are: ${potential_languages}])
2322   fi
2323   if test "x$new_enable_languages" != "x$enable_languages"; then
2324     echo The following languages will be built: ${new_enable_languages}
2325     enable_languages="$new_enable_languages"
2326   fi
2327
2328   AC_SUBST(stage1_languages)
2329   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2330 fi
2331
2332 # Handle --disable-<component> generically.
2333 for dir in $configdirs $build_configdirs $target_configdirs ; do
2334   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2335   varname=`echo $dirname | sed -e s/+/_/g`
2336   if eval test x\${enable_${varname}} "=" xno ; then
2337     noconfigdirs="$noconfigdirs $dir"
2338   fi
2339 done
2340
2341 # Check for Boehm's garbage collector
2342 AC_ARG_ENABLE(objc-gc,
2343 [AS_HELP_STRING([--enable-objc-gc],
2344                 [enable use of Boehm's garbage collector with the
2345                  GNU Objective-C runtime])])
2346 AC_ARG_WITH([target-bdw-gc],
2347 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2348                 [specify prefix directory for installed bdw-gc package.
2349                  Equivalent to --with-target-bdw-gc-include=PATH/include
2350                  plus --with-target-bdw-gc-lib=PATH/lib])])
2351 AC_ARG_WITH([target-bdw-gc-include],
2352 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2353                 [specify directories for installed bdw-gc include files])])
2354 AC_ARG_WITH([target-bdw-gc-lib],
2355 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2356                 [specify directories for installed bdw-gc library])])
2357
2358 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2359   AC_MSG_CHECKING([for bdw garbage collector])
2360   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2361     dnl no bdw-gw options, assume default locations
2362     AC_MSG_RESULT([using bdw-gc in default locations])
2363   else
2364     dnl bdw-gw options, first error checking, complete checking in libobjc
2365     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2366       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2367     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2368       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2369     else
2370       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2371     fi
2372   fi
2373 esac
2374
2375 # Disable libitm, libsanitizer, libvtv if we're not building C++
2376 case ,${enable_languages}, in
2377   *,c++,*)
2378     # Disable libitm, libsanitizer if we're not building libstdc++
2379     case "${noconfigdirs}" in
2380       *target-libstdc++-v3*)
2381         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2382         ;;
2383       *) ;;
2384     esac
2385     ;;
2386   *)
2387     noconfigdirs="$noconfigdirs target-libitm target-libsanitizer target-libvtv"
2388     ;;
2389 esac
2390
2391 # If gcc/ is not in the source tree then we'll not be building a
2392 # target compiler, assume in that case we don't want to build any
2393 # target libraries or tools.
2394 #
2395 # This was added primarily for the benefit for binutils-gdb who reuse
2396 # this configure script, but don't always have target tools available.
2397 if test ! -d ${srcdir}/gcc; then
2398    skipdirs="${skipdirs} ${target_configdirs}"
2399 fi
2400
2401 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2402 # $build_configdirs and $target_configdirs.
2403 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2404
2405 notsupp=""
2406 for dir in . $skipdirs $noconfigdirs ; do
2407   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2408   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2409     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2410     if test -r $srcdir/$dirname/configure ; then
2411       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2412         true
2413       else
2414         notsupp="$notsupp $dir"
2415       fi
2416     fi
2417   fi
2418   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2419     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2420     if test -r $srcdir/$dirname/configure ; then
2421       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2422         true
2423       else
2424         notsupp="$notsupp $dir"
2425       fi
2426     fi
2427   fi
2428   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2429     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2430     if test -r $srcdir/$dirname/configure ; then
2431       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2432         true
2433       else
2434         notsupp="$notsupp $dir"
2435       fi
2436     fi
2437   fi
2438 done
2439
2440 # Quietly strip out all directories which aren't configurable in this tree.
2441 # This relies on all configurable subdirectories being autoconfiscated, which
2442 # is now the case.
2443 build_configdirs_all="$build_configdirs"
2444 build_configdirs=
2445 for i in ${build_configdirs_all} ; do
2446   j=`echo $i | sed -e s/build-//g`
2447   if test -f ${srcdir}/$j/configure ; then
2448     build_configdirs="${build_configdirs} $i"
2449   fi
2450 done
2451
2452 configdirs_all="$configdirs"
2453 configdirs=
2454 for i in ${configdirs_all} ; do
2455   if test -f ${srcdir}/$i/configure ; then
2456     configdirs="${configdirs} $i"
2457   fi
2458 done
2459
2460 target_configdirs_all="$target_configdirs"
2461 target_configdirs=
2462 for i in ${target_configdirs_all} ; do
2463   j=`echo $i | sed -e s/target-//g`
2464   if test -f ${srcdir}/$j/configure ; then
2465     target_configdirs="${target_configdirs} $i"
2466   fi
2467 done
2468
2469 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2470 # so we have to add it after the preceding checks.
2471 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2472 then
2473   case " $configdirs " in
2474     *" libiberty "*)
2475       # If we can build libiberty, we can also build libiberty-linker-plugin.
2476       configdirs="$configdirs libiberty-linker-plugin"
2477       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2478         --with-libiberty=../libiberty-linker-plugin";;
2479     *)
2480       AC_MSG_ERROR([libiberty missing]);;
2481   esac
2482 fi
2483
2484 # Sometimes we have special requirements for the host libiberty.
2485 extra_host_libiberty_configure_flags=
2486 case " $configdirs " in
2487   *" lto-plugin "* | *" libcc1 "* | *" gdbserver "*)
2488     # When these are to be built as shared libraries, the same applies to
2489     # libiberty.
2490     extra_host_libiberty_configure_flags=--enable-shared
2491     ;;
2492 esac
2493 AC_SUBST(extra_host_libiberty_configure_flags)
2494
2495 # Sometimes we have special requirements for the host zlib.
2496 extra_host_zlib_configure_flags=
2497 case " $configdirs " in
2498   *" bfd "*)
2499     # When bfd is to be built as a shared library, the same applies to
2500     # zlib.
2501     if test "$enable_shared" = "yes"; then
2502       extra_host_zlib_configure_flags=--enable-host-shared
2503     fi
2504     ;;
2505 esac
2506 AC_SUBST(extra_host_zlib_configure_flags)
2507
2508 # Produce a warning message for the subdirs we can't configure.
2509 # This isn't especially interesting in the Cygnus tree, but in the individual
2510 # FSF releases, it's important to let people know when their machine isn't
2511 # supported by the one or two programs in a package.
2512
2513 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2514   # If $appdirs is non-empty, at least one of those directories must still
2515   # be configured, or we error out.  (E.g., if the gas release supports a
2516   # specified target in some subdirs but not the gas subdir, we shouldn't
2517   # pretend that all is well.)
2518   if test -n "$appdirs" ; then
2519     for dir in $appdirs ; do
2520       if test -r $dir/Makefile.in ; then
2521         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2522           appdirs=""
2523           break
2524         fi
2525         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2526           appdirs=""
2527           break
2528         fi
2529       fi
2530     done
2531     if test -n "$appdirs" ; then
2532       echo "*** This configuration is not supported by this package." 1>&2
2533       exit 1
2534     fi
2535   fi
2536   # Okay, some application will build, or we don't care to check.  Still
2537   # notify of subdirs not getting built.
2538   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2539   echo "    ${notsupp}" 1>&2
2540   echo "    (Any other directories should still work fine.)" 1>&2
2541 fi
2542
2543 case "$host" in
2544   *msdosdjgpp*)
2545     enable_gdbtk=no ;;
2546 esac
2547
2548 # To find our prefix, in gcc_cv_tool_prefix.
2549 ACX_TOOL_DIRS
2550
2551 copy_dirs=
2552
2553 AC_ARG_WITH([build-sysroot],
2554   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2555                   [use sysroot as the system root during the build])],
2556   [if test x"$withval" != x ; then
2557      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2558    fi],
2559   [SYSROOT_CFLAGS_FOR_TARGET=])
2560 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2561
2562 AC_ARG_WITH([debug-prefix-map],
2563   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2564                   [map A to B, C to D ... in debug information])],
2565   [if test x"$withval" != x; then
2566      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2567      for debug_map in $withval; do
2568        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2569      done
2570    fi],
2571   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2572 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2573
2574 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2575 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2576 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2577 # We want to ensure that TARGET libraries (which we know are built with
2578 # gcc) are built with "-O2 -g", so include those options when setting
2579 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2580 if test "x$CFLAGS_FOR_TARGET" = x; then
2581   if test "x${is_cross_compiler}" = xyes; then
2582     CFLAGS_FOR_TARGET="-g -O2"
2583   else
2584     CFLAGS_FOR_TARGET=$CFLAGS
2585     case " $CFLAGS " in
2586       *" -O2 "*) ;;
2587       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2588     esac
2589     case " $CFLAGS " in
2590       *" -g "* | *" -g3 "*) ;;
2591       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2592     esac
2593   fi
2594 fi
2595 AC_SUBST(CFLAGS_FOR_TARGET)
2596
2597 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2598   if test "x${is_cross_compiler}" = xyes; then
2599     CXXFLAGS_FOR_TARGET="-g -O2"
2600   else
2601     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2602     case " $CXXFLAGS " in
2603       *" -O2 "*) ;;
2604       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2605     esac
2606     case " $CXXFLAGS " in
2607       *" -g "* | *" -g3 "*) ;;
2608       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2609     esac
2610   fi
2611 fi
2612 AC_SUBST(CXXFLAGS_FOR_TARGET)
2613
2614 AC_SUBST(LDFLAGS_FOR_TARGET)
2615
2616 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2617 # the named directory are copied to $(tooldir)/sys-include.
2618 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2619   if test x${is_cross_compiler} = xno ; then
2620     echo 1>&2 '***' --with-headers is only supported when cross compiling
2621     exit 1
2622   fi
2623   if test x"${with_headers}" != xyes ; then
2624     x=${gcc_cv_tool_prefix}
2625     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2626   fi
2627 fi
2628
2629 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2630 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2631 # are permitted.
2632 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2633   if test x${is_cross_compiler} = xno ; then
2634     echo 1>&2 '***' --with-libs is only supported when cross compiling
2635     exit 1
2636   fi
2637   if test x"${with_libs}" != xyes ; then
2638     # Copy the libraries in reverse order, so that files in the first named
2639     # library override files in subsequent libraries.
2640     x=${gcc_cv_tool_prefix}
2641     for l in ${with_libs}; do
2642       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2643     done
2644   fi
2645 fi
2646
2647 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2648 #
2649 # This is done by determining whether or not the appropriate directory
2650 # is available, and by checking whether or not specific configurations
2651 # have requested that this magic not happen.
2652 #
2653 # The command line options always override the explicit settings in
2654 # configure.ac, and the settings in configure.ac override this magic.
2655 #
2656 # If the default for a toolchain is to use GNU as and ld, and you don't
2657 # want to do that, then you should use the --without-gnu-as and
2658 # --without-gnu-ld options for the configure script.  Similarly, if
2659 # the default is to use the included zlib and you don't want to do that,
2660 # you should use the --with-system-zlib option for the configure script.
2661
2662 if test x${use_gnu_as} = x &&
2663    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2664   with_gnu_as=yes
2665   extra_host_args="$extra_host_args --with-gnu-as"
2666 fi
2667
2668 if test x${use_gnu_ld} = x &&
2669    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2670   with_gnu_ld=yes
2671   extra_host_args="$extra_host_args --with-gnu-ld"
2672 fi
2673
2674 if test x${use_included_zlib} = x &&
2675    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2676   :
2677 else
2678   with_system_zlib=yes
2679   extra_host_args="$extra_host_args --with-system-zlib"
2680 fi
2681
2682 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2683 # can detect this case.
2684
2685 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2686   with_newlib=yes
2687   extra_host_args="$extra_host_args --with-newlib"
2688 fi
2689
2690 # Handle ${copy_dirs}
2691 set fnord ${copy_dirs}
2692 shift
2693 while test $# != 0 ; do
2694   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2695     :
2696   else
2697     echo Copying $1 to $2
2698
2699     # Use the install script to create the directory and all required
2700     # parent directories.
2701     if test -d $2 ; then
2702       :
2703     else
2704       echo >config.temp
2705       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2706     fi
2707
2708     # Copy the directory, assuming we have tar.
2709     # FIXME: Should we use B in the second tar?  Not all systems support it.
2710     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2711
2712     # It is the responsibility of the user to correctly adjust all
2713     # symlinks.  If somebody can figure out how to handle them correctly
2714     # here, feel free to add the code.
2715
2716     echo $1 > $2/COPIED
2717   fi
2718   shift; shift
2719 done
2720
2721 # Determine a target-dependent exec_prefix that the installed
2722 # gcc will search in.  Keep this list sorted by triplet, with
2723 # the *-*-osname triplets last.
2724 md_exec_prefix=
2725 case "${target}" in
2726   i[[34567]]86-pc-msdosdjgpp*)
2727     md_exec_prefix=/dev/env/DJDIR/bin
2728     ;;
2729   *-*-hpux* | \
2730   *-*-nto-qnx* | \
2731   *-*-solaris2*)
2732     md_exec_prefix=/usr/ccs/bin
2733     ;;
2734 esac
2735
2736 extra_arflags_for_target=
2737 extra_nmflags_for_target=
2738 extra_ranlibflags_for_target=
2739 target_makefile_frag=/dev/null
2740 case "${target}" in
2741   spu-*-*)
2742     target_makefile_frag="config/mt-spu"
2743     ;;
2744   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2745     target_makefile_frag="config/mt-sde"
2746     ;;
2747   mipsisa*-*-elfoabi*)
2748     target_makefile_frag="config/mt-mips-elfoabi"
2749     ;;
2750   mips*-*-*linux* | mips*-*-gnu*)
2751     target_makefile_frag="config/mt-mips-gnu"
2752     ;;
2753   nios2-*-elf*)
2754     target_makefile_frag="config/mt-nios2-elf"
2755     ;;
2756   *-*-linux-android*)
2757     target_makefile_frag="config/mt-android"
2758     ;;
2759   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2760     target_makefile_frag="config/mt-gnu"
2761     ;;
2762   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2763     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2764     # commands to handle both 32-bit and 64-bit objects.  These flags are
2765     # harmless if we're using GNU nm or ar.
2766     extra_arflags_for_target=" -X32_64"
2767     extra_nmflags_for_target=" -B -X32_64"
2768     ;;
2769 esac
2770
2771 alphaieee_frag=/dev/null
2772 case $target in
2773   alpha*-*-*)
2774     # This just makes sure to use the -mieee option to build target libs.
2775     # This should probably be set individually by each library.
2776     alphaieee_frag="config/mt-alphaieee"
2777     ;;
2778 esac
2779
2780 # If --enable-target-optspace always use -Os instead of -O2 to build
2781 # the target libraries, similarly if it is not specified, use -Os
2782 # on selected platforms.
2783 ospace_frag=/dev/null
2784 case "${enable_target_optspace}:${target}" in
2785   yes:*)
2786     ospace_frag="config/mt-ospace"
2787     ;;
2788   :d30v-*)
2789     ospace_frag="config/mt-d30v"
2790     ;;
2791   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2792     ospace_frag="config/mt-ospace"
2793     ;;
2794   no:* | :*)
2795     ;;
2796   *)
2797     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2798     ;;
2799 esac
2800
2801 # Some systems (e.g., one of the i386-aix systems the gas testers are
2802 # using) don't handle "\$" correctly, so don't use it here.
2803 tooldir='${exec_prefix}'/${target_noncanonical}
2804 build_tooldir=${tooldir}
2805
2806 # Create a .gdbinit file which runs the one in srcdir
2807 # and tells GDB to look there for source files.
2808
2809 if test -r ${srcdir}/.gdbinit ; then
2810   case ${srcdir} in
2811     .) ;;
2812     *) cat > ./.gdbinit <<EOF
2813 # ${NO_EDIT}
2814 dir ${srcdir}
2815 dir .
2816 source ${srcdir}/.gdbinit
2817 EOF
2818     ;;
2819   esac
2820 fi
2821
2822 # Make sure that the compiler is able to generate an executable.  If it
2823 # can't, we are probably in trouble.  We don't care whether we can run the
2824 # executable--we might be using a cross compiler--we only care whether it
2825 # can be created.  At this point the main configure script has set CC.
2826 we_are_ok=no
2827 echo "int main () { return 0; }" > conftest.c
2828 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2829 if test $? = 0 ; then
2830   if test -s conftest || test -s conftest.exe ; then
2831     we_are_ok=yes
2832   fi
2833 fi
2834 case $we_are_ok in
2835   no)
2836     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2837     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2838     rm -f conftest*
2839     exit 1
2840     ;;
2841 esac
2842 rm -f conftest*
2843
2844 # Decide which environment variable is used to find dynamic libraries.
2845 case "${host}" in
2846   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2847   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2848   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2849   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2850 esac
2851
2852 # On systems where the dynamic library environment variable is PATH,
2853 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2854 # built executables to PATH.
2855 if test "$RPATH_ENVVAR" = PATH; then
2856   GCC_SHLIB_SUBDIR=/shlib
2857 else
2858   GCC_SHLIB_SUBDIR=
2859 fi
2860
2861 # Adjust the toplevel makefile according to whether bootstrap was selected.
2862 case $enable_bootstrap in
2863   yes)
2864     bootstrap_suffix=bootstrap
2865     BUILD_CONFIG=bootstrap-debug
2866     ;;
2867   no)
2868     bootstrap_suffix=no-bootstrap
2869     BUILD_CONFIG=
2870     ;;
2871 esac
2872
2873 AC_MSG_CHECKING(for default BUILD_CONFIG)
2874
2875 AC_ARG_WITH([build-config],
2876   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2877                   [use config/NAME.mk build configuration])],
2878   [case $with_build_config in
2879    yes) with_build_config= ;;
2880    no) with_build_config= BUILD_CONFIG= ;;
2881    esac])
2882
2883 if test "x${with_build_config}" != x; then
2884   BUILD_CONFIG=$with_build_config
2885 else
2886   case $BUILD_CONFIG in
2887   bootstrap-debug)
2888     if echo "int f (void) { return 0; }" > conftest.c &&
2889        ${CC} -c conftest.c &&
2890        mv conftest.o conftest.o.g0 &&
2891        ${CC} -c -g conftest.c &&
2892        mv conftest.o conftest.o.g &&
2893        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2894       :
2895     else
2896       BUILD_CONFIG=
2897     fi
2898     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2899     ;;
2900   esac
2901 fi
2902 AC_MSG_RESULT($BUILD_CONFIG)
2903 AC_SUBST(BUILD_CONFIG)
2904
2905 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2906 AC_MSG_CHECKING([for --enable-vtable-verify])
2907 AC_ARG_ENABLE(vtable-verify,
2908 [AS_HELP_STRING([--enable-vtable-verify],
2909                 [Enable vtable verification feature])],
2910 [case "$enableval" in
2911  yes) enable_vtable_verify=yes ;;
2912  no)  enable_vtable_verify=no ;;
2913  *)   enable_vtable_verify=no;;
2914  esac],
2915 [enable_vtable_verify=no])
2916 AC_MSG_RESULT($enable_vtable_verify)
2917
2918 # Record target_configdirs and the configure arguments for target and
2919 # build configuration in Makefile.
2920 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2921 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2922 bootstrap_fixincludes=no
2923
2924 # If we are building libgomp, bootstrap it.
2925 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2926   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2927 fi
2928
2929 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2930 # or bootstrap-ubsan, bootstrap it.
2931 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2932   case "$BUILD_CONFIG" in
2933     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
2934       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2935       bootstrap_fixincludes=yes
2936       ;;
2937   esac
2938 fi
2939
2940 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2941 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2942    test "$enable_vtable_verify" != no; then
2943   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2944 fi
2945
2946 # If we are building libatomic and the list of enabled languages includes the
2947 # D frontend, bootstrap it.
2948 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
2949   case ,${enable_languages}, in
2950     *,d,*)
2951       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
2952       ;;
2953   esac
2954 fi
2955
2956 # Determine whether gdb needs tk/tcl or not.
2957 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2958 # and in that case we want gdb to be built without tk.  Ugh!
2959 # In fact I believe gdb is the *only* package directly dependent on tk,
2960 # so we should be able to put the 'maybe's in unconditionally and
2961 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2962 # 100% sure that that's safe though.
2963
2964 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2965 case "$enable_gdbtk" in
2966   no)
2967     GDB_TK="" ;;
2968   yes)
2969     GDB_TK="${gdb_tk}" ;;
2970   *)
2971     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2972     # distro.  Eventually someone will fix this and move Insight, nee
2973     # gdbtk to a separate directory.
2974     if test -d ${srcdir}/gdb/gdbtk ; then
2975       GDB_TK="${gdb_tk}"
2976     else
2977       GDB_TK=""
2978     fi
2979     ;;
2980 esac
2981 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2982 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2983
2984 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2985 # else does, only include them if one of these is built.  The Makefile
2986 # provides the ordering, so it's enough here to add to the list.
2987 case " ${configdirs} " in
2988   *\ gdb\ *)
2989     configdirs="${configdirs} gnulib gdbsupport"
2990     ;;
2991   *\ gdbserver\ *)
2992     configdirs="${configdirs} gnulib gdbsupport"
2993     ;;
2994   *\ sim\ *)
2995     configdirs="${configdirs} gnulib"
2996     ;;
2997 esac
2998
2999 # Strip out unwanted targets.
3000
3001 # While at that, we remove Makefiles if we were started for recursive
3002 # configuration, so that the top-level Makefile reconfigures them,
3003 # like we used to do when configure itself was recursive.
3004
3005 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
3006 # but now we're fixing up the Makefile ourselves with the additional
3007 # commands passed to AC_CONFIG_FILES.  Use separate variables
3008 # extrasub-{build,host,target} not because there is any reason to split
3009 # the substitutions up that way, but only to remain below the limit of
3010 # 99 commands in a script, for HP-UX sed.
3011
3012 # Do not nest @if/@endif or @unless/@endunless pairs, because
3013 # configure will not warn you at all.
3014
3015 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
3016   yes:yes:*\ gold\ *:*,c++,*) ;;
3017   yes:yes:*\ gold\ *:*)
3018     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
3019     ;;
3020 esac
3021
3022 extrasub_build=
3023 for module in ${build_configdirs} ; do
3024   if test -z "${no_recursion}" \
3025      && test -f ${build_subdir}/${module}/Makefile; then
3026     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
3027     rm -f ${build_subdir}/${module}/Makefile
3028   fi
3029   extrasub_build="$extrasub_build
3030 /^@if build-$module\$/d
3031 /^@endif build-$module\$/d
3032 /^@unless build-$module\$/,/^@endunless build-$module\$/d
3033 /^@if build-$module-$bootstrap_suffix\$/d
3034 /^@endif build-$module-$bootstrap_suffix\$/d
3035 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
3036 done
3037 extrasub_host=
3038 for module in ${configdirs} ; do
3039   if test -z "${no_recursion}"; then
3040     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
3041       if test -f ${file}; then
3042         echo 1>&2 "*** removing ${file} to force reconfigure"
3043         rm -f ${file}
3044       fi
3045     done
3046   fi
3047   case ${module},${bootstrap_fixincludes} in
3048     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
3049     *) host_bootstrap_suffix=$bootstrap_suffix ;;
3050   esac
3051   extrasub_host="$extrasub_host
3052 /^@if $module\$/d
3053 /^@endif $module\$/d
3054 /^@unless $module\$/,/^@endunless $module\$/d
3055 /^@if $module-$host_bootstrap_suffix\$/d
3056 /^@endif $module-$host_bootstrap_suffix\$/d
3057 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
3058 done
3059 extrasub_target=
3060 for module in ${target_configdirs} ; do
3061   if test -z "${no_recursion}" \
3062      && test -f ${target_subdir}/${module}/Makefile; then
3063     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
3064     rm -f ${target_subdir}/${module}/Makefile
3065   fi
3066
3067   # We only bootstrap target libraries listed in bootstrap_target_libs.
3068   case $bootstrap_target_libs in
3069     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
3070     *) target_bootstrap_suffix=no-bootstrap ;;
3071   esac
3072
3073   extrasub_target="$extrasub_target
3074 /^@if target-$module\$/d
3075 /^@endif target-$module\$/d
3076 /^@unless target-$module\$/,/^@endunless target-$module\$/d
3077 /^@if target-$module-$target_bootstrap_suffix\$/d
3078 /^@endif target-$module-$target_bootstrap_suffix\$/d
3079 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
3080 done
3081
3082 # Do the final fixup along with target modules.
3083 extrasub_target="$extrasub_target
3084 /^@if /,/^@endif /d
3085 /^@unless /d
3086 /^@endunless /d"
3087
3088 if test "$enable_pgo_build" != "no"; then
3089   extrasub_build="$extrasub_build
3090 /^@if pgo-build\$/d
3091 /^@endif pgo-build\$/d"
3092 fi
3093
3094 # Create the serialization dependencies.  This uses a temporary file.
3095
3096 AC_ARG_ENABLE([serial-configure],
3097 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3098                 [force sequential configuration of
3099                  sub-packages for the host, target or build
3100                  machine, or all sub-packages])])
3101
3102 case ${enable_serial_configure} in
3103   yes)
3104     enable_serial_build_configure=yes
3105     enable_serial_host_configure=yes
3106     enable_serial_target_configure=yes
3107     ;;
3108 esac
3109
3110 # These force 'configure's to be done one at a time, to avoid problems
3111 # with contention over a shared config.cache.
3112 rm -f serdep.tmp
3113 if test "x${enable_serial_build_configure}" = xyes || test "x${enable_serial_host_configure}" = xyes || test "x${enable_serial_target_configure}" = xyes; then
3114 echo '# serdep.tmp' > serdep.tmp
3115 fi
3116 olditem=
3117 test "x${enable_serial_build_configure}" = xyes &&
3118 for item in ${build_configdirs} ; do
3119   case ${olditem} in
3120     "") ;;
3121     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3122   esac
3123   olditem=${item}
3124 done
3125 olditem=
3126 test "x${enable_serial_host_configure}" = xyes &&
3127 for item in ${configdirs} ; do
3128   case ${olditem} in
3129     "") ;;
3130     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3131   esac
3132   olditem=${item}
3133 done
3134 olditem=
3135 test "x${enable_serial_target_configure}" = xyes &&
3136 for item in ${target_configdirs} ; do
3137   case ${olditem} in
3138     "") ;;
3139     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3140   esac
3141   olditem=${item}
3142 done
3143 serialization_dependencies=serdep.tmp
3144 AC_SUBST_FILE(serialization_dependencies)
3145
3146 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3147 # target, nonopt, and variable assignments.  These are the ones we
3148 # might not want to pass down to subconfigures.  The exception being
3149 # --cache-file=/dev/null, which is used to turn off the use of cache
3150 # files altogether, and which should be passed on to subconfigures.
3151 # Also strip program-prefix, program-suffix, and program-transform-name,
3152 # so that we can pass down a consistent program-transform-name.
3153 baseargs=
3154 tbaseargs=
3155 keep_next=no
3156 skip_next=no
3157 eval "set -- $ac_configure_args"
3158 for ac_arg
3159 do
3160   if test X"$skip_next" = X"yes"; then
3161     skip_next=no
3162     continue
3163   fi
3164   if test X"$keep_next" = X"yes"; then
3165     case $ac_arg in
3166       *\'*)
3167         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3168     esac
3169     baseargs="$baseargs '$ac_arg'"
3170     tbaseargs="$tbaseargs '$ac_arg'"
3171     keep_next=no
3172     continue
3173   fi
3174
3175   # Handle separated arguments.  Based on the logic generated by
3176   # autoconf 2.59.
3177   case $ac_arg in
3178     *=* | --config-cache | -C | -disable-* | --disable-* \
3179       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3180       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3181       | -with-* | --with-* | -without-* | --without-* | --x)
3182       separate_arg=no
3183       ;;
3184     -*)
3185       separate_arg=yes
3186       ;;
3187     *)
3188       separate_arg=no
3189       ;;
3190   esac
3191
3192   skip_targ=no
3193   case $ac_arg in
3194 changequote(,)
3195   --with-* | --without-*)
3196     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3197
3198     case $libopt in
3199     *[-_]include)
3200       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3201       ;;
3202     *[-_]lib)
3203       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3204       ;;
3205     *)
3206       lib=$libopt
3207       ;;
3208     esac
3209 changequote([,])
3210
3211     case $lib in
3212     mpc | mpfr | gmp | isl)
3213       # If we're processing --with-$lib, --with-$lib-include or
3214       # --with-$lib-lib, for one of the libs above, and target is
3215       # different from host, don't pass the current argument to any
3216       # target library's configure.
3217       if test x$is_cross_compiler = xyes; then
3218         skip_targ=yes
3219       fi
3220       ;;
3221     esac
3222     ;;
3223   esac
3224
3225   case "$ac_arg" in
3226     --cache-file=/dev/null | \
3227     -cache-file=/dev/null )
3228       # Handled here to avoid the test to skip args below.
3229       baseargs="$baseargs '$ac_arg'"
3230       tbaseargs="$tbaseargs '$ac_arg'"
3231       # Assert: $separate_arg should always be no.
3232       keep_next=$separate_arg
3233       ;;
3234     --no*)
3235       continue
3236       ;;
3237     --c* | \
3238     --sr* | \
3239     --ho* | \
3240     --bu* | \
3241     --t* | \
3242     --program-* | \
3243     -cache_file* | \
3244     -srcdir* | \
3245     -host* | \
3246     -build* | \
3247     -target* | \
3248     -program-prefix* | \
3249     -program-suffix* | \
3250     -program-transform-name* )
3251       skip_next=$separate_arg
3252       continue
3253       ;;
3254     -*)
3255       # An option.  Add it.
3256       case $ac_arg in
3257         *\'*)
3258           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3259       esac
3260       baseargs="$baseargs '$ac_arg'"
3261       if test X"$skip_targ" = Xno; then
3262         tbaseargs="$tbaseargs '$ac_arg'"
3263       fi
3264       keep_next=$separate_arg
3265       ;;
3266     *)
3267       # Either a variable assignment, or a nonopt (triplet).  Don't
3268       # pass it down; let the Makefile handle this.
3269       continue
3270       ;;
3271   esac
3272 done
3273 # Remove the initial space we just introduced and, as these will be
3274 # expanded by make, quote '$'.
3275 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3276
3277 # Add in --program-transform-name, after --program-prefix and
3278 # --program-suffix have been applied to it.  Autoconf has already
3279 # doubled dollar signs and backslashes in program_transform_name; we want
3280 # the backslashes un-doubled, and then the entire thing wrapped in single
3281 # quotes, because this will be expanded first by make and then by the shell.
3282 # Also, because we want to override the logic in subdir configure scripts to
3283 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3284 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3285 ${program_transform_name}
3286 EOF_SED
3287 gcc_transform_name=`cat conftestsed.out`
3288 rm -f conftestsed.out
3289 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3290 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3291 if test "$silent" = yes; then
3292   baseargs="$baseargs --silent"
3293   tbaseargs="$tbaseargs --silent"
3294 fi
3295 baseargs="$baseargs --disable-option-checking"
3296 tbaseargs="$tbaseargs --disable-option-checking"
3297
3298 # Record and document user additions to sub configure arguments.
3299 AC_ARG_VAR([build_configargs],
3300            [additional configure arguments for build directories])
3301 AC_ARG_VAR([host_configargs],
3302            [additional configure arguments for host directories])
3303 AC_ARG_VAR([target_configargs],
3304            [additional configure arguments for target directories])
3305
3306 # For the build-side libraries, we just need to pretend we're native,
3307 # and not use the same cache file.  Multilibs are neither needed nor
3308 # desired.  We can't even use the same cache file for all build-side
3309 # libraries, as they're compiled differently; some with C, some with
3310 # C++ or with different feature-enabling options.
3311 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3312
3313 # For host modules, accept cache file option, or specification as blank.
3314 case "${cache_file}" in
3315 "") # empty
3316   cache_file_option="" ;;
3317 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3318   cache_file_option="--cache-file=${cache_file}" ;;
3319 *) # relative path
3320   cache_file_option="--cache-file=../${cache_file}" ;;
3321 esac
3322
3323 # Host dirs don't like to share a cache file either, horribly enough.
3324 # This seems to be due to autoconf 2.5x stupidity.
3325 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3326
3327 target_configargs="$target_configargs ${tbaseargs}"
3328
3329 # Passing a --with-cross-host argument lets the target libraries know
3330 # whether they are being built with a cross-compiler or being built
3331 # native.  However, it would be better to use other mechanisms to make the
3332 # sorts of decisions they want to make on this basis.  Please consider
3333 # this option to be deprecated.  FIXME.
3334 if test x${is_cross_compiler} = xyes ; then
3335   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3336 fi
3337
3338 # Special user-friendly check for native x86_64-linux build, if
3339 # multilib is not explicitly enabled.
3340 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3341   x86_64-*linux*:yes:$build:$build:)
3342     # Make sure we have a development environment that handles 32-bit
3343     dev64=no
3344     echo "int main () { return 0; }" > conftest.c
3345     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3346     if test $? = 0 ; then
3347       if test -s conftest || test -s conftest.exe ; then
3348         dev64=yes
3349       fi
3350     fi
3351     rm -f conftest*
3352     if test x${dev64} != xyes ; then
3353       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3354     fi
3355     ;;
3356 esac
3357
3358 # Default to --enable-multilib.
3359 if test x${enable_multilib} = x ; then
3360   target_configargs="--enable-multilib ${target_configargs}"
3361 fi
3362
3363 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3364 # changed from the earlier setting of with_newlib.
3365 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3366   target_configargs="--with-newlib ${target_configargs}"
3367 fi
3368
3369 # Different target subdirs use different values of certain variables
3370 # (notably CXX).  Worse, multilibs use *lots* of different values.
3371 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3372 # it doesn't automatically accept command-line overrides of them.
3373 # This means it's not safe for target subdirs to share a cache file,
3374 # which is disgusting, but there you have it.  Hopefully this can be
3375 # fixed in future.  It's still worthwhile to use a cache file for each
3376 # directory.  I think.
3377
3378 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3379 # We need to pass --target, as newer autoconf's requires consistency
3380 # for target_alias and gcc doesn't manage it consistently.
3381 target_configargs="--cache-file=./config.cache ${target_configargs}"
3382
3383 FLAGS_FOR_TARGET=
3384 case " $target_configdirs " in
3385  *" newlib "*)
3386   case " $target_configargs " in
3387   *" --with-newlib "*)
3388    case "$target" in
3389     *-cygwin*)
3390       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3391       ;;
3392    esac
3393
3394    # If we're not building GCC, don't discard standard headers.
3395    if test -d ${srcdir}/gcc; then
3396      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3397
3398      if test "${build}" != "${host}"; then
3399        # On Canadian crosses, CC_FOR_TARGET will have already been set
3400        # by `configure', so we won't have an opportunity to add -Bgcc/
3401        # to it.  This is right: we don't want to search that directory
3402        # for binaries, but we want the header files in there, so add
3403        # them explicitly.
3404        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3405
3406        # Someone might think of using the pre-installed headers on
3407        # Canadian crosses, in case the installed compiler is not fully
3408        # compatible with the compiler being built.  In this case, it
3409        # would be better to flag an error than risking having
3410        # incompatible object files being constructed.  We can't
3411        # guarantee that an error will be flagged, but let's hope the
3412        # compiler will do it, when presented with incompatible header
3413        # files.
3414      fi
3415    fi
3416
3417    case "${target}-${is_cross_compiler}" in
3418    i[[3456789]]86-*-linux*-no)
3419       # Here host == target, so we don't need to build gcc,
3420       # so we don't want to discard standard headers.
3421       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3422       ;;
3423    *)
3424       # If we're building newlib, use its generic headers last, but search
3425       # for any libc-related directories first (so make it the last -B
3426       # switch).
3427       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3428
3429       # If we're building libgloss, find the startup file, simulator library
3430       # and linker script.
3431       case " $target_configdirs " in
3432         *" libgloss "*)
3433         # Look for startup file, simulator library and maybe linker script.
3434         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3435         # Look for libnosys.a in case the target needs it.
3436         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3437         # Most targets have the linker script in the source directory.
3438         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3439         ;;
3440       esac
3441       ;;
3442    esac
3443    ;;
3444   esac
3445   ;;
3446 esac
3447
3448 case "$target" in
3449   x86_64-*mingw* | *-w64-mingw*)
3450   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3451   # however, use a symlink named 'mingw' in ${prefix} .
3452     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3453     ;;
3454   *-mingw*)
3455   # MinGW can't be handled as Cygwin above since it does not use newlib.
3456     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3457     ;;
3458 esac
3459
3460 # Allow the user to override the flags for
3461 # our build compiler if desired.
3462 if test x"${build}" = x"${host}" ; then
3463   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3464   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3465   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3466   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3467 fi
3468
3469 # On Canadian crosses, we'll be searching the right directories for
3470 # the previously-installed cross compiler, so don't bother to add
3471 # flags for directories within the install tree of the compiler
3472 # being built; programs in there won't even run.
3473 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3474   # Search for pre-installed headers if nothing else fits.
3475   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3476 fi
3477
3478 if test "x${use_gnu_ld}" = x &&
3479    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3480   # Arrange for us to find uninstalled linker scripts.
3481   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3482 fi
3483
3484 # Search for other target-specific linker scripts and such.
3485 case "${target}" in
3486   mep*)
3487     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3488     ;;
3489   # The VxWorks support for shared libraries is getting in
3490   # incrementally.  Make sure it doesn't get activated implicitly:
3491   *vxworks*)
3492     if test "${enable_shared-unset}" = unset ; then
3493       enable_shared=no
3494       # So the build of libraries knows ...
3495       target_configargs="${target_configargs} --disable-shared"
3496       # So gcc knows ...
3497       host_configargs="${host_configargs} --disable-shared"
3498     fi
3499     ;;
3500 esac
3501
3502 # Makefile fragments.
3503 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3504 do
3505   eval fragval=\$$frag
3506   if test $fragval != /dev/null; then
3507     eval $frag=${srcdir}/$fragval
3508   fi
3509 done
3510 AC_SUBST_FILE(host_makefile_frag)
3511 AC_SUBST_FILE(target_makefile_frag)
3512 AC_SUBST_FILE(alphaieee_frag)
3513 AC_SUBST_FILE(ospace_frag)
3514
3515 # Miscellanea: directories, flags, etc.
3516 AC_SUBST(RPATH_ENVVAR)
3517 AC_SUBST(GCC_SHLIB_SUBDIR)
3518 AC_SUBST(tooldir)
3519 AC_SUBST(build_tooldir)
3520 AC_SUBST(CONFIGURE_GDB_TK)
3521 AC_SUBST(GDB_TK)
3522 AC_SUBST(INSTALL_GDB_TK)
3523
3524 # Build module lists & subconfigure args.
3525 AC_SUBST(build_configargs)
3526 AC_SUBST(build_configdirs)
3527
3528 # Host module lists & subconfigure args.
3529 AC_SUBST(host_configargs)
3530 AC_SUBST(configdirs)
3531 AC_SUBST(target_configdirs)
3532
3533 # Target module lists & subconfigure args.
3534 AC_SUBST(target_configargs)
3535
3536
3537 # Build tools.
3538 AC_SUBST(AR_FOR_BUILD)
3539 AC_SUBST(AS_FOR_BUILD)
3540 AC_SUBST(CC_FOR_BUILD)
3541 AC_SUBST(CFLAGS_FOR_BUILD)
3542 AC_SUBST(CPP_FOR_BUILD)
3543 AC_SUBST(CPPFLAGS_FOR_BUILD)
3544 AC_SUBST(CXXFLAGS_FOR_BUILD)
3545 AC_SUBST(CXX_FOR_BUILD)
3546 AC_SUBST(DLLTOOL_FOR_BUILD)
3547 AC_SUBST(DSYMUTIL_FOR_BUILD)
3548 AC_SUBST(GFORTRAN_FOR_BUILD)
3549 AC_SUBST(GOC_FOR_BUILD)
3550 AC_SUBST(GDC_FOR_BUILD)
3551 AC_SUBST(LDFLAGS_FOR_BUILD)
3552 AC_SUBST(LD_FOR_BUILD)
3553 AC_SUBST(NM_FOR_BUILD)
3554 AC_SUBST(RANLIB_FOR_BUILD)
3555 AC_SUBST(WINDMC_FOR_BUILD)
3556 AC_SUBST(WINDRES_FOR_BUILD)
3557
3558 # Generate default definitions for YACC, M4, LEX and other programs that run
3559 # on the build machine.  These are used if the Makefile can't locate these
3560 # programs in objdir.
3561 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3562
3563 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3564 case " $build_configdirs " in
3565   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3566 esac
3567
3568 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3569 case " $build_configdirs " in
3570   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3571 esac
3572
3573 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3574 case " $build_configdirs " in
3575   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3576 esac
3577
3578 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3579 case " $build_configdirs " in
3580   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3581   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3582 esac
3583
3584 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3585 case " $build_configdirs " in
3586   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3587 esac
3588
3589 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3590 case " $build_configdirs " in
3591   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3592   *)
3593 changequote(,)
3594     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3595     # higher, else we use the "missing" dummy.
3596     if ${MAKEINFO} --version \
3597        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3598       :
3599     else
3600       MAKEINFO="$MISSING makeinfo"
3601     fi
3602     ;;
3603 changequote([,])
3604 esac
3605
3606 # FIXME: expect and dejagnu may become build tools?
3607
3608 AC_CHECK_PROGS(EXPECT, expect, expect)
3609 case " $configdirs " in
3610   *" expect "*)
3611     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3612     ;;
3613 esac
3614
3615 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3616 case " $configdirs " in
3617   *" dejagnu "*)
3618     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3619     ;;
3620 esac
3621
3622
3623 # Host tools.
3624 NCN_STRICT_CHECK_TOOLS(AR, ar)
3625 NCN_STRICT_CHECK_TOOLS(AS, as)
3626 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3627 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3628 NCN_STRICT_CHECK_TOOLS(LD, ld)
3629 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3630 NCN_STRICT_CHECK_TOOLS(NM, nm)
3631 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3632 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3633 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3634 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3635 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3636 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3637 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3638 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3639 AC_SUBST(CC)
3640 AC_SUBST(CXX)
3641 AC_SUBST(CFLAGS)
3642 AC_SUBST(CXXFLAGS)
3643 AC_SUBST(GDC)
3644 AC_SUBST(GDCFLAGS)
3645
3646 # Target tools.
3647 AC_ARG_WITH([build-time-tools],
3648   [AS_HELP_STRING([--with-build-time-tools=PATH],
3649                   [use given path to find target tools during the build])],
3650   [case x"$withval" in
3651      x/*) ;;
3652      *)
3653        with_build_time_tools=
3654        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3655        ;;
3656    esac],
3657   [with_build_time_tools=])
3658
3659 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3660 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3661 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3662 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3663 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3664 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3665 NCN_STRICT_CHECK_TARGET_TOOLS(GM2_FOR_TARGET, gm2)
3666
3667 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3668 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3669 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3670 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3671 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3672 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3673 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3674 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3675 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3676 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3677 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3678 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3679 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3680 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3681 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3682
3683 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3684
3685 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3686 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3687 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3688 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3689 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3690                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3691                 c++)
3692 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3693                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3694                 c++)
3695 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3696 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3697 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3698 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3699                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3700 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3701                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3702 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3703                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3704 GCC_TARGET_TOOL(gm2, GM2_FOR_TARGET, GM2,
3705                 [gcc/gm2 -B$$r/$(HOST_SUBDIR)/gcc/], m2)
3706 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3707 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3708 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3709 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3710 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3711 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3712 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3713 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3714 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3715 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3716 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3717
3718 AC_SUBST(FLAGS_FOR_TARGET)
3719 AC_SUBST(RAW_CXX_FOR_TARGET)
3720
3721 # Certain tools may need extra flags.
3722 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3723 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3724 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3725
3726 # When building target libraries, except in a Canadian cross, we use
3727 # the same toolchain as the compiler we just built.
3728 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3729 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3730 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3731 if test $host = $build; then
3732   case " $configdirs " in
3733     *" gcc "*)
3734       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3735       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3736       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3737       ;;
3738   esac
3739 fi
3740
3741 AC_SUBST(COMPILER_AS_FOR_TARGET)
3742 AC_SUBST(COMPILER_LD_FOR_TARGET)
3743 AC_SUBST(COMPILER_NM_FOR_TARGET)
3744
3745 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3746 AC_ARG_ENABLE(maintainer-mode,
3747 [AS_HELP_STRING([--enable-maintainer-mode],
3748                 [enable make rules and dependencies not useful
3749                  (and sometimes confusing) to the casual installer])],
3750       USE_MAINTAINER_MODE=$enableval,
3751       USE_MAINTAINER_MODE=no)
3752 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3753 AC_SUBST(MAINTAINER_MODE_TRUE)
3754 AC_SUBST(MAINTAINER_MODE_FALSE)
3755 if test "$USE_MAINTAINER_MODE" = yes; then
3756   MAINTAINER_MODE_TRUE=
3757   MAINTAINER_MODE_FALSE='#'
3758 else
3759   MAINTAINER_MODE_TRUE='#'
3760   MAINTAINER_MODE_FALSE=
3761 fi
3762 MAINT=$MAINTAINER_MODE_TRUE
3763 AC_SUBST(MAINT)dnl
3764
3765 # ---------------------
3766 # GCC bootstrap support
3767 # ---------------------
3768
3769 # Stage specific cflags for build.
3770 stage1_cflags="-g"
3771 case $build in
3772   vax-*-*)
3773     case ${GCC} in
3774       yes) stage1_cflags="-g -Wa,-J" ;;
3775       *) stage1_cflags="-g -J" ;;
3776     esac ;;
3777 esac
3778
3779 AC_SUBST(stage1_cflags)
3780
3781 # Enable --enable-checking in stage1 of the compiler.
3782 AC_ARG_ENABLE(stage1-checking,
3783 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3784                 [choose additional checking for stage1 of the compiler])],
3785 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3786 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3787   # For --disable-checking or implicit --enable-checking=release, avoid
3788   # setting --enable-checking=gc in the default stage1 checking for LTO
3789   # bootstraps.  See PR62077.
3790   case $BUILD_CONFIG in
3791     *lto*)
3792       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3793     *)
3794       stage1_checking=--enable-checking=yes,types;;
3795   esac
3796   if test "x$enable_checking" = x && \
3797      test -d ${srcdir}/gcc && \
3798      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3799     stage1_checking=--enable-checking=yes,types,extra
3800   fi
3801 else
3802   stage1_checking=--enable-checking=$enable_checking,types
3803 fi])
3804 AC_SUBST(stage1_checking)
3805
3806 # Enable -Werror in bootstrap stage2 and later.
3807 AC_ARG_ENABLE(werror,
3808 [AS_HELP_STRING([--enable-werror],
3809                 [enable -Werror in bootstrap stage2 and later])],
3810 [
3811 case ${enable_werror} in
3812   yes) stage2_werror_flag="--enable-werror-always" ;;
3813   *) stage2_werror_flag="" ;;
3814 esac
3815 ],
3816 [
3817 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3818   case $BUILD_CONFIG in
3819   bootstrap-debug)
3820       stage2_werror_flag="--enable-werror-always" ;;
3821   "")
3822       stage2_werror_flag="--enable-werror-always" ;;
3823   esac
3824 fi
3825 ])
3826
3827 AC_SUBST(stage2_werror_flag)
3828
3829 # Specify what files to not compare during bootstrap.
3830
3831 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3832 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/M2Version*"
3833 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/SYSTEM*"
3834 compare_exclusions="$compare_exclusions | gcc/m2/gm2version*"
3835 case "$target" in
3836   hppa*64*-*-hpux*) ;;
3837   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3838 esac
3839 AC_SUBST(compare_exclusions)
3840
3841 AC_CONFIG_FILES([Makefile],
3842   [sed "$extrasub_build" Makefile |
3843    sed "$extrasub_host" |
3844    sed "$extrasub_target" > mf$$
3845    mv -f mf$$ Makefile],
3846   [extrasub_build="$extrasub_build"
3847    extrasub_host="$extrasub_host"
3848    extrasub_target="$extrasub_target"])
3849 AC_OUTPUT