gcc/optc-gen.awk

   1 #  Copyright (C) 2003-2016 Free Software Foundation, Inc.
   2 #  Contributed by Kelley Cook, June 2004.
   3 #  Original code from Neil Booth, May 2003.
   4 #
   5 # This program is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by the
   7 # Free Software Foundation; either version 3, or (at your option) any
   8 # later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 # This Awk script reads in the option records generated from
  20 # opt-gather.awk, combines the flags of duplicate options and generates a
  21 # C file.
  22 #
  23
  24 # This program uses functions from opt-functions.awk and code from
  25 # opt-read.awk.
  26 #
  27 # Usage: awk -f opt-functions.awk -f opt-read.awk -f optc-gen.awk \
  28 #            [-v header_name=header.h] < inputfile > options.c
  29
  30 # Dump that array of options into a C file.
  31 END {
  32
  33
  34 # Combine the flags of identical switches.  Switches
  35 # appear many times if they are handled by many front
  36 # ends, for example.
  37 for (i = 0; i < n_opts; i++) {
  38     merged_flags[i] = flags[i]
  39 }
  40 for (i = 0; i < n_opts; i++) {
  41     while(i + 1 != n_opts && opts[i] == opts[i + 1] ) {
  42         merged_flags[i + 1] = merged_flags[i] " " merged_flags[i + 1];
  43         i++;
  44     }
  45 }
  46
  47 # Record EnabledBy and LangEnabledBy uses.
  48 n_enabledby = 0;
  49 for (i = 0; i < n_langs; i++) {
  50     n_enabledby_lang[i] = 0;
  51 }
  52 for (i = 0; i < n_opts; i++) {
  53     enabledby_arg = opt_args("EnabledBy", flags[i]);
  54     if (enabledby_arg != "") {
  55         logical_and = index(enabledby_arg, " && ");
  56         if (logical_and != 0) {
  57             # EnabledBy(arg1 && arg2)
  58             split_sep = " && ";
  59         } else {
  60             # EnabledBy(arg) or EnabledBy(arg1 || arg2 || arg3)
  61             split_sep = " \\|\\| ";
  62         }
  63         n_enabledby_names = split(enabledby_arg, enabledby_names, split_sep);
  64         if (logical_and != 0 && n_enabledby_names > 2) {
  65             print "#error " opts[i] " EnabledBy(Wfoo && Wbar && Wbaz) currently not supported"
  66         }
  67         for (j = 1; j <= n_enabledby_names; j++) {
  68             enabledby_name = enabledby_names[j];
  69             enabledby_index = opt_numbers[enabledby_name];
  70             if (enabledby_index == "") {
  71                 print "#error " opts[i] " Enabledby(" enabledby_name "), unknown option '" enabledby_name "'"
  72             } else if (!flag_set_p("Common", merged_flags[enabledby_index])) {
  73                 print "#error " opts[i] " Enabledby(" enabledby_name "), '" \
  74                     enabledby_name "' must have flag 'Common'"          \
  75                     " to use Enabledby(), otherwise use LangEnabledBy()"
  76             } else {
  77                 condition = "";
  78                 if (logical_and != 0) {
  79                     opt_var_name_1 = search_var_name(enabledby_names[1], opt_numbers, opts, flags, n_opts);
  80                     opt_var_name_2 = search_var_name(enabledby_names[2], opt_numbers, opts, flags, n_opts);
  81                     if (opt_var_name_1 == "") {
  82                         print "#error " enabledby_names[1] " does not have a Var() flag"
  83                     }
  84                     if (opt_var_name_2 == "") {
  85                         print "#error " enabledby_names[2] " does not have a Var() flag"
  86                     }
  87                     condition = "opts->x_" opt_var_name_1 " && opts->x_" opt_var_name_2;
  88                 }
  89                 if (enables[enabledby_name] == "") {
  90                     enabledby[n_enabledby] = enabledby_name;
  91                     n_enabledby++;
  92                 }
  93                 enables[enabledby_name] = enables[enabledby_name] opts[i] ";";
  94                 enablesif[enabledby_name] = enablesif[enabledby_name] condition ";";
  95             }
  96         }
  97     }
  98
  99     enabledby_arg = opt_args("LangEnabledBy", flags[i]);
 100     if (enabledby_arg != "") {
 101         enabledby_langs = nth_arg(0, enabledby_arg);
 102         enabledby_name = nth_arg(1, enabledby_arg);
 103         enabledby_posarg = nth_arg(2, enabledby_arg);
 104         enabledby_negarg = nth_arg(3, enabledby_arg);
 105         lang_enabled_by(enabledby_langs, enabledby_name, enabledby_posarg, enabledby_negarg);
 106     }
 107 }
 108
 109
 110 print "/* This file is auto-generated by optc-gen.awk.  */"
 111 print ""
 112 n_headers = split(header_name, headers, " ")
 113 for (i = 1; i <= n_headers; i++)
 114         print "#include " quote headers[i] quote
 115 print "#include " quote "opts.h" quote
 116 print "#include " quote "intl.h" quote
 117 print "#include " quote "insn-attr-common.h" quote
 118 print ""
 119
 120 if (n_extra_c_includes > 0) {
 121         for (i = 0; i < n_extra_c_includes; i++) {
 122                 print "#include " quote extra_c_includes[i] quote
 123         }
 124         print ""
 125 }
 126
 127 for (i = 0; i < n_enums; i++) {
 128         name = enum_names[i]
 129         type = enum_type[name]
 130         print "static const struct cl_enum_arg cl_enum_" name \
 131             "_data[] = "
 132         print "{"
 133         print enum_data[name] "  { NULL, 0, 0 }"
 134         print "};"
 135         print ""
 136         print "static void"
 137         print "cl_enum_" name "_set (void *var, int value)"
 138         print "{"
 139         print "  *((" type " *) var) = (" type ") value;"
 140         print "}"
 141         print ""
 142         print "static int"
 143         print "cl_enum_" name "_get (const void *var)"
 144         print "{"
 145         print "  return (int) *((const " type " *) var);"
 146         print "}"
 147         print ""
 148 }
 149
 150 print "const struct cl_enum cl_enums[] ="
 151 print "{"
 152 for (i = 0; i < n_enums; i++) {
 153         name = enum_names[i]
 154         ehelp = enum_help[name]
 155         if (ehelp == "")
 156                 ehelp = "NULL"
 157         else
 158                 ehelp = quote ehelp quote
 159         unknown_error = enum_unknown_error[name]
 160         if (unknown_error == "")
 161                 unknown_error = "NULL"
 162         else
 163                 unknown_error = quote unknown_error quote
 164         print "  {"
 165         print "    " ehelp ","
 166         print "    " unknown_error ","
 167         print "    cl_enum_" name "_data,"
 168         print "    sizeof (" enum_type[name] "),"
 169         print "    cl_enum_" name "_set,"
 170         print "    cl_enum_" name "_get"
 171         print "  },"
 172 }
 173 print "};"
 174 print "const unsigned int cl_enums_count = " n_enums ";"
 175 print ""
 176
 177 print "const struct gcc_options global_options_init =\n{"
 178 for (i = 0; i < n_extra_vars; i++) {
 179         var = extra_vars[i]
 180         init = extra_vars[i]
 181         if (var ~ "=" ) {
 182                 sub(".*= *", "", init)
 183         } else {
 184                 init = "0"
 185         }
 186         sub(" *=.*", "", var)
 187         name = var
 188         sub("^.*[ *]", "", name)
 189         sub("\\[.*\\]$", "", name)
 190         var_seen[name] = 1
 191         print "  " init ", /* " name " */"
 192 }
 193 for (i = 0; i < n_opts; i++) {
 194         name = var_name(flags[i]);
 195         if (name == "")
 196                 continue;
 197
 198         init = opt_args("Init", flags[i])
 199         if (init != "") {
 200                 if (name in var_init && var_init[name] != init)
 201                         print "#error multiple initializers for " name
 202                 var_init[name] = init
 203         }
 204 }
 205 for (i = 0; i < n_opts; i++) {
 206         name = var_name(flags[i]);
 207         if (name == "")
 208                 continue;
 209
 210         if (name in var_seen)
 211                 continue;
 212
 213         if (name in var_init)
 214                 init = var_init[name]
 215         else
 216                 init = "0"
 217
 218         print "  " init ", /* " name " */"
 219
 220         var_seen[name] = 1;
 221 }
 222 for (i = 0; i < n_opts; i++) {
 223         name = static_var(opts[i], flags[i]);
 224         if (name != "") {
 225                 print "  0, /* " name " (private state) */"
 226                 print "#undef x_" name
 227         }
 228 }
 229 for (i = 0; i < n_opts; i++) {
 230         if (flag_set_p("SetByCombined", flags[i]))
 231                 print "  false, /* frontend_set_" var_name(flags[i]) " */"
 232 }
 233 print "};"
 234 print ""
 235 print "struct gcc_options global_options;"
 236 print "struct gcc_options global_options_set;"
 237 print ""
 238
 239 print "const char * const lang_names[] =\n{"
 240 for (i = 0; i < n_langs; i++) {
 241         macros[i] = "CL_" lang_sanitized_name(langs[i])
 242         s = substr("         ", length (macros[i]))
 243         print "  " quote langs[i] quote ","
 244     }
 245
 246 print "  0\n};\n"
 247 print "const unsigned int cl_options_count = N_OPTS;\n"
 248 print "#if (1U << " n_langs ") > CL_MIN_OPTION_CLASS"
 249 print "  #error the number of languages exceeds the implementation limit"
 250 print "#endif"
 251 print "const unsigned int cl_lang_count = " n_langs ";\n"
 252
 253 print "const struct cl_option cl_options[] =\n{"
 254
 255 j = 0
 256 for (i = 0; i < n_opts; i++) {
 257         back_chain[i] = "N_OPTS";
 258         indices[opts[i]] = j;
 259         # Combine the flags of identical switches.  Switches
 260         # appear many times if they are handled by many front
 261         # ends, for example.
 262         while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 263                 flags[i + 1] = flags[i] " " flags[i + 1];
 264                 if (help[i + 1] == "")
 265                         help[i + 1] = help[i]
 266                 else if (help[i] != "" && help[i + 1] != help[i])
 267                         print "#error Multiple different help strings for " \
 268                                 opts[i] ":\n\t" help[i] "\n\t" help[i + 1]
 269
 270                 i++;
 271                 back_chain[i] = "N_OPTS";
 272                 indices[opts[i]] = j;
 273         }
 274         j++;
 275 }
 276
 277 for (i = 0; i < n_opts; i++) {
 278         # With identical flags, pick only the last one.  The
 279         # earlier loop ensured that it has all flags merged,
 280         # and a nonempty help text if one of the texts was nonempty.
 281         while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 282                 i++;
 283         }
 284
 285         len = length (opts[i]);
 286         enum = opt_enum(opts[i])
 287
 288         # If this switch takes joined arguments, back-chain all
 289         # subsequent switches to it for which it is a prefix.  If
 290         # a later switch S is a longer prefix of a switch T, T
 291         # will be back-chained to S in a later iteration of this
 292         # for() loop, which is what we want.
 293         if (flag_set_p("Joined.*", flags[i])) {
 294                 for (j = i + 1; j < n_opts; j++) {
 295                         if (substr (opts[j], 1, len) != opts[i])
 296                                 break;
 297                         back_chain[j] = enum;
 298                 }
 299         }
 300
 301         s = substr("                                  ", length (opts[i]))
 302         if (i + 1 == n_opts)
 303                 comma = ""
 304
 305         if (help[i] == "")
 306                 hlp = "0"
 307         else
 308                 hlp = quote help[i] quote;
 309
 310         missing_arg_error = opt_args("MissingArgError", flags[i])
 311         if (missing_arg_error == "")
 312                 missing_arg_error = "0"
 313         else
 314                 missing_arg_error = quote missing_arg_error quote
 315
 316
 317         warn_message = opt_args("Warn", flags[i])
 318         if (warn_message == "")
 319                 warn_message = "0"
 320         else
 321                 warn_message = quote warn_message quote
 322
 323         alias_arg = opt_args("Alias", flags[i])
 324         if (alias_arg == "") {
 325                 if (flag_set_p("Ignore", flags[i]))
 326                         alias_data = "NULL, NULL, OPT_SPECIAL_ignore"
 327                 else
 328                         alias_data = "NULL, NULL, N_OPTS"
 329         } else {
 330                 alias_opt = nth_arg(0, alias_arg)
 331                 alias_posarg = nth_arg(1, alias_arg)
 332                 alias_negarg = nth_arg(2, alias_arg)
 333
 334                 if (var_ref(opts[i], flags[i]) != "-1")
 335                         print "#error Alias setting variable"
 336
 337                 if (alias_posarg != "" && alias_negarg == "") {
 338                         if (!flag_set_p("RejectNegative", flags[i]) \
 339                             && opts[i] ~ "^[Wfm]")
 340                                 print "#error Alias with single argument " \
 341                                         "allowing negative form"
 342                 }
 343                 if (alias_posarg != "" \
 344                     && flag_set_p("NegativeAlias", flags[i])) {
 345                         print "#error Alias with multiple arguments " \
 346                                 "used with NegativeAlias"
 347                 }
 348
 349                 alias_opt = opt_enum(alias_opt)
 350                 if (alias_posarg == "")
 351                         alias_posarg = "NULL"
 352                 else
 353                         alias_posarg = quote alias_posarg quote
 354                 if (alias_negarg == "")
 355                         alias_negarg = "NULL"
 356                 else
 357                         alias_negarg = quote alias_negarg quote
 358                 alias_data = alias_posarg ", " alias_negarg ", " alias_opt
 359         }
 360
 361         neg = opt_args("Negative", flags[i]);
 362         if (neg != "")
 363                 idx = indices[neg]
 364         else {
 365                 if (flag_set_p("RejectNegative", flags[i]))
 366                         idx = -1;
 367                 else {
 368                         if (opts[i] ~ "^[Wfm]")
 369                                 idx = indices[opts[i]];
 370                         else
 371                                 idx = -1;
 372                 }
 373         }
 374         # Split the printf after %u to work around an ia64-hp-hpux11.23
 375         # awk bug.
 376         printf("  { %c-%s%c,\n    %s,\n    %s,\n    %s,\n    %s, %s, %u,",
 377                quote, opts[i], quote, hlp, missing_arg_error, warn_message,
 378                alias_data, back_chain[i], len)
 379         printf(" %d,\n", idx)
 380         condition = opt_args("Condition", flags[i])
 381         cl_flags = switch_flags(flags[i])
 382         cl_bit_fields = switch_bit_fields(flags[i])
 383         cl_zero_bit_fields = switch_bit_fields("")
 384         if (condition != "")
 385                 printf("#if %s\n" \
 386                        "    %s,\n" \
 387                        "    0, %s,\n" \
 388                        "#else\n" \
 389                        "    0,\n" \
 390                        "    1 /* Disabled.  */, %s,\n" \
 391                        "#endif\n",
 392                        condition, cl_flags, cl_bit_fields, cl_zero_bit_fields)
 393         else
 394                 printf("    %s,\n" \
 395                        "    0, %s,\n",
 396                        cl_flags, cl_bit_fields)
 397         printf("    %s, %s }%s\n", var_ref(opts[i], flags[i]),
 398                var_set(flags[i]), comma)
 399 }
 400
 401 print "};"
 402
 403 print "\n\n"
 404 print "bool                                                                  "
 405 print "common_handle_option_auto (struct gcc_options *opts,                  "
 406 print "                           struct gcc_options *opts_set,              "
 407 print "                           const struct cl_decoded_option *decoded,   "
 408 print "                           unsigned int lang_mask, int kind,          "
 409 print "                           location_t loc,                            "
 410 print "                           const struct cl_option_handlers *handlers, "
 411 print "                           diagnostic_context *dc)                    "
 412 print "{                                                                     "
 413 print "  size_t scode = decoded->opt_index;                                  "
 414 print "  int value = decoded->value;                                         "
 415 print "  enum opt_code code = (enum opt_code) scode;                         "
 416 print "                                                                      "
 417 print "  gcc_assert (decoded->canonical_option_num_elements <= 2);           "
 418 print "                                                                      "
 419 print "  switch (code)                                                       "
 420 print "    {                                                                 "
 421 # Handle EnabledBy
 422 for (i = 0; i < n_enabledby; i++) {
 423     enabledby_name = enabledby[i];
 424     print "    case " opt_enum(enabledby_name) ":"
 425     n_enables = split(enables[enabledby_name], thisenable, ";");
 426     n_enablesif = split(enablesif[enabledby_name], thisenableif, ";");
 427     if (n_enables != n_enablesif) {
 428         print "#error n_enables != n_enablesif: Something went wrong!"
 429     }
 430     for (j = 1; j < n_enables; j++) {
 431         opt_var_name = var_name(flags[opt_numbers[thisenable[j]]]);
 432         if (opt_var_name != "") {
 433             condition = "!opts_set->x_" opt_var_name
 434             if (thisenableif[j] != "") {
 435                 value = "(" thisenableif[j] ")"
 436             } else {
 437                 value = "value"
 438             }
 439             print "      if (" condition ")"
 440             print "        handle_generated_option (opts, opts_set,"
 441             print "                                 " opt_enum(thisenable[j]) ", NULL, " value ","
 442             print "                                 lang_mask, kind, loc, handlers, dc);"
 443         } else {
 444             print "#error " thisenable[j] " does not have a Var() flag"
 445         }
 446     }
 447     print "      break;\n"
 448 }
 449 print "    default:    "
 450 print "      break;    "
 451 print "    }           "
 452 print "  return true;  "
 453 print "}               "
 454
 455 # Handle LangEnabledBy
 456 for (i = 0; i < n_langs; i++) {
 457     lang_name = lang_sanitized_name(langs[i]);
 458     mark_unused = " ATTRIBUTE_UNUSED";
 459
 460     print "\n\n"
 461     print "bool                                                                  "
 462     print lang_name "_handle_option_auto (struct gcc_options *opts" mark_unused ",              "
 463     print "                           struct gcc_options *opts_set" mark_unused ",              "
 464     print "                           size_t scode" mark_unused ", const char *arg" mark_unused ", int value" mark_unused ",  "
 465     print "                           unsigned int lang_mask" mark_unused ", int kind" mark_unused ",          "
 466     print "                           location_t loc" mark_unused ",                            "
 467     print "                           const struct cl_option_handlers *handlers" mark_unused ", "
 468     print "                           diagnostic_context *dc" mark_unused ")                    "
 469     print "{                                                                     "
 470     print "  enum opt_code code = (enum opt_code) scode;                         "
 471     print "                                                                      "
 472     print "  switch (code)                                                       "
 473     print "    {                                                                 "
 474
 475     for (k = 0; k < n_enabledby_lang[i]; k++) {
 476         enabledby_name = enabledby[lang_name,k];
 477         print "    case " opt_enum(enabledby_name) ":"
 478         n_thisenable = split(enables[lang_name,enabledby_name], thisenable, ";");
 479         for (j = 1; j < n_thisenable; j++) {
 480             n_thisenable_args = split(thisenable[j], thisenable_args, ",");
 481             if (n_thisenable_args == 1) {
 482                 thisenable_opt = thisenable[j];
 483                 value = "value";
 484             } else {
 485                 thisenable_opt = thisenable_args[1];
 486                 with_posarg = thisenable_args[2];
 487                 with_negarg = thisenable_args[3];
 488                 value = "value ? " with_posarg " : " with_negarg;
 489             }
 490             opt_var_name = var_name(flags[opt_numbers[thisenable_opt]]);
 491             if (opt_var_name != "") {
 492                 print "      if (!opts_set->x_" opt_var_name ")"
 493                 print "        handle_generated_option (opts, opts_set,"
 494                 print "                                 " opt_enum(thisenable_opt) ", NULL, " value ","
 495                 print "                                 lang_mask, kind, loc, handlers, dc);"
 496             } else {
 497                 print "#error " thisenable_opt " does not have a Var() flag"
 498             }
 499         }
 500         print "      break;\n"
 501     }
 502     print "    default:    "
 503     print "      break;    "
 504     print "    }           "
 505     print "  return true;  "
 506     print "}               "
 507 }
 508
 509 #Handle CPP()
 510 print "\n"
 511 print "#include " quote "cpplib.h" quote;
 512 print "void"
 513 print "cpp_handle_option_auto (const struct gcc_options * opts,                   "
 514 print "                        size_t scode, struct cpp_options * cpp_opts)"
 515 print "{                                                                     "
 516 print "  enum opt_code code = (enum opt_code) scode;                         "
 517 print "                                                                      "
 518 print "  switch (code)                                                       "
 519 print "    {                                                                 "
 520 for (i = 0; i < n_opts; i++) {
 521     # With identical flags, pick only the last one.  The
 522     # earlier loop ensured that it has all flags merged,
 523     # and a nonempty help text if one of the texts was nonempty.
 524     while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 525         i++;
 526     }
 527
 528     cpp_option = nth_arg(0, opt_args("CPP", flags[i]));
 529     if (cpp_option != "") {
 530         opt_var_name = var_name(flags[i]);
 531         init = opt_args("Init", flags[i])
 532         if (opt_var_name != "" && init != "") {
 533             print "    case " opt_enum(opts[i]) ":"
 534             print "      cpp_opts->" cpp_option " = opts->x_" opt_var_name ";"
 535             print "      break;"
 536         } else if (opt_var_name == "" && init == "") {
 537             print "#error CPP() requires setting Init() and Var() for " opts[i]
 538         } else if (opt_var_name != "") {
 539             print "#error CPP() requires setting Init() for " opts[i]
 540         } else {
 541             print "#error CPP() requires setting Var() for " opts[i]
 542         }
 543     }
 544 }
 545 print "    default:    "
 546 print "      break;    "
 547 print "    }           "
 548 print "}\n"
 549 print "void"
 550 print "init_global_opts_from_cpp(struct gcc_options * opts,                   "
 551 print "                         const struct cpp_options * cpp_opts)"
 552 print "{                                                                     "
 553 for (i = 0; i < n_opts; i++) {
 554     # With identical flags, pick only the last one.  The
 555     # earlier loop ensured that it has all flags merged,
 556     # and a nonempty help text if one of the texts was nonempty.
 557     while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 558         i++;
 559     }
 560     cpp_option = nth_arg(0, opt_args("CPP", flags[i]));
 561     opt_var_name = var_name(flags[i]);
 562     if (cpp_option != "" && opt_var_name != "") {
 563         print "  opts->x_" opt_var_name " = cpp_opts->" cpp_option ";"
 564     }
 565 }
 566 print "}               "
 567
 568 }
 569