gcc/opt-functions.awk

   1 #  Copyright (C) 2003-2018 Free Software Foundation, Inc.
   2 #  Contributed by Kelley Cook, June 2004.
   3 #  Original code from Neil Booth, May 2003.
   4 #
   5 # This program is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by the
   7 # Free Software Foundation; either version 3, or (at your option) any
   8 # later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 # Some common subroutines for use by opt[ch]-gen.awk.
  20
  21 # Define some helpful character classes, for portability.
  22 BEGIN {
  23         lower = "abcdefghijklmnopqrstuvwxyz"
  24         upper = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
  25         digit = "0123456789"
  26         alnum = lower "" upper "" digit
  27 }
  28
  29 # Return nonzero if FLAGS contains a flag matching REGEX.
  30 function flag_set_p(regex, flags)
  31 {
  32     # Ignore the arguments of flags with arguments.
  33     gsub ("\\([^)]+\\)", "", flags);
  34     return (" " flags " ") ~ (" " regex " ")
  35 }
  36
  37 # Return STRING if FLAGS contains a flag matching regexp REGEX,
  38 # otherwise return the empty string.
  39 function test_flag(regex, flags, string)
  40 {
  41         if (flag_set_p(regex, flags))
  42                 return string
  43         return ""
  44 }
  45
  46 # Return a field initializer, with trailing comma, for a field that is
  47 # 1 if FLAGS contains a flag matching REGEX and 0 otherwise.
  48 function flag_init(regex, flags)
  49 {
  50         if (flag_set_p(regex, flags))
  51                 return "1 /* " regex " */, "
  52         else
  53                 return "0, "
  54 }
  55
  56 # If FLAGS contains a "NAME(...argument...)" flag, return the value
  57 # of the argument.  Return the empty string otherwise.
  58 function opt_args(name, flags)
  59 {
  60         flags = " " flags
  61         if (flags !~ " " name "\\(")
  62                 return ""
  63         sub(".* " name "\\(", "", flags)
  64         if (flags ~ "^[{]")
  65         {
  66                 sub ("^[{]", "", flags)
  67                 sub ("}\\).*", "", flags)
  68         }
  69         else
  70                 sub("\\).*", "", flags)
  71
  72         return flags
  73 }
  74
  75 # Return the Nth comma-separated element of S.  Return the empty string
  76 # if S does not contain N elements.
  77 function nth_arg(n, s)
  78 {
  79         while (n-- > 0) {
  80                 if (s !~ ",")
  81                         return ""
  82                 sub("[^,]*, *", "", s)
  83         }
  84         sub(",.*", "", s)
  85         return s
  86 }
  87
  88 # Return a bitmask of CL_* values for option flags FLAGS.
  89 function switch_flags (flags)
  90 {
  91         result = "0"
  92         for (j = 0; j < n_langs; j++) {
  93                 regex = langs[j]
  94                 gsub ( "\\+", "\\+", regex )
  95                 result = result test_flag(regex, flags, " | " macros[j])
  96         }
  97         result = result \
  98           test_flag("Common", flags, " | CL_COMMON") \
  99           test_flag("Target", flags, " | CL_TARGET") \
 100           test_flag("PchIgnore", flags, " | CL_PCH_IGNORE") \
 101           test_flag("Driver", flags, " | CL_DRIVER") \
 102           test_flag("Joined", flags, " | CL_JOINED") \
 103           test_flag("JoinedOrMissing", flags, " | CL_JOINED") \
 104           test_flag("Separate", flags, " | CL_SEPARATE") \
 105           test_flag("Undocumented", flags,  " | CL_UNDOCUMENTED") \
 106           test_flag("NoDWARFRecord", flags,  " | CL_NO_DWARF_RECORD") \
 107           test_flag("Warning", flags,  " | CL_WARNING") \
 108           test_flag("(Optimization|PerFunction)", flags,  " | CL_OPTIMIZATION")
 109         sub( "^0 \\| ", "", result )
 110         return result
 111 }
 112
 113 # Return bit-field initializers for option flags FLAGS.
 114 function switch_bit_fields (flags)
 115 {
 116         vn = var_name(flags);
 117         if (host_wide_int[vn] == "yes")
 118                 hwi = "Host_Wide_Int"
 119         else
 120                 hwi = ""
 121         result = ""
 122         sep_args = opt_args("Args", flags)
 123         if (sep_args == "")
 124                 sep_args = 0
 125         else
 126                 sep_args--
 127         result = result sep_args ", "
 128
 129         result = result \
 130           flag_init("SeparateAlias", flags) \
 131           flag_init("NegativeAlias", flags) \
 132           flag_init("NoDriverArg", flags) \
 133           flag_init("RejectDriver", flags) \
 134           flag_init("RejectNegative", flags) \
 135           flag_init("JoinedOrMissing", flags) \
 136           flag_init("UInteger", flags) \
 137           flag_init("Host_Wide_Int", hwi) \
 138           flag_init("ToLower", flags) \
 139           flag_init("Report", flags) \
 140           flag_init("Deprecated", flags)
 141
 142         sub(", $", "", result)
 143         return result
 144 }
 145
 146 # If FLAGS includes a Var flag, return the name of the variable it specifies.
 147 # Return the empty string otherwise.
 148 function var_name(flags)
 149 {
 150         return nth_arg(0, opt_args("Var", flags))
 151 }
 152
 153 # Return the name of the variable if FLAGS has a HOST_WIDE_INT variable.
 154 # Return the empty string otherwise.
 155 function host_wide_int_var_name(flags)
 156 {
 157         split (flags, array, "[ \t]+")
 158         if (array[1] == "HOST_WIDE_INT")
 159                 return array[2]
 160         else
 161                 return ""
 162 }
 163
 164 # Return true if the option described by FLAGS has a globally-visible state.
 165 function global_state_p(flags)
 166 {
 167         return (var_name(flags) != "" \
 168                 || opt_args("Mask", flags) != "" \
 169                 || opt_args("InverseMask", flags) != "")
 170 }
 171
 172 # Return true if the option described by FLAGS must have some state
 173 # associated with it.
 174 function needs_state_p(flags)
 175 {
 176         return (flag_set_p("Target", flags) \
 177                 && !flag_set_p("Alias.*", flags) \
 178                 && !flag_set_p("Ignore", flags))
 179 }
 180
 181 # If FLAGS describes an option that needs state without a public
 182 # variable name, return the name of that field, minus the initial
 183 # "x_", otherwise return "".  NAME is the name of the option.
 184 function static_var(name, flags)
 185 {
 186         if (global_state_p(flags) || !needs_state_p(flags))
 187                 return ""
 188         gsub ("[^" alnum "]", "_", name)
 189         return "VAR_" name
 190 }
 191
 192 # Return the type of variable that should be associated with the given flags.
 193 function var_type(flags)
 194 {
 195         if (flag_set_p("Defer", flags))
 196                 return "void *"
 197         else if (flag_set_p("Enum.*", flags)) {
 198                 en = opt_args("Enum", flags);
 199                 return enum_type[en] " "
 200         }
 201         else if (!flag_set_p("Joined.*", flags) && !flag_set_p("Separate", flags))
 202                 return "int "
 203         else if (flag_set_p("UInteger", flags))
 204                 return "int "
 205         else
 206                 return "const char *"
 207 }
 208
 209 # Return the type of variable that should be associated with the given flags
 210 # for use within a structure.  Simple variables are changed to signed char
 211 # type instead of int to save space.
 212 function var_type_struct(flags)
 213 {
 214         if (flag_set_p("UInteger", flags))
 215                 return "int "
 216         else if (flag_set_p("Enum.*", flags)) {
 217                 en = opt_args("Enum", flags);
 218                 return enum_type[en] " "
 219         }
 220         else if (!flag_set_p("Joined.*", flags) && !flag_set_p("Separate", flags)) {
 221                 if (flag_set_p(".*Mask.*", flags)) {
 222                         if (host_wide_int[var_name(flags)] == "yes")
 223                                 return "HOST_WIDE_INT "
 224                         else
 225                                 return "int "
 226                 }
 227                 else
 228                         return "signed char "
 229         }
 230         else
 231                 return "const char *"
 232 }
 233
 234 # Given that an option has flags FLAGS, return an initializer for the
 235 # "var_enum", "var_type" and "var_value" fields of its cl_options[] entry.
 236 function var_set(flags)
 237 {
 238         if (flag_set_p("Defer", flags))
 239                 return "0, CLVC_DEFER, 0"
 240         s = nth_arg(1, opt_args("Var", flags))
 241         if (s != "")
 242                 return "0, CLVC_EQUAL, " s
 243         s = opt_args("Mask", flags);
 244         if (s != "") {
 245                 vn = var_name(flags);
 246                 if (vn)
 247                         return "0, CLVC_BIT_SET, OPTION_MASK_" s
 248                 else
 249                         return "0, CLVC_BIT_SET, MASK_" s
 250         }
 251         s = nth_arg(0, opt_args("InverseMask", flags));
 252         if (s != "") {
 253                 vn = var_name(flags);
 254                 if (vn)
 255                         return "0, CLVC_BIT_CLEAR, OPTION_MASK_" s
 256                 else
 257                         return "0, CLVC_BIT_CLEAR, MASK_" s
 258         }
 259         if (flag_set_p("Enum.*", flags)) {
 260                 en = opt_args("Enum", flags);
 261                 return enum_index[en] ", CLVC_ENUM, 0"
 262         }
 263         if (var_type(flags) == "const char *")
 264                 return "0, CLVC_STRING, 0"
 265         return "0, CLVC_BOOLEAN, 0"
 266 }
 267
 268 # Given that an option called NAME has flags FLAGS, return an initializer
 269 # for the "flag_var" field of its cl_options[] entry.
 270 function var_ref(name, flags)
 271 {
 272         name = var_name(flags) static_var(name, flags)
 273         if (name != "")
 274                 return "offsetof (struct gcc_options, x_" name ")"
 275         if (opt_args("Mask", flags) != "")
 276                 return "offsetof (struct gcc_options, x_target_flags)"
 277         if (opt_args("InverseMask", flags) != "")
 278                 return "offsetof (struct gcc_options, x_target_flags)"
 279         return "(unsigned short) -1"
 280 }
 281
 282 # Given the option called NAME return a sanitized version of its name.
 283 function opt_sanitized_name(name)
 284 {
 285         gsub ("[^" alnum "]", "_", name)
 286         return name
 287 }
 288
 289 # Given the option called NAME return the appropriate enum for it.
 290 function opt_enum(name)
 291 {
 292         return "OPT_" opt_sanitized_name(name)
 293 }
 294
 295 # Given the language called NAME return a sanitized version of its name.
 296 function lang_sanitized_name(name)
 297 {
 298     gsub( "[^" alnum "_]", "X", name )
 299     return name
 300 }
 301
 302 # Search for a valid var_name among all OPTS equal to option NAME.
 303 # If not found, return "".
 304 function search_var_name(name, opt_numbers, opts, flags, n_opts)
 305 {
 306     opt_var_name = var_name(flags[opt_numbers[name]]);
 307     if (opt_var_name != "") {
 308         return opt_var_name;
 309     }
 310     for (k = 0; k < n_opts; k++) {
 311         if (opts[k] == name && var_name(flags[k]) != "") {
 312             return var_name(flags[k]);
 313         }
 314     }
 315     return ""
 316 }
 317
 318 function integer_range_info(range_option, init, option)
 319 {
 320     if (range_option != "") {
 321         start = nth_arg(0, range_option);
 322         end = nth_arg(1, range_option);
 323         if (init != "" && init != "-1" && (init < start || init > end))
 324           print "#error initial value " init " of '" option "' must be in range [" start "," end "]"
 325         return start ", " end
 326     }
 327     else
 328         return "-1, -1"
 329 }
 330
 331 # Handle LangEnabledBy(ENABLED_BY_LANGS, ENABLEDBY_NAME, ENABLEDBY_POSARG,
 332 # ENABLEDBY_NEGARG). This function does not return anything.
 333 function lang_enabled_by(enabledby_langs, enabledby_name, enabledby_posarg, enabledby_negarg)
 334 {
 335     n_enabledby_arg_langs = split(enabledby_langs, enabledby_arg_langs, " ");
 336     if (enabledby_posarg != "" && enabledby_negarg != "") {
 337         with_args = "," enabledby_posarg "," enabledby_negarg
 338     } else if (enabledby_posarg == "" && enabledby_negarg == "") {
 339         with_args = ""
 340     } else {
 341         print "#error " opts[i] " LangEnabledBy("enabledby_langs","enabledby_name", " \
 342             enabledby_posarg", " enabledby_negargs                  \
 343             ") with three arguments, it should have either 2 or 4"
 344     }
 345
 346     n_enabledby_array = split(enabledby_name, enabledby_array, " \\|\\| ");
 347     for (k = 1; k <= n_enabledby_array; k++) {
 348         enabledby_index = opt_numbers[enabledby_array[k]];
 349         if (enabledby_index == "") {
 350              print "#error " opts[i] " LangEnabledBy("enabledby_langs","enabledby_name", " \
 351                  enabledby_posarg", " enabledby_negargs"), unknown option '" enabledby_name "'"
 352         } else {
 353             for (j = 1; j <= n_enabledby_arg_langs; j++) {
 354                  lang_name = lang_sanitized_name(enabledby_arg_langs[j]);
 355                  lang_index = lang_numbers[enabledby_arg_langs[j]];
 356                  if (enables[lang_name,enabledby_array[k]] == "") {
 357                      enabledby[lang_name,n_enabledby_lang[lang_index]] = enabledby_array[k];
 358                      n_enabledby_lang[lang_index]++;
 359                  }
 360                  enables[lang_name,enabledby_array[k]] \
 361                      = enables[lang_name,enabledby_array[k]] opts[i] with_args ";";
 362             }
 363         }
 364     }
 365 }