| blob | b3ce3dbe3d9b837e75e9e17cc9ce088a1889f82b |
1 dnl
2 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
3 dnl
4 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
5 dnl end of configure. This lets tested variables be reassigned, and the
6 dnl conditional will depend on the final state of the variable. For a simple
7 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
8 dnl
9 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
10 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
11 m4_divert_text([glibcxx_diversion],dnl
12 AM_CONDITIONAL([$1],[$2])
13 )dnl
14 ])dnl
15 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
18 dnl
19 dnl Check to see what architecture and operating system we are compiling
20 dnl for. Also, if architecture- or OS-specific flags are required for
21 dnl compilation, pick them up here.
22 dnl
23 AC_DEFUN([GLIBCXX_CHECK_HOST], [
24 . $glibcxx_srcdir/configure.host
25 AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
26 AC_MSG_NOTICE([OS config directory is $os_include_dir])
27 ])
29 dnl
30 dnl Initialize the rest of the library configury. At this point we have
31 dnl variables like $host.
32 dnl
33 dnl Sets:
34 dnl SUBDIRS
35 dnl Substs:
36 dnl glibcxx_builddir (absolute path)
37 dnl glibcxx_srcdir (absolute path)
38 dnl toplevel_builddir (absolute path)
39 dnl toplevel_srcdir (absolute path)
40 dnl with_cross_host
41 dnl with_newlib
42 dnl with_target_subdir
43 dnl plus
44 dnl - the variables in GLIBCXX_CHECK_HOST / configure.host
45 dnl - default settings for all AM_CONFITIONAL test variables
46 dnl - lots of tools, like CC and CXX
47 dnl
48 AC_DEFUN([GLIBCXX_CONFIGURE], [
49 # Keep these sync'd with the list in Makefile.am. The first provides an
50 # expandable list at autoconf time; the second provides an expandable list
51 # (i.e., shell variable) at configure time.
52 m4_define([glibcxx_SUBDIRS],[include libsupc++ python src src/c++98 src/c++11 doc po testsuite])
53 SUBDIRS='glibcxx_SUBDIRS'
55 # These need to be absolute paths, yet at the same time need to
56 # canonicalize only relative paths, because then amd will not unmount
57 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
58 glibcxx_builddir=`${PWDCMD-pwd}`
59 case $srcdir in
60 [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
61 *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
62 esac
63 toplevel_builddir=${glibcxx_builddir}/..
64 toplevel_srcdir=${glibcxx_srcdir}/..
65 AC_SUBST(glibcxx_builddir)
66 AC_SUBST(glibcxx_srcdir)
67 AC_SUBST(toplevel_builddir)
68 AC_SUBST(toplevel_srcdir)
70 # We use these options to decide which functions to include. They are
71 # set from the top level.
72 AC_ARG_WITH([target-subdir],
73 AC_HELP_STRING([--with-target-subdir=SUBDIR],
74 [configuring in a subdirectory]))
76 AC_ARG_WITH([cross-host],
77 AC_HELP_STRING([--with-cross-host=HOST],
78 [configuring with a cross compiler]))
80 AC_ARG_WITH([newlib],
81 AC_HELP_STRING([--with-newlib],
82 [assume newlib as a system C library]))
84 # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
85 # available). Uncomment the next line to force a particular method.
86 AC_PROG_LN_S
87 #LN_S='cp -p'
89 AC_CHECK_TOOL(AS, as)
90 AC_CHECK_TOOL(AR, ar)
91 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
93 AM_MAINTAINER_MODE
95 # Set up safe default values for all subsequent AM_CONDITIONAL tests
96 # which are themselves conditionally expanded.
97 ## (Right now, this only matters for enable_wchar_t, but nothing prevents
98 ## other macros from doing the same. This should be automated.) -pme
100 # Check for C library flavor since GNU/Linux platforms use different
101 # configuration directories depending on the C library in use.
102 AC_EGREP_CPP([_using_uclibc], [
103 #include <stdio.h>
104 #if __UCLIBC__
105 _using_uclibc
106 #endif
107 ], uclibc=yes, uclibc=no)
109 AC_EGREP_CPP([_using_bionic], [
110 #include <stdio.h>
111 #if __BIONIC__
112 _using_bionic
113 #endif
114 ], bionic=yes, bionic=no)
116 # Find platform-specific directories containing configuration info.
117 # Also possibly modify flags used elsewhere, as needed by the platform.
118 GLIBCXX_CHECK_HOST
119 ])
122 dnl
123 dnl Tests for newer compiler features, or features that are present in newer
124 dnl compiler versions but not older compiler versions still in use, should
125 dnl be placed here.
126 dnl
127 dnl Defines:
128 dnl WERROR='-Werror' if requested and possible; g++'s that lack the
129 dnl new inlining code or the new system_header pragma will die on -Werror.
130 dnl Leave it out by default and use maint-mode to use it.
131 dnl SECTION_FLAGS='-ffunction-sections -fdata-sections' if
132 dnl compiler supports it and the user has not requested debug mode.
133 dnl
134 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
135 # All these tests are for C++; save the language and the compiler flags.
136 # The CXXFLAGS thing is suspicious, but based on similar bits previously
137 # found in GLIBCXX_CONFIGURE.
138 AC_LANG_SAVE
139 AC_LANG_CPLUSPLUS
140 ac_test_CXXFLAGS="${CXXFLAGS+set}"
141 ac_save_CXXFLAGS="$CXXFLAGS"
143 # Check for maintainer-mode bits.
144 if test x"$USE_MAINTAINER_MODE" = xno; then
145 WERROR=''
146 else
147 WERROR='-Werror'
148 fi
150 # Check for -ffunction-sections -fdata-sections
151 AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
152 CXXFLAGS='-g -Werror -ffunction-sections -fdata-sections'
153 AC_TRY_COMPILE([int foo; void bar() { };],, [ac_fdsections=yes], [ac_fdsections=no])
154 if test "$ac_test_CXXFLAGS" = set; then
155 CXXFLAGS="$ac_save_CXXFLAGS"
156 else
157 # this is the suspicious part
158 CXXFLAGS=''
159 fi
160 if test x"$ac_fdsections" = x"yes"; then
161 SECTION_FLAGS='-ffunction-sections -fdata-sections'
162 fi
163 AC_MSG_RESULT($ac_fdsections)
165 AC_LANG_RESTORE
166 AC_SUBST(WERROR)
167 AC_SUBST(SECTION_FLAGS)
168 ])
171 dnl
172 dnl Check if the assembler used supports disabling generation of hardware
173 dnl capabilities. This is only supported by Sun as at the moment.
174 dnl
175 dnl Defines:
176 dnl HWCAP_FLAGS='-Wa,-nH' if possible.
177 dnl
178 AC_DEFUN([GLIBCXX_CHECK_ASSEMBLER_HWCAP], [
179 test -z "$HWCAP_FLAGS" && HWCAP_FLAGS=''
181 # Restrict the test to Solaris, other assemblers (e.g. AIX as) have -nH
182 # with a different meaning.
183 case ${target_os} in
184 solaris2*)
185 ac_save_CFLAGS="$CFLAGS"
186 CFLAGS="$CFLAGS -Wa,-nH"
188 AC_MSG_CHECKING([for as that supports -Wa,-nH])
189 AC_TRY_COMPILE([], [return 0;], [ac_hwcap_flags=yes],[ac_hwcap_flags=no])
190 if test "$ac_hwcap_flags" = "yes"; then
191 HWCAP_FLAGS="-Wa,-nH $HWCAP_FLAGS"
192 fi
193 AC_MSG_RESULT($ac_hwcap_flags)
195 CFLAGS="$ac_save_CFLAGS"
196 ;;
197 esac
199 AC_SUBST(HWCAP_FLAGS)
200 ])
203 dnl
204 dnl If GNU ld is in use, check to see if tricky linker opts can be used. If
205 dnl the native linker is in use, all variables will be defined to something
206 dnl safe (like an empty string).
207 dnl
208 dnl Defines:
209 dnl SECTION_LDFLAGS='-Wl,--gc-sections' if possible
210 dnl OPT_LDFLAGS='-Wl,-O1' and '-z,relro' if possible
211 dnl LD (as a side effect of testing)
212 dnl Sets:
213 dnl with_gnu_ld
214 dnl glibcxx_ld_is_gold (set to "no" or "yes")
215 dnl glibcxx_gnu_ld_version (possibly)
216 dnl
217 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
218 dnl set glibcxx_gnu_ld_version to 12345. Zeros cause problems.
219 dnl
220 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
221 # If we're not using GNU ld, then there's no point in even trying these
222 # tests. Check for that first. We should have already tested for gld
223 # by now (in libtool), but require it now just to be safe...
224 test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
225 test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
226 AC_REQUIRE([AC_PROG_LD])
227 AC_REQUIRE([AC_PROG_AWK])
229 # The name set by libtool depends on the version of libtool. Shame on us
230 # for depending on an impl detail, but c'est la vie. Older versions used
231 # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
232 # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
233 # makes sense). We'll test with_gnu_ld everywhere else, so if that isn't
234 # set (hence we're using an older libtool), then set it.
235 if test x${with_gnu_ld+set} != xset; then
236 if test x${ac_cv_prog_gnu_ld+set} != xset; then
237 # We got through "ac_require(ac_prog_ld)" and still not set? Huh?
238 with_gnu_ld=no
239 else
240 with_gnu_ld=$ac_cv_prog_gnu_ld
241 fi
242 fi
244 # Start by getting the version number. I think the libtool test already
245 # does some of this, but throws away the result.
246 glibcxx_ld_is_gold=no
247 if test x"$with_gnu_ld" = x"yes"; then
248 AC_MSG_CHECKING([for ld version])
249 changequote(,)
250 if $LD --version 2>/dev/null | grep 'GNU gold' >/dev/null 2>&1; then
251 glibcxx_ld_is_gold=yes
252 fi
253 ldver=`$LD --version 2>/dev/null |
254 sed -e 's/GNU gold /GNU ld /;s/GNU ld version /GNU ld /;s/GNU ld ([^)]*) /GNU ld /;s/GNU ld \([0-9.][0-9.]*\).*/\1/; q'`
255 changequote([,])
256 glibcxx_gnu_ld_version=`echo $ldver | \
257 $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
258 AC_MSG_RESULT($glibcxx_gnu_ld_version)
259 fi
261 # Set --gc-sections.
262 glibcxx_have_gc_sections=no
263 if test "$glibcxx_ld_is_gold" = "yes"; then
264 if $LD --help 2>/dev/null | grep gc-sections >/dev/null 2>&1; then
265 glibcxx_have_gc_sections=yes
266 fi
267 else
268 glibcxx_gcsections_min_ld=21602
269 if test x"$with_gnu_ld" = x"yes" &&
270 test $glibcxx_gnu_ld_version -gt $glibcxx_gcsections_min_ld ; then
271 glibcxx_have_gc_sections=yes
272 fi
273 fi
274 if test "$glibcxx_have_gc_sections" = "yes"; then
275 # Sufficiently young GNU ld it is! Joy and bunny rabbits!
276 # NB: This flag only works reliably after 2.16.1. Configure tests
277 # for this are difficult, so hard wire a value that should work.
279 ac_test_CFLAGS="${CFLAGS+set}"
280 ac_save_CFLAGS="$CFLAGS"
281 CFLAGS='-Wl,--gc-sections'
283 # Check for -Wl,--gc-sections
284 AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
285 AC_TRY_LINK([ int one(void) { return 1; }
286 int two(void) { return 2; }
287 ], [ two(); ] , [ac_gcsections=yes], [ac_gcsections=no])
288 if test "$ac_gcsections" = "yes"; then
289 rm -f conftest.c
290 touch conftest.c
291 if $CC -c conftest.c; then
292 if $LD --gc-sections -o conftest conftest.o 2>&1 | \
293 grep "Warning: gc-sections option ignored" > /dev/null; then
294 ac_gcsections=no
295 fi
296 fi
297 rm -f conftest.c conftest.o conftest
298 fi
299 if test "$ac_gcsections" = "yes"; then
300 SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
301 fi
302 AC_MSG_RESULT($ac_gcsections)
304 if test "$ac_test_CFLAGS" = set; then
305 CFLAGS="$ac_save_CFLAGS"
306 else
307 # this is the suspicious part
308 CFLAGS=''
309 fi
310 fi
312 # Set -z,relro.
313 # Note this is only for shared objects.
314 ac_ld_relro=no
315 if test x"$with_gnu_ld" = x"yes"; then
316 AC_MSG_CHECKING([for ld that supports -Wl,-z,relro])
317 cxx_z_relo=`$LD -v --help 2>/dev/null | grep "z relro"`
318 if test -n "$cxx_z_relo"; then
319 OPT_LDFLAGS="-Wl,-z,relro"
320 ac_ld_relro=yes
321 fi
322 AC_MSG_RESULT($ac_ld_relro)
323 fi
325 # Set linker optimization flags.
326 if test x"$with_gnu_ld" = x"yes"; then
327 OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
328 fi
330 AC_SUBST(SECTION_LDFLAGS)
331 AC_SUBST(OPT_LDFLAGS)
332 ])
335 dnl
336 dnl Check for headers for, and arguments to, the setrlimit() function.
337 dnl Used only in testsuite_hooks.h. Called from GLIBCXX_CONFIGURE_TESTSUITE.
338 dnl
339 dnl Defines:
340 dnl _GLIBCXX_RES_LIMITS if we can set artificial resource limits
341 dnl various HAVE_LIMIT_* for individual limit names
342 dnl
343 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
344 AC_MSG_CHECKING([for RLIMIT_$1])
345 AC_TRY_COMPILE(
346 [#include <unistd.h>
347 #include <sys/time.h>
348 #include <sys/resource.h>
349 ],
350 [ int f = RLIMIT_$1 ; ],
351 [glibcxx_mresult=1], [glibcxx_mresult=0])
352 AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
353 [Only used in build directory testsuite_hooks.h.])
354 if test $glibcxx_mresult = 1 ; then res=yes ; else res=no ; fi
355 AC_MSG_RESULT($res)
356 ])
358 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
359 setrlimit_have_headers=yes
360 AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
361 [],
362 [setrlimit_have_headers=no])
363 # If don't have the headers, then we can't run the tests now, and we
364 # won't be seeing any of these during testsuite compilation.
365 if test $setrlimit_have_headers = yes; then
366 # Can't do these in a loop, else the resulting syntax is wrong.
367 GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
368 GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
369 GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
370 GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
371 GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
373 # Check for rlimit, setrlimit.
374 AC_CACHE_VAL(glibcxx_cv_setrlimit, [
375 AC_TRY_COMPILE(
376 [#include <unistd.h>
377 #include <sys/time.h>
378 #include <sys/resource.h>
379 ],
380 [struct rlimit r;
381 setrlimit(0, &r);],
382 [glibcxx_cv_setrlimit=yes], [glibcxx_cv_setrlimit=no])
383 ])
384 fi
386 AC_MSG_CHECKING([for testsuite resource limits support])
387 if test $setrlimit_have_headers = yes && test $glibcxx_cv_setrlimit = yes; then
388 ac_res_limits=yes
389 AC_DEFINE(_GLIBCXX_RES_LIMITS, 1,
390 [Define if using setrlimit to set resource limits during
391 "make check"])
392 else
393 ac_res_limits=no
394 fi
395 AC_MSG_RESULT($ac_res_limits)
396 ])
399 dnl
400 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
401 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
402 dnl
403 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
405 AC_LANG_SAVE
406 AC_LANG_CPLUSPLUS
407 ac_save_CXXFLAGS="$CXXFLAGS"
408 CXXFLAGS="$CXXFLAGS -fno-exceptions"
410 AC_MSG_CHECKING([for S_ISREG or S_IFREG])
411 AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
412 GCC_TRY_COMPILE_OR_LINK(
413 [#include <sys/stat.h>],
414 [struct stat buffer;
415 fstat(0, &buffer);
416 S_ISREG(buffer.st_mode);],
417 [glibcxx_cv_S_ISREG=yes],
418 [glibcxx_cv_S_ISREG=no])
419 ])
420 AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
421 GCC_TRY_COMPILE_OR_LINK(
422 [#include <sys/stat.h>],
423 [struct stat buffer;
424 fstat(0, &buffer);
425 S_IFREG & buffer.st_mode;],
426 [glibcxx_cv_S_IFREG=yes],
427 [glibcxx_cv_S_IFREG=no])
428 ])
429 res=no
430 if test $glibcxx_cv_S_ISREG = yes; then
431 AC_DEFINE(HAVE_S_ISREG, 1,
432 [Define if S_IFREG is available in <sys/stat.h>.])
433 res=S_ISREG
434 elif test $glibcxx_cv_S_IFREG = yes; then
435 AC_DEFINE(HAVE_S_IFREG, 1,
436 [Define if S_IFREG is available in <sys/stat.h>.])
437 res=S_IFREG
438 fi
439 AC_MSG_RESULT($res)
441 CXXFLAGS="$ac_save_CXXFLAGS"
442 AC_LANG_RESTORE
443 ])
446 dnl
447 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
448 dnl
449 AC_DEFUN([GLIBCXX_CHECK_POLL], [
451 AC_LANG_SAVE
452 AC_LANG_CPLUSPLUS
453 ac_save_CXXFLAGS="$CXXFLAGS"
454 CXXFLAGS="$CXXFLAGS -fno-exceptions"
456 AC_MSG_CHECKING([for poll])
457 AC_CACHE_VAL(glibcxx_cv_POLL, [
458 GCC_TRY_COMPILE_OR_LINK(
459 [#include <poll.h>],
460 [struct pollfd pfd[1];
461 pfd[0].events = POLLIN;
462 poll(pfd, 1, 0);],
463 [glibcxx_cv_POLL=yes],
464 [glibcxx_cv_POLL=no])
465 ])
466 if test $glibcxx_cv_POLL = yes; then
467 AC_DEFINE(HAVE_POLL, 1, [Define if poll is available in <poll.h>.])
468 fi
469 AC_MSG_RESULT($glibcxx_cv_POLL)
471 CXXFLAGS="$ac_save_CXXFLAGS"
472 AC_LANG_RESTORE
473 ])
476 dnl
477 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
478 dnl
479 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
481 AC_LANG_SAVE
482 AC_LANG_CPLUSPLUS
483 ac_save_CXXFLAGS="$CXXFLAGS"
484 CXXFLAGS="$CXXFLAGS -fno-exceptions"
486 AC_MSG_CHECKING([for writev])
487 AC_CACHE_VAL(glibcxx_cv_WRITEV, [
488 GCC_TRY_COMPILE_OR_LINK(
489 [#include <sys/uio.h>],
490 [struct iovec iov[2];
491 writev(0, iov, 0);],
492 [glibcxx_cv_WRITEV=yes],
493 [glibcxx_cv_WRITEV=no])
494 ])
495 if test $glibcxx_cv_WRITEV = yes; then
496 AC_DEFINE(HAVE_WRITEV, 1, [Define if writev is available in <sys/uio.h>.])
497 fi
498 AC_MSG_RESULT($glibcxx_cv_WRITEV)
500 CXXFLAGS="$ac_save_CXXFLAGS"
501 AC_LANG_RESTORE
502 ])
505 dnl
506 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
507 dnl Also check whether int64_t is actually a typedef to long or long long.
508 dnl
509 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
511 AC_LANG_SAVE
512 AC_LANG_CPLUSPLUS
514 AC_MSG_CHECKING([for int64_t])
515 AC_CACHE_VAL(glibcxx_cv_INT64_T, [
516 AC_TRY_COMPILE(
517 [#include <stdint.h>],
518 [int64_t var;],
519 [glibcxx_cv_INT64_T=yes],
520 [glibcxx_cv_INT64_T=no])
521 ])
523 if test $glibcxx_cv_INT64_T = yes; then
524 AC_DEFINE(HAVE_INT64_T, 1, [Define if int64_t is available in <stdint.h>.])
525 AC_MSG_RESULT($glibcxx_cv_INT64_T)
527 AC_MSG_CHECKING([for int64_t as long])
528 AC_CACHE_VAL(glibcxx_cv_int64_t_long, [
529 AC_TRY_COMPILE(
530 [#include <stdint.h>
531 template<typename, typename> struct same { enum { value = -1 }; };
532 template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
533 int array[same<int64_t, long>::value];], [],
534 [glibcxx_cv_int64_t_long=yes], [glibcxx_cv_int64_t_long=no])
535 ])
537 if test $glibcxx_cv_int64_t_long = yes; then
538 AC_DEFINE(HAVE_INT64_T_LONG, 1, [Define if int64_t is a long.])
539 AC_MSG_RESULT($glibcxx_cv_int64_t_long)
540 fi
542 AC_MSG_CHECKING([for int64_t as long long])
543 AC_CACHE_VAL(glibcxx_cv_int64_t_long_long, [
544 AC_TRY_COMPILE(
545 [#include <stdint.h>
546 template<typename, typename> struct same { enum { value = -1 }; };
547 template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
548 int array[same<int64_t, long long>::value];], [],
549 [glibcxx_cv_int64_t_long_long=yes], [glibcxx_cv_int64_t_long_long=no])
550 ])
552 if test $glibcxx_cv_int64_t_long_long = yes; then
553 AC_DEFINE(HAVE_INT64_T_LONG_LONG, 1, [Define if int64_t is a long long.])
554 AC_MSG_RESULT($glibcxx_cv_int64_t_long_long)
555 fi
556 fi
558 AC_LANG_RESTORE
559 ])
562 dnl
563 dnl Check whether LFS support is available.
564 dnl
565 AC_DEFUN([GLIBCXX_CHECK_LFS], [
566 AC_LANG_SAVE
567 AC_LANG_CPLUSPLUS
568 ac_save_CXXFLAGS="$CXXFLAGS"
569 CXXFLAGS="$CXXFLAGS -fno-exceptions"
570 AC_MSG_CHECKING([for LFS support])
571 AC_CACHE_VAL(glibcxx_cv_LFS, [
572 GCC_TRY_COMPILE_OR_LINK(
573 [#include <unistd.h>
574 #include <stdio.h>
575 #include <sys/stat.h>
576 ],
577 [FILE* fp;
578 fopen64("t", "w");
579 fseeko64(fp, 0, SEEK_CUR);
580 ftello64(fp);
581 lseek64(1, 0, SEEK_CUR);
582 struct stat64 buf;
583 fstat64(1, &buf);],
584 [glibcxx_cv_LFS=yes],
585 [glibcxx_cv_LFS=no])
586 ])
587 if test $glibcxx_cv_LFS = yes; then
588 AC_DEFINE(_GLIBCXX_USE_LFS, 1, [Define if LFS support is available.])
589 fi
590 AC_MSG_RESULT($glibcxx_cv_LFS)
591 CXXFLAGS="$ac_save_CXXFLAGS"
592 AC_LANG_RESTORE
593 ])
596 dnl
597 dnl Check for whether a fully dynamic basic_string implementation should
598 dnl be turned on, that does not put empty objects in per-process static
599 dnl memory (mostly useful together with shared memory allocators, see PR
600 dnl libstdc++/16612 for details).
601 dnl
602 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING to 1
603 dnl --disable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING to 0
604 dnl otherwise undefined
605 dnl + Usage: GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
606 dnl Where DEFAULT is either `yes' or `no'.
607 dnl
608 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
609 GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
610 if test $enable_fully_dynamic_string = yes; then
611 enable_fully_dynamic_string_def=1
612 else
613 enable_fully_dynamic_string_def=0
614 fi
615 AC_DEFINE_UNQUOTED([_GLIBCXX_FULLY_DYNAMIC_STRING], [${enable_fully_dynamic_string_def}],
616 [Define to 1 if a fully dynamic basic_string is wanted, 0 to disable, undefined for platform defaults])
617 ])
620 dnl
621 dnl Does any necessary configuration of the testsuite directory. Generates
622 dnl the testsuite_hooks.h header.
623 dnl
624 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
625 dnl
626 dnl Sets:
627 dnl enable_abi_check
628 dnl GLIBCXX_TEST_WCHAR_T
629 dnl GLIBCXX_TEST_THREAD
630 dnl Substs:
631 dnl baseline_dir
632 dnl baseline_subdir_switch
633 dnl
634 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
635 if $GLIBCXX_IS_NATIVE ; then
636 # Do checks for resource limit functions.
637 GLIBCXX_CHECK_SETRLIMIT
639 # Look for setenv, so that extended locale tests can be performed.
640 GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
641 fi
643 if $GLIBCXX_IS_NATIVE && test $is_hosted = yes &&
644 test $enable_symvers != no; then
645 case "$host" in
646 *-*-cygwin*)
647 enable_abi_check=no ;;
648 *)
649 enable_abi_check=yes ;;
650 esac
651 else
652 # Only build this as native, since automake does not understand
653 # CXX_FOR_BUILD.
654 enable_abi_check=no
655 fi
657 # Export file names for ABI checking.
658 baseline_dir="$glibcxx_srcdir/config/abi/post/${abi_baseline_pair}"
659 AC_SUBST(baseline_dir)
660 baseline_subdir_switch="$abi_baseline_subdir_switch"
661 AC_SUBST(baseline_subdir_switch)
662 ])
665 dnl
666 dnl Does any necessary configuration for docbook in the docs directory.
667 dnl
668 dnl XSLTPROC must be set before this
669 dnl
670 dnl Sets:
671 dnl glibcxx_stylesheets
672 dnl Substs:
673 dnl XSL_STYLE_DIR
674 dnl
675 AC_DEFUN([GLIBCXX_CONFIGURE_DOCBOOK], [
677 AC_MSG_CHECKING([for docbook stylesheets for documentation creation])
678 glibcxx_stylesheets=no
679 if test x${XSLTPROC} = xyes && echo '<title/>' | xsltproc --noout --nonet --xinclude http://docbook.sourceforge.net/release/xsl-ns/current/xhtml-1_1/docbook.xsl - 2>/dev/null; then
680 glibcxx_stylesheets=yes
681 fi
682 AC_MSG_RESULT($glibcxx_stylesheets)
684 AC_MSG_CHECKING([for local stylesheet directory])
685 glibcxx_local_stylesheets=no
686 if test x"$glibcxx_stylesheets" = x"yes"; then
687 if test -d /usr/share/sgml/docbook/xsl-ns-stylesheets; then
688 glibcxx_local_stylesheets=yes
689 XSL_STYLE_DIR=/usr/share/sgml/docbook/xsl-ns-stylesheets
690 fi
691 if test -d /usr/share/xml/docbook/stylesheet/docbook-xsl-ns; then
692 glibcxx_local_stylesheets=yes
693 XSL_STYLE_DIR=/usr/share/xml/docbook/stylesheet/docbook-xsl-ns
694 fi
695 if test -d /usr/share/xml/docbook/stylesheet/nwalsh5/current; then
696 glibcxx_local_stylesheets=yes
697 XSL_STYLE_DIR=/usr/share/xml/docbook/stylesheet/nwalsh5/current
698 fi
699 fi
700 AC_MSG_RESULT($glibcxx_local_stylesheets)
702 if test x"$glibcxx_local_stylesheets" = x"yes"; then
703 AC_SUBST(XSL_STYLE_DIR)
704 AC_MSG_NOTICE($XSL_STYLE_DIR)
705 else
706 glibcxx_stylesheets=no
707 fi
709 # Check for epub3 dependencies.
710 AC_MSG_CHECKING([for epub3 stylesheets for documentation creation])
711 glibcxx_epub_stylesheets=no
712 if test x"$glibcxx_local_stylesheets" = x"yes"; then
713 if test -f "$XSL_STYLE_DIR/epub3/chunk.xsl"; then
714 glibcxx_epub_stylesheets=yes
715 fi
716 fi
717 AC_MSG_RESULT($glibcxx_epub_stylesheets)
718 AM_CONDITIONAL(BUILD_EPUB, test x"$glibcxx_epub_stylesheets" = x"yes")
720 ])
723 dnl
724 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
725 dnl
726 dnl Substs:
727 dnl GLIBCXX_INCLUDES
728 dnl TOPLEVEL_INCLUDES
729 dnl
730 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
731 # Used for every C++ compile we perform.
732 GLIBCXX_INCLUDES="\
733 -I$glibcxx_builddir/include/$host_alias \
734 -I$glibcxx_builddir/include \
735 -I$glibcxx_srcdir/libsupc++"
737 # For Canadian crosses, pick this up too.
738 if test $CANADIAN = yes; then
739 GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
740 fi
742 # Stuff in the actual top level. Currently only used by libsupc++ to
743 # get unwind* headers from the libgcc dir.
744 #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/libgcc -I$(toplevel_srcdir)/include'
745 TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/libgcc'
747 # Now, export this to all the little Makefiles....
748 AC_SUBST(GLIBCXX_INCLUDES)
749 AC_SUBST(TOPLEVEL_INCLUDES)
750 ])
753 dnl
754 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
755 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
756 dnl
757 dnl Substs:
758 dnl OPTIMIZE_CXXFLAGS
759 dnl WARN_FLAGS
760 dnl
761 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
762 # Optimization flags that are probably a good idea for thrill-seekers. Just
763 # uncomment the lines below and make, everything else is ready to go...
764 # Alternatively OPTIMIZE_CXXFLAGS can be set in configure.host.
765 # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
766 AC_SUBST(OPTIMIZE_CXXFLAGS)
768 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual -Wabi'
769 AC_SUBST(WARN_FLAGS)
770 ])
773 dnl
774 dnl All installation directory information is determined here.
775 dnl
776 dnl Substs:
777 dnl gxx_install_dir
778 dnl glibcxx_prefixdir
779 dnl glibcxx_toolexecdir
780 dnl glibcxx_toolexeclibdir
781 dnl
782 dnl Assumes cross_compiling bits already done, and with_cross_host in
783 dnl particular.
784 dnl
785 dnl This logic must match gcc/configure.ac's setting of gcc_gxx_include_dir.
786 dnl config/gxx-include-dir.m4 must be kept consistant with this as well.
787 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
788 glibcxx_toolexecdir=no
789 glibcxx_toolexeclibdir=no
790 glibcxx_prefixdir=$prefix
792 AC_MSG_CHECKING([for gxx-include-dir])
793 AC_ARG_WITH([gxx-include-dir],
794 AC_HELP_STRING([--with-gxx-include-dir=DIR],
795 [installation directory for include files]),
796 [case "$withval" in
797 yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
798 no) gxx_include_dir=no ;;
799 *) gxx_include_dir=$withval ;;
800 esac],
801 [gxx_include_dir=no])
802 AC_MSG_RESULT($gxx_include_dir)
804 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
805 AC_ARG_ENABLE([version-specific-runtime-libs],
806 AC_HELP_STRING([--enable-version-specific-runtime-libs],
807 [Specify that runtime libraries should be installed in a compiler-specific directory]),
808 [case "$enableval" in
809 yes) version_specific_libs=yes ;;
810 no) version_specific_libs=no ;;
811 *) AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
812 esac],
813 [version_specific_libs=no])
814 AC_MSG_RESULT($version_specific_libs)
816 # Default case for install directory for include files.
817 if test $version_specific_libs = no && test $gxx_include_dir = no; then
818 gxx_include_dir='include/c++/${gcc_version}'
819 if test -n "$with_cross_host" &&
820 test x"$with_cross_host" != x"no"; then
821 gxx_include_dir='${prefix}/${target_alias}/'"$gxx_include_dir"
822 else
823 gxx_include_dir='${prefix}/'"$gxx_include_dir"
824 fi
825 fi
827 # Version-specific runtime libs processing.
828 if test $version_specific_libs = yes; then
829 # Need the gcc compiler version to know where to install libraries
830 # and header files if --enable-version-specific-runtime-libs option
831 # is selected. FIXME: these variables are misnamed, there are
832 # no executables installed in _toolexecdir or _toolexeclibdir.
833 if test x"$gxx_include_dir" = x"no"; then
834 gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
835 fi
836 glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
837 glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
838 fi
840 # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
841 # Install a library built with a cross compiler in tooldir, not libdir.
842 if test x"$glibcxx_toolexecdir" = x"no"; then
843 if test -n "$with_cross_host" &&
844 test x"$with_cross_host" != x"no"; then
845 glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
846 glibcxx_toolexeclibdir='${toolexecdir}/lib'
847 else
848 glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
849 glibcxx_toolexeclibdir='${libdir}'
850 fi
851 multi_os_directory=`$CXX -print-multi-os-directory`
852 case $multi_os_directory in
853 .) ;; # Avoid trailing /.
854 *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
855 esac
856 fi
858 AC_MSG_CHECKING([for install location])
859 AC_MSG_RESULT($gxx_include_dir)
861 AC_SUBST(glibcxx_prefixdir)
862 AC_SUBST(gxx_include_dir)
863 AC_SUBST(glibcxx_toolexecdir)
864 AC_SUBST(glibcxx_toolexeclibdir)
865 ])
868 dnl
869 dnl GLIBCXX_ENABLE
870 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
871 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
872 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
873 dnl
874 dnl See manual/appendix_porting.html#appendix.porting.build_hacking for
875 dnl documentation.
876 dnl
877 m4_define([GLIBCXX_ENABLE],[dnl
878 m4_define([_g_switch],[--enable-$1])dnl
879 m4_define([_g_help],[AC_HELP_STRING([_g_switch$3],[$4 @<:@default=$2@:>@])])dnl
880 AC_ARG_ENABLE([$1],m4_dquote(_g_help),
881 m4_bmatch([$5],
882 [^permit ],
883 [[
884 case "$enableval" in
885 m4_bpatsubst([$5],[permit ])) ;;
886 *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
887 dnl Idea for future: generate a URL pointing to
888 dnl "onlinedocs/configopts.html#whatever"
889 esac
890 ]],
891 [^$],
892 [[
893 case "$enableval" in
894 yes|no) ;;
895 *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
896 esac
897 ]],
898 [[$5]]),
899 [enable_]m4_bpatsubst([$1],-,_)[=][$2])
900 m4_undefine([_g_switch])dnl
901 m4_undefine([_g_help])dnl
902 ])
905 dnl
906 dnl Check for ISO/IEC 9899:1999 "C99" support.
907 dnl
908 dnl --enable-c99 defines _GLIBCXX_USE_C99
909 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
910 dnl + Usage: GLIBCXX_ENABLE_C99[(DEFAULT)]
911 dnl Where DEFAULT is either `yes' or `no'.
912 dnl + If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
913 dnl
914 AC_DEFUN([GLIBCXX_ENABLE_C99], [
915 GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
917 if test x"$enable_c99" = x"yes"; then
919 AC_LANG_SAVE
920 AC_LANG_CPLUSPLUS
922 # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
923 # undefined and fake C99 facilities - like pre-standard snprintf - may be
924 # spuriously enabled.
925 # Long term, -std=c++0x could be even better, could manage to explicitly
926 # request C99 facilities to the underlying C headers.
927 ac_save_CXXFLAGS="$CXXFLAGS"
928 CXXFLAGS="$CXXFLAGS -std=c++98"
929 ac_save_LIBS="$LIBS"
930 ac_save_gcc_no_link="$gcc_no_link"
932 if test x$gcc_no_link != xyes; then
933 # Use -fno-exceptions to that the C driver can link these tests without
934 # hitting undefined references to personality routines.
935 CXXFLAGS="$CXXFLAGS -fno-exceptions"
936 AC_CHECK_LIB(m, sin, [
937 LIBS="$LIBS -lm"
938 ], [
939 # Use the default compile-only tests in GCC_TRY_COMPILE_OR_LINK
940 gcc_no_link=yes
941 ])
942 fi
944 # Check for the existence of <math.h> functions used if C99 is enabled.
945 AC_MSG_CHECKING([for ISO C99 support in <math.h>])
946 AC_CACHE_VAL(glibcxx_cv_c99_math, [
947 GCC_TRY_COMPILE_OR_LINK(
948 [#include <math.h>
949 volatile double d1, d2;
950 volatile int i;],
951 [i = fpclassify(d1);
952 i = isfinite(d1);
953 i = isinf(d1);
954 i = isnan(d1);
955 i = isnormal(d1);
956 i = signbit(d1);
957 i = isgreater(d1, d2);
958 i = isgreaterequal(d1, d2);
959 i = isless(d1, d2);
960 i = islessequal(d1, d2);
961 i = islessgreater(d1, d2);
962 i = islessgreater(d1, d2);
963 i = isunordered(d1, d2);
964 ],[glibcxx_cv_c99_math=yes], [glibcxx_cv_c99_math=no])
965 ])
966 AC_MSG_RESULT($glibcxx_cv_c99_math)
967 if test x"$glibcxx_cv_c99_math" = x"yes"; then
968 AC_DEFINE(_GLIBCXX_USE_C99_MATH, 1,
969 [Define if C99 functions or macros in <math.h> should be imported
970 in <cmath> in namespace std.])
971 fi
973 # Check for the existence of <complex.h> complex math functions.
974 # This is necessary even though libstdc++ uses the builtin versions
975 # of these functions, because if the builtin cannot be used, a reference
976 # to the library function is emitted.
977 AC_CHECK_HEADERS(tgmath.h, ac_has_tgmath_h=yes, ac_has_tgmath_h=no)
978 AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
979 glibcxx_cv_c99_complex=no;
980 if test x"$ac_has_complex_h" = x"yes"; then
981 AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
982 GCC_TRY_COMPILE_OR_LINK(
983 [#include <complex.h>
984 typedef __complex__ float float_type;
985 typedef __complex__ double double_type;
986 typedef __complex__ long double ld_type;
987 volatile float_type tmpf;
988 volatile double_type tmpd;
989 volatile ld_type tmpld;
990 volatile float f;
991 volatile double d;
992 volatile long double ld;],
993 [f = cabsf(tmpf);
994 f = cargf(tmpf);
995 tmpf = ccosf(tmpf);
996 tmpf = ccoshf(tmpf);
997 tmpf = cexpf(tmpf);
998 tmpf = clogf(tmpf);
999 tmpf = csinf(tmpf);
1000 tmpf = csinhf(tmpf);
1001 tmpf = csqrtf(tmpf);
1002 tmpf = ctanf(tmpf);
1003 tmpf = ctanhf(tmpf);
1004 tmpf = cpowf(tmpf, tmpf);
1005 tmpf = cprojf(tmpf);
1006 d = cabs(tmpd);
1007 d = carg(tmpd);
1008 tmpd = ccos(tmpd);
1009 tmpd = ccosh(tmpd);
1010 tmpd = cexp(tmpd);
1011 tmpd = clog(tmpd);
1012 tmpd = csin(tmpd);
1013 tmpd = csinh(tmpd);
1014 tmpd = csqrt(tmpd);
1015 tmpd = ctan(tmpd);
1016 tmpd = ctanh(tmpd);
1017 tmpd = cpow(tmpd, tmpd);
1018 tmpd = cproj(tmpd);
1019 ld = cabsl(tmpld);
1020 ld = cargl(tmpld);
1021 tmpld = ccosl(tmpld);
1022 tmpld = ccoshl(tmpld);
1023 tmpld = cexpl(tmpld);
1024 tmpld = clogl(tmpld);
1025 tmpld = csinl(tmpld);
1026 tmpld = csinhl(tmpld);
1027 tmpld = csqrtl(tmpld);
1028 tmpld = ctanl(tmpld);
1029 tmpld = ctanhl(tmpld);
1030 tmpld = cpowl(tmpld, tmpld);
1031 tmpld = cprojl(tmpld);
1032 ],[glibcxx_cv_c99_complex=yes], [glibcxx_cv_c99_complex=no])
1033 fi
1034 AC_MSG_RESULT($glibcxx_cv_c99_complex)
1035 if test x"$glibcxx_cv_c99_complex" = x"yes"; then
1036 AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX, 1,
1037 [Define if C99 functions in <complex.h> should be used in
1038 <complex>. Using compiler builtins for these functions requires
1039 corresponding C99 library functions to be present.])
1040 fi
1042 # Check for the existence in <stdio.h> of vscanf, et. al.
1043 AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
1044 AC_CACHE_VAL(glibcxx_cv_c99_stdio, [
1045 GCC_TRY_COMPILE_OR_LINK(
1046 [#include <stdio.h>
1047 #include <stdarg.h>
1048 void foo(char* fmt, ...)
1049 {
1050 va_list args; va_start(args, fmt);
1051 vfscanf(stderr, "%i", args);
1052 vscanf("%i", args);
1053 vsnprintf(fmt, 0, "%i", args);
1054 vsscanf(fmt, "%i", args);
1055 }],
1056 [snprintf("12", 0, "%i");],
1057 [glibcxx_cv_c99_stdio=yes], [glibcxx_cv_c99_stdio=no])
1058 ])
1059 AC_MSG_RESULT($glibcxx_cv_c99_stdio)
1061 # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1062 AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1063 AC_CACHE_VAL(glibcxx_cv_c99_stdlib, [
1064 GCC_TRY_COMPILE_OR_LINK(
1065 [#include <stdlib.h>
1066 volatile float f;
1067 volatile long double ld;
1068 volatile unsigned long long ll;
1069 lldiv_t mydivt;],
1070 [char* tmp;
1071 f = strtof("gnu", &tmp);
1072 ld = strtold("gnu", &tmp);
1073 ll = strtoll("gnu", &tmp, 10);
1074 ll = strtoull("gnu", &tmp, 10);
1075 ll = llabs(10);
1076 mydivt = lldiv(10,1);
1077 ll = mydivt.quot;
1078 ll = mydivt.rem;
1079 ll = atoll("10");
1080 _Exit(0);
1081 ],[glibcxx_cv_c99_stdlib=yes], [glibcxx_cv_c99_stdlib=no])
1082 ])
1083 AC_MSG_RESULT($glibcxx_cv_c99_stdlib)
1085 # Check for the existence in <wchar.h> of wcstold, etc.
1086 glibcxx_cv_c99_wchar=no;
1087 if test x"$ac_has_wchar_h" = xyes &&
1088 test x"$ac_has_wctype_h" = xyes; then
1089 AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
1090 AC_TRY_COMPILE([#include <wchar.h>
1091 namespace test
1092 {
1093 using ::wcstold;
1094 using ::wcstoll;
1095 using ::wcstoull;
1096 }
1097 ],[],[glibcxx_cv_c99_wchar=yes], [glibcxx_cv_c99_wchar=no])
1099 # Checks for wide character functions that may not be present.
1100 # Injection of these is wrapped with guard macros.
1101 # NB: only put functions here, instead of immediately above, if
1102 # absolutely necessary.
1103 AC_TRY_COMPILE([#include <wchar.h>
1104 namespace test { using ::vfwscanf; } ], [],
1105 [AC_DEFINE(HAVE_VFWSCANF,1,
1106 [Defined if vfwscanf exists.])],[])
1108 AC_TRY_COMPILE([#include <wchar.h>
1109 namespace test { using ::vswscanf; } ], [],
1110 [AC_DEFINE(HAVE_VSWSCANF,1,
1111 [Defined if vswscanf exists.])],[])
1113 AC_TRY_COMPILE([#include <wchar.h>
1114 namespace test { using ::vwscanf; } ], [],
1115 [AC_DEFINE(HAVE_VWSCANF,1,[Defined if vwscanf exists.])],[])
1117 AC_TRY_COMPILE([#include <wchar.h>
1118 namespace test { using ::wcstof; } ], [],
1119 [AC_DEFINE(HAVE_WCSTOF,1,[Defined if wcstof exists.])],[])
1121 AC_TRY_COMPILE([#include <wctype.h>],
1122 [ wint_t t; int i = iswblank(t);],
1123 [AC_DEFINE(HAVE_ISWBLANK,1,
1124 [Defined if iswblank exists.])],[])
1126 AC_MSG_RESULT($glibcxx_cv_c99_wchar)
1127 fi
1129 # Option parsed, now set things appropriately.
1130 if test x"$glibcxx_cv_c99_math" = x"no" ||
1131 test x"$glibcxx_cv_c99_complex" = x"no" ||
1132 test x"$glibcxx_cv_c99_stdio" = x"no" ||
1133 test x"$glibcxx_cv_c99_stdlib" = x"no" ||
1134 test x"$glibcxx_cv_c99_wchar" = x"no"; then
1135 enable_c99=no;
1136 else
1137 AC_DEFINE(_GLIBCXX_USE_C99, 1,
1138 [Define if C99 functions or macros from <wchar.h>, <math.h>,
1139 <complex.h>, <stdio.h>, and <stdlib.h> can be used or exposed.])
1140 fi
1142 gcc_no_link="$ac_save_gcc_no_link"
1143 LIBS="$ac_save_LIBS"
1144 CXXFLAGS="$ac_save_CXXFLAGS"
1145 AC_LANG_RESTORE
1146 fi
1148 AC_MSG_CHECKING([for fully enabled ISO C99 support])
1149 AC_MSG_RESULT($enable_c99)
1150 ])
1153 dnl
1154 dnl Check for clock_gettime, nanosleep and sched_yield, used in the
1155 dnl implementation of 20.11.7 [time.clock], and 30.3.2 [thread.thread.this]
1156 dnl in the C++11 standard.
1157 dnl
1158 dnl --enable-libstdcxx-time
1159 dnl --enable-libstdcxx-time=yes
1160 dnl checks for the availability of monotonic and realtime clocks,
1161 dnl nanosleep and sched_yield in libc and libposix4 and, if needed,
1162 dnl links in the latter.
1163 dnl --enable-libstdcxx-time=rt
1164 dnl also searches (and, if needed, links) librt. Note that this is
1165 dnl not always desirable because, in glibc 2.16 and earlier, for
1166 dnl example, in turn it triggers the linking of libpthread too,
1167 dnl which activates locking,
1168 dnl a large overhead for single-thread programs.
1169 dnl --enable-libstdcxx-time=no
1170 dnl --disable-libstdcxx-time
1171 dnl disables the checks completely
1172 dnl
1173 dnl N.B. Darwin provides nanosleep but doesn't support the whole POSIX
1174 dnl Timers option, so doesn't define _POSIX_TIMERS. Because the test
1175 dnl below fails Darwin unconditionally defines _GLIBCXX_USE_NANOSLEEP in
1176 dnl os_defines.h and also defines _GLIBCXX_USE_SCHED_YIELD.
1177 dnl
1178 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_TIME], [
1180 GLIBCXX_ENABLE(libstdcxx-time,auto,[[[=KIND]]],
1181 [use KIND for check type],
1182 [permit yes|no|rt])
1184 AC_LANG_SAVE
1185 AC_LANG_CPLUSPLUS
1186 ac_save_CXXFLAGS="$CXXFLAGS"
1187 CXXFLAGS="$CXXFLAGS -fno-exceptions"
1188 ac_save_LIBS="$LIBS"
1190 ac_has_clock_monotonic=no
1191 ac_has_clock_realtime=no
1192 ac_has_nanosleep=no
1193 ac_has_sched_yield=no
1195 if test x"$enable_libstdcxx_time" = x"auto"; then
1197 case "${target_os}" in
1198 cygwin*)
1199 ac_has_nanosleep=yes
1200 ;;
1201 darwin*)
1202 ac_has_nanosleep=yes
1203 ac_has_sched_yield=yes
1204 ;;
1205 gnu* | linux* | kfreebsd*-gnu | knetbsd*-gnu)
1206 AC_MSG_CHECKING([for at least GNU libc 2.17])
1207 AC_TRY_COMPILE(
1208 [#include <features.h>],
1209 [
1210 #if ! __GLIBC_PREREQ(2, 17)
1211 #error
1212 #endif
1213 ],
1214 [glibcxx_glibc217=yes], [glibcxx_glibc217=no])
1215 AC_MSG_RESULT($glibcxx_glibc217)
1217 if test x"$glibcxx_glibc217" = x"yes"; then
1218 ac_has_clock_monotonic=yes
1219 ac_has_clock_realtime=yes
1220 fi
1221 ac_has_nanosleep=yes
1222 ac_has_sched_yield=yes
1223 ;;
1224 freebsd*|netbsd*)
1225 ac_has_clock_monotonic=yes
1226 ac_has_clock_realtime=yes
1227 ac_has_nanosleep=yes
1228 ac_has_sched_yield=yes
1229 ;;
1230 openbsd*)
1231 ac_has_clock_monotonic=yes
1232 ac_has_clock_realtime=yes
1233 ac_has_nanosleep=yes
1234 ;;
1235 solaris*)
1236 GLIBCXX_LIBS="$GLIBCXX_LIBS -lrt"
1237 ac_has_clock_monotonic=yes
1238 ac_has_clock_realtime=yes
1239 ac_has_nanosleep=yes
1240 ac_has_sched_yield=yes
1241 ;;
1242 esac
1244 elif test x"$enable_libstdcxx_time" != x"no"; then
1246 if test x"$enable_libstdcxx_time" = x"rt"; then
1247 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1248 AC_SEARCH_LIBS(nanosleep, [rt posix4])
1249 else
1250 AC_SEARCH_LIBS(clock_gettime, [posix4])
1251 AC_SEARCH_LIBS(nanosleep, [posix4])
1252 fi
1254 case "$ac_cv_search_clock_gettime" in
1255 -l*) GLIBCXX_LIBS=$ac_cv_search_clock_gettime
1256 ;;
1257 esac
1258 case "$ac_cv_search_nanosleep" in
1259 -l*) GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_nanosleep"
1260 ;;
1261 esac
1263 AC_SEARCH_LIBS(sched_yield, [rt posix4])
1265 case "$ac_cv_search_sched_yield" in
1266 -lposix4*)
1267 GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1268 ac_has_sched_yield=yes
1269 ;;
1270 -lrt*)
1271 if test x"$enable_libstdcxx_time" = x"rt"; then
1272 GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1273 ac_has_sched_yield=yes
1274 fi
1275 ;;
1276 *)
1277 ac_has_sched_yield=yes
1278 ;;
1279 esac
1281 AC_CHECK_HEADERS(unistd.h, ac_has_unistd_h=yes, ac_has_unistd_h=no)
1283 if test x"$ac_has_unistd_h" = x"yes"; then
1284 AC_MSG_CHECKING([for monotonic clock])
1285 AC_TRY_LINK(
1286 [#include <unistd.h>
1287 #include <time.h>
1288 ],
1289 [#if _POSIX_TIMERS > 0 && defined(_POSIX_MONOTONIC_CLOCK)
1290 timespec tp;
1291 #endif
1292 clock_gettime(CLOCK_MONOTONIC, &tp);
1293 ], [ac_has_clock_monotonic=yes], [ac_has_clock_monotonic=no])
1295 AC_MSG_RESULT($ac_has_clock_monotonic)
1297 AC_MSG_CHECKING([for realtime clock])
1298 AC_TRY_LINK(
1299 [#include <unistd.h>
1300 #include <time.h>
1301 ],
1302 [#if _POSIX_TIMERS > 0
1303 timespec tp;
1304 #endif
1305 clock_gettime(CLOCK_REALTIME, &tp);
1306 ], [ac_has_clock_realtime=yes], [ac_has_clock_realtime=no])
1308 AC_MSG_RESULT($ac_has_clock_realtime)
1310 AC_MSG_CHECKING([for nanosleep])
1311 AC_TRY_LINK(
1312 [#include <unistd.h>
1313 #include <time.h>
1314 ],
1315 [#if _POSIX_TIMERS > 0
1316 timespec tp;
1317 #endif
1318 nanosleep(&tp, 0);
1319 ], [ac_has_nanosleep=yes], [ac_has_nanosleep=no])
1321 AC_MSG_RESULT($ac_has_nanosleep)
1322 fi
1323 fi
1325 if test x"$ac_has_clock_monotonic" != x"yes"; then
1326 case ${target_os} in
1327 linux*)
1328 AC_MSG_CHECKING([for clock_gettime syscall])
1329 AC_TRY_COMPILE(
1330 [#include <unistd.h>
1331 #include <time.h>
1332 #include <sys/syscall.h>
1333 ],
1334 [#if _POSIX_TIMERS > 0 && defined(_POSIX_MONOTONIC_CLOCK)
1335 timespec tp;
1336 #endif
1337 syscall(SYS_clock_gettime, CLOCK_MONOTONIC, &tp);
1338 syscall(SYS_clock_gettime, CLOCK_REALTIME, &tp);
1339 ], [ac_has_clock_monotonic_syscall=yes], [ac_has_clock_monotonic_syscall=no])
1340 AC_MSG_RESULT($ac_has_clock_monotonic_syscall)
1341 if test x"$ac_has_clock_monotonic_syscall" = x"yes"; then
1342 AC_DEFINE(_GLIBCXX_USE_CLOCK_GETTIME_SYSCALL, 1,
1343 [ Defined if clock_gettime syscall has monotonic and realtime clock support. ])
1344 ac_has_clock_monotonic=yes
1345 ac_has_clock_realtime=yes
1346 fi;;
1347 esac
1348 fi
1350 if test x"$ac_has_clock_monotonic" = x"yes"; then
1351 AC_DEFINE(_GLIBCXX_USE_CLOCK_MONOTONIC, 1,
1352 [ Defined if clock_gettime has monotonic clock support. ])
1353 fi
1355 if test x"$ac_has_clock_realtime" = x"yes"; then
1356 AC_DEFINE(_GLIBCXX_USE_CLOCK_REALTIME, 1,
1357 [ Defined if clock_gettime has realtime clock support. ])
1358 fi
1360 if test x"$ac_has_sched_yield" = x"yes"; then
1361 AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1362 [ Defined if sched_yield is available. ])
1363 fi
1365 if test x"$ac_has_nanosleep" = x"yes"; then
1366 AC_DEFINE(_GLIBCXX_USE_NANOSLEEP, 1,
1367 [ Defined if nanosleep is available. ])
1368 else
1369 AC_MSG_CHECKING([for sleep])
1370 AC_TRY_COMPILE([#include <unistd.h>],
1371 [sleep(1)],
1372 [ac_has_sleep=yes],[ac_has_sleep=no])
1373 if test x"$ac_has_sleep" = x"yes"; then
1374 AC_DEFINE(HAVE_SLEEP,1, [Defined if sleep exists.])
1375 fi
1376 AC_MSG_RESULT($ac_has_sleep)
1377 AC_MSG_CHECKING([for usleep])
1378 AC_TRY_COMPILE([#include <unistd.h>],
1379 [sleep(1);
1380 usleep(100);],
1381 [ac_has_usleep=yes],[ac_has_usleep=no])
1382 if test x"$ac_has_usleep" = x"yes"; then
1383 AC_DEFINE(HAVE_USLEEP,1, [Defined if usleep exists.])
1384 fi
1385 AC_MSG_RESULT($ac_has_usleep)
1386 fi
1388 if test x"$ac_has_nanosleep$ac_has_sleep" = x"nono"; then
1389 AC_MSG_CHECKING([for Sleep])
1390 AC_TRY_COMPILE([#include <windows.h>],
1391 [Sleep(1)],
1392 [ac_has_win32_sleep=yes],[ac_has_win32_sleep=no])
1393 if test x"$ac_has_win32_sleep" = x"yes"; then
1394 AC_DEFINE(HAVE_WIN32_SLEEP,1, [Defined if Sleep exists.])
1395 fi
1396 AC_MSG_RESULT($ac_has_win32_sleep)
1397 fi
1399 AC_SUBST(GLIBCXX_LIBS)
1401 CXXFLAGS="$ac_save_CXXFLAGS"
1402 LIBS="$ac_save_LIBS"
1403 AC_LANG_RESTORE
1404 ])
1406 dnl
1407 dnl Check for gettimeofday, used in the implementation of 20.11.7
1408 dnl [time.clock] in the C++11 standard.
1409 dnl
1410 AC_DEFUN([GLIBCXX_CHECK_GETTIMEOFDAY], [
1412 AC_MSG_CHECKING([for gettimeofday])
1414 AC_LANG_SAVE
1415 AC_LANG_CPLUSPLUS
1416 ac_save_CXXFLAGS="$CXXFLAGS"
1417 CXXFLAGS="$CXXFLAGS -fno-exceptions"
1419 ac_has_gettimeofday=no;
1420 AC_CHECK_HEADERS(sys/time.h, ac_has_sys_time_h=yes, ac_has_sys_time_h=no)
1421 if test x"$ac_has_sys_time_h" = x"yes"; then
1422 AC_MSG_CHECKING([for gettimeofday])
1423 GCC_TRY_COMPILE_OR_LINK([#include <sys/time.h>],
1424 [timeval tv; gettimeofday(&tv, 0);],
1425 [ac_has_gettimeofday=yes], [ac_has_gettimeofday=no])
1427 AC_MSG_RESULT($ac_has_gettimeofday)
1428 fi
1430 if test x"$ac_has_gettimeofday" = x"yes"; then
1431 AC_DEFINE(_GLIBCXX_USE_GETTIMEOFDAY, 1,
1432 [ Defined if gettimeofday is available. ])
1433 fi
1435 CXXFLAGS="$ac_save_CXXFLAGS"
1436 AC_LANG_RESTORE
1437 ])
1439 dnl
1440 dnl Check for ISO/IEC 9899:1999 "C99" support to ISO/IEC DTR 19768 "TR1"
1441 dnl facilities in Chapter 8, "C compatibility".
1442 dnl
1443 AC_DEFUN([GLIBCXX_CHECK_C99_TR1], [
1445 AC_LANG_SAVE
1446 AC_LANG_CPLUSPLUS
1448 # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
1449 # undefined and fake C99 facilities may be spuriously enabled.
1450 ac_save_CXXFLAGS="$CXXFLAGS"
1451 CXXFLAGS="$CXXFLAGS -std=c++98"
1453 # Check for the existence of <complex.h> complex math functions used
1454 # by tr1/complex.
1455 AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
1456 ac_c99_complex_tr1=no;
1457 if test x"$ac_has_complex_h" = x"yes"; then
1458 AC_MSG_CHECKING([for ISO C99 support to TR1 in <complex.h>])
1459 AC_TRY_COMPILE([#include <complex.h>],
1460 [typedef __complex__ float float_type; float_type tmpf;
1461 cacosf(tmpf);
1462 casinf(tmpf);
1463 catanf(tmpf);
1464 cacoshf(tmpf);
1465 casinhf(tmpf);
1466 catanhf(tmpf);
1467 typedef __complex__ double double_type; double_type tmpd;
1468 cacos(tmpd);
1469 casin(tmpd);
1470 catan(tmpd);
1471 cacosh(tmpd);
1472 casinh(tmpd);
1473 catanh(tmpd);
1474 typedef __complex__ long double ld_type; ld_type tmpld;
1475 cacosl(tmpld);
1476 casinl(tmpld);
1477 catanl(tmpld);
1478 cacoshl(tmpld);
1479 casinhl(tmpld);
1480 catanhl(tmpld);
1481 ],[ac_c99_complex_tr1=yes], [ac_c99_complex_tr1=no])
1482 fi
1483 AC_MSG_RESULT($ac_c99_complex_tr1)
1484 if test x"$ac_c99_complex_tr1" = x"yes"; then
1485 AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX_TR1, 1,
1486 [Define if C99 functions in <complex.h> should be used in
1487 <tr1/complex>. Using compiler builtins for these functions
1488 requires corresponding C99 library functions to be present.])
1489 fi
1491 # Check for the existence of <ctype.h> functions.
1492 AC_MSG_CHECKING([for ISO C99 support to TR1 in <ctype.h>])
1493 AC_CACHE_VAL(glibcxx_cv_c99_ctype_tr1, [
1494 AC_TRY_COMPILE([#include <ctype.h>],
1495 [int ch;
1496 int ret;
1497 ret = isblank(ch);
1498 ],[glibcxx_cv_c99_ctype_tr1=yes],
1499 [glibcxx_cv_c99_ctype_tr1=no])
1500 ])
1501 AC_MSG_RESULT($glibcxx_cv_c99_ctype_tr1)
1502 if test x"$glibcxx_cv_c99_ctype_tr1" = x"yes"; then
1503 AC_DEFINE(_GLIBCXX_USE_C99_CTYPE_TR1, 1,
1504 [Define if C99 functions in <ctype.h> should be imported in
1505 <tr1/cctype> in namespace std::tr1.])
1506 fi
1508 # Check for the existence of <fenv.h> functions.
1509 AC_CHECK_HEADERS(fenv.h, ac_has_fenv_h=yes, ac_has_fenv_h=no)
1510 ac_c99_fenv_tr1=no;
1511 if test x"$ac_has_fenv_h" = x"yes"; then
1512 AC_MSG_CHECKING([for ISO C99 support to TR1 in <fenv.h>])
1513 AC_TRY_COMPILE([#include <fenv.h>],
1514 [int except, mode;
1515 fexcept_t* pflag;
1516 fenv_t* penv;
1517 int ret;
1518 ret = feclearexcept(except);
1519 ret = fegetexceptflag(pflag, except);
1520 ret = feraiseexcept(except);
1521 ret = fesetexceptflag(pflag, except);
1522 ret = fetestexcept(except);
1523 ret = fegetround();
1524 ret = fesetround(mode);
1525 ret = fegetenv(penv);
1526 ret = feholdexcept(penv);
1527 ret = fesetenv(penv);
1528 ret = feupdateenv(penv);
1529 ],[ac_c99_fenv_tr1=yes], [ac_c99_fenv_tr1=no])
1530 fi
1531 AC_MSG_RESULT($ac_c99_fenv_tr1)
1532 if test x"$ac_c99_fenv_tr1" = x"yes"; then
1533 AC_DEFINE(_GLIBCXX_USE_C99_FENV_TR1, 1,
1534 [Define if C99 functions in <fenv.h> should be imported in
1535 <tr1/cfenv> in namespace std::tr1.])
1536 fi
1538 # Check for the existence of <stdint.h> types.
1539 AC_MSG_CHECKING([for ISO C99 support to TR1 in <stdint.h>])
1540 AC_CACHE_VAL(glibcxx_cv_c99_stdint_tr1, [
1541 AC_TRY_COMPILE([#define __STDC_LIMIT_MACROS
1542 #define __STDC_CONSTANT_MACROS
1543 #include <stdint.h>],
1544 [typedef int8_t my_int8_t;
1545 my_int8_t i8 = INT8_MIN;
1546 i8 = INT8_MAX;
1547 typedef int16_t my_int16_t;
1548 my_int16_t i16 = INT16_MIN;
1549 i16 = INT16_MAX;
1550 typedef int32_t my_int32_t;
1551 my_int32_t i32 = INT32_MIN;
1552 i32 = INT32_MAX;
1553 typedef int64_t my_int64_t;
1554 my_int64_t i64 = INT64_MIN;
1555 i64 = INT64_MAX;
1556 typedef int_fast8_t my_int_fast8_t;
1557 my_int_fast8_t if8 = INT_FAST8_MIN;
1558 if8 = INT_FAST8_MAX;
1559 typedef int_fast16_t my_int_fast16_t;
1560 my_int_fast16_t if16 = INT_FAST16_MIN;
1561 if16 = INT_FAST16_MAX;
1562 typedef int_fast32_t my_int_fast32_t;
1563 my_int_fast32_t if32 = INT_FAST32_MIN;
1564 if32 = INT_FAST32_MAX;
1565 typedef int_fast64_t my_int_fast64_t;
1566 my_int_fast64_t if64 = INT_FAST64_MIN;
1567 if64 = INT_FAST64_MAX;
1568 typedef int_least8_t my_int_least8_t;
1569 my_int_least8_t il8 = INT_LEAST8_MIN;
1570 il8 = INT_LEAST8_MAX;
1571 typedef int_least16_t my_int_least16_t;
1572 my_int_least16_t il16 = INT_LEAST16_MIN;
1573 il16 = INT_LEAST16_MAX;
1574 typedef int_least32_t my_int_least32_t;
1575 my_int_least32_t il32 = INT_LEAST32_MIN;
1576 il32 = INT_LEAST32_MAX;
1577 typedef int_least64_t my_int_least64_t;
1578 my_int_least64_t il64 = INT_LEAST64_MIN;
1579 il64 = INT_LEAST64_MAX;
1580 typedef intmax_t my_intmax_t;
1581 my_intmax_t im = INTMAX_MAX;
1582 im = INTMAX_MIN;
1583 typedef intptr_t my_intptr_t;
1584 my_intptr_t ip = INTPTR_MAX;
1585 ip = INTPTR_MIN;
1586 typedef uint8_t my_uint8_t;
1587 my_uint8_t ui8 = UINT8_MAX;
1588 ui8 = UINT8_MAX;
1589 typedef uint16_t my_uint16_t;
1590 my_uint16_t ui16 = UINT16_MAX;
1591 ui16 = UINT16_MAX;
1592 typedef uint32_t my_uint32_t;
1593 my_uint32_t ui32 = UINT32_MAX;
1594 ui32 = UINT32_MAX;
1595 typedef uint64_t my_uint64_t;
1596 my_uint64_t ui64 = UINT64_MAX;
1597 ui64 = UINT64_MAX;
1598 typedef uint_fast8_t my_uint_fast8_t;
1599 my_uint_fast8_t uif8 = UINT_FAST8_MAX;
1600 uif8 = UINT_FAST8_MAX;
1601 typedef uint_fast16_t my_uint_fast16_t;
1602 my_uint_fast16_t uif16 = UINT_FAST16_MAX;
1603 uif16 = UINT_FAST16_MAX;
1604 typedef uint_fast32_t my_uint_fast32_t;
1605 my_uint_fast32_t uif32 = UINT_FAST32_MAX;
1606 uif32 = UINT_FAST32_MAX;
1607 typedef uint_fast64_t my_uint_fast64_t;
1608 my_uint_fast64_t uif64 = UINT_FAST64_MAX;
1609 uif64 = UINT_FAST64_MAX;
1610 typedef uint_least8_t my_uint_least8_t;
1611 my_uint_least8_t uil8 = UINT_LEAST8_MAX;
1612 uil8 = UINT_LEAST8_MAX;
1613 typedef uint_least16_t my_uint_least16_t;
1614 my_uint_least16_t uil16 = UINT_LEAST16_MAX;
1615 uil16 = UINT_LEAST16_MAX;
1616 typedef uint_least32_t my_uint_least32_t;
1617 my_uint_least32_t uil32 = UINT_LEAST32_MAX;
1618 uil32 = UINT_LEAST32_MAX;
1619 typedef uint_least64_t my_uint_least64_t;
1620 my_uint_least64_t uil64 = UINT_LEAST64_MAX;
1621 uil64 = UINT_LEAST64_MAX;
1622 typedef uintmax_t my_uintmax_t;
1623 my_uintmax_t uim = UINTMAX_MAX;
1624 uim = UINTMAX_MAX;
1625 typedef uintptr_t my_uintptr_t;
1626 my_uintptr_t uip = UINTPTR_MAX;
1627 uip = UINTPTR_MAX;
1628 ],[glibcxx_cv_c99_stdint_tr1=yes],
1629 [glibcxx_cv_c99_stdint_tr1=no])
1630 ])
1631 AC_MSG_RESULT($glibcxx_cv_c99_stdint_tr1)
1632 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1633 AC_DEFINE(_GLIBCXX_USE_C99_STDINT_TR1, 1,
1634 [Define if C99 types in <stdint.h> should be imported in
1635 <tr1/cstdint> in namespace std::tr1.])
1636 fi
1638 # Check for the existence of <math.h> functions.
1639 AC_MSG_CHECKING([for ISO C99 support to TR1 in <math.h>])
1640 AC_CACHE_VAL(glibcxx_cv_c99_math_tr1, [
1641 AC_TRY_COMPILE([#include <math.h>],
1642 [typedef double_t my_double_t;
1643 typedef float_t my_float_t;
1644 acosh(0.0);
1645 acoshf(0.0f);
1646 acoshl(0.0l);
1647 asinh(0.0);
1648 asinhf(0.0f);
1649 asinhl(0.0l);
1650 atanh(0.0);
1651 atanhf(0.0f);
1652 atanhl(0.0l);
1653 cbrt(0.0);
1654 cbrtf(0.0f);
1655 cbrtl(0.0l);
1656 copysign(0.0, 0.0);
1657 copysignf(0.0f, 0.0f);
1658 copysignl(0.0l, 0.0l);
1659 erf(0.0);
1660 erff(0.0f);
1661 erfl(0.0l);
1662 erfc(0.0);
1663 erfcf(0.0f);
1664 erfcl(0.0l);
1665 exp2(0.0);
1666 exp2f(0.0f);
1667 exp2l(0.0l);
1668 expm1(0.0);
1669 expm1f(0.0f);
1670 expm1l(0.0l);
1671 fdim(0.0, 0.0);
1672 fdimf(0.0f, 0.0f);
1673 fdiml(0.0l, 0.0l);
1674 fma(0.0, 0.0, 0.0);
1675 fmaf(0.0f, 0.0f, 0.0f);
1676 fmal(0.0l, 0.0l, 0.0l);
1677 fmax(0.0, 0.0);
1678 fmaxf(0.0f, 0.0f);
1679 fmaxl(0.0l, 0.0l);
1680 fmin(0.0, 0.0);
1681 fminf(0.0f, 0.0f);
1682 fminl(0.0l, 0.0l);
1683 hypot(0.0, 0.0);
1684 hypotf(0.0f, 0.0f);
1685 hypotl(0.0l, 0.0l);
1686 ilogb(0.0);
1687 ilogbf(0.0f);
1688 ilogbl(0.0l);
1689 lgamma(0.0);
1690 lgammaf(0.0f);
1691 lgammal(0.0l);
1692 llrint(0.0);
1693 llrintf(0.0f);
1694 llrintl(0.0l);
1695 llround(0.0);
1696 llroundf(0.0f);
1697 llroundl(0.0l);
1698 log1p(0.0);
1699 log1pf(0.0f);
1700 log1pl(0.0l);
1701 log2(0.0);
1702 log2f(0.0f);
1703 log2l(0.0l);
1704 logb(0.0);
1705 logbf(0.0f);
1706 logbl(0.0l);
1707 lrint(0.0);
1708 lrintf(0.0f);
1709 lrintl(0.0l);
1710 lround(0.0);
1711 lroundf(0.0f);
1712 lroundl(0.0l);
1713 nan(0);
1714 nanf(0);
1715 nanl(0);
1716 nearbyint(0.0);
1717 nearbyintf(0.0f);
1718 nearbyintl(0.0l);
1719 nextafter(0.0, 0.0);
1720 nextafterf(0.0f, 0.0f);
1721 nextafterl(0.0l, 0.0l);
1722 nexttoward(0.0, 0.0);
1723 nexttowardf(0.0f, 0.0f);
1724 nexttowardl(0.0l, 0.0l);
1725 remainder(0.0, 0.0);
1726 remainderf(0.0f, 0.0f);
1727 remainderl(0.0l, 0.0l);
1728 remquo(0.0, 0.0, 0);
1729 remquof(0.0f, 0.0f, 0);
1730 remquol(0.0l, 0.0l, 0);
1731 rint(0.0);
1732 rintf(0.0f);
1733 rintl(0.0l);
1734 round(0.0);
1735 roundf(0.0f);
1736 roundl(0.0l);
1737 scalbln(0.0, 0l);
1738 scalblnf(0.0f, 0l);
1739 scalblnl(0.0l, 0l);
1740 scalbn(0.0, 0);
1741 scalbnf(0.0f, 0);
1742 scalbnl(0.0l, 0);
1743 tgamma(0.0);
1744 tgammaf(0.0f);
1745 tgammal(0.0l);
1746 trunc(0.0);
1747 truncf(0.0f);
1748 truncl(0.0l);
1749 ],[glibcxx_cv_c99_math_tr1=yes], [glibcxx_cv_c99_math_tr1=no])
1750 ])
1751 AC_MSG_RESULT($glibcxx_cv_c99_math_tr1)
1752 if test x"$glibcxx_cv_c99_math_tr1" = x"yes"; then
1753 AC_DEFINE(_GLIBCXX_USE_C99_MATH_TR1, 1,
1754 [Define if C99 functions or macros in <math.h> should be imported
1755 in <tr1/cmath> in namespace std::tr1.])
1756 fi
1758 # Check for the existence of <inttypes.h> functions (NB: doesn't make
1759 # sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1760 ac_c99_inttypes_tr1=no;
1761 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1762 AC_MSG_CHECKING([for ISO C99 support to TR1 in <inttypes.h>])
1763 AC_TRY_COMPILE([#include <inttypes.h>],
1764 [intmax_t i, numer, denom, base;
1765 const char* s;
1766 char** endptr;
1767 intmax_t ret = imaxabs(i);
1768 imaxdiv_t dret = imaxdiv(numer, denom);
1769 ret = strtoimax(s, endptr, base);
1770 uintmax_t uret = strtoumax(s, endptr, base);
1771 ],[ac_c99_inttypes_tr1=yes], [ac_c99_inttypes_tr1=no])
1772 fi
1773 AC_MSG_RESULT($ac_c99_inttypes_tr1)
1774 if test x"$ac_c99_inttypes_tr1" = x"yes"; then
1775 AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_TR1, 1,
1776 [Define if C99 functions in <inttypes.h> should be imported in
1777 <tr1/cinttypes> in namespace std::tr1.])
1778 fi
1780 # Check for the existence of whcar_t <inttypes.h> functions (NB: doesn't
1781 # make sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1782 ac_c99_inttypes_wchar_t_tr1=no;
1783 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1784 AC_MSG_CHECKING([for wchar_t ISO C99 support to TR1 in <inttypes.h>])
1785 AC_TRY_COMPILE([#include <inttypes.h>],
1786 [intmax_t base;
1787 const wchar_t* s;
1788 wchar_t** endptr;
1789 intmax_t ret = wcstoimax(s, endptr, base);
1790 uintmax_t uret = wcstoumax(s, endptr, base);
1791 ],[ac_c99_inttypes_wchar_t_tr1=yes],
1792 [ac_c99_inttypes_wchar_t_tr1=no])
1793 fi
1794 AC_MSG_RESULT($ac_c99_inttypes_wchar_t_tr1)
1795 if test x"$ac_c99_inttypes_wchar_t_tr1" = x"yes"; then
1796 AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_WCHAR_T_TR1, 1,
1797 [Define if wchar_t C99 functions in <inttypes.h> should be
1798 imported in <tr1/cinttypes> in namespace std::tr1.])
1799 fi
1801 # Check for the existence of the <stdbool.h> header.
1802 AC_CHECK_HEADERS(stdbool.h)
1804 # Check for the existence of the <stdalign.h> header.
1805 AC_CHECK_HEADERS(stdalign.h)
1807 CXXFLAGS="$ac_save_CXXFLAGS"
1808 AC_LANG_RESTORE
1809 ])
1811 dnl
1812 dnl Check whether "/dev/random" and "/dev/urandom" are available for the
1813 dnl random_device of "TR1" (Chapter 5.1, "Random number generation").
1814 dnl
1815 AC_DEFUN([GLIBCXX_CHECK_RANDOM_TR1], [
1817 AC_MSG_CHECKING([for "/dev/random" and "/dev/urandom" for TR1 random_device])
1818 AC_CACHE_VAL(glibcxx_cv_random_tr1, [
1819 if test -r /dev/random && test -r /dev/urandom; then
1820 ## For MSys environment the test above is detect as false-positive
1821 ## on mingw-targets. So disable it explicit for them.
1822 case ${target_os} in
1823 *mingw*) glibcxx_cv_random_tr1=no ;;
1824 *) glibcxx_cv_random_tr1=yes ;;
1825 esac
1826 else
1827 glibcxx_cv_random_tr1=no;
1828 fi
1829 ])
1830 AC_MSG_RESULT($glibcxx_cv_random_tr1)
1832 if test x"$glibcxx_cv_random_tr1" = x"yes"; then
1833 AC_DEFINE(_GLIBCXX_USE_RANDOM_TR1, 1,
1834 [Define if /dev/random and /dev/urandom are available for
1835 the random_device of TR1 (Chapter 5.1).])
1836 fi
1838 ])
1840 dnl
1841 dnl Compute the EOF, SEEK_CUR, and SEEK_END integer constants.
1842 dnl
1843 AC_DEFUN([GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS], [
1845 AC_CACHE_CHECK([for the value of EOF], glibcxx_cv_stdio_eof, [
1846 AC_COMPUTE_INT([glibcxx_cv_stdio_eof], [[EOF]],
1847 [#include <stdio.h>],
1848 [AC_MSG_ERROR([computing EOF failed])])
1849 ])
1850 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_EOF, $glibcxx_cv_stdio_eof,
1851 [Define to the value of the EOF integer constant.])
1853 AC_CACHE_CHECK([for the value of SEEK_CUR], glibcxx_cv_stdio_seek_cur, [
1854 AC_COMPUTE_INT([glibcxx_cv_stdio_seek_cur], [[SEEK_CUR]],
1855 [#include <stdio.h>],
1856 [AC_MSG_ERROR([computing SEEK_CUR failed])])
1857 ])
1858 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_CUR, $glibcxx_cv_stdio_seek_cur,
1859 [Define to the value of the SEEK_CUR integer constant.])
1861 AC_CACHE_CHECK([for the value of SEEK_END], glibcxx_cv_stdio_seek_end, [
1862 AC_COMPUTE_INT([glibcxx_cv_stdio_seek_end], [[SEEK_END]],
1863 [#include <stdio.h>],
1864 [AC_MSG_ERROR([computing SEEK_END failed])])
1865 ])
1866 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_END, $glibcxx_cv_stdio_seek_end,
1867 [Define to the value of the SEEK_END integer constant.])
1868 ])
1870 dnl
1871 dnl Check whether required C++ overloads are present in <stdio.h>.
1872 dnl
1873 AC_DEFUN([GLIBCXX_CHECK_STDIO_PROTO], [
1875 AC_LANG_SAVE
1876 AC_LANG_CPLUSPLUS
1878 AC_MSG_CHECKING([for gets declaration])
1879 AC_CACHE_VAL(glibcxx_cv_gets, [
1880 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1881 [#include <stdio.h>
1882 namespace test
1883 {
1884 using ::gets;
1885 }
1886 ])],
1887 [glibcxx_cv_gets=yes],
1888 [glibcxx_cv_gets=no]
1889 )])
1891 if test $glibcxx_cv_gets = yes; then
1892 AC_DEFINE(HAVE_GETS, 1, [Define if gets is available in <stdio.h>.])
1893 fi
1894 AC_MSG_RESULT($glibcxx_cv_gets)
1896 AC_LANG_RESTORE
1897 ])
1899 dnl
1900 dnl Check whether macros, etc are present for <system_error>
1901 dnl
1902 AC_DEFUN([GLIBCXX_CHECK_SYSTEM_ERROR], [
1904 m4_pushdef([n_syserr], [1])dnl
1905 m4_foreach([syserr], [EOWNERDEAD, ENOTRECOVERABLE, ENOLINK, EPROTO, ENODATA,
1906 ENOSR, ENOSTR, ETIME, EBADMSG, ECANCELED,
1907 EOVERFLOW, ENOTSUP, EIDRM, ETXTBSY,
1908 ECHILD, ENOSPC, EPERM,
1909 ETIMEDOUT, EWOULDBLOCK],
1910 [m4_pushdef([SYSERR], m4_toupper(syserr))dnl
1911 AC_MSG_CHECKING([for syserr])
1912 AC_CACHE_VAL([glibcxx_cv_system_error[]n_syserr], [
1913 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
1914 [int i = syserr;])],
1915 [glibcxx_cv_system_error[]n_syserr=yes],
1916 [glibcxx_cv_system_error[]n_syserr=no])
1917 ])
1918 AC_MSG_RESULT([$glibcxx_cv_system_error[]n_syserr])
1919 if test x"$glibcxx_cv_system_error[]n_syserr" = x"yes"; then
1920 AC_DEFINE([HAVE_]SYSERR, 1, [Define if ]syserr[ exists.])
1921 fi
1922 m4_define([n_syserr], m4_incr(n_syserr))dnl
1923 m4_popdef([SYSERR])dnl
1924 ])
1925 m4_popdef([n_syserr])dnl
1926 ])
1928 dnl
1929 dnl Check for what type of C headers to use.
1930 dnl
1931 dnl --enable-cheaders= [does stuff].
1932 dnl --disable-cheaders [does not do anything, really].
1933 dnl + Usage: GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1934 dnl Where DEFAULT is either 'c' or 'c_std' or 'c_global'.
1935 dnl
1936 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1937 GLIBCXX_ENABLE(cheaders,$1,[[[=KIND]]],
1938 [construct "C" headers for g++], [permit c|c_std|c_global])
1939 AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1941 C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1943 # Allow overrides to configure.host here.
1944 if test $enable_cheaders = c_global; then
1945 c_compatibility=yes
1946 fi
1948 AC_SUBST(C_INCLUDE_DIR)
1949 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1950 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1951 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_GLOBAL, test $enable_cheaders = c_global)
1952 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1953 ])
1956 dnl
1957 dnl Check for which locale library to use. The choice is mapped to
1958 dnl a subdirectory of config/locale.
1959 dnl
1960 dnl Default is generic.
1961 dnl
1962 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
1963 GLIBCXX_ENABLE(clocale,auto,[[[=MODEL]]],
1964 [use MODEL for target locale package],
1965 [permit generic|gnu|ieee_1003.1-2001|newlib|yes|no|auto])
1967 # Deal with gettext issues. Default to not using it (=no) until we detect
1968 # support for it later. Let the user turn it off via --e/d, but let that
1969 # default to on for easier handling.
1970 USE_NLS=no
1971 AC_ARG_ENABLE(nls,
1972 AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1973 [],
1974 [enable_nls=yes])
1976 # Either a known package, or "auto"
1977 if test $enable_clocale = no || test $enable_clocale = yes; then
1978 enable_clocale=auto
1979 fi
1980 enable_clocale_flag=$enable_clocale
1982 # Probe for locale model to use if none specified.
1983 # Default to "generic".
1984 if test $enable_clocale_flag = auto; then
1985 case ${target_os} in
1986 linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1987 enable_clocale_flag=gnu
1988 ;;
1989 darwin* | freebsd*)
1990 enable_clocale_flag=darwin
1991 ;;
1992 openbsd*)
1993 enable_clocale_flag=newlib
1994 ;;
1995 *)
1996 if test x"$with_newlib" = x"yes"; then
1997 enable_clocale_flag=newlib
1998 else
1999 enable_clocale_flag=generic
2000 fi
2001 ;;
2002 esac
2003 fi
2005 # Sanity check model, and test for special functionality.
2006 if test $enable_clocale_flag = gnu; then
2007 AC_EGREP_CPP([_GLIBCXX_ok], [
2008 #include <features.h>
2009 #if (__GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 3)) && !defined(__UCLIBC__)
2010 _GLIBCXX_ok
2011 #endif
2012 ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
2014 # Set it to scream when it hurts.
2015 ac_save_CFLAGS="$CFLAGS"
2016 CFLAGS="-Wimplicit-function-declaration -Werror"
2018 # Use strxfrm_l if available.
2019 AC_TRY_COMPILE([#define _GNU_SOURCE 1
2020 #include <string.h>
2021 #include <locale.h>],
2022 [char s[128]; __locale_t loc; strxfrm_l(s, "C", 5, loc);],
2023 AC_DEFINE(HAVE_STRXFRM_L, 1,
2024 [Define if strxfrm_l is available in <string.h>.]),)
2026 # Use strerror_l if available.
2027 AC_TRY_COMPILE([#define _GNU_SOURCE 1
2028 #include <string.h>
2029 #include <locale.h>],
2030 [__locale_t loc; strerror_l(5, loc);],
2031 AC_DEFINE(HAVE_STRERROR_L, 1,
2032 [Define if strerror_l is available in <string.h>.]),)
2034 CFLAGS="$ac_save_CFLAGS"
2035 fi
2037 # Perhaps use strerror_r if available, and strerror_l isn't.
2038 ac_save_CFLAGS="$CFLAGS"
2039 CFLAGS="-Wimplicit-function-declaration -Werror"
2040 AC_TRY_COMPILE([#define _GNU_SOURCE 1
2041 #include <string.h>
2042 #include <locale.h>],
2043 [char s[128]; strerror_r(5, s, 128);],
2044 AC_DEFINE(HAVE_STRERROR_R, 1,
2045 [Define if strerror_r is available in <string.h>.]),)
2046 CFLAGS="$ac_save_CFLAGS"
2048 # Set configure bits for specified locale package
2049 AC_MSG_CHECKING([for C locale to use])
2050 case ${enable_clocale_flag} in
2051 generic)
2052 AC_MSG_RESULT(generic)
2054 CLOCALE_H=config/locale/generic/c_locale.h
2055 CLOCALE_CC=config/locale/generic/c_locale.cc
2056 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2057 CCOLLATE_CC=config/locale/generic/collate_members.cc
2058 CCTYPE_CC=config/locale/generic/ctype_members.cc
2059 CMESSAGES_H=config/locale/generic/messages_members.h
2060 CMESSAGES_CC=config/locale/generic/messages_members.cc
2061 CMONEY_CC=config/locale/generic/monetary_members.cc
2062 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2063 CTIME_H=config/locale/generic/time_members.h
2064 CTIME_CC=config/locale/generic/time_members.cc
2065 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2066 ;;
2067 darwin)
2068 AC_MSG_RESULT(darwin or freebsd)
2070 CLOCALE_H=config/locale/generic/c_locale.h
2071 CLOCALE_CC=config/locale/generic/c_locale.cc
2072 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2073 CCOLLATE_CC=config/locale/generic/collate_members.cc
2074 CCTYPE_CC=config/locale/darwin/ctype_members.cc
2075 CMESSAGES_H=config/locale/generic/messages_members.h
2076 CMESSAGES_CC=config/locale/generic/messages_members.cc
2077 CMONEY_CC=config/locale/generic/monetary_members.cc
2078 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2079 CTIME_H=config/locale/generic/time_members.h
2080 CTIME_CC=config/locale/generic/time_members.cc
2081 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2082 ;;
2084 gnu)
2085 AC_MSG_RESULT(gnu)
2087 # Declare intention to use gettext, and add support for specific
2088 # languages.
2089 # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
2090 ALL_LINGUAS="de fr"
2092 # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
2093 AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
2094 if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
2095 USE_NLS=yes
2096 fi
2097 # Export the build objects.
2098 for ling in $ALL_LINGUAS; do \
2099 glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
2100 glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
2101 done
2102 AC_SUBST(glibcxx_MOFILES)
2103 AC_SUBST(glibcxx_POFILES)
2105 CLOCALE_H=config/locale/gnu/c_locale.h
2106 CLOCALE_CC=config/locale/gnu/c_locale.cc
2107 CCODECVT_CC=config/locale/gnu/codecvt_members.cc
2108 CCOLLATE_CC=config/locale/gnu/collate_members.cc
2109 CCTYPE_CC=config/locale/gnu/ctype_members.cc
2110 CMESSAGES_H=config/locale/gnu/messages_members.h
2111 CMESSAGES_CC=config/locale/gnu/messages_members.cc
2112 CMONEY_CC=config/locale/gnu/monetary_members.cc
2113 CNUMERIC_CC=config/locale/gnu/numeric_members.cc
2114 CTIME_H=config/locale/gnu/time_members.h
2115 CTIME_CC=config/locale/gnu/time_members.cc
2116 CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
2117 ;;
2118 ieee_1003.1-2001)
2119 AC_MSG_RESULT(IEEE 1003.1)
2121 CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
2122 CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
2123 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2124 CCOLLATE_CC=config/locale/generic/collate_members.cc
2125 CCTYPE_CC=config/locale/generic/ctype_members.cc
2126 CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
2127 CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
2128 CMONEY_CC=config/locale/generic/monetary_members.cc
2129 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2130 CTIME_H=config/locale/generic/time_members.h
2131 CTIME_CC=config/locale/generic/time_members.cc
2132 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2133 ;;
2134 newlib)
2135 AC_MSG_RESULT(newlib)
2137 CLOCALE_H=config/locale/generic/c_locale.h
2138 CLOCALE_CC=config/locale/generic/c_locale.cc
2139 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2140 CCOLLATE_CC=config/locale/generic/collate_members.cc
2141 CCTYPE_CC=config/locale/newlib/ctype_members.cc
2142 CMESSAGES_H=config/locale/generic/messages_members.h
2143 CMESSAGES_CC=config/locale/generic/messages_members.cc
2144 CMONEY_CC=config/locale/generic/monetary_members.cc
2145 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2146 CTIME_H=config/locale/generic/time_members.h
2147 CTIME_CC=config/locale/generic/time_members.cc
2148 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2149 ;;
2150 esac
2152 # This is where the testsuite looks for locale catalogs, using the
2153 # -DLOCALEDIR define during testsuite compilation.
2154 glibcxx_localedir=${glibcxx_builddir}/po/share/locale
2155 AC_SUBST(glibcxx_localedir)
2157 # A standalone libintl (e.g., GNU libintl) may be in use.
2158 if test $USE_NLS = yes; then
2159 AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
2160 AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
2161 fi
2162 if test $USE_NLS = yes; then
2163 AC_DEFINE(_GLIBCXX_USE_NLS, 1,
2164 [Define if NLS translations are to be used.])
2165 fi
2167 AC_SUBST(USE_NLS)
2168 AC_SUBST(CLOCALE_H)
2169 AC_SUBST(CMESSAGES_H)
2170 AC_SUBST(CCODECVT_CC)
2171 AC_SUBST(CCOLLATE_CC)
2172 AC_SUBST(CCTYPE_CC)
2173 AC_SUBST(CMESSAGES_CC)
2174 AC_SUBST(CMONEY_CC)
2175 AC_SUBST(CNUMERIC_CC)
2176 AC_SUBST(CTIME_H)
2177 AC_SUBST(CTIME_CC)
2178 AC_SUBST(CLOCALE_CC)
2179 AC_SUBST(CLOCALE_INTERNAL_H)
2180 ])
2183 dnl
2184 dnl Check for which std::allocator base class to use. The choice is
2185 dnl mapped from a subdirectory of include/ext.
2186 dnl
2187 dnl Default is new.
2188 dnl
2189 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
2190 AC_MSG_CHECKING([for std::allocator base class])
2191 GLIBCXX_ENABLE(libstdcxx-allocator,auto,[[[=KIND]]],
2192 [use KIND for target std::allocator base],
2193 [permit new|malloc|mt|bitmap|pool|yes|no|auto])
2195 # If they didn't use this option switch, or if they specified --enable
2196 # with no specific model, we'll have to look for one. If they
2197 # specified --disable (???), do likewise.
2198 if test $enable_libstdcxx_allocator = no ||
2199 test $enable_libstdcxx_allocator = yes;
2200 then
2201 enable_libstdcxx_allocator=auto
2202 fi
2204 # Either a known package, or "auto". Auto implies the default choice
2205 # for a particular platform.
2206 enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
2208 # Probe for host-specific support if no specific model is specified.
2209 # Default to "new".
2210 if test $enable_libstdcxx_allocator_flag = auto; then
2211 case ${target_os} in
2212 linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
2213 enable_libstdcxx_allocator_flag=new
2214 ;;
2215 *)
2216 enable_libstdcxx_allocator_flag=new
2217 ;;
2218 esac
2219 fi
2220 AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
2223 # Set configure bits for specified locale package
2224 case ${enable_libstdcxx_allocator_flag} in
2225 bitmap)
2226 ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
2227 ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
2228 ;;
2229 malloc)
2230 ALLOCATOR_H=config/allocator/malloc_allocator_base.h
2231 ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
2232 ;;
2233 mt)
2234 ALLOCATOR_H=config/allocator/mt_allocator_base.h
2235 ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
2236 ;;
2237 new)
2238 ALLOCATOR_H=config/allocator/new_allocator_base.h
2239 ALLOCATOR_NAME=__gnu_cxx::new_allocator
2240 ;;
2241 pool)
2242 ALLOCATOR_H=config/allocator/pool_allocator_base.h
2243 ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
2244 ;;
2245 esac
2247 AC_SUBST(ALLOCATOR_H)
2248 AC_SUBST(ALLOCATOR_NAME)
2249 ])
2252 dnl
2253 dnl Check for whether the Boost-derived checks should be turned on.
2254 dnl
2255 dnl --enable-concept-checks turns them on.
2256 dnl --disable-concept-checks leaves them off.
2257 dnl + Usage: GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
2258 dnl Where DEFAULT is either `yes' or `no'.
2259 dnl
2260 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
2261 GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
2262 if test $enable_concept_checks = yes; then
2263 AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1,
2264 [Define to use concept checking code from the boost libraries.])
2265 fi
2266 ])
2268 dnl
2269 dnl Use extern templates.
2270 dnl
2271 dnl --enable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 1
2272 dnl --disable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 0
2274 dnl + Usage: GLIBCXX_ENABLE_TEMPLATE[(DEFAULT)]
2275 dnl Where DEFAULT is `yes' or `no'.
2276 dnl
2277 AC_DEFUN([GLIBCXX_ENABLE_EXTERN_TEMPLATE], [
2279 GLIBCXX_ENABLE(extern-template,$1,,[enable extern template])
2281 AC_MSG_CHECKING([for extern template support])
2282 AC_MSG_RESULT([$enable_extern_template])
2284 GLIBCXX_CONDITIONAL(ENABLE_EXTERN_TEMPLATE, test $enable_extern_template = yes)
2285 ])
2287 dnl
2288 dnl Use vtable verification.
2289 dnl
2290 dnl --enable-vtable-verify defines _GLIBCXX_VTABLE_VERIFY to 1
2291 dnl --disable-vtable-verify defines _GLIBCXX_VTABLE_VERIFY to 0
2293 dnl + Usage: GLIBCXX_ENABLE_VTABLE_VERIFY[(DEFAULT)]
2294 dnl Where DEFAULT is `yes' or `no'.
2295 dnl
2296 AC_DEFUN([GLIBCXX_ENABLE_VTABLE_VERIFY], [
2298 GLIBCXX_ENABLE(vtable-verify,$1,,[enable vtable verify])
2300 AC_MSG_CHECKING([for vtable verify support])
2301 AC_MSG_RESULT([$enable_vtable_verify])
2303 if test $enable_vtable_verify = yes; then
2304 VTV_CXXFLAGS="-fvtable-verify=std -Wl,-u_vtable_map_vars_start,-u_vtable_map_vars_end"
2305 VTV_PCH_CXXFLAGS="-fvtable-verify=std"
2306 VTV_CXXLINKFLAGS="-L${toplevel_builddir}/libvtv/.libs -Wl,--rpath -Wl,${toplevel_builddir}/libvtv/.libs"
2307 else
2308 VTV_CXXFLAGS=
2309 VTV_PCH_CXXFLAGS=
2310 VTV_CXXLINKFLAGS=
2311 fi
2313 AC_SUBST(VTV_CXXFLAGS)
2314 AC_SUBST(VTV_PCH_CXXFLAGS)
2315 AC_SUBST(VTV_CXXLINKFLAGS)
2316 GLIBCXX_CONDITIONAL(ENABLE_VTABLE_VERIFY, test $enable_vtable_verify = yes)
2317 ])
2319 dnl
2320 dnl Check for parallel mode pre-requisites, including OpenMP support.
2321 dnl
2322 dnl + Usage: GLIBCXX_ENABLE_PARALLEL
2323 dnl
2324 AC_DEFUN([GLIBCXX_ENABLE_PARALLEL], [
2326 enable_parallel=no;
2328 # See if configured libgomp/omp.h exists. (libgomp may be in
2329 # noconfigdirs but not explicitly disabled.)
2330 if echo " ${TARGET_CONFIGDIRS} " | grep " libgomp " > /dev/null 2>&1 ; then
2331 enable_parallel=yes;
2332 else
2333 AC_MSG_NOTICE([target-libgomp not built])
2334 fi
2336 AC_MSG_CHECKING([for parallel mode support])
2337 AC_MSG_RESULT([$enable_parallel])
2338 ])
2341 dnl
2342 dnl Check for which I/O library to use: stdio, or something specific.
2343 dnl
2344 dnl Default is stdio.
2345 dnl
2346 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
2347 AC_MSG_CHECKING([for underlying I/O to use])
2348 GLIBCXX_ENABLE(cstdio,stdio,[[[=PACKAGE]]],
2349 [use target-specific I/O package], [permit stdio])
2351 # Now that libio has been removed, you can have any color you want as long
2352 # as it's black. This is one big no-op until other packages are added, but
2353 # showing the framework never hurts.
2354 case ${enable_cstdio} in
2355 stdio)
2356 CSTDIO_H=config/io/c_io_stdio.h
2357 BASIC_FILE_H=config/io/basic_file_stdio.h
2358 BASIC_FILE_CC=config/io/basic_file_stdio.cc
2359 AC_MSG_RESULT(stdio)
2360 ;;
2361 esac
2363 AC_SUBST(CSTDIO_H)
2364 AC_SUBST(BASIC_FILE_H)
2365 AC_SUBST(BASIC_FILE_CC)
2366 ])
2369 dnl
2370 dnl Check for "unusual" flags to pass to the compiler while building.
2371 dnl
2372 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
2373 dnl experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
2374 dnl --disable-cxx-flags passes nothing.
2375 dnl + See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
2376 dnl http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
2377 dnl http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
2378 dnl + Usage: GLIBCXX_ENABLE_CXX_FLAGS(default flags)
2379 dnl If "default flags" is an empty string, the effect is the same
2380 dnl as --disable or --enable=no.
2381 dnl
2382 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
2383 AC_MSG_CHECKING([for extra compiler flags for building])
2384 GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
2385 [pass compiler FLAGS when building library],
2386 [case "x$enable_cxx_flags" in
2387 xno | x) enable_cxx_flags= ;;
2388 x-*) ;;
2389 *) AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2390 esac])
2392 # Run through flags (either default or command-line) and set anything
2393 # extra (e.g., #defines) that must accompany particular g++ options.
2394 if test -n "$enable_cxx_flags"; then
2395 for f in $enable_cxx_flags; do
2396 case "$f" in
2397 -fhonor-std) ;;
2398 -*) ;;
2399 *) # and we're trying to pass /what/ exactly?
2400 AC_MSG_ERROR([compiler flags start with a -]) ;;
2401 esac
2402 done
2403 fi
2405 EXTRA_CXX_FLAGS="$enable_cxx_flags"
2406 AC_MSG_RESULT($EXTRA_CXX_FLAGS)
2407 AC_SUBST(EXTRA_CXX_FLAGS)
2408 ])
2411 dnl
2412 dnl Check to see if debugging libraries are to be built.
2413 dnl
2414 dnl --enable-libstdcxx-debug
2415 dnl builds a separate set of debugging libraries in addition to the
2416 dnl normal (shared, static) libstdc++ binaries.
2417 dnl
2418 dnl --disable-libstdcxx-debug
2419 dnl builds only one (non-debug) version of libstdc++.
2420 dnl
2421 dnl --enable-libstdcxx-debug-flags=FLAGS
2422 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
2423 dnl
2424 dnl + Usage: GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
2425 dnl Where DEFAULT is either `yes' or `no'.
2426 dnl
2427 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
2428 AC_MSG_CHECKING([for additional debug build])
2429 GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
2430 AC_MSG_RESULT($enable_libstdcxx_debug)
2431 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
2432 ])
2435 dnl
2436 dnl Check for explicit debug flags.
2437 dnl
2438 dnl --enable-libstdcxx-debug-flags='-O1'
2439 dnl is a general method for passing flags to be used when
2440 dnl building debug libraries with --enable-debug.
2441 dnl
2442 dnl --disable-libstdcxx-debug-flags does nothing.
2443 dnl + Usage: GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
2444 dnl If "default flags" is an empty string, the effect is the same
2445 dnl as --disable or --enable=no.
2446 dnl
2447 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
2448 GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
2449 [pass compiler FLAGS when building debug library],
2450 [case "x$enable_libstdcxx_debug_flags" in
2451 xno | x) enable_libstdcxx_debug_flags= ;;
2452 x-*) ;;
2453 *) AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2454 esac])
2456 # Option parsed, now set things appropriately
2457 DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
2458 AC_SUBST(DEBUG_FLAGS)
2460 AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
2461 ])
2464 dnl
2465 dnl Check if the user only wants a freestanding library implementation.
2466 dnl
2467 dnl --disable-hosted-libstdcxx will turn off most of the library build,
2468 dnl installing only the headers required by [17.4.1.3] and the language
2469 dnl support library. More than that will be built (to keep the Makefiles
2470 dnl conveniently clean), but not installed.
2471 dnl
2472 dnl Sets:
2473 dnl is_hosted (yes/no)
2474 dnl
2475 dnl Defines:
2476 dnl _GLIBCXX_HOSTED (always defined, either to 1 or 0)
2477 dnl
2478 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
2479 AC_ARG_ENABLE([hosted-libstdcxx],
2480 AC_HELP_STRING([--disable-hosted-libstdcxx],
2481 [only build freestanding C++ runtime support]),,
2482 [case "$host" in
2483 arm*-*-symbianelf*)
2484 enable_hosted_libstdcxx=no
2485 ;;
2486 *)
2487 enable_hosted_libstdcxx=yes
2488 ;;
2489 esac])
2490 if test "$enable_hosted_libstdcxx" = no; then
2491 AC_MSG_NOTICE([Only freestanding libraries will be built])
2492 is_hosted=no
2493 hosted_define=0
2494 enable_abi_check=no
2495 enable_libstdcxx_pch=no
2496 else
2497 is_hosted=yes
2498 hosted_define=1
2499 fi
2500 GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
2501 AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
2502 [Define to 1 if a full hosted library is built, or 0 if freestanding.])
2503 ])
2506 dnl
2507 dnl Check if the user wants a non-verbose library implementation.
2508 dnl
2509 dnl --disable-libstdcxx-verbose will turn off descriptive messages to
2510 dnl standard error on termination.
2511 dnl
2512 dnl Defines:
2513 dnl _GLIBCXX_VERBOSE (always defined, either to 1 or 0)
2514 dnl
2515 AC_DEFUN([GLIBCXX_ENABLE_VERBOSE], [
2516 AC_ARG_ENABLE([libstdcxx-verbose],
2517 AC_HELP_STRING([--disable-libstdcxx-verbose],
2518 [disable termination messages to standard error]),,
2519 [enable_libstdcxx_verbose=yes])
2520 if test x"$enable_libstdcxx_verbose" = xyes; then
2521 verbose_define=1
2522 else
2523 AC_MSG_NOTICE([verbose termination messages are disabled])
2524 verbose_define=0
2525 fi
2526 AC_DEFINE_UNQUOTED(_GLIBCXX_VERBOSE, $verbose_define,
2527 [Define to 1 if a verbose library is built, or 0 otherwise.])
2528 ])
2531 dnl
2532 dnl Check for template specializations for the 'long long' type.
2533 dnl The result determines only whether 'long long' I/O is enabled; things
2534 dnl like numeric_limits<> specializations are always available.
2535 dnl
2536 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
2537 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
2538 dnl + Usage: GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
2539 dnl Where DEFAULT is either `yes' or `no'.
2540 dnl
2541 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
2542 GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
2543 if test $enable_long_long = yes; then
2544 AC_DEFINE(_GLIBCXX_USE_LONG_LONG, 1,
2545 [Define if code specialized for long long should be used.])
2546 fi
2547 AC_MSG_CHECKING([for enabled long long specializations])
2548 AC_MSG_RESULT([$enable_long_long])
2549 ])
2552 dnl
2553 dnl Check for decimal floating point.
2554 dnl See:
2555 dnl http://gcc.gnu.org/onlinedocs/gcc/Decimal-Float.html#Decimal-Float
2556 dnl
2557 dnl This checks to see if the host supports decimal floating point types.
2558 dnl
2559 dnl Defines:
2560 dnl _GLIBCXX_USE_DECIMAL_FLOAT
2561 dnl
2562 AC_DEFUN([GLIBCXX_ENABLE_DECIMAL_FLOAT], [
2564 # Fake what AC_TRY_COMPILE does, without linking as this is
2565 # unnecessary for this test.
2567 cat > conftest.$ac_ext << EOF
2568 [#]line __oline__ "configure"
2569 int main()
2570 {
2571 _Decimal32 d1;
2572 _Decimal64 d2;
2573 _Decimal128 d3;
2574 return 0;
2575 }
2576 EOF
2578 AC_MSG_CHECKING([for ISO/IEC TR 24733 ])
2579 if AC_TRY_EVAL(ac_compile); then
2580 AC_DEFINE(_GLIBCXX_USE_DECIMAL_FLOAT, 1,
2581 [Define if ISO/IEC TR 24733 decimal floating point types are supported on this host.])
2582 enable_dfp=yes
2583 else
2584 enable_dfp=no
2585 fi
2586 AC_MSG_RESULT($enable_dfp)
2587 rm -f conftest*
2588 ])
2590 dnl
2591 dnl Check for GNU 128-bit integer and floating point types.
2592 dnl
2593 dnl Note: also checks that the types aren't standard types.
2594 dnl
2595 dnl Defines:
2596 dnl _GLIBCXX_USE_INT128
2597 dnl _GLIBCXX_USE_FLOAT128
2598 dnl
2599 AC_DEFUN([GLIBCXX_ENABLE_INT128_FLOAT128], [
2601 AC_LANG_SAVE
2602 AC_LANG_CPLUSPLUS
2604 # Fake what AC_TRY_COMPILE does, without linking as this is
2605 # unnecessary for this test.
2607 cat > conftest.$ac_ext << EOF
2608 [#]line __oline__ "configure"
2609 template<typename T1, typename T2>
2610 struct same
2611 { typedef T2 type; };
2613 template<typename T>
2614 struct same<T, T>;
2616 int main()
2617 {
2618 typename same<long, __int128>::type i1;
2619 typename same<long long, __int128>::type i2;
2620 }
2621 EOF
2623 AC_MSG_CHECKING([for __int128])
2624 if AC_TRY_EVAL(ac_compile); then
2625 AC_DEFINE(_GLIBCXX_USE_INT128, 1,
2626 [Define if __int128 is supported on this host.])
2627 enable_int128=yes
2628 else
2629 enable_int128=no
2630 fi
2631 AC_MSG_RESULT($enable_int128)
2632 rm -f conftest*
2634 cat > conftest.$ac_ext << EOF
2635 [#]line __oline__ "configure"
2636 template<typename T1, typename T2>
2637 struct same
2638 { typedef T2 type; };
2640 template<typename T>
2641 struct same<T, T>;
2643 int main()
2644 {
2645 typename same<double, __float128>::type f1;
2646 typename same<long double, __float128>::type f2;
2647 }
2648 EOF
2650 AC_MSG_CHECKING([for __float128])
2651 if AC_TRY_EVAL(ac_compile); then
2652 AC_DEFINE(_GLIBCXX_USE_FLOAT128, 1,
2653 [Define if __float128 is supported on this host.])
2654 enable_float128=yes
2655 else
2656 enable_float128=no
2657 fi
2658 AC_MSG_RESULT($enable_float128)
2659 rm -f conftest*
2661 AC_LANG_RESTORE
2662 ])
2664 dnl
2665 dnl Check for template specializations for the 'wchar_t' type.
2666 dnl
2667 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
2668 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
2669 dnl + Usage: GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
2670 dnl Where DEFAULT is either `yes' or `no'.
2671 dnl
2672 dnl Necessary support must also be present.
2673 dnl
2674 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
2675 GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
2677 # Test wchar.h for mbstate_t, which is needed for char_traits and fpos.
2678 AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
2679 AC_MSG_CHECKING([for mbstate_t])
2680 AC_TRY_COMPILE([#include <wchar.h>],
2681 [mbstate_t teststate;],
2682 have_mbstate_t=yes, have_mbstate_t=no)
2683 AC_MSG_RESULT($have_mbstate_t)
2684 if test x"$have_mbstate_t" = xyes; then
2685 AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
2686 fi
2688 # Test it always, for use in GLIBCXX_ENABLE_C99, together with
2689 # ac_has_wchar_h.
2690 AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
2692 if test x"$enable_wchar_t" = x"yes"; then
2694 AC_LANG_SAVE
2695 AC_LANG_CPLUSPLUS
2697 if test x"$ac_has_wchar_h" = xyes &&
2698 test x"$ac_has_wctype_h" = xyes; then
2699 AC_TRY_COMPILE([#include <wchar.h>
2700 #include <stddef.h>
2701 wint_t i;
2702 long l = WEOF;
2703 long j = WCHAR_MIN;
2704 long k = WCHAR_MAX;
2705 namespace test
2706 {
2707 using ::btowc;
2708 using ::fgetwc;
2709 using ::fgetws;
2710 using ::fputwc;
2711 using ::fputws;
2712 using ::fwide;
2713 using ::fwprintf;
2714 using ::fwscanf;
2715 using ::getwc;
2716 using ::getwchar;
2717 using ::mbrlen;
2718 using ::mbrtowc;
2719 using ::mbsinit;
2720 using ::mbsrtowcs;
2721 using ::putwc;
2722 using ::putwchar;
2723 using ::swprintf;
2724 using ::swscanf;
2725 using ::ungetwc;
2726 using ::vfwprintf;
2727 using ::vswprintf;
2728 using ::vwprintf;
2729 using ::wcrtomb;
2730 using ::wcscat;
2731 using ::wcschr;
2732 using ::wcscmp;
2733 using ::wcscoll;
2734 using ::wcscpy;
2735 using ::wcscspn;
2736 using ::wcsftime;
2737 using ::wcslen;
2738 using ::wcsncat;
2739 using ::wcsncmp;
2740 using ::wcsncpy;
2741 using ::wcspbrk;
2742 using ::wcsrchr;
2743 using ::wcsrtombs;
2744 using ::wcsspn;
2745 using ::wcsstr;
2746 using ::wcstod;
2747 using ::wcstok;
2748 using ::wcstol;
2749 using ::wcstoul;
2750 using ::wcsxfrm;
2751 using ::wctob;
2752 using ::wmemchr;
2753 using ::wmemcmp;
2754 using ::wmemcpy;
2755 using ::wmemmove;
2756 using ::wmemset;
2757 using ::wprintf;
2758 using ::wscanf;
2759 }
2760 ],[],[], [enable_wchar_t=no])
2761 else
2762 enable_wchar_t=no
2763 fi
2765 AC_LANG_RESTORE
2766 fi
2768 if test x"$enable_wchar_t" = x"yes"; then
2769 AC_DEFINE(_GLIBCXX_USE_WCHAR_T, 1,
2770 [Define if code specialized for wchar_t should be used.])
2771 fi
2773 AC_MSG_CHECKING([for enabled wchar_t specializations])
2774 AC_MSG_RESULT([$enable_wchar_t])
2775 ])
2778 dnl
2779 dnl Check to see if building and using a C++ precompiled header can be done.
2780 dnl
2781 dnl --enable-libstdcxx-pch=yes
2782 dnl default, this shows intent to use stdc++.h.gch If it looks like it
2783 dnl may work, after some light-hearted attempts to puzzle out compiler
2784 dnl support, flip bits on in include/Makefile.am
2785 dnl
2786 dnl --disable-libstdcxx-pch
2787 dnl turns off attempts to use or build stdc++.h.gch.
2788 dnl
2789 dnl Substs:
2790 dnl glibcxx_PCHFLAGS
2791 dnl
2792 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
2793 GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
2794 if test $enable_libstdcxx_pch = yes; then
2795 AC_CACHE_CHECK([for compiler with PCH support],
2796 [glibcxx_cv_prog_CXX_pch],
2797 [ac_save_CXXFLAGS="$CXXFLAGS"
2798 CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
2799 AC_LANG_SAVE
2800 AC_LANG_CPLUSPLUS
2801 echo '#include <math.h>' > conftest.h
2802 if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
2803 -o conftest.h.gch 1>&5 2>&1 &&
2804 echo '#error "pch failed"' > conftest.h &&
2805 echo '#include "conftest.h"' > conftest.cc &&
2806 $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
2807 then
2808 glibcxx_cv_prog_CXX_pch=yes
2809 else
2810 glibcxx_cv_prog_CXX_pch=no
2811 fi
2812 rm -f conftest*
2813 CXXFLAGS=$ac_save_CXXFLAGS
2814 AC_LANG_RESTORE
2815 ])
2816 enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
2817 fi
2819 AC_MSG_CHECKING([for enabled PCH])
2820 AC_MSG_RESULT([$enable_libstdcxx_pch])
2822 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
2823 if test $enable_libstdcxx_pch = yes; then
2824 glibcxx_PCHFLAGS="-include bits/stdc++.h"
2825 else
2826 glibcxx_PCHFLAGS=""
2827 fi
2828 AC_SUBST(glibcxx_PCHFLAGS)
2829 ])
2832 dnl
2833 dnl Check for atomic builtins.
2834 dnl See:
2835 dnl http://gcc.gnu.org/onlinedocs/gcc/_005f_005fatomic-Builtins.html
2836 dnl
2837 dnl This checks to see if the host supports the compiler-generated
2838 dnl builtins for atomic operations for various integral sizes. Note, this
2839 dnl is intended to be an all-or-nothing switch, so all the atomic operations
2840 dnl that are used should be checked.
2841 dnl
2842 dnl Note:
2843 dnl libgomp and libgfortran use a link test, see CHECK_SYNC_FETCH_AND_ADD.
2844 dnl
2845 AC_DEFUN([GLIBCXX_ENABLE_ATOMIC_BUILTINS], [
2846 AC_LANG_SAVE
2847 AC_LANG_CPLUSPLUS
2848 old_CXXFLAGS="$CXXFLAGS"
2850 # Do link tests if possible, instead asm tests, limited to some platforms
2851 # see discussion in PR target/40134, PR libstdc++/40133 and the thread
2852 # starting at http://gcc.gnu.org/ml/gcc-patches/2009-07/msg00322.html
2853 atomic_builtins_link_tests=no
2854 if test x$gcc_no_link != xyes; then
2855 # Can do link tests. Limit to some tested platforms
2856 case "$host" in
2857 *-*-linux* | *-*-uclinux* | *-*-kfreebsd*-gnu | *-*-gnu*)
2858 atomic_builtins_link_tests=yes
2859 ;;
2860 esac
2861 fi
2863 if test x$atomic_builtins_link_tests = xyes; then
2865 # Do link tests.
2867 CXXFLAGS="$CXXFLAGS -fno-exceptions"
2869 AC_MSG_CHECKING([for atomic builtins for bool])
2870 AC_CACHE_VAL(glibcxx_cv_atomic_bool, [
2871 AC_TRY_LINK(
2872 [ ],
2873 [typedef bool atomic_type;
2874 atomic_type c1;
2875 atomic_type c2;
2876 atomic_type c3(0);
2877 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2878 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2879 __ATOMIC_RELAXED);
2880 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2881 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2882 ],
2883 [glibcxx_cv_atomic_bool=yes],
2884 [glibcxx_cv_atomic_bool=no])
2885 ])
2886 AC_MSG_RESULT($glibcxx_cv_atomic_bool)
2888 AC_MSG_CHECKING([for atomic builtins for short])
2889 AC_CACHE_VAL(glibcxx_cv_atomic_short, [
2890 AC_TRY_LINK(
2891 [ ],
2892 [typedef short atomic_type;
2893 atomic_type c1;
2894 atomic_type c2;
2895 atomic_type c3(0);
2896 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2897 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2898 __ATOMIC_RELAXED);
2899 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2900 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2901 ],
2902 [glibcxx_cv_atomic_short=yes],
2903 [glibcxx_cv_atomic_short=no])
2904 ])
2905 AC_MSG_RESULT($glibcxx_cv_atomic_short)
2907 AC_MSG_CHECKING([for atomic builtins for int])
2908 AC_CACHE_VAL(glibcxx_cv_atomic_int, [
2909 AC_TRY_LINK(
2910 [ ],
2911 [typedef int atomic_type;
2912 atomic_type c1;
2913 atomic_type c2;
2914 atomic_type c3(0);
2915 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2916 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2917 __ATOMIC_RELAXED);
2918 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2919 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2920 ],
2921 [glibcxx_cv_atomic_int=yes],
2922 [glibcxx_cv_atomic_int=no])
2923 ])
2924 AC_MSG_RESULT($glibcxx_cv_atomic_int)
2926 AC_MSG_CHECKING([for atomic builtins for long long])
2927 AC_CACHE_VAL(glibcxx_cv_atomic_long_long, [
2928 AC_TRY_LINK(
2929 [ ],
2930 [typedef long long atomic_type;
2931 atomic_type c1;
2932 atomic_type c2;
2933 atomic_type c3(0);
2934 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2935 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2936 __ATOMIC_RELAXED);
2937 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2938 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2939 ],
2940 [glibcxx_cv_atomic_long_long=yes],
2941 [glibcxx_cv_atomic_long_long=no])
2942 ])
2943 AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
2945 else
2947 # Do asm tests.
2949 # Compile unoptimized.
2950 CXXFLAGS='-O0 -S'
2952 # Fake what AC_TRY_COMPILE does.
2954 cat > conftest.$ac_ext << EOF
2955 [#]line __oline__ "configure"
2956 int main()
2957 {
2958 typedef bool atomic_type;
2959 atomic_type c1;
2960 atomic_type c2;
2961 atomic_type c3(0);
2962 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2963 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2964 __ATOMIC_RELAXED);
2965 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2966 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2968 return 0;
2969 }
2970 EOF
2972 AC_MSG_CHECKING([for atomic builtins for bool])
2973 if AC_TRY_EVAL(ac_compile); then
2974 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
2975 glibcxx_cv_atomic_bool=no
2976 else
2977 glibcxx_cv_atomic_bool=yes
2978 fi
2979 fi
2980 AC_MSG_RESULT($glibcxx_cv_atomic_bool)
2981 rm -f conftest*
2983 cat > conftest.$ac_ext << EOF
2984 [#]line __oline__ "configure"
2985 int main()
2986 {
2987 typedef short atomic_type;
2988 atomic_type c1;
2989 atomic_type c2;
2990 atomic_type c3(0);
2991 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2992 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2993 __ATOMIC_RELAXED);
2994 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2995 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2997 return 0;
2998 }
2999 EOF
3001 AC_MSG_CHECKING([for atomic builtins for short])
3002 if AC_TRY_EVAL(ac_compile); then
3003 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
3004 glibcxx_cv_atomic_short=no
3005 else
3006 glibcxx_cv_atomic_short=yes
3007 fi
3008 fi
3009 AC_MSG_RESULT($glibcxx_cv_atomic_short)
3010 rm -f conftest*
3012 cat > conftest.$ac_ext << EOF
3013 [#]line __oline__ "configure"
3014 int main()
3015 {
3016 // NB: _Atomic_word not necessarily int.
3017 typedef int atomic_type;
3018 atomic_type c1;
3019 atomic_type c2;
3020 atomic_type c3(0);
3021 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
3022 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
3023 __ATOMIC_RELAXED);
3024 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
3025 __atomic_load_n(&c1, __ATOMIC_RELAXED);
3027 return 0;
3028 }
3029 EOF
3031 AC_MSG_CHECKING([for atomic builtins for int])
3032 if AC_TRY_EVAL(ac_compile); then
3033 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
3034 glibcxx_cv_atomic_int=no
3035 else
3036 glibcxx_cv_atomic_int=yes
3037 fi
3038 fi
3039 AC_MSG_RESULT($glibcxx_cv_atomic_int)
3040 rm -f conftest*
3042 cat > conftest.$ac_ext << EOF
3043 [#]line __oline__ "configure"
3044 int main()
3045 {
3046 typedef long long atomic_type;
3047 atomic_type c1;
3048 atomic_type c2;
3049 atomic_type c3(0);
3050 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
3051 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
3052 __ATOMIC_RELAXED);
3053 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
3054 __atomic_load_n(&c1, __ATOMIC_RELAXED);
3056 return 0;
3057 }
3058 EOF
3060 AC_MSG_CHECKING([for atomic builtins for long long])
3061 if AC_TRY_EVAL(ac_compile); then
3062 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
3063 glibcxx_cv_atomic_long_long=no
3064 else
3065 glibcxx_cv_atomic_long_long=yes
3066 fi
3067 fi
3068 AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
3069 rm -f conftest*
3071 fi
3073 CXXFLAGS="$old_CXXFLAGS"
3074 AC_LANG_RESTORE
3076 # Set atomicity_dir to builtins if all but the long long test above passes.
3077 if test $glibcxx_cv_atomic_bool = yes \
3078 && test $glibcxx_cv_atomic_short = yes \
3079 && test $glibcxx_cv_atomic_int = yes; then
3080 AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS, 1,
3081 [Define if the compiler supports C++11 atomics.])
3082 atomicity_dir=cpu/generic/atomicity_builtins
3083 fi
3085 # If still generic, set to mutex.
3086 if test $atomicity_dir = "cpu/generic" ; then
3087 atomicity_dir=cpu/generic/atomicity_mutex
3088 AC_MSG_WARN([No native atomic operations are provided for this platform.])
3089 if test "x$target_thread_file" = xsingle; then
3090 AC_MSG_WARN([They cannot be faked when thread support is disabled.])
3091 AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
3092 else
3093 AC_MSG_WARN([They will be faked using a mutex.])
3094 AC_MSG_WARN([Performance of certain classes will degrade as a result.])
3095 fi
3096 fi
3098 ])
3101 dnl
3102 dnl Check for exception handling support. If an explicit enable/disable
3103 dnl sjlj exceptions is given, we don't have to detect. Otherwise the
3104 dnl target may or may not support call frame exceptions.
3105 dnl
3106 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
3107 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
3108 dnl Neither one forces an attempt at detection.
3109 dnl
3110 dnl Defines:
3111 dnl _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
3112 dnl
3113 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
3114 AC_MSG_CHECKING([for exception model to use])
3115 AC_LANG_SAVE
3116 AC_LANG_CPLUSPLUS
3117 GLIBCXX_ENABLE(sjlj-exceptions,auto,,
3118 [force use of builtin_setjmp for exceptions],
3119 [permit yes|no|auto])
3121 if test $enable_sjlj_exceptions = auto; then
3122 # Botheration. Now we've got to detect the exception model. Link tests
3123 # against libgcc.a are problematic since we've not been given proper -L
3124 # bits for single-tree newlib and libgloss.
3125 #
3126 # Fake what AC_TRY_COMPILE does. XXX Look at redoing this new-style.
3127 cat > conftest.$ac_ext << EOF
3128 [#]line __oline__ "configure"
3129 struct S { ~S(); };
3130 void bar();
3131 void foo()
3132 {
3133 S s;
3134 bar();
3135 }
3136 EOF
3137 old_CXXFLAGS="$CXXFLAGS"
3138 CXXFLAGS=-S
3139 if AC_TRY_EVAL(ac_compile); then
3140 if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
3141 enable_sjlj_exceptions=yes
3142 elif grep _Unwind_SjLj_Register conftest.s >/dev/null 2>&1 ; then
3143 enable_sjlj_exceptions=yes
3144 elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
3145 enable_sjlj_exceptions=no
3146 elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
3147 enable_sjlj_exceptions=no
3148 fi
3149 fi
3150 CXXFLAGS="$old_CXXFLAGS"
3151 rm -f conftest*
3152 fi
3154 # This is a tad weird, for hysterical raisins. We have to map
3155 # enable/disable to two different models.
3156 case $enable_sjlj_exceptions in
3157 yes)
3158 AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
3159 [Define if the compiler is configured for setjmp/longjmp exceptions.])
3160 ac_exception_model_name=sjlj
3161 ;;
3162 no)
3163 ac_exception_model_name="call frame"
3164 ;;
3165 *)
3166 AC_MSG_ERROR([unable to detect exception model])
3167 ;;
3168 esac
3169 AC_LANG_RESTORE
3170 AC_MSG_RESULT($ac_exception_model_name)
3171 ])
3174 dnl
3175 dnl Allow visibility attributes to be used on namespaces, objects, etc.
3176 dnl
3177 dnl --enable-libstdcxx-visibility enables attempt to use visibility attributes.
3178 dnl --disable-libstdcxx-visibility turns off all use of visibility attributes.
3179 dnl + Usage: GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY[(DEFAULT)]
3180 dnl Where DEFAULT is 'yes'.
3181 dnl
3182 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY], [
3183 GLIBCXX_ENABLE(libstdcxx-visibility,$1,,[enables visibility safe usage])
3185 if test x$enable_libstdcxx_visibility = xyes ; then
3186 dnl all hail libgfortran
3187 dnl Check whether the target supports hidden visibility.
3188 AC_CACHE_CHECK([whether the target supports hidden visibility],
3189 glibcxx_cv_have_attribute_visibility, [
3190 save_CFLAGS="$CFLAGS"
3191 CFLAGS="$CFLAGS -Werror"
3192 AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }],
3193 [], glibcxx_cv_have_attribute_visibility=yes,
3194 glibcxx_cv_have_attribute_visibility=no)
3195 CFLAGS="$save_CFLAGS"])
3196 if test $glibcxx_cv_have_attribute_visibility = no; then
3197 enable_libstdcxx_visibility=no
3198 fi
3199 fi
3201 GLIBCXX_CONDITIONAL(ENABLE_VISIBILITY, test $enable_libstdcxx_visibility = yes)
3202 AC_MSG_NOTICE([visibility supported: $enable_libstdcxx_visibility])
3203 ])
3206 dnl
3207 dnl Add version tags to symbols in shared library (or not), additionally
3208 dnl marking other symbols as private/local (or not).
3209 dnl
3210 dnl Sets libtool_VERSION, and determines shared library SONAME.
3211 dnl
3212 dnl This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
3213 dnl
3214 dnl --enable-symvers=style adds a version script to the linker call when
3215 dnl creating the shared library. The choice of version script is
3216 dnl controlled by 'style'.
3217 dnl --disable-symvers does not.
3218 dnl
3219 dnl + Usage: GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
3220 dnl Where DEFAULT is either 'yes' or 'no'. Passing `yes' tries to
3221 dnl choose a default style based on linker characteristics. Passing
3222 dnl 'no' disables versioning.
3223 dnl
3224 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
3226 GLIBCXX_ENABLE(symvers,$1,[[[=STYLE]]],
3227 [enables symbol versioning of the shared library],
3228 [permit yes|no|gnu|gnu-versioned-namespace|darwin|darwin-export|sun])
3230 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
3231 # don't know enough about $LD to do tricks...
3232 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
3233 # Sun style symbol versions needs GNU c++filt for make_sunver.pl to work
3234 # with extern "C++" in version scripts.
3235 AC_REQUIRE([GCC_PROG_GNU_CXXFILT])
3237 # Turn a 'yes' into a suitable default.
3238 if test x$enable_symvers = xyes ; then
3239 if test $enable_shared = no || test "x$LD" = x || test x$gcc_no_link = xyes; then
3240 enable_symvers=no
3241 else
3242 if test $with_gnu_ld = yes ; then
3243 case ${target_os} in
3244 hpux*)
3245 enable_symvers=no ;;
3246 *)
3247 enable_symvers=gnu ;;
3248 esac
3249 else
3250 case ${target_os} in
3251 darwin*)
3252 enable_symvers=darwin ;;
3253 # Sun symbol versioning exists since Solaris 2.5.
3254 solaris2.[[5-9]]* | solaris2.1[[0-9]]*)
3255 # make_sunver.pl needs GNU c++filt to support extern "C++" in
3256 # version scripts, so disable symbol versioning if none can be
3257 # found.
3258 if test -z "$ac_cv_path_CXXFILT"; then
3259 AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
3260 AC_MSG_WARN([=== no GNU c++filt could be found.])
3261 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3262 enable_symvers=no
3263 else
3264 enable_symvers=sun
3265 fi
3266 ;;
3267 *)
3268 enable_symvers=no ;;
3269 esac
3270 fi
3271 fi
3272 fi
3274 # Check to see if 'darwin' or 'darwin-export' can win.
3275 if test x$enable_symvers = xdarwin-export ; then
3276 enable_symvers=darwin
3277 fi
3279 # Check if 'sun' was requested on non-Solaris 2 platforms.
3280 if test x$enable_symvers = xsun ; then
3281 case ${target_os} in
3282 solaris2*)
3283 # All fine.
3284 ;;
3285 *)
3286 # Unlikely to work.
3287 AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
3288 AC_MSG_WARN([=== you are not targetting Solaris 2.])
3289 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3290 enable_symvers=no
3291 ;;
3292 esac
3293 fi
3295 # Check to see if 'gnu' can win.
3296 if test $enable_symvers = gnu ||
3297 test $enable_symvers = gnu-versioned-namespace ||
3298 test $enable_symvers = sun; then
3299 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
3300 AC_MSG_CHECKING([for shared libgcc])
3301 ac_save_CFLAGS="$CFLAGS"
3302 CFLAGS=' -lgcc_s'
3303 AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
3304 CFLAGS="$ac_save_CFLAGS"
3305 if test $glibcxx_shared_libgcc = no; then
3306 cat > conftest.c <<EOF
3307 int main (void) { return 0; }
3308 EOF
3309 changequote(,)dnl
3310 glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
3311 -shared -shared-libgcc -o conftest.so \
3312 conftest.c -v 2>&1 >/dev/null \
3313 | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
3314 changequote([,])dnl
3315 rm -f conftest.c conftest.so
3316 if test x${glibcxx_libgcc_s_suffix+set} = xset; then
3317 CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
3318 AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
3319 CFLAGS="$ac_save_CFLAGS"
3320 fi
3321 fi
3322 AC_MSG_RESULT($glibcxx_shared_libgcc)
3324 # For GNU ld, we need at least this version. The format is described in
3325 # GLIBCXX_CHECK_LINKER_FEATURES above.
3326 glibcxx_min_gnu_ld_version=21400
3328 # If no shared libgcc, can't win.
3329 if test $glibcxx_shared_libgcc != yes; then
3330 AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3331 AC_MSG_WARN([=== you are not building a shared libgcc_s.])
3332 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3333 enable_symvers=no
3334 elif test $with_gnu_ld != yes && test $enable_symvers = sun; then
3335 : All interesting versions of Sun ld support sun style symbol versioning.
3336 elif test $with_gnu_ld != yes ; then
3337 # just fail for now
3338 AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3339 AC_MSG_WARN([=== you are not using the GNU linker.])
3340 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3341 enable_symvers=no
3342 elif test $glibcxx_ld_is_gold = yes ; then
3343 : All versions of gold support symbol versioning.
3344 elif test $glibcxx_gnu_ld_version -lt $glibcxx_min_gnu_ld_version ; then
3345 # The right tools, the right setup, but too old. Fallbacks?
3346 AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
3347 AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
3348 AC_MSG_WARN(=== You would need to upgrade your binutils to version)
3349 AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
3350 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3351 enable_symvers=no
3352 fi
3353 fi
3355 # For libtool versioning info, format is CURRENT:REVISION:AGE
3356 libtool_VERSION=6:20:0
3358 # Everything parsed; figure out what files and settings to use.
3359 case $enable_symvers in
3360 no)
3361 SYMVER_FILE=config/abi/pre/none.ver
3362 ;;
3363 gnu)
3364 SYMVER_FILE=config/abi/pre/gnu.ver
3365 AC_DEFINE(_GLIBCXX_SYMVER_GNU, 1,
3366 [Define to use GNU versioning in the shared library.])
3367 ;;
3368 gnu-versioned-namespace)
3369 libtool_VERSION=7:0:0
3370 SYMVER_FILE=config/abi/pre/gnu-versioned-namespace.ver
3371 AC_DEFINE(_GLIBCXX_SYMVER_GNU_NAMESPACE, 1,
3372 [Define to use GNU namespace versioning in the shared library.])
3373 ;;
3374 darwin)
3375 SYMVER_FILE=config/abi/pre/gnu.ver
3376 AC_DEFINE(_GLIBCXX_SYMVER_DARWIN, 1,
3377 [Define to use darwin versioning in the shared library.])
3378 ;;
3379 sun)
3380 SYMVER_FILE=config/abi/pre/gnu.ver
3381 AC_DEFINE(_GLIBCXX_SYMVER_SUN, 1,
3382 [Define to use Sun versioning in the shared library.])
3383 ;;
3384 esac
3386 if test x$enable_symvers != xno ; then
3387 AC_DEFINE(_GLIBCXX_SYMVER, 1,
3388 [Define to use symbol versioning in the shared library.])
3389 fi
3391 AC_CACHE_CHECK([whether the target supports .symver directive],
3392 glibcxx_cv_have_as_symver_directive, [
3393 AC_TRY_COMPILE([void foo (void); __asm (".symver foo, bar@SYMVER");],
3394 [], glibcxx_cv_have_as_symver_directive=yes,
3395 glibcxx_cv_have_as_symver_directive=no)])
3396 if test $glibcxx_cv_have_as_symver_directive = yes; then
3397 AC_DEFINE(HAVE_AS_SYMVER_DIRECTIVE, 1,
3398 [Define to 1 if the target assembler supports .symver directive.])
3399 fi
3401 AC_SUBST(SYMVER_FILE)
3402 AC_SUBST(port_specific_symbol_files)
3403 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS, test $enable_symvers != no)
3404 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU, test $enable_symvers = gnu)
3405 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU_NAMESPACE, test $enable_symvers = gnu-versioned-namespace)
3406 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_DARWIN, test $enable_symvers = darwin)
3407 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_SUN, test $enable_symvers = sun)
3408 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
3410 if test $enable_symvers != no ; then
3411 case ${target_os} in
3412 # The Solaris 2 runtime linker doesn't support the GNU extension of
3413 # binding the same symbol to different versions
3414 solaris2*)
3415 ;;
3416 # Other platforms with GNU symbol versioning (GNU/Linux, more?) do.
3417 *)
3418 AC_DEFINE(HAVE_SYMVER_SYMBOL_RENAMING_RUNTIME_SUPPORT, 1,
3419 [Define to 1 if the target runtime linker supports binding the same symbol to different versions.])
3420 ;;
3421 esac
3422 fi
3424 # Now, set up compatibility support, if any.
3425 # In addition, need this to deal with std::size_t mangling in
3426 # src/compatibility.cc. In a perfect world, could use
3427 # typeid(std::size_t).name()[0] to do direct substitution.
3428 AC_MSG_CHECKING([for size_t as unsigned int])
3429 ac_save_CFLAGS="$CFLAGS"
3430 CFLAGS="-Werror"
3431 AC_TRY_COMPILE(, [__SIZE_TYPE__* stp; unsigned int* uip; stp = uip;],
3432 [glibcxx_size_t_is_i=yes], [glibcxx_size_t_is_i=no])
3433 CFLAGS=$ac_save_CFLAGS
3434 if test "$glibcxx_size_t_is_i" = yes; then
3435 AC_DEFINE(_GLIBCXX_SIZE_T_IS_UINT, 1, [Define if size_t is unsigned int.])
3436 fi
3437 AC_MSG_RESULT([$glibcxx_size_t_is_i])
3439 AC_MSG_CHECKING([for ptrdiff_t as int])
3440 ac_save_CFLAGS="$CFLAGS"
3441 CFLAGS="-Werror"
3442 AC_TRY_COMPILE(, [__PTRDIFF_TYPE__* ptp; int* ip; ptp = ip;],
3443 [glibcxx_ptrdiff_t_is_i=yes], [glibcxx_ptrdiff_t_is_i=no])
3444 CFLAGS=$ac_save_CFLAGS
3445 if test "$glibcxx_ptrdiff_t_is_i" = yes; then
3446 AC_DEFINE(_GLIBCXX_PTRDIFF_T_IS_INT, 1, [Define if ptrdiff_t is int.])
3447 fi
3448 AC_MSG_RESULT([$glibcxx_ptrdiff_t_is_i])
3449 ])
3452 dnl
3453 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
3454 dnl We must stage the required headers so that they will be installed
3455 dnl with the library (unlike libgcc, the STL implementation is provided
3456 dnl solely within headers). Since we must not inject random user-space
3457 dnl macro names into user-provided C++ code, we first stage into <file>-in
3458 dnl and process to <file> with an output command. The reason for a two-
3459 dnl stage process here is to correctly handle $srcdir!=$objdir without
3460 dnl having to write complex code (the sed commands to clean the macro
3461 dnl namespace are complex and fragile enough as it is). We must also
3462 dnl add a relative path so that -I- is supported properly.
3463 dnl
3464 dnl Substs:
3465 dnl thread_header
3466 dnl
3467 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
3468 AC_MSG_CHECKING([for thread model used by GCC])
3469 target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3470 AC_MSG_RESULT([$target_thread_file])
3471 GCC_AC_THREAD_HEADER([$target_thread_file])
3472 ])
3475 dnl
3476 dnl Check if gthread implementation defines the types and functions
3477 dnl required by the c++0x thread library. Conforming gthread
3478 dnl implementations can define __GTHREADS_CXX0X to enable use with c++0x.
3479 dnl
3480 dnl GLIBCXX_ENABLE_SYMVERS must be done before this.
3481 dnl
3482 AC_DEFUN([GLIBCXX_CHECK_GTHREADS], [
3483 GLIBCXX_ENABLE(libstdcxx-threads,auto,,[enable C++11 threads support])
3485 if test x$enable_libstdcxx_threads = xauto ||
3486 test x$enable_libstdcxx_threads = xyes; then
3488 AC_LANG_SAVE
3489 AC_LANG_CPLUSPLUS
3491 ac_save_CXXFLAGS="$CXXFLAGS"
3492 CXXFLAGS="$CXXFLAGS -fno-exceptions \
3493 -I${toplevel_srcdir}/libgcc -I${toplevel_builddir}/libgcc"
3495 target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3496 case $target_thread_file in
3497 posix)
3498 CXXFLAGS="$CXXFLAGS -DSUPPORTS_WEAK -DGTHREAD_USE_WEAK -D_PTHREADS"
3499 esac
3501 AC_MSG_CHECKING([whether it can be safely assumed that mutex_timedlock is available])
3503 AC_TRY_COMPILE([#include <unistd.h>],
3504 [
3505 // In case of POSIX threads check _POSIX_TIMEOUTS.
3506 #if (defined(_PTHREADS) \
3507 && (!defined(_POSIX_TIMEOUTS) || _POSIX_TIMEOUTS <= 0))
3508 #error
3509 #endif
3510 ], [ac_gthread_use_mutex_timedlock=1], [ac_gthread_use_mutex_timedlock=0])
3512 AC_DEFINE_UNQUOTED(_GTHREAD_USE_MUTEX_TIMEDLOCK, $ac_gthread_use_mutex_timedlock,
3513 [Define to 1 if mutex_timedlock is available.])
3515 if test $ac_gthread_use_mutex_timedlock = 1 ; then res_mutex_timedlock=yes ;
3516 else res_mutex_timedlock=no ; fi
3517 AC_MSG_RESULT([$res_mutex_timedlock])
3519 AC_MSG_CHECKING([for gthreads library])
3521 AC_TRY_COMPILE([#include "gthr.h"],
3522 [
3523 #ifndef __GTHREADS_CXX0X
3524 #error
3525 #endif
3526 ], [case $target_os in
3527 # gthreads support breaks symbol versioning on Solaris 9 (PR
3528 # libstdc++/52189).
3529 solaris2.9*)
3530 if test x$enable_symvers = xno; then
3531 ac_has_gthreads=yes
3532 elif test x$enable_libstdcxx_threads = xyes; then
3533 AC_MSG_WARN([You have requested C++11 threads support, but])
3534 AC_MSG_WARN([this breaks symbol versioning.])
3535 ac_has_gthreads=yes
3536 else
3537 ac_has_gthreads=no
3538 fi
3539 ;;
3540 *)
3541 ac_has_gthreads=yes
3542 ;;
3543 esac],
3544 [ac_has_gthreads=no])
3545 else
3546 ac_has_gthreads=no
3547 fi
3549 AC_MSG_RESULT([$ac_has_gthreads])
3551 if test x"$ac_has_gthreads" = x"yes"; then
3552 AC_DEFINE(_GLIBCXX_HAS_GTHREADS, 1,
3553 [Define if gthreads library is available.])
3554 fi
3556 CXXFLAGS="$ac_save_CXXFLAGS"
3557 AC_LANG_RESTORE
3558 ])
3561 # Check whether LC_MESSAGES is available in <locale.h>.
3562 # Ulrich Drepper <drepper@cygnus.com>, 1995.
3563 #
3564 # This file file be copied and used freely without restrictions. It can
3565 # be used in projects which are not available under the GNU Public License
3566 # but which still want to provide support for the GNU gettext functionality.
3567 # Please note that the actual code is *not* freely available.
3568 AC_DEFUN([AC_LC_MESSAGES], [
3569 AC_CHECK_HEADER(locale.h, [
3570 AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
3571 [AC_TRY_COMPILE([#include <locale.h>], [return LC_MESSAGES],
3572 ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
3573 if test $ac_cv_val_LC_MESSAGES = yes; then
3574 AC_DEFINE(HAVE_LC_MESSAGES, 1,
3575 [Define if LC_MESSAGES is available in <locale.h>.])
3576 fi
3577 ])
3578 ])
3580 dnl
3581 dnl Check whether rdrand is supported in the assembler.
3582 AC_DEFUN([GLIBCXX_CHECK_X86_RDRAND], [
3583 AC_MSG_CHECKING([for rdrand support in assembler])
3584 AC_CACHE_VAL(ac_cv_x86_rdrand, [
3585 ac_cv_x86_rdrand=no
3586 case "$target" in
3587 i?86-*-* | \
3588 x86_64-*-*)
3589 AC_TRY_COMPILE(, [asm("rdrand %eax");],
3590 [ac_cv_x86_rdrand=yes], [ac_cv_x86_rdrand=no])
3591 esac
3592 ])
3593 if test $ac_cv_x86_rdrand = yes; then
3594 AC_DEFINE(_GLIBCXX_X86_RDRAND, 1,
3595 [ Defined if as can handle rdrand. ])
3596 fi
3597 AC_MSG_RESULT($ac_cv_x86_rdrand)
3598 ])
3600 dnl
3601 dnl Check whether get_nprocs is available in <sys/sysinfo.h>, and define _GLIBCXX_USE_GET_NPROCS.
3602 dnl
3603 AC_DEFUN([GLIBCXX_CHECK_GET_NPROCS], [
3605 AC_LANG_SAVE
3606 AC_LANG_CPLUSPLUS
3607 ac_save_CXXFLAGS="$CXXFLAGS"
3608 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3610 AC_MSG_CHECKING([for get_nprocs])
3611 AC_CACHE_VAL(glibcxx_cv_GET_NPROCS, [
3612 GCC_TRY_COMPILE_OR_LINK(
3613 [#include <sys/sysinfo.h>],
3614 [int n = get_nprocs();],
3615 [glibcxx_cv_GET_NPROCS=yes],
3616 [glibcxx_cv_GET_NPROCS=no])
3617 ])
3618 if test $glibcxx_cv_GET_NPROCS = yes; then
3619 AC_DEFINE(_GLIBCXX_USE_GET_NPROCS, 1, [Define if get_nprocs is available in <sys/sysinfo.h>.])
3620 fi
3621 AC_MSG_RESULT($glibcxx_cv_GET_NPROCS)
3623 CXXFLAGS="$ac_save_CXXFLAGS"
3624 AC_LANG_RESTORE
3625 ])
3627 dnl
3628 dnl Check whether sysconf(_SC_NPROCESSORS_ONLN) is available in <unistd.h>, and define _GLIBCXX_USE_SC_NPROCESSORS_ONLN.
3629 dnl
3630 AC_DEFUN([GLIBCXX_CHECK_SC_NPROCESSORS_ONLN], [
3632 AC_LANG_SAVE
3633 AC_LANG_CPLUSPLUS
3634 ac_save_CXXFLAGS="$CXXFLAGS"
3635 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3637 AC_MSG_CHECKING([for _SC_NPROCESSORS_ONLN])
3638 AC_CACHE_VAL(glibcxx_cv_SC_NPROCESSORS_ONLN, [
3639 GCC_TRY_COMPILE_OR_LINK(
3640 [#include <unistd.h>],
3641 [int n = sysconf(_SC_NPROCESSORS_ONLN);],
3642 [glibcxx_cv_SC_NPROCESSORS_ONLN=yes],
3643 [glibcxx_cv_SC_NPROCESSORS_ONLN=no])
3644 ])
3645 if test $glibcxx_cv_SC_NPROCESSORS_ONLN = yes; then
3646 AC_DEFINE(_GLIBCXX_USE_SC_NPROCESSORS_ONLN, 1, [Define if _SC_NPROCESSORS_ONLN is available in <unistd.h>.])
3647 fi
3648 AC_MSG_RESULT($glibcxx_cv_SC_NPROCESSORS_ONLN)
3650 CXXFLAGS="$ac_save_CXXFLAGS"
3651 AC_LANG_RESTORE
3652 ])
3654 dnl
3655 dnl Check whether sysconf(_SC_NPROC_ONLN) is available in <unistd.h>, and define _GLIBCXX_USE_SC_NPROC_ONLN.
3656 dnl
3657 AC_DEFUN([GLIBCXX_CHECK_SC_NPROC_ONLN], [
3659 AC_LANG_SAVE
3660 AC_LANG_CPLUSPLUS
3661 ac_save_CXXFLAGS="$CXXFLAGS"
3662 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3664 AC_MSG_CHECKING([for _SC_NPROC_ONLN])
3665 AC_CACHE_VAL(glibcxx_cv_SC_NPROC_ONLN, [
3666 GCC_TRY_COMPILE_OR_LINK(
3667 [#include <unistd.h>],
3668 [int n = sysconf(_SC_NPROC_ONLN);],
3669 [glibcxx_cv_SC_NPROC_ONLN=yes],
3670 [glibcxx_cv_SC_NPROC_ONLN=no])
3671 ])
3672 if test $glibcxx_cv_SC_NPROC_ONLN = yes; then
3673 AC_DEFINE(_GLIBCXX_USE_SC_NPROC_ONLN, 1, [Define if _SC_NPROC_ONLN is available in <unistd.h>.])
3674 fi
3675 AC_MSG_RESULT($glibcxx_cv_SC_NPROC_ONLN)
3677 CXXFLAGS="$ac_save_CXXFLAGS"
3678 AC_LANG_RESTORE
3679 ])
3681 dnl
3682 dnl Check whether pthread_num_processors_np is available in <pthread.h>, and define _GLIBCXX_USE_PTHREADS_NUM_PROCESSORS_NP.
3683 dnl
3684 AC_DEFUN([GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP], [
3686 AC_LANG_SAVE
3687 AC_LANG_CPLUSPLUS
3688 ac_save_CXXFLAGS="$CXXFLAGS"
3689 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3691 AC_MSG_CHECKING([for pthreads_num_processors_np])
3692 AC_CACHE_VAL(glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP, [
3693 GCC_TRY_COMPILE_OR_LINK(
3694 [#include <pthread.h>],
3695 [int n = pthread_num_processors_np();],
3696 [glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP=yes],
3697 [glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP=no])
3698 ])
3699 if test $glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP = yes; then
3700 AC_DEFINE(_GLIBCXX_USE_PTHREADS_NUM_PROCESSORS_NP, 1, [Define if pthreads_num_processors_np is available in <pthread.h>.])
3701 fi
3702 AC_MSG_RESULT($glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP)
3704 CXXFLAGS="$ac_save_CXXFLAGS"
3705 AC_LANG_RESTORE
3706 ])
3708 dnl
3709 dnl Check whether sysctl is available in <pthread.h>, and define _GLIBCXX_USE_SYSCTL_HW_NCPU.
3710 dnl
3711 AC_DEFUN([GLIBCXX_CHECK_SYSCTL_HW_NCPU], [
3713 AC_LANG_SAVE
3714 AC_LANG_CPLUSPLUS
3715 ac_save_CXXFLAGS="$CXXFLAGS"
3716 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3718 AC_MSG_CHECKING([for hw.ncpu sysctl])
3719 AC_CACHE_VAL(glibcxx_cv_SYSCTL_HW_NCPU, [
3720 GCC_TRY_COMPILE_OR_LINK(
3721 [
3722 #include <stddef.h>
3723 #include <sys/sysctl.h>
3724 ],
3725 [
3726 int count;
3727 size_t size = sizeof(count);
3728 int mib[] = { CTL_HW, HW_NCPU };
3729 sysctl(mib, 2, &count, &size, NULL, 0);
3730 ],
3731 [glibcxx_cv_SYSCTL_HW_NCPU=yes],
3732 [glibcxx_cv_SYSCTL_HW_NCPU=no])
3733 ])
3734 if test $glibcxx_cv_SYSCTL_HW_NCPU = yes; then
3735 AC_DEFINE(_GLIBCXX_USE_SYSCTL_HW_NCPU, 1, [Define if sysctl(), CTL_HW and HW_NCPU are available in <sys/sysctl.h>.])
3736 fi
3737 AC_MSG_RESULT($glibcxx_cv_SYSCTL_HW_NCPU)
3739 CXXFLAGS="$ac_save_CXXFLAGS"
3740 AC_LANG_RESTORE
3741 ])
3743 dnl
3744 dnl Check to see if python pretty printing can be activated.
3745 dnl
3746 dnl --with-python-dir=dir
3747 dnl installs directory into $prefix/dir
3748 AC_DEFUN([GLIBCXX_ENABLE_PYTHON], [
3750 AC_MSG_CHECKING([for custom python install directory])
3751 AC_ARG_WITH([python-dir],
3752 AS_HELP_STRING([--with-python-dir],
3753 [the location to install Python modules. This path is relative starting from the prefix.]),
3754 [with_python_dir=$withval], [with_python_dir="no"])
3755 AC_MSG_RESULT(${with_python_dir})
3757 # Needed for installing Python modules during make install.
3758 python_mod_dir="${with_python_dir}"
3759 AC_SUBST(python_mod_dir)
3760 GLIBCXX_CONDITIONAL(ENABLE_PYTHONDIR, test $python_mod_dir != no)
3761 ])
3763 dnl
3764 dnl Check to see if -Werror is disabled.
3765 dnl
3766 dnl --enable-werror/--disable-werror
3767 AC_DEFUN([GLIBCXX_ENABLE_WERROR], [
3768 AC_MSG_CHECKING([for -Werror])
3769 GLIBCXX_ENABLE(werror,$1,,[turns on -Werror])
3770 AC_MSG_RESULT($enable_werror)
3771 GLIBCXX_CONDITIONAL(ENABLE_WERROR, test $enable_werror = yes)
3772 ])
3774 dnl
3775 dnl Check whether obsolescent tmpnam is available in <stdio.h>,
3776 dnl and define _GLIBCXX_USE_TMPNAM.
3777 dnl
3778 AC_DEFUN([GLIBCXX_CHECK_TMPNAM], [dnl
3779 dnl
3780 AC_LANG_SAVE
3781 AC_LANG_CPLUSPLUS
3782 ac_save_CXXFLAGS="$CXXFLAGS"
3783 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3784 dnl
3785 AC_MSG_CHECKING([for tmpnam])
3786 AC_CACHE_VAL(glibcxx_cv_TMPNAM, [dnl
3787 GCC_TRY_COMPILE_OR_LINK(
3788 [#include <stdio.h>],
3789 [char *tmp = tmpnam(NULL);],
3790 [glibcxx_cv_TMPNAM=yes],
3791 [glibcxx_cv_TMPNAM=no])
3792 ])
3793 if test $glibcxx_cv_TMPNAM = yes; then
3794 AC_DEFINE(_GLIBCXX_USE_TMPNAM, 1, [Define if obsolescent tmpnam is available in <stdio.h>.])
3795 fi
3796 AC_MSG_RESULT($glibcxx_cv_TMPNAM)
3797 dnl
3798 CXXFLAGS="$ac_save_CXXFLAGS"
3799 AC_LANG_RESTORE
3800 ])
3802 dnl
3803 dnl Check to see if sys/sdt.h exists and that it is suitable for use.
3804 dnl Some versions of sdt.h were not compatible with C++11.
3805 dnl
3806 AC_DEFUN([GLIBCXX_CHECK_SDT_H], [
3807 AC_MSG_RESULT([for suitable sys/sdt.h])
3808 # Note that this test has to be run with the C language.
3809 # Otherwise, sdt.h will try to include some headers from
3810 # libstdc++ itself.
3811 AC_LANG_SAVE
3812 AC_LANG_C
3813 AC_CACHE_VAL(glibcxx_cv_sys_sdt_h, [
3814 # Because we have to run the test in C, we use grep rather
3815 # than the compiler to check for the bug. The bug is that
3816 # were strings without trailing whitespace, causing g++
3817 # to look for operator"". The pattern searches for the fixed
3818 # output.
3819 AC_EGREP_CPP([ \",\" ], [
3820 #include <sys/sdt.h>
3821 int f() { STAP_PROBE(hi, bob); }
3822 ], [glibcxx_cv_sys_sdt_h=yes], [glibcxx_cv_sys_sdt_h=no])
3823 ])
3824 AC_LANG_RESTORE
3825 if test $glibcxx_cv_sys_sdt_h = yes; then
3826 AC_DEFINE(HAVE_SYS_SDT_H, 1,
3827 [Define to 1 if you have a suitable <sys/sdt.h> header file])
3828 fi
3829 AC_MSG_RESULT($glibcxx_cv_sys_sdt_h)
3830 ])
3832 # Macros from the top-level gcc directory.
3833 m4_include([../config/gc++filt.m4])
3834 m4_include([../config/tls.m4])
3835 m4_include([../config/gthr.m4])