gcc/ada/a-nudira.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --         A D A . N U M E R I C S . D I S C R E T E _ R A N D O M          --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 --                                                                          --
  31 -- GNAT was originally developed  by the GNAT team at  New York University. --
  32 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  33 --                                                                          --
  34 ------------------------------------------------------------------------------
  35
  36 --  Note: the implementation used in this package was contributed by Robert
  37 --  Eachus. It is based on the work of L. Blum, M. Blum, and M. Shub, SIAM
  38 --  Journal of Computing, Vol 15. No 2, May 1986. The particular choices for P
  39 --  and Q chosen here guarantee a period of 562,085,314,430,582 (about 2**49),
  40 --  and the generated sequence has excellent randomness properties. For further
  41 --  details, see the paper "Fast Generation of Trustworthy Random Numbers", by
  42 --  Robert Eachus, which describes both the algorithm and the efficient
  43 --  implementation approach used here.
  44
  45 with Interfaces;
  46
  47 generic
  48    type Result_Subtype is (<>);
  49
  50 package Ada.Numerics.Discrete_Random is
  51
  52    --  The algorithm used here is reliable from a required statistical point of
  53    --  view only up to 48 bits. We try to behave reasonably in the case of
  54    --  larger types, but we can't guarantee the required properties. So
  55    --  generate a warning for these (slightly) dubious cases.
  56
  57    pragma Compile_Time_Warning
  58      (Result_Subtype'Size > 48,
  59       "statistical properties not guaranteed for size > 48");
  60
  61    --  Basic facilities
  62
  63    type Generator is limited private;
  64
  65    function Random (Gen : Generator) return Result_Subtype;
  66
  67    procedure Reset (Gen : Generator);
  68    procedure Reset (Gen : Generator; Initiator : Integer);
  69
  70    --  Advanced facilities
  71
  72    type State is private;
  73
  74    procedure Save  (Gen : Generator; To_State   : out State);
  75    procedure Reset (Gen : Generator; From_State : State);
  76
  77    Max_Image_Width : constant := 80;
  78
  79    function Image (Of_State    : State)  return String;
  80    function Value (Coded_State : String) return State;
  81
  82 private
  83    subtype Int is Interfaces.Integer_32;
  84    subtype Rst is Result_Subtype;
  85
  86    --  We prefer to use 14 digits for Flt, but some targets are more limited
  87
  88    type Flt is digits Positive'Min (14, Long_Long_Float'Digits);
  89
  90    RstF : constant Flt := Flt (Rst'Pos (Rst'First));
  91    RstL : constant Flt := Flt (Rst'Pos (Rst'Last));
  92
  93    Offs : constant Flt := RstF - 0.5;
  94
  95    K1   : constant := 94_833_359;
  96    K1F  : constant := 94_833_359.0;
  97    K2   : constant := 47_416_679;
  98    K2F  : constant := 47_416_679.0;
  99    Scal : constant Flt := (RstL - RstF + 1.0) / (K1F * K2F);
 100
 101    type State is record
 102       X1  : Int := Int (2999 ** 2);
 103       X2  : Int := Int (1439 ** 2);
 104       P   : Int := K1;
 105       Q   : Int := K2;
 106       FP  : Flt := K1F;
 107       Scl : Flt := Scal;
 108    end record;
 109
 110    type Generator is limited record
 111       Gen_State : State;
 112    end record;
 113
 114 end Ada.Numerics.Discrete_Random;