libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([xmalloc.c])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  66 # rely on it - libiberty is built before texinfo.
  67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  68 if test "x$MAKEINFO" = "x"; then
  69     MAKEINFO="@echo makeinfo missing; true"
  70     BUILD_INFO=
  71 else
  72     BUILD_INFO=info
  73     case "$MAKEINFO" in
  74       */missing\ makeinfo*)
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is missing. Info documentation will not be built.])
  78         ;;
  79       *)
  80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  81           x*\ [[1-3]].* )
  82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  83             BUILD_INFO=
  84             AC_MSG_WARN([
  85 *** Makeinfo is too old. Info documentation will not be built.])
  86           ;;
  87         esac
  88         ;;
  89     esac
  90 fi
  91 AC_SUBST(MAKEINFO)
  92 AC_SUBST(BUILD_INFO)
  93
  94 AC_CHECK_PROG(PERL, perl, perl, )
  95 if test x"$PERL" = x""; then
  96   HAVE_PERL='#'
  97 else
  98   HAVE_PERL=''
  99 fi
 100 AC_SUBST(HAVE_PERL)
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl When we start using automake:
 105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 106
 107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 108 dnl to call AC_CHECK_PROG.
 109 AC_CHECK_TOOL(AR, ar)
 110 AC_CHECK_TOOL(RANLIB, ranlib, :)
 111
 112 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 113 # Add --enable-multilib to configure.
 114 # Default to --enable-multilib
 115 AC_ARG_ENABLE(multilib,
 116 [  --enable-multilib       build many library versions (default)],
 117 [case "$enableval" in
 118   yes) multilib=yes ;;
 119   no)  multilib=no ;;
 120   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 121  esac],
 122               [multilib=yes])
 123
 124 # Even if the default multilib is not a cross compilation,
 125 # it may be that some of the other multilibs are.
 126 if test $cross_compiling = no && test $multilib = yes \
 127    && test "x${with_multisubdir}" != x ; then
 128    cross_compiling=maybe
 129 fi
 130
 131 # We may wish to install the target headers somewhere.
 132 AC_MSG_CHECKING([whether to install libiberty headers and static library])
 133 dnl install-libiberty is disabled by default
 134
 135 AC_ARG_ENABLE(install-libiberty,
 136 [  --enable-install-libiberty       Install headers and library for end users],
 137 enable_install_libiberty=$enableval,
 138 enable_install_libiberty=no)dnl
 139
 140 # Option parsed, now set things appropriately.
 141 case x"$enable_install_libiberty" in
 142   xyes|x)
 143     target_header_dir=libiberty
 144     ;;
 145   xno)
 146     target_header_dir=
 147     ;;
 148   *)
 149     # This could be sanity-checked in various ways...
 150     target_header_dir="${enable_install_libiberty}"
 151     ;;
 152 esac
 153 AC_MSG_RESULT($enable_install_libiberty)
 154 AC_MSG_NOTICE([target_header_dir = $target_header_dir])
 155
 156 GCC_NO_EXECUTABLES
 157 AC_PROG_CC
 158 AC_SYS_LARGEFILE
 159 AC_PROG_CPP_WERROR
 160
 161 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 162                           -Wstrict-prototypes], [ac_libiberty_warn_cflags])
 163 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 164
 165 AC_PROG_CC_C_O
 166 # autoconf is lame and doesn't give us any substitution variable for this.
 167 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 168   NO_MINUS_C_MINUS_O=yes
 169 else
 170   OUTPUT_OPTION='-o $@'
 171 fi
 172 AC_SUBST(NO_MINUS_C_MINUS_O)
 173 AC_SUBST(OUTPUT_OPTION)
 174
 175 AC_C_CONST
 176 AC_C_INLINE
 177 AC_C_BIGENDIAN
 178
 179 dnl When we start using libtool:
 180 dnl Default to a non shared library.  This may be overridden by the
 181 dnl configure option --enable-shared.
 182 dnl AM_DISABLE_SHARED
 183
 184 dnl When we start using libtool:
 185 dnl AM_PROG_LIBTOOL
 186
 187 dnl When we start using automake:
 188 dnl AM_CONFIG_HEADER(config.h:config.in)
 189 AC_CONFIG_HEADER(config.h:config.in)
 190
 191 dnl When we start using automake:
 192 dnl AM_MAINTAINER_MODE
 193 dnl AC_EXEEXT
 194
 195 dnl When we start using automake:
 196 dnl AM_PROG_INSTALL
 197 AC_PROG_INSTALL
 198
 199 # Don't build the shared library for build.
 200 if [[ -n "${with_build_subdir}" ]]; then
 201   enable_shared=no
 202 fi
 203
 204 frag=
 205 case "${host}" in
 206   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 207                         frag=mh-aix ;;
 208   *-*-cxux7*)           frag=mh-cxux7 ;;
 209   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 210   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 211   i370-*-opened*)       frag=mh-openedition ;;
 212   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 213 esac
 214
 215 if [[ -n "${frag}" ]]; then
 216   frag=${libiberty_topdir}/libiberty/config/$frag
 217 fi
 218
 219 GCC_PICFLAG
 220
 221 # If they didn't specify --enable-shared, don't generate shared libs.
 222 case "${enable_shared}" in
 223   yes) shared=yes ;;
 224   no) shared=no ;;
 225   "") shared=no ;;
 226   *) shared=yes ;;
 227 esac
 228
 229 # ...unless --enable-host-shared was passed from top-level config:
 230 if [[ "${enable_host_shared}" = "yes" ]]; then
 231   shared=yes
 232 fi
 233
 234 if [[ "${shared}" != "yes" ]]; then
 235   PICFLAG=
 236 fi
 237 AC_SUBST(PICFLAG)
 238
 239 echo "# Warning: this fragment is automatically generated" > temp-frag
 240
 241 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 242   echo "Appending ${frag} to xhost-mkfrag"
 243   echo "# Following fragment copied from ${frag}" >> temp-frag
 244   cat ${frag} >> temp-frag
 245 fi
 246
 247 # record if we want to build shared libs.
 248 if [[ "${shared}" = "yes" ]]; then
 249   echo enable_shared = yes >> temp-frag
 250 else
 251   echo enable_shared = no >> temp-frag
 252 fi
 253
 254 frag=xhost-mkfrag
 255 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 256
 257 host_makefile_frag=${frag}
 258 AC_SUBST_FILE(host_makefile_frag)
 259
 260 # It's OK to check for header files.  Although the compiler may not be
 261 # able to link anything, it had better be able to at least compile
 262 # something.
 263 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h process.h sys/prctl.h)
 264 AC_HEADER_SYS_WAIT
 265 AC_HEADER_TIME
 266
 267 libiberty_AC_DECLARE_ERRNO
 268
 269 # Determine the size of an int for struct fibnode.
 270 AC_CHECK_SIZEOF([int])
 271
 272 # Look for a 64-bit type.
 273 AC_MSG_CHECKING([for a 64-bit type])
 274 AC_CACHE_VAL(liberty_cv_uint64,
 275 [AC_TRY_COMPILE(
 276 [#ifdef HAVE_STDINT_H
 277 #include <stdint.h>
 278 #endif],
 279 [extern uint64_t foo;],
 280 liberty_cv_uint64=uint64_t,
 281 [AC_TRY_COMPILE(
 282 [#ifdef HAVE_LIMITS_H
 283 #include <limits.h>
 284 #endif
 285 #ifndef CHAR_BIT
 286 #define CHAR_BIT 8
 287 #endif],
 288 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 289 liberty_cv_uint64="unsigned long",
 290 [AC_TRY_COMPILE(
 291 [#ifdef HAVE_LIMITS_H
 292 #include <limits.h>
 293 #endif
 294 #ifndef CHAR_BIT
 295 #define CHAR_BIT 8
 296 #endif],
 297 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 298 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 299 AC_MSG_RESULT($liberty_cv_uint64)
 300 if test "$liberty_cv_uint64" != none; then
 301   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 302                      [Define to an unsigned 64-bit type available in the compiler.])
 303 fi
 304
 305 AC_TYPE_INTPTR_T
 306 AC_TYPE_UINTPTR_T
 307 AC_TYPE_SSIZE_T
 308
 309 # Given the above check, we always have uintptr_t or a fallback
 310 # definition.  So define HAVE_UINTPTR_T in case any imported code
 311 # relies on it.
 312 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 313
 314 AC_TYPE_PID_T
 315
 316 # This is the list of functions which libiberty will provide if they
 317 # are not available on the host.
 318
 319 funcs="asprintf"
 320 funcs="$funcs atexit"
 321 funcs="$funcs basename"
 322 funcs="$funcs bcmp"
 323 funcs="$funcs bcopy"
 324 funcs="$funcs bsearch"
 325 funcs="$funcs bzero"
 326 funcs="$funcs calloc"
 327 funcs="$funcs clock"
 328 funcs="$funcs ffs"
 329 funcs="$funcs getcwd"
 330 funcs="$funcs getpagesize"
 331 funcs="$funcs gettimeofday"
 332 funcs="$funcs index"
 333 funcs="$funcs insque"
 334 funcs="$funcs memchr"
 335 funcs="$funcs memcmp"
 336 funcs="$funcs memcpy"
 337 funcs="$funcs memmem"
 338 funcs="$funcs memmove"
 339 funcs="$funcs mempcpy"
 340 funcs="$funcs memset"
 341 funcs="$funcs mkstemps"
 342 funcs="$funcs putenv"
 343 funcs="$funcs random"
 344 funcs="$funcs rename"
 345 funcs="$funcs rindex"
 346 funcs="$funcs setenv"
 347 funcs="$funcs snprintf"
 348 funcs="$funcs sigsetmask"
 349 funcs="$funcs stpcpy"
 350 funcs="$funcs stpncpy"
 351 funcs="$funcs strcasecmp"
 352 funcs="$funcs strchr"
 353 funcs="$funcs strdup"
 354 funcs="$funcs strncasecmp"
 355 funcs="$funcs strndup"
 356 funcs="$funcs strnlen"
 357 funcs="$funcs strrchr"
 358 funcs="$funcs strstr"
 359 funcs="$funcs strtod"
 360 funcs="$funcs strtol"
 361 funcs="$funcs strtoul"
 362 funcs="$funcs strverscmp"
 363 funcs="$funcs tmpnam"
 364 funcs="$funcs vasprintf"
 365 funcs="$funcs vfprintf"
 366 funcs="$funcs vprintf"
 367 funcs="$funcs vsnprintf"
 368 funcs="$funcs vsprintf"
 369 funcs="$funcs waitpid"
 370 funcs="$funcs setproctitle"
 371
 372 # Also in the old function.def file: alloca, vfork, getopt.
 373
 374 vars="sys_errlist sys_nerr sys_siglist"
 375
 376 checkfuncs="__fsetlocking canonicalize_file_name dup3 getrlimit getrusage \
 377  getsysinfo gettimeofday on_exit psignal pstat_getdynamic pstat_getstatic \
 378  realpath setrlimit sbrk spawnve spawnvpe strerror strsignal sysconf sysctl \
 379  sysmp table times wait3 wait4"
 380
 381 # These are neither executed nor required, but they help keep
 382 # autoheader happy without adding a bunch of text to acconfig.h.
 383 if test "x" = "y"; then
 384   AC_CHECK_FUNCS(asprintf atexit \
 385     basename bcmp bcopy bsearch bzero \
 386     calloc canonicalize_file_name clock \
 387     dup3 \
 388     ffs __fsetlocking \
 389     getcwd getpagesize getrlimit getrusage getsysinfo gettimeofday \
 390     index insque \
 391     memchr memcmp memcpy memmem memmove memset mkstemps \
 392     on_exit \
 393     psignal pstat_getdynamic pstat_getstatic putenv \
 394     random realpath rename rindex \
 395     sbrk setenv setproctitle setrlimit sigsetmask snprintf spawnve spawnvpe \
 396      stpcpy stpncpy strcasecmp strchr strdup \
 397      strerror strncasecmp strndup strnlen strrchr strsignal strstr strtod \
 398      strtol strtoul strverscmp sysconf sysctl sysmp \
 399     table times tmpnam \
 400     vasprintf vfprintf vprintf vsprintf \
 401     wait3 wait4 waitpid)
 402   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 403   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 404   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 405   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 406 fi
 407
 408 # For each of these functions, if the host does not provide the
 409 # function we want to put FN.o in LIBOBJS, and if the host does
 410 # provide the function, we want to define HAVE_FN in config.h.
 411
 412 setobjs=
 413 CHECK=
 414 if test -n "${with_target_subdir}"; then
 415
 416   # We are being configured as a target library.  AC_REPLACE_FUNCS
 417   # may not work correctly, because the compiler may not be able to
 418   # link executables.  Note that we may still be being configured
 419   # native.
 420
 421   # If we are being configured for newlib, we know which functions
 422   # newlib provide and which ones we will be expected to provide.
 423
 424   if test "x${with_newlib}" = "xyes"; then
 425     AC_LIBOBJ([asprintf])
 426     AC_LIBOBJ([basename])
 427     AC_LIBOBJ([insque])
 428     AC_LIBOBJ([random])
 429     AC_LIBOBJ([strdup])
 430     AC_LIBOBJ([vasprintf])
 431
 432     for f in $funcs; do
 433       case "$f" in
 434         asprintf | basename | insque | random | strdup | vasprintf)
 435           ;;
 436         *)
 437           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 438           AC_DEFINE_UNQUOTED($n)
 439           ;;
 440       esac
 441     done
 442
 443     # newlib doesnt provide any of the variables in $vars, so we
 444     # dont have to check them here.
 445
 446     # Of the functions in $checkfuncs, newlib only has strerror.
 447     AC_DEFINE(HAVE_STRERROR)
 448
 449     setobjs=yes
 450
 451   fi
 452
 453   # If we are being configured for Mingw, we know which functions
 454   # Mingw provides and which ones we will be expected to provide.
 455
 456   case "${host}" in
 457   *-*-mingw*)
 458     AC_LIBOBJ([asprintf])
 459     AC_LIBOBJ([basename])
 460     AC_LIBOBJ([bcmp])
 461     AC_LIBOBJ([bcopy])
 462     AC_LIBOBJ([bzero])
 463     AC_LIBOBJ([clock])
 464     AC_LIBOBJ([ffs])
 465     AC_LIBOBJ([getpagesize])
 466     AC_LIBOBJ([index])
 467     AC_LIBOBJ([insque])
 468     AC_LIBOBJ([mempcpy])
 469     AC_LIBOBJ([mkstemps])
 470     AC_LIBOBJ([random])
 471     AC_LIBOBJ([rindex])
 472     AC_LIBOBJ([sigsetmask])
 473     AC_LIBOBJ([stpcpy])
 474     AC_LIBOBJ([stpncpy])
 475     AC_LIBOBJ([strndup])
 476     AC_LIBOBJ([strnlen])
 477     AC_LIBOBJ([strverscmp])
 478     AC_LIBOBJ([vasprintf])
 479     AC_LIBOBJ([waitpid])
 480
 481     for f in $funcs; do
 482       case "$f" in
 483         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strnlen | strverscmp | vasprintf | waitpid)
 484           ;;
 485         *)
 486           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 487           AC_DEFINE_UNQUOTED($n)
 488           ;;
 489       esac
 490     done
 491
 492     # Mingw doesnt provide any of the variables in $vars, so we
 493     # dont have to check them here.
 494
 495     # Of the functions in $checkfuncs, Mingw only has strerror.
 496     AC_DEFINE(HAVE_STRERROR)
 497
 498     setobjs=yes
 499     ;;
 500
 501   *-*-msdosdjgpp)
 502     AC_LIBOBJ([vasprintf])
 503     AC_LIBOBJ([vsnprintf])
 504     AC_LIBOBJ([snprintf])
 505     AC_LIBOBJ([asprintf])
 506
 507     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 508              getcwd getpagesize getrusage gettimeofday \
 509              index insque memchr memcmp memcpy memmove memset psignal \
 510              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 511              strchr strdup strerror strncasecmp strrchr strstr strtod \
 512              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 513              vsprintf waitpid
 514     do
 515       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 516       AC_DEFINE_UNQUOTED($n)
 517     done
 518
 519
 520     setobjs=yes
 521     ;;
 522
 523   esac
 524
 525 else
 526
 527    # Not a target library, so we set things up to run the test suite.
 528    CHECK=really-check
 529
 530 fi
 531
 532 AC_SUBST(CHECK)
 533 AC_SUBST(target_header_dir)
 534
 535 case "${host}" in
 536   *-*-cygwin* | *-*-mingw*)
 537     AC_DEFINE(HAVE_SYS_ERRLIST)
 538     AC_DEFINE(HAVE_SYS_NERR)
 539     ;;
 540 esac
 541
 542 if test -z "${setobjs}"; then
 543   case "${host}" in
 544
 545   *-*-vxworks*)
 546     # Handle VxWorks configuration specially, since on VxWorks the
 547     # libraries are actually on the target board, not in the file
 548     # system.
 549     AC_LIBOBJ([basename])
 550     AC_LIBOBJ([getpagesize])
 551     AC_LIBOBJ([insque])
 552     AC_LIBOBJ([random])
 553     AC_LIBOBJ([strcasecmp])
 554     AC_LIBOBJ([strncasecmp])
 555     AC_LIBOBJ([strdup])
 556     AC_LIBOBJ([vfork])
 557     AC_LIBOBJ([waitpid])
 558     AC_LIBOBJ([vasprintf])
 559     for f in $funcs; do
 560       case "$f" in
 561         basename | getpagesize | insque | random | strcasecmp)
 562           ;;
 563         strncasecmp | strdup | vfork | waitpid | vasprintf)
 564           ;;
 565         *)
 566           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 567           AC_DEFINE_UNQUOTED($n)
 568           ;;
 569       esac
 570     done
 571
 572     # VxWorks doesn't provide any of the variables in $vars, so we
 573     # don't have to check them here.
 574
 575     # Of the functions in $checkfuncs, VxWorks only has strerror.
 576     AC_DEFINE(HAVE_STRERROR)
 577
 578     setobjs=yes
 579     ;;
 580
 581   esac
 582 fi
 583
 584 if test -z "${setobjs}"; then
 585
 586   case "${host}" in
 587
 588   *-*-mingw32*)
 589     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 590     # macros, so the test below won't find them.
 591     libiberty_cv_var_sys_nerr=yes
 592     libiberty_cv_var_sys_errlist=yes
 593     ;;
 594
 595   *-*-msdosdjgpp*)
 596     # vfork and fork are stubs.
 597     ac_cv_func_vfork_works=no
 598     ;;
 599
 600   *-*-uwin*)
 601     # Under some versions of uwin, vfork is notoriously buggy and the test
 602     # can hang configure; on other versions, vfork exists just as a stub.
 603     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 604     ac_cv_func_vfork_works=no
 605     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 606     # macros (actually, these are imported from a DLL, but the end effect
 607     # is the same), so the test below won't find them.
 608     libiberty_cv_var_sys_nerr=yes
 609     libiberty_cv_var_sys_errlist=yes
 610     ;;
 611
 612   *-*-*vms*)
 613     # Under VMS, vfork works very different than on Unix. The standard test
 614     # won't work, and it isn't easily adaptable. It makes more sense to
 615     # just force it.
 616     ac_cv_func_vfork_works=yes
 617     ;;
 618
 619   esac
 620
 621   # We haven't set the list of objects yet.  Use the standard autoconf
 622   # tests.  This will only work if the compiler works.
 623   AC_ISC_POSIX
 624   AC_REPLACE_FUNCS($funcs)
 625   libiberty_AC_FUNC_C_ALLOCA
 626   AC_FUNC_FORK
 627   if test $ac_cv_func_vfork_works = no; then
 628     AC_LIBOBJ([vfork])
 629   fi
 630   # We only need _doprnt if we might use it to implement v*printf.
 631   if test $ac_cv_func_vprintf != yes \
 632      || test $ac_cv_func_vfprintf != yes \
 633      || test $ac_cv_func_vsprintf != yes; then
 634     AC_REPLACE_FUNCS(_doprnt)
 635   else
 636     AC_CHECK_FUNCS(_doprnt)
 637   fi
 638
 639   for v in $vars; do
 640     AC_MSG_CHECKING([for $v])
 641     AC_CACHE_VAL(libiberty_cv_var_$v,
 642       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 643                       [eval "libiberty_cv_var_$v=yes"],
 644                       [eval "libiberty_cv_var_$v=no"])])
 645     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 646       AC_MSG_RESULT(yes)
 647       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 648       AC_DEFINE_UNQUOTED($n)
 649     else
 650       AC_MSG_RESULT(no)
 651     fi
 652   done
 653
 654   # special check for _system_configuration because AIX <4.3.2 do not
 655   # contain the `physmem' member.
 656   AC_MSG_CHECKING([for external symbol _system_configuration])
 657   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 658                         [[double x = _system_configuration.physmem;]])],
 659     [AC_MSG_RESULT([yes])
 660     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 661               [Define if you have the _system_configuration variable.])],
 662     [AC_MSG_RESULT([no])])
 663
 664   AC_CHECK_FUNCS($checkfuncs)
 665   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 666   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 667   AC_CHECK_DECLS([strverscmp])
 668   libiberty_NEED_DECLARATION(canonicalize_file_name)
 669 fi
 670
 671 # Figure out which version of pexecute to use.
 672 case "${host}" in
 673      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 674      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 675      *-*-msdos*)                pexecute=pex-msdos  ;;
 676      *)                         pexecute=pex-unix   ;;
 677 esac
 678 AC_SUBST(pexecute)
 679
 680 libiberty_AC_FUNC_STRNCMP
 681
 682 # Install a library built with a cross compiler in $(tooldir) rather
 683 # than $(libdir).
 684 if test -z "${with_cross_host}"; then
 685   INSTALL_DEST=libdir
 686 else
 687   INSTALL_DEST=tooldir
 688 fi
 689 AC_SUBST(INSTALL_DEST)
 690
 691 m4_pattern_allow(LIBOBJS)
 692 L=""
 693 for l in x $LIBOBJS; do
 694   case $l in
 695     x) ;;
 696     *) L="$L ./$l" ;;
 697   esac
 698 done
 699 LIBOBJS="$L"
 700
 701 dnl Required by html and install-html
 702 AC_SUBST(datarootdir)
 703 AC_SUBST(docdir)
 704 AC_SUBST(htmldir)
 705
 706 # We need multilib support, but only if configuring for the target.
 707 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 708 AC_CONFIG_COMMANDS([default],
 709   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 710 if test -n "$CONFIG_FILES"; then
 711   if test -n "${with_target_subdir}"; then
 712     # FIXME: We shouldn't need to set ac_file
 713     ac_file=Makefile
 714     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 715     . ${libiberty_topdir}/config-ml.in
 716   fi
 717 fi]],
 718 [[srcdir=${srcdir}
 719 host=${host}
 720 target=${target}
 721 with_target_subdir=${with_target_subdir}
 722 with_multisubdir=${with_multisubdir}
 723 ac_configure_args="--enable-multilib ${ac_configure_args}"
 724 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 725 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 726 libiberty_topdir=${libiberty_topdir}
 727 ]])
 728 AC_OUTPUT