libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=6:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  54                                       [turns on -Werror @<:@default=yes@:>@])])
  55 if test "x$enable_werror" != "xno"; then
  56   WERROR="-Werror"
  57 fi
  58 AC_SUBST(WERROR)
  59
  60 glibgo_toolexecdir=no
  61 glibgo_toolexeclibdir=no
  62
  63 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  64 AC_ARG_ENABLE([version-specific-runtime-libs],
  65   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  67   [case "$enableval" in
  68     yes) version_specific_libs=yes ;;
  69     no)  version_specific_libs=no ;;
  70     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71    esac],
  72   [version_specific_libs=no])
  73 AC_MSG_RESULT($version_specific_libs)
  74
  75 # Version-specific runtime libs processing.
  76 if test $version_specific_libs = yes; then
  77   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  78   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  79 fi
  80
  81 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  82 # Install a library built with a cross compiler in tooldir, not libdir.
  83 if test -n "$with_cross_host" &&
  84    test x"$with_cross_host" != x"no"; then
  85   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  86   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  87 else
  88   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  89   nover_glibgo_toolexeclibdir='${libdir}'
  90 fi
  91 multi_os_directory=`$GOC -print-multi-os-directory`
  92 case $multi_os_directory in
  93   .) ;; # Avoid trailing /.
  94   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
  95 esac
  96
  97 if test x"$glibgo_toolexecdir" = x"no"; then
  98   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
  99   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 100 fi
 101
 102 AC_SUBST(glibgo_toolexecdir)
 103 AC_SUBST(glibgo_toolexeclibdir)
 104 AC_SUBST(nover_glibgo_toolexeclibdir)
 105
 106 # See if the user wants to configure without libffi.  Some
 107 # architectures don't support it.  FIXME: We should set a default
 108 # based on the host.
 109 AC_ARG_WITH(libffi,
 110   AS_HELP_STRING([--without-libffi],
 111                  [don't use libffi]),
 112   [:],
 113   [with_libffi=${with_libffi_default-yes}])
 114
 115 LIBFFI=
 116 LIBFFIINCS=
 117 if test "$with_libffi" != no; then
 118    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 119    LIBFFI=../libffi/libffi_convenience.la
 120    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 121 fi
 122 AC_SUBST(LIBFFI)
 123 AC_SUBST(LIBFFIINCS)
 124
 125 # See if the user wants to configure without libatomic. This is useful if we are
 126 # on an architecture for which libgo does not need an atomic support library and
 127 # libatomic does not support our C compiler.
 128 AC_ARG_WITH(libatomic,
 129   AS_HELP_STRING([--without-libatomic],
 130                  [don't use libatomic]),
 131   [:],
 132   [with_libatomic=${with_libatomic_default-yes}])
 133
 134 LIBATOMIC=
 135 if test "$with_libatomic" != no; then
 136    LIBATOMIC=../libatomic/libatomic_convenience.la
 137 fi
 138 AC_SUBST(LIBATOMIC)
 139
 140 # Used to tell GNU make to include a file without telling automake to
 141 # include it.
 142 go_include="-include"
 143 AC_SUBST(go_include)
 144
 145 is_darwin=no
 146 is_freebsd=no
 147 is_irix=no
 148 is_linux=no
 149 is_netbsd=no
 150 is_openbsd=no
 151 is_dragonfly=no
 152 is_rtems=no
 153 is_solaris=no
 154 GOOS=unknown
 155 case ${host} in
 156   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 157   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 158   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 159   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 160   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 161   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 162   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 163   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 164   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 165 esac
 166 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 167 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 168 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 169 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 170 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 171 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 172 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 173 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 174 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 175 AC_SUBST(GOOS)
 176
 177 dnl Test whether we need to use DejaGNU or whether we can use the
 178 dnl simpler gotest approach.  We can only use gotest for a native
 179 dnl build.
 180 USE_DEJAGNU=no
 181 case ${host} in
 182   *-*-rtems*) USE_DEJAGNU=yes ;;
 183   ${build}) ;;
 184   *) USE_DEJAGNU=yes ;;
 185 esac
 186 AC_SUBST(USE_DEJAGNU)
 187
 188 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 189 is_386=no
 190 is_alpha=no
 191 is_arm=no
 192 is_arm64=no
 193 is_m68k=no
 194 mips_abi=unknown
 195 is_ppc=no
 196 is_ppc64=no
 197 is_sparc=no
 198 is_sparc64=no
 199 is_x86_64=no
 200 GOARCH=unknown
 201 case ${host} in
 202   alpha*-*-*)
 203     is_alpha=yes
 204     GOARCH=alpha
 205     ;;
 206   aarch64-*-*)
 207     is_arm64=yes
 208     GOARCH=arm64
 209     ;;
 210   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 211     is_arm=yes
 212     GOARCH=arm
 213     ;;
 214 changequote(,)dnl
 215   i[34567]86-*-* | x86_64-*-*)
 216 changequote([,])dnl
 217     AC_COMPILE_IFELSE([
 218 #ifdef __x86_64__
 219 #error 64-bit
 220 #endif],
 221 [is_386=yes], [is_x86_64=yes])
 222     if test "$is_386" = "yes"; then
 223       GOARCH=386
 224     else
 225       GOARCH=amd64
 226     fi
 227     ;;
 228   m68k*-*-*)
 229     is_m68k=yes
 230     GOARCH=m68k
 231     ;;
 232   mips*-*-*)
 233     AC_COMPILE_IFELSE([
 234 #if _MIPS_SIM != _ABIO32
 235 #error not o32
 236 #endif],
 237 [mips_abi="o32"],
 238         [AC_COMPILE_IFELSE([
 239 #if _MIPS_SIM != _ABIN32
 240 #error not n32
 241 #endif],
 242 [mips_abi="n32"],
 243         [AC_COMPILE_IFELSE([
 244 #if _MIPS_SIM != _ABI64
 245 #error not n64
 246 #endif],
 247 [mips_abi="n64"],
 248         [AC_COMPILE_IFELSE([
 249 #if _MIPS_SIM != _ABIO64
 250 #error not o64
 251 #endif],
 252 [mips_abi="o64"],
 253         [AC_MSG_ERROR([unknown MIPS ABI])
 254 [mips_abi="n32"]])])])])
 255     case "$mips_abi" in
 256     "o32") GOARCH=mipso32 ;;
 257     "n32") GOARCH=mipsn32 ;;
 258     "n64") GOARCH=mipsn64 ;;
 259     "o64") GOARCH=mipso64 ;;
 260     esac
 261     ;;
 262   rs6000*-*-* | powerpc*-*-*)
 263     AC_COMPILE_IFELSE([
 264 #ifdef _ARCH_PPC64
 265 #error 64-bit
 266 #endif],
 267 [is_ppc=yes], [is_ppc64=yes])
 268     if test "$is_ppc" = "yes"; then
 269       GOARCH=ppc
 270     else
 271       GOARCH=ppc64
 272     fi
 273     ;;
 274   sparc*-*-*)
 275     AC_COMPILE_IFELSE([
 276 #if defined(__sparcv9) || defined(__arch64__)
 277 #error 64-bit
 278 #endif],
 279 [is_sparc=yes], [is_sparc64=yes])
 280     if test "$is_sparc" = "yes"; then
 281       GOARCH=sparc
 282     else
 283       GOARCH=sparc64
 284     fi
 285     ;;
 286 esac
 287 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 288 AM_CONDITIONAL(LIBGO_IS_ALPHA, test $is_alpha = yes)
 289 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 290 AM_CONDITIONAL(LIBGO_IS_ARM64, test $is_arm64 = yes)
 291 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 292 AM_CONDITIONAL(LIBGO_IS_MIPS, test $mips_abi != unknown)
 293 AM_CONDITIONAL(LIBGO_IS_MIPSO32, test $mips_abi = o32)
 294 AM_CONDITIONAL(LIBGO_IS_MIPSN32, test $mips_abi = n32)
 295 AM_CONDITIONAL(LIBGO_IS_MIPSN64, test $mips_abi = n64)
 296 AM_CONDITIONAL(LIBGO_IS_MIPSO64, test $mips_abi = o64)
 297 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 298 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 299 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 300 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 301 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 302 AC_SUBST(GOARCH)
 303
 304 dnl Some files are only present when needed for specific architectures.
 305 GO_LIBCALL_OS_FILE=
 306 GO_LIBCALL_OS_ARCH_FILE=
 307 GO_SYSCALL_OS_FILE=
 308 GO_SYSCALL_OS_ARCH_FILE=
 309 if test -f ${srcdir}/go/syscall/libcall_${GOOS}.go; then
 310   GO_LIBCALL_OS_FILE=go/syscall/libcall_${GOOS}.go
 311 fi
 312 if test -f ${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go; then
 313   GO_LIBCALL_OS_ARCH_FILE=go/syscall/libcall_${GOOS}_${GOARCH}.go
 314 fi
 315 if test -f ${srcdir}/go/syscall/syscall_${GOOS}.go; then
 316   GO_SYSCALL_OS_FILE=go/syscall/syscall_${GOOS}.go
 317 fi
 318 if test -f ${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go; then
 319   GO_SYSCALL_OS_ARCH_FILE=go/syscall/syscall_${GOOS}_${GOARCH}.go
 320 fi
 321 AC_SUBST(GO_LIBCALL_OS_FILE)
 322 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 323 AC_SUBST(GO_SYSCALL_OS_FILE)
 324 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 325
 326 dnl Special flags used to generate sysinfo.go.
 327 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 328 case "$target" in
 329     mips-sgi-irix6.5*)
 330         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 331         # msghdr in <sys/socket.h>.
 332         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 333         ;;
 334     *-*-solaris2.1[[01]])
 335         # Solaris 10+ needs this so struct msghdr gets the msg_control
 336         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 337         # above doesn't work with C99.
 338         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 339         ;;
 340 esac
 341 AC_SUBST(OSCFLAGS)
 342
 343 dnl Use -fsplit-stack when compiling C code if available.
 344 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 345 [libgo_cv_c_split_stack_supported],
 346 [CFLAGS_hold=$CFLAGS
 347 CFLAGS="$CFLAGS -fsplit-stack"
 348 AC_COMPILE_IFELSE([[int i;]],
 349 [libgo_cv_c_split_stack_supported=yes],
 350 [libgo_cv_c_split_stack_supported=no])
 351 CFLAGS=$CFLAGS_hold])
 352 if test "$libgo_cv_c_split_stack_supported" = yes; then
 353   SPLIT_STACK=-fsplit-stack
 354   AC_DEFINE(USING_SPLIT_STACK, 1,
 355                 [Define if the compiler supports -fsplit-stack])
 356 else
 357   SPLIT_STACK=
 358 fi
 359 AC_SUBST(SPLIT_STACK)
 360 AM_CONDITIONAL(USING_SPLIT_STACK,
 361         test "$libgo_cv_c_split_stack_supported" = yes)
 362
 363 dnl Check whether the linker does stack munging when calling from
 364 dnl split-stack into non-split-stack code.  We check this by looking
 365 dnl at the --help output.  FIXME: This is only half right: it's
 366 dnl possible for the linker to support this for some targets but not
 367 dnl others.
 368 AC_CACHE_CHECK([whether linker supports split stack],
 369 [libgo_cv_c_linker_supports_split_stack],
 370 [libgo_cv_c_linker_supports_split_stack=no
 371 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 372   libgo_cv_c_linker_supports_split_stack=yes
 373 fi])
 374 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 375   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 376             [Define if the linker support split stack adjustments])
 377 fi
 378
 379 dnl Test for the -lm library.
 380 MATH_LIBS=
 381 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 382 AC_SUBST(MATH_LIBS)
 383
 384 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 385 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 386   [libgo_cv_lib_sockets=
 387    libgo_check_both=no
 388    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 389    if test "$libgo_check_socket" = "yes"; then
 390      unset ac_cv_func_connect
 391      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 392                   libgo_check_both=yes)
 393    fi
 394    if test "$libgo_check_both" = "yes"; then
 395      libgo_old_libs=$LIBS
 396      LIBS="$LIBS -lsocket -lnsl"
 397      unset ac_cv_func_accept
 398      AC_CHECK_FUNC(accept,
 399                    [libgo_check_nsl=no
 400                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 401      unset ac_cv_func_accept
 402      LIBS=$libgo_old_libs
 403    fi
 404    unset ac_cv_func_gethostbyname
 405    libgo_old_libs="$LIBS"
 406    AC_CHECK_FUNC(gethostbyname, ,
 407                  [AC_CHECK_LIB(nsl, main,
 408                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 409    unset ac_cv_func_gethostbyname
 410    LIBS=$libgo_old_libs
 411 ])
 412 NET_LIBS="$libgo_cv_lib_sockets"
 413 AC_SUBST(NET_LIBS)
 414
 415 dnl Test whether the compiler supports the -pthread option.
 416 AC_CACHE_CHECK([whether -pthread is supported],
 417 [libgo_cv_lib_pthread],
 418 [CFLAGS_hold=$CFLAGS
 419 CFLAGS="$CFLAGS -pthread"
 420 AC_COMPILE_IFELSE([[int i;]],
 421 [libgo_cv_lib_pthread=yes],
 422 [libgo_cv_lib_pthread=no])
 423 CFLAGS=$CFLAGS_hold])
 424 PTHREAD_CFLAGS=
 425 if test "$libgo_cv_lib_pthread" = yes; then
 426   PTHREAD_CFLAGS=-pthread
 427 fi
 428 AC_SUBST(PTHREAD_CFLAGS)
 429
 430 dnl Test for the -lpthread library.
 431 PTHREAD_LIBS=
 432 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 433 AC_SUBST(PTHREAD_LIBS)
 434
 435 dnl Test if -lrt is required for sched_yield and/or nanosleep.
 436 AC_SEARCH_LIBS([sched_yield], [rt])
 437 AC_SEARCH_LIBS([nanosleep], [rt])
 438
 439 AC_C_BIGENDIAN
 440
 441 GCC_CHECK_UNWIND_GETIPINFO
 442
 443 AC_ARG_ENABLE(sjlj-exceptions,
 444   AC_HELP_STRING([--enable-sjlj-exceptions],
 445                  [force use of builtin_setjmp for exceptions]),
 446   [case "$enableval" in
 447    yes|no|auto) ;;
 448    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 449    esac],
 450   [enable_sjlj_exceptions=auto])
 451
 452 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 453 [libgo_cv_lib_sjlj_exceptions],
 454 [AC_LANG_CONFTEST(
 455   [AC_LANG_SOURCE([
 456 void bar ();
 457 void clean (int *);
 458 void foo ()
 459 {
 460   int i __attribute__ ((cleanup (clean)));
 461   bar();
 462 }
 463 ])])
 464 CFLAGS_hold=$CFLAGS
 465 CFLAGS="--save-temps -fexceptions"
 466 libgo_cv_lib_sjlj_exceptions=unknown
 467 AS_IF([ac_fn_c_try_compile],
 468   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 469     libgo_cv_lib_sjlj_exceptions=yes
 470   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 471     libgo_cv_lib_sjlj_exceptions=no
 472   fi])
 473 CFLAGS=$CFLAGS_hold
 474 rm -f conftest*
 475 ])
 476
 477 if test "$enable_sjlj_exceptions" = "auto"; then
 478   enable_sjlj_exceptions=$libgo_cv_lib_sjlj_exceptions
 479 fi
 480
 481 case $enable_sjlj_exceptions in
 482 yes)
 483   AC_DEFINE(LIBGO_SJLJ_EXCEPTIONS, 1,
 484         [Define if the C++ compiler is configured for setjmp/longjmp exceptions.])
 485   ;;
 486 no)
 487   ;;
 488 *)
 489   AC_MSG_ERROR([unable to detect exception model])
 490   ;;
 491 esac
 492
 493 AC_CHECK_HEADERS(sched.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/reboot.h netinet/icmp6.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 494
 495 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 496 [#ifdef HAVE_SYS_SOCKET_H
 497 #include <sys/socket.h>
 498 #endif
 499 ])
 500
 501 AC_CACHE_CHECK([whether <ustat.h> can be used],
 502 [libgo_cv_c_ustat_h],
 503 [CFLAGS_hold=$CFLAGS
 504 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 505 AC_COMPILE_IFELSE(
 506 [AC_LANG_SOURCE([
 507 #include <sys/types.h>
 508 #ifdef HAVE_LINUX_FILTER_H
 509 #include <linux/filter.h>
 510 #endif
 511 #include <ustat.h>
 512 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 513 CFLAGS=$CFLAGS_hold])
 514 if test $libgo_cv_c_ustat_h = yes; then
 515   AC_DEFINE(HAVE_USTAT_H, 1,
 516     [Define to 1 if you have the <ustat.h> header file and it works.])
 517 fi
 518
 519 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 520
 521 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv dl_iterate_phdr)
 522 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 523 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 524
 525 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice tee unlinkat unshare utimensat)
 526 AC_TYPE_OFF_T
 527 AC_CHECK_TYPES([loff_t])
 528
 529 LIBS_hold="$LIBS"
 530 LIBS="$LIBS -lm"
 531 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 532 LIBS="$LIBS_hold"
 533
 534 CFLAGS_hold="$CFLAGS"
 535 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 536 LIBS_hold="$LIBS"
 537 LIBS="$LIBS $PTHREAD_LIBS"
 538 AC_CHECK_FUNCS(sem_timedwait)
 539 CFLAGS="$CFLAGS_hold"
 540 LIBS="$LIBS_hold"
 541
 542 LIBS_hold="$LIBS"
 543 LIBS="$LIBS $MATH_LIBS"
 544 AC_CHECK_FUNCS(matherr)
 545 LIBS="$LIBS_hold"
 546
 547 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 548 [libgo_cv_func___sync_bool_compare_and_swap_4],
 549 [AC_LINK_IFELSE([
 550 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 551 uint32 i;
 552 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 553 ],
 554 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 555 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 556 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 557   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 558     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 559 fi
 560
 561 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 562 [libgo_cv_func___sync_bool_compare_and_swap_8],
 563 [AC_LINK_IFELSE([
 564 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 565 uint64 i;
 566 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 567 ],
 568 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 569 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 570 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 571   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 572     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 573 fi
 574
 575 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 576 [libgo_cv_func___sync_fetch_and_add_4],
 577 [AC_LINK_IFELSE([
 578 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 579 uint32 i;
 580 int main() { return __sync_fetch_and_add (&i, 1); }
 581 ],
 582 [libgo_cv_func___sync_fetch_and_add_4=yes],
 583 [libgo_cv_func___sync_fetch_and_add_4=no])])
 584 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 585   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 586     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 587 fi
 588
 589 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 590 [libgo_cv_func___sync_add_and_fetch_8],
 591 [AC_LINK_IFELSE([
 592 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 593 uint64 i;
 594 int main() { return __sync_add_and_fetch (&i, 1); }
 595 ],
 596 [libgo_cv_func___sync_add_and_fetch_8=yes],
 597 [libgo_cv_func___sync_add_and_fetch_8=no])])
 598 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 599   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 600     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 601 fi
 602
 603 dnl For x86 we want to use the -minline-all-stringops option to avoid
 604 dnl forcing a stack split when calling memcpy and friends.
 605 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 606 [libgo_cv_c_stringops],
 607 [CFLAGS_hold=$CFLAGS
 608 CFLAGS="$CFLAGS -minline-all-stringops"
 609 AC_COMPILE_IFELSE([int i;],
 610 [libgo_cv_c_stringops=yes],
 611 [libgo_cv_c_stringops=no])
 612 CFLAGS=$CFLAGS_hold])
 613 STRINGOPS_FLAG=
 614 if test "$libgo_cv_c_stringops" = yes; then
 615   STRINGOPS_FLAG=-minline-all-stringops
 616 fi
 617 AC_SUBST(STRINGOPS_FLAG)
 618
 619 dnl For x86 we want to compile the math library with -mfancy-math-387
 620 dnl -funsafe-math-optimizations so that we can use the builtin
 621 dnl instructions directly.
 622 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 623 [libgo_cv_c_fancymath],
 624 [CFLAGS_hold=$CFLAGS
 625 CFLAGS="$CFLAGS -mfancy-math-387"
 626 AC_COMPILE_IFELSE([int i;],
 627 [libgo_cv_c_fancymath=yes],
 628 [libgo_cv_c_fancymath=no])
 629 CFLAGS=$CFLAGS_hold])
 630 MATH_FLAG=
 631 if test "$libgo_cv_c_fancymath" = yes; then
 632   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations"
 633 else
 634   MATH_FLAG="-ffp-contract=off"
 635 fi
 636 AC_SUBST(MATH_FLAG)
 637
 638 CFLAGS_hold=$CFLAGS
 639 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 640 AC_CHECK_TYPES([off64_t])
 641 CFLAGS=$CFLAGS_hold
 642
 643 dnl Work out the size of the epoll_events struct on GNU/Linux.
 644 AC_CACHE_CHECK([epoll_event size],
 645 [libgo_cv_c_epoll_event_size],
 646 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 647 [sizeof (struct epoll_event)],
 648 [#include <sys/epoll.h>],
 649 [libgo_cv_c_epoll_event_size=0])])
 650 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 651 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 652
 653 dnl Work out the offset of the fd field in the epoll_events struct on
 654 dnl GNU/Linux.
 655 AC_CACHE_CHECK([epoll_event data.fd offset],
 656 [libgo_cv_c_epoll_event_fd_offset],
 657 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 658 [offsetof (struct epoll_event, data.fd)],
 659 [#include <stddef.h>
 660 #include <sys/epoll.h>],
 661 [libgo_cv_c_epoll_event_fd_offset=0])])
 662 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 663 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 664
 665 dnl See if struct exception is defined in <math.h>.
 666 AC_CHECK_TYPE([struct exception],
 667 [libgo_has_struct_exception=yes],
 668 [libgo_has_struct_exception=no],
 669 [#include <math.h>])
 670 if test "$libgo_has_struct_exception" = "yes"; then
 671   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 672             [Define to 1 if <math.h> defines struct exception])
 673 fi
 674
 675 dnl See whether setcontext changes the value of TLS variables.
 676 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 677 [libgo_cv_lib_setcontext_clobbers_tls],
 678 [CFLAGS_hold="$CFLAGS"
 679 CFLAGS="$PTHREAD_CFLAGS"
 680 LIBS_hold="$LIBS"
 681 LIBS="$LIBS $PTHREAD_LIBS"
 682 AC_CHECK_SIZEOF([void *])
 683 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 684 AC_RUN_IFELSE(
 685   [AC_LANG_SOURCE([
 686 #include <pthread.h>
 687 #include <stdlib.h>
 688 #include <ucontext.h>
 689 #include <unistd.h>
 690
 691 __thread int tls;
 692
 693 static char stack[[10 * 1024 * 1024]];
 694 static ucontext_t c;
 695
 696 /* Called via makecontext/setcontext.  */
 697
 698 static void
 699 cfn (void)
 700 {
 701   exit (tls);
 702 }
 703
 704 /* Called via pthread_create.  */
 705
 706 static void *
 707 tfn (void *dummy)
 708 {
 709   /* The thread should still see this value after calling
 710      setcontext.  */
 711   tls = 0;
 712
 713   setcontext (&c);
 714
 715   /* The call to setcontext should not return.  */
 716   abort ();
 717 }
 718
 719 int
 720 main ()
 721 {
 722   pthread_t tid;
 723
 724   /* The thread should not see this value.  */
 725   tls = 1;
 726
 727   if (getcontext (&c) < 0)
 728     abort ();
 729
 730   c.uc_stack.ss_sp = stack;
 731 #ifdef MAKECONTEXT_STACK_TOP
 732   c.uc_stack.ss_sp += sizeof stack;
 733 #endif
 734   c.uc_stack.ss_flags = 0;
 735   c.uc_stack.ss_size = sizeof stack;
 736   c.uc_link = NULL;
 737   makecontext (&c, cfn, 0);
 738
 739   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 740     abort ();
 741
 742   if (pthread_join (tid, NULL) != 0)
 743     abort ();
 744
 745   /* The thread should have called exit.  */
 746   abort ();
 747 }
 748 ])],
 749 [libgo_cv_lib_setcontext_clobbers_tls=no],
 750 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 751 [case "$target:$ptr_type_size" in
 752   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 753     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 754   *)
 755     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 756  esac
 757 ])
 758 CFLAGS="$CFLAGS_hold"
 759 LIBS="$LIBS_hold"
 760 ])
 761 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 762   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 763             [Define if setcontext clobbers TLS variables])
 764 fi
 765
 766 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 767 libgo_cv_ro_eh_frame, [
 768 libgo_cv_ro_eh_frame=no
 769 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 770 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 771   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 772     libgo_cv_ro_eh_frame=yes
 773   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 774        | grep -v '#write' > /dev/null; then
 775     libgo_cv_ro_eh_frame=yes
 776   fi
 777 fi
 778 rm -f conftest.*
 779 ])
 780 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 781   AC_DEFINE(EH_FRAME_FLAGS, "a",
 782             [Define to the flags needed for the .section .eh_frame directive.])
 783 else
 784   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 785             [Define to the flags needed for the .section .eh_frame directive.])
 786 fi
 787
 788 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 789 libgo_cv_as_comdat_gnu, [
 790 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 791 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 792   libgo_cv_as_comdat_gnu=yes
 793 else
 794   libgo_cv_as_comdat_gnu=no
 795 fi
 796 ])
 797 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 798   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 799             [Define if your assembler supports GNU comdat group syntax.])
 800 fi
 801
 802 AC_CACHE_CHECK([assembler supports pc related relocs],
 803 libgo_cv_as_x86_pcrel, [
 804 libgo_cv_as_x86_pcrel=yes
 805 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 806 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 807     libgo_cv_as_x86_pcrel=no
 808 fi
 809 ])
 810 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 811   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 812             [Define if your assembler supports PC relative relocs.])
 813 fi
 814
 815 AC_CACHE_CHECK([assembler supports unwind section type],
 816 libgo_cv_as_x86_64_unwind_section_type, [
 817 libgo_cv_as_x86_64_unwind_section_type=yes
 818 echo '.section .eh_frame,"a",@unwind' > conftest.s
 819 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 820     libgo_cv_as_x86_64_unwind_section_type=no
 821 fi
 822 ])
 823 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 824   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 825             [Define if your assembler supports unwind section type.])
 826 fi
 827
 828 AC_CACHE_SAVE
 829
 830 if test ${multilib} = yes; then
 831   multilib_arg="--enable-multilib"
 832 else
 833   multilib_arg=
 834 fi
 835
 836 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 837
 838 AC_CONFIG_COMMANDS([default],
 839 [if test -n "$CONFIG_FILES"; then
 840    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 841    # that multilib installs will end up installed in the correct place.
 842    # The testsuite needs it for multilib-aware ABI baseline files.
 843    # To work around this not being passed down from config-ml.in ->
 844    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 845    # append it here.  Only modify Makefiles that have just been created.
 846    #
 847    # Also, get rid of this simulated-VPATH thing that automake does.
 848    cat > vpsed << \_EOF
 849 s!`test -f '$<' || echo '$(srcdir)/'`!!
 850 _EOF
 851    for i in $SUBDIRS; do
 852     case $CONFIG_FILES in
 853      *${i}/Makefile*)
 854        #echo "Adding MULTISUBDIR to $i/Makefile"
 855        sed -f vpsed $i/Makefile > tmp
 856        grep '^MULTISUBDIR =' Makefile >> tmp
 857        mv tmp $i/Makefile
 858        ;;
 859     esac
 860    done
 861    rm vpsed
 862  fi
 863 ],
 864 [
 865 # Variables needed in config.status (file generation) which aren't already
 866 # passed by autoconf.
 867 SUBDIRS="$SUBDIRS"
 868 ])
 869
 870 AC_OUTPUT