gcc/ada/s-taprop-mingw.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --     S Y S T E M . T A S K _ P R I M I T I V E S . O P E R A T I O N S    --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNARL was developed by the GNARL team at Florida State University.       --
  28 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This is a NT (native) version of this package
  33
  34 --  This package contains all the GNULL primitives that interface directly with
  35 --  the underlying OS.
  36
  37 pragma Polling (Off);
  38 --  Turn off polling, we do not want ATC polling to take place during tasking
  39 --  operations. It causes infinite loops and other problems.
  40
  41 with Ada.Unchecked_Deallocation;
  42
  43 with Interfaces.C;
  44 with Interfaces.C.Strings;
  45
  46 with System.Tasking.Debug;
  47 with System.OS_Primitives;
  48 with System.Task_Info;
  49 with System.Interrupt_Management;
  50 with System.Win32.Ext;
  51
  52 with System.Soft_Links;
  53 --  We use System.Soft_Links instead of System.Tasking.Initialization because
  54 --  the later is a higher level package that we shouldn't depend on. For
  55 --  example when using the restricted run time, it is replaced by
  56 --  System.Tasking.Restricted.Stages.
  57
  58 package body System.Task_Primitives.Operations is
  59
  60    package SSL renames System.Soft_Links;
  61
  62    use System.Tasking.Debug;
  63    use System.Tasking;
  64    use Interfaces.C;
  65    use Interfaces.C.Strings;
  66    use System.OS_Interface;
  67    use System.Parameters;
  68    use System.OS_Primitives;
  69    use System.Task_Info;
  70    use System.Win32;
  71    use System.Win32.Ext;
  72
  73    pragma Link_With ("-Xlinker --stack=0x200000,0x1000");
  74    --  Change the default stack size (2 MB) for tasking programs on Windows.
  75    --  This allows about 1000 tasks running at the same time. Note that
  76    --  we set the stack size for non tasking programs on System unit.
  77    --  Also note that under Windows XP, we use a Windows XP extension to
  78    --  specify the stack size on a per task basis, as done under other OSes.
  79
  80    ---------------------
  81    -- Local Functions --
  82    ---------------------
  83
  84    procedure InitializeCriticalSection (pCriticalSection : access RTS_Lock);
  85    procedure InitializeCriticalSection
  86      (pCriticalSection : access CRITICAL_SECTION);
  87    pragma Import
  88      (Stdcall, InitializeCriticalSection, "InitializeCriticalSection");
  89
  90    procedure EnterCriticalSection (pCriticalSection : access RTS_Lock);
  91    procedure EnterCriticalSection
  92      (pCriticalSection : access CRITICAL_SECTION);
  93    pragma Import (Stdcall, EnterCriticalSection, "EnterCriticalSection");
  94
  95    procedure LeaveCriticalSection (pCriticalSection : access RTS_Lock);
  96    procedure LeaveCriticalSection (pCriticalSection : access CRITICAL_SECTION);
  97    pragma Import (Stdcall, LeaveCriticalSection, "LeaveCriticalSection");
  98
  99    procedure DeleteCriticalSection (pCriticalSection : access RTS_Lock);
 100    procedure DeleteCriticalSection
 101      (pCriticalSection : access CRITICAL_SECTION);
 102    pragma Import (Stdcall, DeleteCriticalSection, "DeleteCriticalSection");
 103
 104    ----------------
 105    -- Local Data --
 106    ----------------
 107
 108    Environment_Task_Id : Task_Id;
 109    --  A variable to hold Task_Id for the environment task
 110
 111    Single_RTS_Lock : aliased RTS_Lock;
 112    --  This is a lock to allow only one thread of control in the RTS at
 113    --  a time; it is used to execute in mutual exclusion from all other tasks.
 114    --  Used mainly in Single_Lock mode, but also to protect All_Tasks_List
 115
 116    Time_Slice_Val : Integer;
 117    pragma Import (C, Time_Slice_Val, "__gl_time_slice_val");
 118
 119    Dispatching_Policy : Character;
 120    pragma Import (C, Dispatching_Policy, "__gl_task_dispatching_policy");
 121
 122    function Get_Policy (Prio : System.Any_Priority) return Character;
 123    pragma Import (C, Get_Policy, "__gnat_get_specific_dispatching");
 124    --  Get priority specific dispatching policy
 125
 126    Foreign_Task_Elaborated : aliased Boolean := True;
 127    --  Used to identified fake tasks (i.e., non-Ada Threads)
 128
 129    Annex_D : Boolean := False;
 130    --  Set to True if running with Annex-D semantics
 131
 132    ------------------------------------
 133    -- The thread local storage index --
 134    ------------------------------------
 135
 136    TlsIndex : DWORD;
 137    pragma Export (Ada, TlsIndex);
 138    --  To ensure that this variable won't be local to this package, since
 139    --  in some cases, inlining forces this variable to be global anyway.
 140
 141    --------------------
 142    -- Local Packages --
 143    --------------------
 144
 145    package Specific is
 146
 147       function Is_Valid_Task return Boolean;
 148       pragma Inline (Is_Valid_Task);
 149       --  Does executing thread have a TCB?
 150
 151       procedure Set (Self_Id : Task_Id);
 152       pragma Inline (Set);
 153       --  Set the self id for the current task
 154
 155    end Specific;
 156
 157    package body Specific is
 158
 159       function Is_Valid_Task return Boolean is
 160       begin
 161          return TlsGetValue (TlsIndex) /= System.Null_Address;
 162       end Is_Valid_Task;
 163
 164       procedure Set (Self_Id : Task_Id) is
 165          Succeeded : BOOL;
 166       begin
 167          Succeeded := TlsSetValue (TlsIndex, To_Address (Self_Id));
 168          pragma Assert (Succeeded = Win32.TRUE);
 169       end Set;
 170
 171    end Specific;
 172
 173    ---------------------------------
 174    -- Support for foreign threads --
 175    ---------------------------------
 176
 177    function Register_Foreign_Thread (Thread : Thread_Id) return Task_Id;
 178    --  Allocate and Initialize a new ATCB for the current Thread
 179
 180    function Register_Foreign_Thread
 181      (Thread : Thread_Id) return Task_Id is separate;
 182
 183    ----------------------------------
 184    -- Condition Variable Functions --
 185    ----------------------------------
 186
 187    procedure Initialize_Cond (Cond : not null access Condition_Variable);
 188    --  Initialize given condition variable Cond
 189
 190    procedure Finalize_Cond (Cond : not null access Condition_Variable);
 191    --  Finalize given condition variable Cond
 192
 193    procedure Cond_Signal (Cond : not null access Condition_Variable);
 194    --  Signal condition variable Cond
 195
 196    procedure Cond_Wait
 197      (Cond : not null access Condition_Variable;
 198       L    : not null access RTS_Lock);
 199    --  Wait on conditional variable Cond, using lock L
 200
 201    procedure Cond_Timed_Wait
 202      (Cond      : not null access Condition_Variable;
 203       L         : not null access RTS_Lock;
 204       Rel_Time  : Duration;
 205       Timed_Out : out Boolean;
 206       Status    : out Integer);
 207    --  Do timed wait on condition variable Cond using lock L. The duration
 208    --  of the timed wait is given by Rel_Time. When the condition is
 209    --  signalled, Timed_Out shows whether or not a time out occurred.
 210    --  Status is only valid if Timed_Out is False, in which case it
 211    --  shows whether Cond_Timed_Wait completed successfully.
 212
 213    ---------------------
 214    -- Initialize_Cond --
 215    ---------------------
 216
 217    procedure Initialize_Cond (Cond : not null access Condition_Variable) is
 218       hEvent : HANDLE;
 219    begin
 220       hEvent := CreateEvent (null, Win32.TRUE, Win32.FALSE, Null_Ptr);
 221       pragma Assert (hEvent /= 0);
 222       Cond.all := Condition_Variable (hEvent);
 223    end Initialize_Cond;
 224
 225    -------------------
 226    -- Finalize_Cond --
 227    -------------------
 228
 229    --  No such problem here, DosCloseEventSem has been derived.
 230    --  What does such refer to in above comment???
 231
 232    procedure Finalize_Cond (Cond : not null access Condition_Variable) is
 233       Result : BOOL;
 234    begin
 235       Result := CloseHandle (HANDLE (Cond.all));
 236       pragma Assert (Result = Win32.TRUE);
 237    end Finalize_Cond;
 238
 239    -----------------
 240    -- Cond_Signal --
 241    -----------------
 242
 243    procedure Cond_Signal (Cond : not null access Condition_Variable) is
 244       Result : BOOL;
 245    begin
 246       Result := SetEvent (HANDLE (Cond.all));
 247       pragma Assert (Result = Win32.TRUE);
 248    end Cond_Signal;
 249
 250    ---------------
 251    -- Cond_Wait --
 252    ---------------
 253
 254    --  Pre-condition: Cond is posted
 255    --                 L is locked.
 256
 257    --  Post-condition: Cond is posted
 258    --                  L is locked.
 259
 260    procedure Cond_Wait
 261      (Cond : not null access Condition_Variable;
 262       L    : not null access RTS_Lock)
 263    is
 264       Result      : DWORD;
 265       Result_Bool : BOOL;
 266
 267    begin
 268       --  Must reset Cond BEFORE L is unlocked
 269
 270       Result_Bool := ResetEvent (HANDLE (Cond.all));
 271       pragma Assert (Result_Bool = Win32.TRUE);
 272       Unlock (L, Global_Lock => True);
 273
 274       --  No problem if we are interrupted here: if the condition is signaled,
 275       --  WaitForSingleObject will simply not block
 276
 277       Result := WaitForSingleObject (HANDLE (Cond.all), Wait_Infinite);
 278       pragma Assert (Result = 0);
 279
 280       Write_Lock (L, Global_Lock => True);
 281    end Cond_Wait;
 282
 283    ---------------------
 284    -- Cond_Timed_Wait --
 285    ---------------------
 286
 287    --  Pre-condition: Cond is posted
 288    --                 L is locked.
 289
 290    --  Post-condition: Cond is posted
 291    --                  L is locked.
 292
 293    procedure Cond_Timed_Wait
 294      (Cond      : not null access Condition_Variable;
 295       L         : not null access RTS_Lock;
 296       Rel_Time  : Duration;
 297       Timed_Out : out Boolean;
 298       Status    : out Integer)
 299    is
 300       Time_Out_Max : constant DWORD := 16#FFFF0000#;
 301       --  NT 4 can't handle excessive timeout values (e.g. DWORD'Last - 1)
 302
 303       Time_Out    : DWORD;
 304       Result      : BOOL;
 305       Wait_Result : DWORD;
 306
 307    begin
 308       --  Must reset Cond BEFORE L is unlocked
 309
 310       Result := ResetEvent (HANDLE (Cond.all));
 311       pragma Assert (Result = Win32.TRUE);
 312       Unlock (L, Global_Lock => True);
 313
 314       --  No problem if we are interrupted here: if the condition is signaled,
 315       --  WaitForSingleObject will simply not block
 316
 317       if Rel_Time <= 0.0 then
 318          Timed_Out := True;
 319          Wait_Result := 0;
 320
 321       else
 322          if Rel_Time >= Duration (Time_Out_Max) / 1000 then
 323             Time_Out := Time_Out_Max;
 324          else
 325             Time_Out := DWORD (Rel_Time * 1000);
 326          end if;
 327
 328          Wait_Result := WaitForSingleObject (HANDLE (Cond.all), Time_Out);
 329
 330          if Wait_Result = WAIT_TIMEOUT then
 331             Timed_Out := True;
 332             Wait_Result := 0;
 333          else
 334             Timed_Out := False;
 335          end if;
 336       end if;
 337
 338       Write_Lock (L, Global_Lock => True);
 339
 340       --  Ensure post-condition
 341
 342       if Timed_Out then
 343          Result := SetEvent (HANDLE (Cond.all));
 344          pragma Assert (Result = Win32.TRUE);
 345       end if;
 346
 347       Status := Integer (Wait_Result);
 348    end Cond_Timed_Wait;
 349
 350    ------------------
 351    -- Stack_Guard  --
 352    ------------------
 353
 354    --  The underlying thread system sets a guard page at the bottom of a thread
 355    --  stack, so nothing is needed.
 356    --  ??? Check the comment above
 357
 358    procedure Stack_Guard (T : ST.Task_Id; On : Boolean) is
 359       pragma Unreferenced (T, On);
 360    begin
 361       null;
 362    end Stack_Guard;
 363
 364    --------------------
 365    -- Get_Thread_Id  --
 366    --------------------
 367
 368    function Get_Thread_Id (T : ST.Task_Id) return OSI.Thread_Id is
 369    begin
 370       return T.Common.LL.Thread;
 371    end Get_Thread_Id;
 372
 373    ----------
 374    -- Self --
 375    ----------
 376
 377    function Self return Task_Id is
 378       Self_Id : constant Task_Id := To_Task_Id (TlsGetValue (TlsIndex));
 379    begin
 380       if Self_Id = null then
 381          return Register_Foreign_Thread (GetCurrentThread);
 382       else
 383          return Self_Id;
 384       end if;
 385    end Self;
 386
 387    ---------------------
 388    -- Initialize_Lock --
 389    ---------------------
 390
 391    --  Note: mutexes and cond_variables needed per-task basis are initialized
 392    --  in Initialize_TCB and the Storage_Error is handled. Other mutexes (such
 393    --  as RTS_Lock, Memory_Lock...) used in the RTS is initialized before any
 394    --  status change of RTS. Therefore raising Storage_Error in the following
 395    --  routines should be able to be handled safely.
 396
 397    procedure Initialize_Lock
 398      (Prio : System.Any_Priority;
 399       L    : not null access Lock)
 400    is
 401    begin
 402       InitializeCriticalSection (L.Mutex'Access);
 403       L.Owner_Priority := 0;
 404       L.Priority := Prio;
 405    end Initialize_Lock;
 406
 407    procedure Initialize_Lock
 408      (L : not null access RTS_Lock; Level : Lock_Level)
 409    is
 410       pragma Unreferenced (Level);
 411    begin
 412       InitializeCriticalSection (L);
 413    end Initialize_Lock;
 414
 415    -------------------
 416    -- Finalize_Lock --
 417    -------------------
 418
 419    procedure Finalize_Lock (L : not null access Lock) is
 420    begin
 421       DeleteCriticalSection (L.Mutex'Access);
 422    end Finalize_Lock;
 423
 424    procedure Finalize_Lock (L : not null access RTS_Lock) is
 425    begin
 426       DeleteCriticalSection (L);
 427    end Finalize_Lock;
 428
 429    ----------------
 430    -- Write_Lock --
 431    ----------------
 432
 433    procedure Write_Lock
 434      (L : not null access Lock; Ceiling_Violation : out Boolean) is
 435    begin
 436       L.Owner_Priority := Get_Priority (Self);
 437
 438       if L.Priority < L.Owner_Priority then
 439          Ceiling_Violation := True;
 440          return;
 441       end if;
 442
 443       EnterCriticalSection (L.Mutex'Access);
 444
 445       Ceiling_Violation := False;
 446    end Write_Lock;
 447
 448    procedure Write_Lock
 449      (L           : not null access RTS_Lock;
 450       Global_Lock : Boolean := False)
 451    is
 452    begin
 453       if not Single_Lock or else Global_Lock then
 454          EnterCriticalSection (L);
 455       end if;
 456    end Write_Lock;
 457
 458    procedure Write_Lock (T : Task_Id) is
 459    begin
 460       if not Single_Lock then
 461          EnterCriticalSection (T.Common.LL.L'Access);
 462       end if;
 463    end Write_Lock;
 464
 465    ---------------
 466    -- Read_Lock --
 467    ---------------
 468
 469    procedure Read_Lock
 470      (L : not null access Lock; Ceiling_Violation : out Boolean) is
 471    begin
 472       Write_Lock (L, Ceiling_Violation);
 473    end Read_Lock;
 474
 475    ------------
 476    -- Unlock --
 477    ------------
 478
 479    procedure Unlock (L : not null access Lock) is
 480    begin
 481       LeaveCriticalSection (L.Mutex'Access);
 482    end Unlock;
 483
 484    procedure Unlock
 485      (L : not null access RTS_Lock; Global_Lock : Boolean := False) is
 486    begin
 487       if not Single_Lock or else Global_Lock then
 488          LeaveCriticalSection (L);
 489       end if;
 490    end Unlock;
 491
 492    procedure Unlock (T : Task_Id) is
 493    begin
 494       if not Single_Lock then
 495          LeaveCriticalSection (T.Common.LL.L'Access);
 496       end if;
 497    end Unlock;
 498
 499    -----------------
 500    -- Set_Ceiling --
 501    -----------------
 502
 503    --  Dynamic priority ceilings are not supported by the underlying system
 504
 505    procedure Set_Ceiling
 506      (L    : not null access Lock;
 507       Prio : System.Any_Priority)
 508    is
 509       pragma Unreferenced (L, Prio);
 510    begin
 511       null;
 512    end Set_Ceiling;
 513
 514    -----------
 515    -- Sleep --
 516    -----------
 517
 518    procedure Sleep
 519      (Self_ID : Task_Id;
 520       Reason  : System.Tasking.Task_States)
 521    is
 522       pragma Unreferenced (Reason);
 523
 524    begin
 525       pragma Assert (Self_ID = Self);
 526
 527       if Single_Lock then
 528          Cond_Wait (Self_ID.Common.LL.CV'Access, Single_RTS_Lock'Access);
 529       else
 530          Cond_Wait (Self_ID.Common.LL.CV'Access, Self_ID.Common.LL.L'Access);
 531       end if;
 532
 533       if Self_ID.Deferral_Level = 0
 534         and then Self_ID.Pending_ATC_Level < Self_ID.ATC_Nesting_Level
 535       then
 536          Unlock (Self_ID);
 537          raise Standard'Abort_Signal;
 538       end if;
 539    end Sleep;
 540
 541    -----------------
 542    -- Timed_Sleep --
 543    -----------------
 544
 545    --  This is for use within the run-time system, so abort is assumed to be
 546    --  already deferred, and the caller should be holding its own ATCB lock.
 547
 548    procedure Timed_Sleep
 549      (Self_ID  : Task_Id;
 550       Time     : Duration;
 551       Mode     : ST.Delay_Modes;
 552       Reason   : System.Tasking.Task_States;
 553       Timedout : out Boolean;
 554       Yielded  : out Boolean)
 555    is
 556       pragma Unreferenced (Reason);
 557       Check_Time : Duration := Monotonic_Clock;
 558       Rel_Time   : Duration;
 559       Abs_Time   : Duration;
 560
 561       Result : Integer;
 562       pragma Unreferenced (Result);
 563
 564       Local_Timedout : Boolean;
 565
 566    begin
 567       Timedout := True;
 568       Yielded  := False;
 569
 570       if Mode = Relative then
 571          Rel_Time := Time;
 572          Abs_Time := Duration'Min (Time, Max_Sensible_Delay) + Check_Time;
 573       else
 574          Rel_Time := Time - Check_Time;
 575          Abs_Time := Time;
 576       end if;
 577
 578       if Rel_Time > 0.0 then
 579          loop
 580             exit when Self_ID.Pending_ATC_Level < Self_ID.ATC_Nesting_Level;
 581
 582             if Single_Lock then
 583                Cond_Timed_Wait
 584                  (Self_ID.Common.LL.CV'Access,
 585                   Single_RTS_Lock'Access,
 586                   Rel_Time, Local_Timedout, Result);
 587             else
 588                Cond_Timed_Wait
 589                  (Self_ID.Common.LL.CV'Access,
 590                   Self_ID.Common.LL.L'Access,
 591                   Rel_Time, Local_Timedout, Result);
 592             end if;
 593
 594             Check_Time := Monotonic_Clock;
 595             exit when Abs_Time <= Check_Time;
 596
 597             if not Local_Timedout then
 598
 599                --  Somebody may have called Wakeup for us
 600
 601                Timedout := False;
 602                exit;
 603             end if;
 604
 605             Rel_Time := Abs_Time - Check_Time;
 606          end loop;
 607       end if;
 608    end Timed_Sleep;
 609
 610    -----------------
 611    -- Timed_Delay --
 612    -----------------
 613
 614    procedure Timed_Delay
 615      (Self_ID : Task_Id;
 616       Time    : Duration;
 617       Mode    : ST.Delay_Modes)
 618    is
 619       Check_Time : Duration := Monotonic_Clock;
 620       Rel_Time   : Duration;
 621       Abs_Time   : Duration;
 622
 623       Timedout : Boolean;
 624       Result   : Integer;
 625       pragma Unreferenced (Timedout, Result);
 626
 627    begin
 628       if Single_Lock then
 629          Lock_RTS;
 630       end if;
 631
 632       Write_Lock (Self_ID);
 633
 634       if Mode = Relative then
 635          Rel_Time := Time;
 636          Abs_Time := Time + Check_Time;
 637       else
 638          Rel_Time := Time - Check_Time;
 639          Abs_Time := Time;
 640       end if;
 641
 642       if Rel_Time > 0.0 then
 643          Self_ID.Common.State := Delay_Sleep;
 644
 645          loop
 646             exit when Self_ID.Pending_ATC_Level < Self_ID.ATC_Nesting_Level;
 647
 648             if Single_Lock then
 649                Cond_Timed_Wait
 650                  (Self_ID.Common.LL.CV'Access,
 651                   Single_RTS_Lock'Access,
 652                   Rel_Time, Timedout, Result);
 653             else
 654                Cond_Timed_Wait
 655                  (Self_ID.Common.LL.CV'Access,
 656                   Self_ID.Common.LL.L'Access,
 657                   Rel_Time, Timedout, Result);
 658             end if;
 659
 660             Check_Time := Monotonic_Clock;
 661             exit when Abs_Time <= Check_Time;
 662
 663             Rel_Time := Abs_Time - Check_Time;
 664          end loop;
 665
 666          Self_ID.Common.State := Runnable;
 667       end if;
 668
 669       Unlock (Self_ID);
 670
 671       if Single_Lock then
 672          Unlock_RTS;
 673       end if;
 674
 675       Yield;
 676    end Timed_Delay;
 677
 678    ------------
 679    -- Wakeup --
 680    ------------
 681
 682    procedure Wakeup (T : Task_Id; Reason : System.Tasking.Task_States) is
 683       pragma Unreferenced (Reason);
 684    begin
 685       Cond_Signal (T.Common.LL.CV'Access);
 686    end Wakeup;
 687
 688    -----------
 689    -- Yield --
 690    -----------
 691
 692    procedure Yield (Do_Yield : Boolean := True) is
 693    begin
 694       if Do_Yield then
 695          SwitchToThread;
 696
 697       elsif Annex_D then
 698          --  If running with Annex-D semantics we need a delay
 699          --  above 0 milliseconds here otherwise processes give
 700          --  enough time to the other tasks to have a chance to
 701          --  run.
 702          --
 703          --  This makes cxd8002 ACATS pass on Windows.
 704
 705          Sleep (1);
 706       end if;
 707    end Yield;
 708
 709    ------------------
 710    -- Set_Priority --
 711    ------------------
 712
 713    type Prio_Array_Type is array (System.Any_Priority) of Integer;
 714    pragma Atomic_Components (Prio_Array_Type);
 715
 716    Prio_Array : Prio_Array_Type;
 717    --  Global array containing the id of the currently running task for
 718    --  each priority.
 719    --
 720    --  Note: we assume that we are on a single processor with run-til-blocked
 721    --  scheduling.
 722
 723    procedure Set_Priority
 724      (T                   : Task_Id;
 725       Prio                : System.Any_Priority;
 726       Loss_Of_Inheritance : Boolean := False)
 727    is
 728       Res        : BOOL;
 729       Array_Item : Integer;
 730
 731    begin
 732       Res := SetThreadPriority
 733         (T.Common.LL.Thread, Interfaces.C.int (Underlying_Priorities (Prio)));
 734       pragma Assert (Res = Win32.TRUE);
 735
 736       if Dispatching_Policy = 'F' or else Get_Policy (Prio) = 'F' then
 737
 738          --  Annex D requirement [RM D.2.2 par. 9]:
 739          --    If the task drops its priority due to the loss of inherited
 740          --    priority, it is added at the head of the ready queue for its
 741          --    new active priority.
 742
 743          if Loss_Of_Inheritance
 744            and then Prio < T.Common.Current_Priority
 745          then
 746             Array_Item := Prio_Array (T.Common.Base_Priority) + 1;
 747             Prio_Array (T.Common.Base_Priority) := Array_Item;
 748
 749             loop
 750                --  Let some processes a chance to arrive
 751
 752                Yield;
 753
 754                --  Then wait for our turn to proceed
 755
 756                exit when Array_Item = Prio_Array (T.Common.Base_Priority)
 757                  or else Prio_Array (T.Common.Base_Priority) = 1;
 758             end loop;
 759
 760             Prio_Array (T.Common.Base_Priority) :=
 761               Prio_Array (T.Common.Base_Priority) - 1;
 762          end if;
 763       end if;
 764
 765       T.Common.Current_Priority := Prio;
 766    end Set_Priority;
 767
 768    ------------------
 769    -- Get_Priority --
 770    ------------------
 771
 772    function Get_Priority (T : Task_Id) return System.Any_Priority is
 773    begin
 774       return T.Common.Current_Priority;
 775    end Get_Priority;
 776
 777    ----------------
 778    -- Enter_Task --
 779    ----------------
 780
 781    --  There were two paths were we needed to call Enter_Task :
 782    --  1) from System.Task_Primitives.Operations.Initialize
 783    --  2) from System.Tasking.Stages.Task_Wrapper
 784
 785    --  The thread initialisation has to be done only for the first case
 786
 787    --  This is because the GetCurrentThread NT call does not return the real
 788    --  thread handler but only a "pseudo" one. It is not possible to release
 789    --  the thread handle and free the system resources from this "pseudo"
 790    --  handle. So we really want to keep the real thread handle set in
 791    --  System.Task_Primitives.Operations.Create_Task during thread creation.
 792
 793    procedure Enter_Task (Self_ID : Task_Id) is
 794       procedure Init_Float;
 795       pragma Import (C, Init_Float, "__gnat_init_float");
 796       --  Properly initializes the FPU for x86 systems
 797
 798    begin
 799       Specific.Set (Self_ID);
 800       Init_Float;
 801
 802       if Self_ID.Common.Task_Info /= null
 803         and then
 804           Self_ID.Common.Task_Info.CPU >= CPU_Number (Number_Of_Processors)
 805       then
 806          raise Invalid_CPU_Number;
 807       end if;
 808
 809       Self_ID.Common.LL.Thread_Id := GetCurrentThreadId;
 810    end Enter_Task;
 811
 812    --------------
 813    -- New_ATCB --
 814    --------------
 815
 816    function New_ATCB (Entry_Num : Task_Entry_Index) return Task_Id is
 817    begin
 818       return new Ada_Task_Control_Block (Entry_Num);
 819    end New_ATCB;
 820
 821    -------------------
 822    -- Is_Valid_Task --
 823    -------------------
 824
 825    function Is_Valid_Task return Boolean renames Specific.Is_Valid_Task;
 826
 827    -----------------------------
 828    -- Register_Foreign_Thread --
 829    -----------------------------
 830
 831    function Register_Foreign_Thread return Task_Id is
 832    begin
 833       if Is_Valid_Task then
 834          return Self;
 835       else
 836          return Register_Foreign_Thread (GetCurrentThread);
 837       end if;
 838    end Register_Foreign_Thread;
 839
 840    --------------------
 841    -- Initialize_TCB --
 842    --------------------
 843
 844    procedure Initialize_TCB (Self_ID : Task_Id; Succeeded : out Boolean) is
 845    begin
 846       --  Initialize thread ID to 0, this is needed to detect threads that
 847       --  are not yet activated.
 848
 849       Self_ID.Common.LL.Thread := 0;
 850
 851       Initialize_Cond (Self_ID.Common.LL.CV'Access);
 852
 853       if not Single_Lock then
 854          Initialize_Lock (Self_ID.Common.LL.L'Access, ATCB_Level);
 855       end if;
 856
 857       Succeeded := True;
 858    end Initialize_TCB;
 859
 860    -----------------
 861    -- Create_Task --
 862    -----------------
 863
 864    procedure Create_Task
 865      (T          : Task_Id;
 866       Wrapper    : System.Address;
 867       Stack_Size : System.Parameters.Size_Type;
 868       Priority   : System.Any_Priority;
 869       Succeeded  : out Boolean)
 870    is
 871       Initial_Stack_Size : constant := 1024;
 872       --  We set the initial stack size to 1024. On Windows version prior to XP
 873       --  there is no way to fix a task stack size. Only the initial stack size
 874       --  can be set, the operating system will raise the task stack size if
 875       --  needed.
 876
 877       function Is_Windows_XP return Integer;
 878       pragma Import (C, Is_Windows_XP, "__gnat_is_windows_xp");
 879       --  Returns 1 if running on Windows XP
 880
 881       hTask          : HANDLE;
 882       TaskId         : aliased DWORD;
 883       pTaskParameter : Win32.PVOID;
 884       Result         : DWORD;
 885       Entry_Point    : PTHREAD_START_ROUTINE;
 886
 887    begin
 888       pTaskParameter := To_Address (T);
 889
 890       Entry_Point := To_PTHREAD_START_ROUTINE (Wrapper);
 891
 892       if Is_Windows_XP = 1 then
 893          hTask := CreateThread
 894            (null,
 895             DWORD (Stack_Size),
 896             Entry_Point,
 897             pTaskParameter,
 898             DWORD (Create_Suspended) or
 899               DWORD (Stack_Size_Param_Is_A_Reservation),
 900             TaskId'Unchecked_Access);
 901       else
 902          hTask := CreateThread
 903            (null,
 904             Initial_Stack_Size,
 905             Entry_Point,
 906             pTaskParameter,
 907             DWORD (Create_Suspended),
 908             TaskId'Unchecked_Access);
 909       end if;
 910
 911       --  Step 1: Create the thread in blocked mode
 912
 913       if hTask = 0 then
 914          Succeeded := False;
 915          return;
 916       end if;
 917
 918       --  Step 2: set its TCB
 919
 920       T.Common.LL.Thread := hTask;
 921
 922       --  Step 3: set its priority (child has inherited priority from parent)
 923
 924       Set_Priority (T, Priority);
 925
 926       if Time_Slice_Val = 0
 927         or else Dispatching_Policy = 'F'
 928         or else Get_Policy (Priority) = 'F'
 929       then
 930          --  Here we need Annex D semantics so we disable the NT priority
 931          --  boost. A priority boost is temporarily given by the system to a
 932          --  thread when it is taken out of a wait state.
 933
 934          SetThreadPriorityBoost (hTask, DisablePriorityBoost => Win32.TRUE);
 935       end if;
 936
 937       --  Step 4: Handle Task_Info
 938
 939       if T.Common.Task_Info /= null then
 940          if T.Common.Task_Info.CPU /= Task_Info.Any_CPU then
 941             Result := SetThreadIdealProcessor (hTask, T.Common.Task_Info.CPU);
 942             pragma Assert (Result = 1);
 943          end if;
 944       end if;
 945
 946       --  Step 5: Now, start it for good:
 947
 948       Result := ResumeThread (hTask);
 949       pragma Assert (Result = 1);
 950
 951       Succeeded := Result = 1;
 952    end Create_Task;
 953
 954    ------------------
 955    -- Finalize_TCB --
 956    ------------------
 957
 958    procedure Finalize_TCB (T : Task_Id) is
 959       Self_ID   : Task_Id := T;
 960       Result    : DWORD;
 961       Succeeded : BOOL;
 962       Is_Self   : constant Boolean := T = Self;
 963
 964       procedure Free is new
 965         Ada.Unchecked_Deallocation (Ada_Task_Control_Block, Task_Id);
 966
 967    begin
 968       if not Single_Lock then
 969          Finalize_Lock (T.Common.LL.L'Access);
 970       end if;
 971
 972       Finalize_Cond (T.Common.LL.CV'Access);
 973
 974       if T.Known_Tasks_Index /= -1 then
 975          Known_Tasks (T.Known_Tasks_Index) := null;
 976       end if;
 977
 978       if Self_ID.Common.LL.Thread /= 0 then
 979
 980          --  This task has been activated. Wait for the thread to terminate
 981          --  then close it. This is needed to release system resources.
 982
 983          Result := WaitForSingleObject (T.Common.LL.Thread, Wait_Infinite);
 984          pragma Assert (Result /= WAIT_FAILED);
 985          Succeeded := CloseHandle (T.Common.LL.Thread);
 986          pragma Assert (Succeeded = Win32.TRUE);
 987       end if;
 988
 989       Free (Self_ID);
 990
 991       if Is_Self then
 992          Specific.Set (null);
 993       end if;
 994    end Finalize_TCB;
 995
 996    ---------------
 997    -- Exit_Task --
 998    ---------------
 999
1000    procedure Exit_Task is
1001    begin
1002       Specific.Set (null);
1003    end Exit_Task;
1004
1005    ----------------
1006    -- Abort_Task --
1007    ----------------
1008
1009    procedure Abort_Task (T : Task_Id) is
1010       pragma Unreferenced (T);
1011    begin
1012       null;
1013    end Abort_Task;
1014
1015    ----------------------
1016    -- Environment_Task --
1017    ----------------------
1018
1019    function Environment_Task return Task_Id is
1020    begin
1021       return Environment_Task_Id;
1022    end Environment_Task;
1023
1024    --------------
1025    -- Lock_RTS --
1026    --------------
1027
1028    procedure Lock_RTS is
1029    begin
1030       Write_Lock (Single_RTS_Lock'Access, Global_Lock => True);
1031    end Lock_RTS;
1032
1033    ----------------
1034    -- Unlock_RTS --
1035    ----------------
1036
1037    procedure Unlock_RTS is
1038    begin
1039       Unlock (Single_RTS_Lock'Access, Global_Lock => True);
1040    end Unlock_RTS;
1041
1042    ----------------
1043    -- Initialize --
1044    ----------------
1045
1046    procedure Initialize (Environment_Task : Task_Id) is
1047       Discard : BOOL;
1048       pragma Unreferenced (Discard);
1049
1050    begin
1051       Environment_Task_Id := Environment_Task;
1052       OS_Primitives.Initialize;
1053       Interrupt_Management.Initialize;
1054
1055       if Time_Slice_Val = 0 or else Dispatching_Policy = 'F' then
1056          --  Here we need Annex D semantics, switch the current process to the
1057          --  Realtime_Priority_Class.
1058
1059          Discard := OS_Interface.SetPriorityClass
1060                       (GetCurrentProcess, Realtime_Priority_Class);
1061
1062          Annex_D := True;
1063       end if;
1064
1065       TlsIndex := TlsAlloc;
1066
1067       --  Initialize the lock used to synchronize chain of all ATCBs
1068
1069       Initialize_Lock (Single_RTS_Lock'Access, RTS_Lock_Level);
1070
1071       Environment_Task.Common.LL.Thread := GetCurrentThread;
1072
1073       --  Make environment task known here because it doesn't go through
1074       --  Activate_Tasks, which does it for all other tasks.
1075
1076       Known_Tasks (Known_Tasks'First) := Environment_Task;
1077       Environment_Task.Known_Tasks_Index := Known_Tasks'First;
1078
1079       Enter_Task (Environment_Task);
1080    end Initialize;
1081
1082    ---------------------
1083    -- Monotonic_Clock --
1084    ---------------------
1085
1086    function Monotonic_Clock return Duration
1087      renames System.OS_Primitives.Monotonic_Clock;
1088
1089    -------------------
1090    -- RT_Resolution --
1091    -------------------
1092
1093    function RT_Resolution return Duration is
1094    begin
1095       return 0.000_001; --  1 micro-second
1096    end RT_Resolution;
1097
1098    ----------------
1099    -- Initialize --
1100    ----------------
1101
1102    procedure Initialize (S : in out Suspension_Object) is
1103    begin
1104       --  Initialize internal state. It is always initialized to False (ARM
1105       --  D.10 par. 6).
1106
1107       S.State := False;
1108       S.Waiting := False;
1109
1110       --  Initialize internal mutex
1111
1112       InitializeCriticalSection (S.L'Access);
1113
1114       --  Initialize internal condition variable
1115
1116       S.CV := CreateEvent (null, Win32.TRUE, Win32.FALSE, Null_Ptr);
1117       pragma Assert (S.CV /= 0);
1118    end Initialize;
1119
1120    --------------
1121    -- Finalize --
1122    --------------
1123
1124    procedure Finalize (S : in out Suspension_Object) is
1125       Result : BOOL;
1126    begin
1127       --  Destroy internal mutex
1128
1129       DeleteCriticalSection (S.L'Access);
1130
1131       --  Destroy internal condition variable
1132
1133       Result := CloseHandle (S.CV);
1134       pragma Assert (Result = Win32.TRUE);
1135    end Finalize;
1136
1137    -------------------
1138    -- Current_State --
1139    -------------------
1140
1141    function Current_State (S : Suspension_Object) return Boolean is
1142    begin
1143       --  We do not want to use lock on this read operation. State is marked
1144       --  as Atomic so that we ensure that the value retrieved is correct.
1145
1146       return S.State;
1147    end Current_State;
1148
1149    ---------------
1150    -- Set_False --
1151    ---------------
1152
1153    procedure Set_False (S : in out Suspension_Object) is
1154    begin
1155       SSL.Abort_Defer.all;
1156
1157       EnterCriticalSection (S.L'Access);
1158
1159       S.State := False;
1160
1161       LeaveCriticalSection (S.L'Access);
1162
1163       SSL.Abort_Undefer.all;
1164    end Set_False;
1165
1166    --------------
1167    -- Set_True --
1168    --------------
1169
1170    procedure Set_True (S : in out Suspension_Object) is
1171       Result : BOOL;
1172    begin
1173       SSL.Abort_Defer.all;
1174
1175       EnterCriticalSection (S.L'Access);
1176
1177       --  If there is already a task waiting on this suspension object then
1178       --  we resume it, leaving the state of the suspension object to False,
1179       --  as it is specified in ARM D.10 par. 9. Otherwise, it just leaves
1180       --  the state to True.
1181
1182       if S.Waiting then
1183          S.Waiting := False;
1184          S.State := False;
1185
1186          Result := SetEvent (S.CV);
1187          pragma Assert (Result = Win32.TRUE);
1188       else
1189          S.State := True;
1190       end if;
1191
1192       LeaveCriticalSection (S.L'Access);
1193
1194       SSL.Abort_Undefer.all;
1195    end Set_True;
1196
1197    ------------------------
1198    -- Suspend_Until_True --
1199    ------------------------
1200
1201    procedure Suspend_Until_True (S : in out Suspension_Object) is
1202       Result      : DWORD;
1203       Result_Bool : BOOL;
1204    begin
1205       SSL.Abort_Defer.all;
1206
1207       EnterCriticalSection (S.L'Access);
1208
1209       if S.Waiting then
1210          --  Program_Error must be raised upon calling Suspend_Until_True
1211          --  if another task is already waiting on that suspension object
1212          --  (ARM D.10 par. 10).
1213
1214          LeaveCriticalSection (S.L'Access);
1215
1216          SSL.Abort_Undefer.all;
1217
1218          raise Program_Error;
1219       else
1220          --  Suspend the task if the state is False. Otherwise, the task
1221          --  continues its execution, and the state of the suspension object
1222          --  is set to False (ARM D.10 par. 9).
1223
1224          if S.State then
1225             S.State := False;
1226
1227             LeaveCriticalSection (S.L'Access);
1228
1229             SSL.Abort_Undefer.all;
1230          else
1231             S.Waiting := True;
1232
1233             --  Must reset CV BEFORE L is unlocked
1234
1235             Result_Bool := ResetEvent (S.CV);
1236             pragma Assert (Result_Bool = Win32.TRUE);
1237
1238             LeaveCriticalSection (S.L'Access);
1239
1240             SSL.Abort_Undefer.all;
1241
1242             Result := WaitForSingleObject (S.CV, Wait_Infinite);
1243             pragma Assert (Result = 0);
1244          end if;
1245       end if;
1246    end Suspend_Until_True;
1247
1248    ----------------
1249    -- Check_Exit --
1250    ----------------
1251
1252    --  Dummy versions.  The only currently working versions is for solaris
1253    --  (native).
1254
1255    function Check_Exit (Self_ID : ST.Task_Id) return Boolean is
1256       pragma Unreferenced (Self_ID);
1257    begin
1258       return True;
1259    end Check_Exit;
1260
1261    --------------------
1262    -- Check_No_Locks --
1263    --------------------
1264
1265    function Check_No_Locks (Self_ID : ST.Task_Id) return Boolean is
1266       pragma Unreferenced (Self_ID);
1267    begin
1268       return True;
1269    end Check_No_Locks;
1270
1271    ------------------
1272    -- Suspend_Task --
1273    ------------------
1274
1275    function Suspend_Task
1276      (T           : ST.Task_Id;
1277       Thread_Self : Thread_Id) return Boolean
1278    is
1279    begin
1280       if T.Common.LL.Thread /= Thread_Self then
1281          return SuspendThread (T.Common.LL.Thread) = NO_ERROR;
1282       else
1283          return True;
1284       end if;
1285    end Suspend_Task;
1286
1287    -----------------
1288    -- Resume_Task --
1289    -----------------
1290
1291    function Resume_Task
1292      (T           : ST.Task_Id;
1293       Thread_Self : Thread_Id) return Boolean
1294    is
1295    begin
1296       if T.Common.LL.Thread /= Thread_Self then
1297          return ResumeThread (T.Common.LL.Thread) = NO_ERROR;
1298       else
1299          return True;
1300       end if;
1301    end Resume_Task;
1302
1303    --------------------
1304    -- Stop_All_Tasks --
1305    --------------------
1306
1307    procedure Stop_All_Tasks is
1308    begin
1309       null;
1310    end Stop_All_Tasks;
1311
1312    ---------------
1313    -- Stop_Task --
1314    ---------------
1315
1316    function Stop_Task (T : ST.Task_Id) return Boolean is
1317       pragma Unreferenced (T);
1318    begin
1319       return False;
1320    end Stop_Task;
1321
1322    -------------------
1323    -- Continue_Task --
1324    -------------------
1325
1326    function Continue_Task (T : ST.Task_Id) return Boolean is
1327       pragma Unreferenced (T);
1328    begin
1329       return False;
1330    end Continue_Task;
1331
1332 end System.Task_Primitives.Operations;