libffi/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(fficonfig.h.in)
   3 AM_CONFIG_HEADER(fficonfig.h)
   4
   5 # This works around the fact that libtool configuration may change LD
   6 # for this particular configuration, but some shells, instead of
   7 # keeping the changes in LD private, export them just because LD is
   8 # exported.
   9 ORIGINAL_LD_FOR_MULTILIBS=$LD
  10
  11 dnl Default to --enable-multilib
  12 AC_ARG_ENABLE(multilib,
  13 [  --enable-multilib       build many library versions (default)],
  14 [case "${enableval}" in
  15   yes) multilib=yes ;;
  16   no)  multilib=no ;;
  17   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  18  esac], [multilib=yes])dnl
  19
  20 dnl We may get other options which we don't document:
  21 dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
  22
  23 if test "${srcdir}" = "."; then
  24   if test "${with_target_subdir}" != "."; then
  25     libffi_basedir="${srcdir}/${with_multisrctop}.."
  26   else
  27     libffi_basedir="${srcdir}/${with_multisrctop}"
  28   fi
  29 else
  30   libffi_basedir="${srcdir}"
  31 fi
  32 AC_SUBST(libffi_basedir)
  33
  34 AC_CANONICAL_HOST
  35
  36 AM_PROG_LIBTOOL
  37
  38 AM_INIT_AUTOMAKE(libffi,2.00-beta,no-define)
  39
  40 AC_EXEEXT
  41 AM_MAINTAINER_MODE
  42
  43 AC_PROG_CC
  44 AC_PROG_LIBTOOL
  45
  46 TARGETDIR="unknown"
  47 case "$host" in
  48 mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS; TARGETDIR=mips;;
  49 i*86-*-linux*) TARGET=X86; TARGETDIR=x86;;
  50 i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;;
  51 i*86-*-beos*) TARGET=X86; TARGETDIR=x86;;
  52 i*86-*-freebsd*) TARGET=X86; TARGETDIR=x86;;
  53 i*86-*-netbsdelf*) TARGET=X86; TARGETDIR=x86;;
  54 i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;;
  55 i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;;
  56 i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;;
  57 sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;;
  58 sparc*-sun-*) TARGET=SPARC; TARGETDIR=sparc;;
  59 sparc-*-linux* | sparc-*-netbsdelf*) TARGET=SPARC; TARGETDIR=sparc;;
  60 sparc64-*-linux* | sparc64-*-netbsd*) TARGET=SPARC; TARGETDIR=sparc;;
  61 alpha*-*-linux* | alpha*-*-osf* | alpha*-*-freebsd* | alpha*-*-netbsd*) TARGET=ALPHA; TARGETDIR=alpha;;
  62 ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;;
  63 m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;;
  64 mips64*-*);;
  65 mips*-*-linux*) TARGET=MIPS_LINUX; TARGETDIR=mips;;
  66 powerpc-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;;
  67 powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;;
  68 powerpc-*-darwin*) TARGET=POWERPC_DARWIN; TARGETDIR=powerpc;;
  69 powerpc-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  70 rs6000-*-aix*) TARGET=POWERPC_AIX; TARGETDIR=powerpc;;
  71 arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;;
  72 s390-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  73 s390x-*-linux-*) TARGET=S390; TARGETDIR=s390;;
  74 x86_64-*-linux*) TARGET=X86_64; TARGETDIR=x86;;
  75 sh-*-linux* | sh[[34]]*-*-linux*) TARGET=SH; TARGETDIR=sh;;
  76 esac
  77
  78 if test $TARGETDIR = unknown; then
  79   AC_ERROR("libffi has not been ported to $host.")
  80 fi
  81
  82 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
  83 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
  84 AM_CONDITIONAL(MIPS_LINUX, test x$TARGET = xMIPS_LINUX)
  85 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
  86 AM_CONDITIONAL(X86, test x$TARGET = xX86)
  87 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
  88 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
  89 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
  90 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
  91 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
  92 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
  93 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
  94 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
  95 AM_CONDITIONAL(S390, test x$TARGET = xS390)
  96 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
  97 AM_CONDITIONAL(SH, test x$TARGET = xSH)
  98
  99 if test x$TARGET = xMIPS_LINUX; then
 100   TARGET=MIPS
 101 fi
 102
 103 AC_HEADER_STDC
 104 AC_CHECK_FUNCS(memcpy)
 105 AC_FUNC_ALLOCA
 106
 107 dnl AC_CHECK_SIZEOF(char)
 108 AC_COMPILE_CHECK_SIZEOF(short)
 109 AC_COMPILE_CHECK_SIZEOF(int)
 110 AC_COMPILE_CHECK_SIZEOF(long)
 111 AC_COMPILE_CHECK_SIZEOF(long long)
 112 AC_COMPILE_CHECK_SIZEOF(float)
 113 AC_COMPILE_CHECK_SIZEOF(double)
 114 AC_COMPILE_CHECK_SIZEOF(long double)
 115
 116 AC_COMPILE_CHECK_SIZEOF(void *)
 117 AC_C_BIGENDIAN_CROSS
 118
 119 if test x$TARGET = xSPARC; then
 120     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 121         libffi_cv_as_sparc_ua_pcrel, [
 122         save_CFLAGS="$CFLAGS"
 123         save_LDFLAGS="$LDFLAGS"
 124         CFLAGS="$CFLAGS -fpic"
 125         LDFLAGS="$LDFLAGS -shared"
 126         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 127                     [libffi_cv_as_sparc_ua_pcrel=yes],
 128                     [libffi_cv_as_sparc_ua_pcrel=no])
 129         CFLAGS="$save_CFLAGS"
 130         LDFLAGS="$save_LDFLAGS"])
 131     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 132         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 133                   [Define if your assembler and linker support unaligned PC relative relocs.])
 134     fi
 135 fi
 136
 137 AC_SUBST(TARGET)
 138 AC_SUBST(TARGETDIR)
 139
 140 AC_SUBST(SHELL)
 141
 142 AC_ARG_ENABLE(debug,
 143 [  --enable-debug          debugging mode],
 144   if test "$enable_debug" = "yes"; then
 145     AC_DEFINE(FFI_DEBUG)
 146   fi)
 147
 148 AC_ARG_ENABLE(structs,
 149 [  --disable-structs       omit code for struct support],
 150   if test "$enable_structs" = "no"; then
 151     AC_DEFINE(FFI_NO_STRUCTS)
 152   fi)
 153
 154 AC_ARG_ENABLE(raw-api,
 155 [  --disable-raw-api       make the raw api unavailable],
 156   if test "$enable_raw_api" = "no"; then
 157     AC_DEFINE(FFI_NO_RAW_API)
 158   fi)
 159
 160 AC_ARG_ENABLE(purify-safety,
 161 [  --enable-purify-safety  purify-safe mode],
 162   if test "$enable_purify_safety" = "yes"; then
 163     AC_DEFINE(USING_PURIFY)
 164   fi)
 165
 166 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 167
 168 if test "${multilib}" = "yes"; then
 169   multilib_arg="--enable-multilib"
 170 else
 171   multilib_arg=
 172 fi
 173
 174 AC_OUTPUT(include/Makefile include/ffi.h Makefile,
 175 [
 176 if test -n "$CONFIG_FILES"; then
 177    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 178    ac_file=Makefile . ${libffi_basedir}/../config-ml.in
 179 fi
 180 ],
 181 srcdir=${srcdir}
 182 host=${host}
 183 target=${target}
 184 with_multisubdir=${with_multisubdir}
 185 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 186 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 187 libffi_basedir=${libffi_basedir}
 188 CC="${CC}"
 189 DEFS="$DEFS"
 190 test ! -d include && mkdir include
 191 test ! -f include/fficonfig.h && cp fficonfig.h include/fficonfig.h
 192 if cmp -s fficonfig.h include/fficonfig.h 2>/dev/null; then
 193         echo fficonfig.h unchanged
 194 else
 195         echo Moving fficonfig.h to include/fficonfig.h
 196         cp fficonfig.h include/fficonfig.h
 197 fi
 198 )
 199
 200 # Make target subdirectories if required.
 201 test -d src || mkdir src
 202 test -d src/${TARGETDIR} || mkdir src/${TARGETDIR}