libcpp/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT(cpplib, [ ], gcc-bugs@gcc.gnu.org, cpplib)
   6 AC_CONFIG_SRCDIR(ucnid.h)
   7 AC_CONFIG_MACRO_DIR(../config)
   8 AC_CANONICAL_SYSTEM
   9
  10 # Checks for programs.
  11 AC_PROG_MAKE_SET
  12 AC_PROG_INSTALL
  13 AC_PROG_CC
  14 AC_PROG_RANLIB
  15
  16 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
  17 AC_CHECK_PROGS([ACLOCAL], [aclocal], [$MISSING aclocal])
  18 AC_CHECK_PROGS([AUTOCONF], [autoconf], [$MISSING autoconf])
  19 AC_CHECK_PROGS([AUTOHEADER], [autoheader], [$MISSING autoheader])
  20
  21 # Figure out what compiler warnings we can enable.
  22 # See config/warnings.m4 for details.
  23
  24 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
  25                           -Wmissing-prototypes -Wold-style-definition])
  26 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long])
  27
  28 # Only enable with --enable-werror-always until existing warnings are
  29 # corrected.
  30 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual])
  31
  32 # Checks for header files.
  33 AC_HEADER_TIME
  34 ACX_HEADER_STRING
  35 AC_CHECK_HEADERS(iconv.h locale.h fcntl.h limits.h stddef.h \
  36         stdlib.h strings.h string.h sys/file.h unistd.h)
  37
  38 # Checks for typedefs, structures, and compiler characteristics.
  39 AC_C_CONST
  40 AC_C_INLINE
  41 AC_FUNC_OBSTACK
  42 AC_TYPE_OFF_T
  43 AC_TYPE_SIZE_T
  44 AC_STRUCT_TM
  45 AC_CHECK_SIZEOF(int)
  46 AC_CHECK_SIZEOF(long)
  47 define(libcpp_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
  48   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
  49   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
  50   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
  51   putchar_unlocked putc_unlocked)
  52 AC_CHECK_FUNCS(libcpp_UNLOCKED_FUNCS)
  53 AC_CHECK_DECLS(m4_split(m4_normalize(abort asprintf basename errno getopt \
  54   libcpp_UNLOCKED_FUNCS vasprintf)))
  55
  56 # Checks for library functions.
  57 AC_FUNC_ALLOCA
  58 AC_HEADER_STDC
  59 AM_LANGINFO_CODESET
  60 ZW_GNU_GETTEXT_SISTER_DIR
  61
  62 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
  63 [AC_TRY_COMPILE([
  64 #include <sys/types.h>
  65 ],
  66 [if ((uchar *)0) return 0;
  67  if (sizeof(uchar)) return 0;],
  68 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
  69 if test $ac_cv_type_uchar = yes; then
  70   AC_DEFINE(HAVE_UCHAR, 1,
  71   [Define if <sys/types.h> defines \`uchar'.])
  72 fi
  73
  74 AM_ICONV
  75
  76 # More defines and substitutions.
  77 PACKAGE="$PACKAGE_TARNAME"
  78 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Define to the name of this package.])
  79 AC_SUBST(PACKAGE)
  80
  81 if test "x$enable_nls" != xno; then
  82   USED_CATALOGS='$(CATALOGS)'
  83 else
  84   USED_CATALOGS=
  85 fi
  86 AC_SUBST(USED_CATALOGS)
  87
  88 AC_ARG_ENABLE(maintainer-mode,
  89 [  --enable-maintainer-mode enable rules only needed by maintainers],,
  90 enable_maintainer_mode=no)
  91
  92 if test "x$enable_maintainer_mode" = xno; then
  93   MAINT='#'
  94 else
  95   MAINT=
  96 fi
  97 AC_SUBST(MAINT)
  98
  99 AC_ARG_ENABLE(checking,
 100 [  --enable-checking      enable expensive run-time checks],,
 101 enable_checking=no)
 102
 103 if test $enable_checking != no ; then
 104   AC_DEFINE(ENABLE_CHECKING, 1,
 105 [Define if you want more run-time sanity checks.])
 106 fi
 107
 108 m4_changequote(,)
 109 case $target in
 110         alpha*-*-* | \
 111         arm*-*-eabi* | \
 112         arm*-*-symbianelf* | \
 113         x86_64-*-* | \
 114         ia64-*-* | \
 115         hppa*64*-*-* | parisc*64*-*-* | \
 116         i[34567]86-*-solaris2.1[0-9]* | \
 117         mips*-*-* | \
 118         mmix-*-* | \
 119         powerpc*-*-* | \
 120         rs6000*-*-* | \
 121         s390*-*-* | \
 122         sparc64*-*-* | ultrasparc-*-freebsd* | \
 123         sparcv9-*-solaris2* | \
 124         sparc-*-solaris2.[789] | sparc-*-solaris2.1[0-9]* | \
 125         sh[123456789l]*-*-*)
 126                 need_64bit_hwint=yes ;;
 127         *)
 128                 need_64bit_hwint=no ;;
 129 esac
 130
 131 case $need_64bit_hwint:$ac_cv_sizeof_long in
 132         *:8 | no:*) host_wide_int=long ;;
 133         *) host_wide_int='long long' ;;
 134 esac
 135 m4_changequote([,])
 136
 137 AC_DEFINE_UNQUOTED(HOST_WIDE_INT, $host_wide_int,
 138 [Define to the widest efficient host integer type at least
 139    as wide as the target's size_t type.])
 140
 141 # Output.
 142
 143 AC_CONFIG_HEADERS(config.h:config.in, [echo timestamp > stamp-h1])
 144 AC_CONFIG_FILES(Makefile)
 145 AC_OUTPUT