libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  88 GCC_NO_EXECUTABLES
  89
  90 # (1) We use an abnormal CXX (without library references), so we
  91 # must cache it under a different name.
  92 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  93 # the non-multilib-adjusted value will be used in multilibs.
  94 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  95 # (4) As another side effect, automake doesn't automatically include them
  96 # in Makefile.in.
  97 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  98 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  99 # used in later tests.  This may not be necessary in libjava; I don't know.
 100 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103 save_CXXFLAGS="$CXXFLAGS"
 104 CXXFLAGS="$CXXFLAGS -fno-builtin"
 105 AC_PROG_CC
 106 AC_PROG_CXX
 107 CXXFLAGS="$save_CXXFLAGS"
 108 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109 AC_SUBST(CFLAGS)
 110 AC_SUBST(CXXFLAGS)
 111 AC_SUBST(LDFLAGS)
 112
 113 AM_INIT_AUTOMAKE([1.9.0])
 114
 115 AC_CHECK_TOOL(AS, as)
 116 AC_CHECK_TOOL(LD, ld)
 117 AC_CHECK_TOOL(AR, ar)
 118 AC_CHECK_TOOL(RANLIB, ranlib, :)
 119 AC_PROG_AWK
 120 AC_CHECK_PROGS([JAR], [jar fastjar], no)
 121 AC_PATH_PROG([ZIP], [zip], no)
 122 AC_PATH_PROG([UNZIP], [unzip], unzip)
 123 AM_CONDITIONAL(BASH_JAR, test "$JAR" = no)
 124 if test "$ZIP" = no; then
 125   if test "$JAR" = no; then
 126     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 127   fi
 128 else
 129   # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 130   JAR=`pwd`/scripts/jar
 131 fi
 132
 133 AC_PROG_INSTALL
 134
 135 AM_MAINTAINER_MODE
 136
 137 AC_EXEEXT
 138
 139 # configure.host sets the following important variables
 140 #       libgcj_cflags    - host specific C compiler flags
 141 #       libgcj_cxxflags  - host specific C++ compiler flags
 142 #       libgcj_javaflags - host specific Java compiler flags
 143
 144 libgcj_cflags=
 145 libgcj_cxxflags=
 146 libgcj_javaflags=
 147
 148 . ${srcdir}/configure.host
 149
 150 LIBGCJ_CFLAGS="${libgcj_cflags}"
 151 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 152 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 153 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 154 AC_SUBST(LIBGCJ_CFLAGS)
 155 AC_SUBST(LIBGCJ_CXXFLAGS)
 156 AC_SUBST(LIBGCJ_JAVAFLAGS)
 157 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 158
 159 # Only use libltdl for non-newlib builds.
 160 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 161    AC_LTDL_SHLIBPATH
 162 fi
 163
 164 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 165
 166 # See if the user has requested runtime debugging.
 167 LIBGCJDEBUG="disable"
 168 AC_SUBST(LIBGCJDEBUG)
 169 AC_ARG_ENABLE(libgcj-debug,
 170   AS_HELP_STRING([--enable-libgcj-debug],
 171                  [enable runtime debugging code]),
 172   [if test "$enable_libgcj_debug" = yes; then
 173     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 174     LIBGCJDEBUG="enable"
 175   fi])
 176
 177 # Determine which AWT peer libraries to build
 178 AC_ARG_ENABLE(java-awt,
 179   AS_HELP_STRING([--enable-java-awt],
 180                  [list of AWT peer implementations to be built]))
 181
 182 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 183 use_xlib_awt=""
 184 use_gtk_awt=""
 185 use_qt_awt=""
 186 # The default toolkit to use is the first one specified.
 187 TOOLKIT=
 188 AC_SUBST(TOOLKIT)
 189
 190 for peer in $peerlibs ; do
 191   case $peer in
 192     xlib)
 193       if test "$no_x" = yes; then
 194         echo "*** xlib peers requested but no X library available" 1>&2
 195         exit 1
 196       else
 197         use_xlib_awt="yes"
 198         if test -z "$TOOLKIT"; then
 199            TOOLKIT=gnu.awt.xlib.XToolkit
 200         fi
 201       fi
 202       ;;
 203     gtk)
 204       if test "$no_x" = yes; then
 205          echo "*** gtk peers requested but no X library available" 1>&2
 206          exit 1
 207       else
 208          use_gtk_awt=yes
 209          if test -z "$TOOLKIT"; then
 210             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 211          fi
 212       fi
 213       ;;
 214     qt)
 215       if test "$no_x" = yes; then
 216          # Perhaps we should admit the possibility of embedded Qt.
 217          echo "*** Qt peers requested but no X library available" 1>&2
 218          exit 1
 219       else
 220          use_qt_awt=yes
 221          if test -z "$TOOLKIT"; then
 222             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 223          fi
 224       fi
 225       ;;
 226     no)
 227       use_xlib_awt=
 228       use_gtk_awt=
 229       use_qt_awt=
 230       break
 231       ;;
 232     *)
 233       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 234       exit 1
 235   esac
 236 done
 237
 238 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 239
 240 # Create standard.omit based on decisions we just made.
 241 cp $srcdir/standard.omit.in standard.omit
 242 if test "$use_xlib_awt" != yes; then
 243    echo gnu/awt/xlib >> standard.omit
 244    echo gnu/gcj/xlib >> standard.omit
 245 fi
 246
 247 if test -z "${with_multisubdir}"; then
 248    builddotdot=.
 249 else
 250    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 251 fi
 252
 253 NATIVE=yes
 254
 255 # Which gcj do we use?
 256 which_gcj=default
 257 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 258 if test -n "${with_cross_host}"; then
 259   # We are being configured with a cross compiler. We can't
 260   # use ac_exeext, because that is for the target platform.
 261   NATIVE=no
 262   cross_host_exeext=
 263   case "${with_cross_host}" in
 264      *mingw* | *cygwin*)
 265          cross_host_exeext=.exe
 266      ;;
 267   esac
 268   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 269      if test x"$build_noncanonical" = x"$with_cross_host"; then
 270         # Ordinary cross (host!=target and host=build)
 271         which_gcj=built
 272      else
 273         # Canadian cross (host!=target and host!=build)
 274         which_gcj=cross
 275      fi
 276   else
 277      which_gcj=cross
 278   fi
 279 else
 280   # We are being configured with a native or crossed-native compiler
 281   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 282      if test x"$build" = x"$host"; then
 283         # True native build (host=target and host=build)
 284         which_gcj=built
 285      else
 286         # Crossed-native build (host=target and host!=build)
 287         which_gcj=cross
 288      fi
 289   else
 290      which_gcj=path
 291   fi
 292 fi
 293 case "${which_gcj}" in
 294    built)
 295       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 296       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 297    ;;
 298    cross)
 299       if test "x${with_newlib}" = "xyes"; then
 300          # FIXME (comment): Why is this needed?
 301          GCC_UNWIND_INCLUDE=
 302          GCJ="${target_noncanonical}-gcj"
 303       else
 304          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 305       fi
 306       GCJH='$(target_noncanonical)-gcjh'
 307    ;;
 308    path)
 309       GCJ="gcj -B`${PWDCMD-pwd}`/"
 310       GCJH=gcjh
 311    ;;
 312 esac
 313
 314 AC_SUBST(GCJH)
 315
 316 # Create it, so that compile/link tests don't fail
 317 test -f libgcj.spec || touch libgcj.spec
 318
 319
 320
 321 # Set up to configure Classpath.
 322 # FIXME: no supported way to pass args in autoconf.
 323 ac_configure_args="$ac_configure_args --disable-load-library"
 324 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 325 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 326 dir1=`cd $srcdir && pwd`
 327 dir2=`pwd`
 328 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 329 ac_configure_args="$ac_configure_args --disable-core-jni"
 330 dnl FIXME?
 331 ac_configure_args="$ac_configure_args --disable-examples"
 332 ac_configure_args="$ac_configure_args --with-glibj=build"
 333 if test "$use_gtk_awt" != yes; then
 334   ac_configure_args="$ac_configure_args --disable-gtk-peer"
 335 fi
 336 if test "$use_qt_awt" != yes; then
 337   ac_configure_args="$ac_configure_args --disable-qt-peer"
 338 else
 339   # We need this as qt is disabled by default in classpath.
 340   ac_configure_args="$ac_configure_args --enable-qt-peer"
 341 fi
 342 dnl --with-gcj=$GCJ
 343 dnl --with-javah=$GCJH
 344 dnl gjdoc?
 345 dnl gtk-cairo -- just export here...
 346 dnl --enable-regen-headers?
 347
 348 # Only use libltdl for non-newlib builds.
 349 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 350    AC_LIBLTDL_CONVENIENCE
 351    AC_LIBTOOL_DLOPEN
 352    DIRLTDL=libltdl
 353    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 354    # Sigh.  Libtool's macro doesn't do the right thing.
 355    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 356    # FIXME: this is a hack.
 357    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 358    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 359 fi
 360 AC_SUBST(INCLTDL)
 361 AC_SUBST(LIBLTDL)
 362 AC_SUBST(DIRLTDL)
 363 AC_PROG_LIBTOOL
 364 AM_PROG_GCJ
 365 AM_PROG_CC_C_O
 366
 367 AC_CONFIG_SUBDIRS(classpath libltdl)
 368
 369 # The -no-testsuite modules omit the test subdir.
 370 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 371
 372 # Should the runtime set system properties by examining the
 373 # environment variable GCJ_PROPERTIES?
 374 AC_ARG_ENABLE(getenv-properties,
 375   AS_HELP_STRING([--disable-getenv-properties],
 376                  [don't set system properties from GCJ_PROPERTIES]))
 377
 378 # Whether GCJ_PROPERTIES is used depends on the target.
 379 if test -z "$enable_getenv_properties"; then
 380    enable_getenv_properties=${enable_getenv_properties_default-yes}
 381 fi
 382 if test "$enable_getenv_properties" = no; then
 383    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 384      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 385 fi
 386
 387 # Whether we should use arguments to main()
 388 if test -z "$enable_main_args"; then
 389    enable_main_args=${enable_main_args_default-yes}
 390 fi
 391 if test "$enable_main_args" = no; then
 392    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 393 fi
 394
 395
 396 # Should we use hashtable-based synchronization?
 397 # Currently works only for Linux X86/ia64
 398 # Typically faster and more space-efficient
 399 AC_ARG_ENABLE(hash-synchronization,
 400   AS_HELP_STRING([--enable-hash-synchronization],
 401                  [use global hash table for monitor locks]))
 402
 403 if test -z "$enable_hash_synchronization"; then
 404    enable_hash_synchronization=$enable_hash_synchronization_default
 405 fi
 406
 407 AC_ARG_WITH(java-home,
 408   AS_HELP_STRING([--with-java-home=DIRECTORY],
 409                  [value of java.home system property]),
 410                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 411 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 412 AC_SUBST(JAVA_HOME)
 413
 414 # What is the native OS API for MinGW?
 415 AC_ARG_WITH(win32-nlsapi,
 416   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 417                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 418 [case "${withval}" in
 419   ansi) with_win32_nlsapi=ansi ;;
 420   unicows) with_win32_nlsapi=unicows ;;
 421   unicode) with_win32_nlsapi=unicode ;;
 422   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 423 esac],[with_win32_nlsapi=ansi])
 424
 425 case "${with_win32_nlsapi}" in
 426   unicows | unicode)
 427     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 428       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 429     ;;
 430 esac
 431
 432 # configure.host sets slow_pthread_self if the synchronization code should
 433 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 434 if test "${slow_pthread_self}" = "yes"; then
 435   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 436     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 437 fi
 438
 439 # Check for gc debugging.  This option is handled both here and in the GC.
 440 AC_ARG_ENABLE(gc-debug,
 441    AS_HELP_STRING([--enable-gc-debug],
 442                   [include full support for pointer backtracing etc.]),
 443 [ if test "$enable_gc_debug" = "yes"; then
 444     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 445               [Define if we want to use debug calls into the garbage collector.])
 446   fi])
 447
 448 # See if the user has the interpreter included.
 449 AC_ARG_ENABLE(interpreter,
 450   AS_HELP_STRING([--enable-interpreter],
 451                  [enable interpreter]),
 452   [if test "$enable_interpreter" = yes; then
 453     # This can also be set in configure.host.
 454     libgcj_interpreter=yes
 455   elif test "$enable_interpreter" = no; then
 456     libgcj_interpreter=no
 457   fi])
 458
 459 if test "$libgcj_interpreter" = yes; then
 460    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 461 fi
 462 INTERPRETER="$libgcj_interpreter"
 463 AC_SUBST(INTERPRETER)
 464
 465 AC_MSG_CHECKING([for exception model to use])
 466 AC_LANG_PUSH(C++)
 467 AC_ARG_ENABLE(sjlj-exceptions,
 468   AS_HELP_STRING([--enable-sjlj-exceptions],
 469                  [force use of builtin_setjmp for exceptions]),
 470 [:],
 471 [dnl Botheration.  Now we've got to detect the exception model.
 472 dnl Link tests against libgcc.a are problematic since -- at least
 473 dnl as of this writing -- we've not been given proper -L bits for
 474 dnl single-tree newlib and libgloss.
 475 dnl
 476 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 477 dnl conftest files before we got a change to grep them first.
 478 cat > conftest.$ac_ext << EOF
 479 [#]line __oline__ "configure"
 480 struct S { ~S(); };
 481 void bar();
 482 void foo()
 483 {
 484   S s;
 485   bar();
 486 }
 487 EOF
 488 old_CXXFLAGS="$CXXFLAGS"
 489 CXXFLAGS=-S
 490 if AC_TRY_EVAL(ac_compile); then
 491   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 492     enable_sjlj_exceptions=yes
 493   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 494     enable_sjlj_exceptions=no
 495   fi
 496 fi
 497 CXXFLAGS="$old_CXXFLAGS"
 498 rm -f conftest*])
 499 if test x$enable_sjlj_exceptions = xyes; then
 500   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 501         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 502   ac_exception_model_name=sjlj
 503 elif test x$enable_sjlj_exceptions = xno; then
 504   ac_exception_model_name="call frame"
 505 else
 506   AC_MSG_ERROR([unable to detect exception model])
 507 fi
 508 AC_LANG_POP(C++)
 509 AC_MSG_RESULT($ac_exception_model_name)
 510
 511 # If we are non using SJLJ exceptions, and this host does not have support
 512 # for unwinding from a signal handler, enable checked dereferences and divides.
 513 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 514   CHECKREFSPEC=-fcheck-references
 515   DIVIDESPEC=-fuse-divide-subroutine
 516   EXCEPTIONSPEC=
 517 fi
 518
 519 # See if the user wants to disable java.net.  This is the mildly
 520 # ugly way that we admit that target-side configuration sucks.
 521 AC_ARG_ENABLE(java-net,
 522   AS_HELP_STRING([--disable-java-net],
 523                  [disable java.net]))
 524
 525 # Whether java.net is built by default can depend on the target.
 526 if test -z "$enable_java_net"; then
 527    enable_java_net=${enable_java_net_default-yes}
 528 fi
 529 if test "$enable_java_net" = no; then
 530    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 531 fi
 532
 533 # See if the user wants to configure without libffi.  Some
 534 # architectures don't support it, and default values are set in
 535 # configure.host.
 536 AC_ARG_WITH(libffi,
 537   AS_HELP_STRING([--without-libffi],
 538                  [don't use libffi]),
 539   [:],
 540   [with_libffi=${with_libffi_default-yes}])
 541
 542 LIBFFI=
 543 LIBFFIINCS=
 544 if test "$with_libffi" != no; then
 545    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 546    LIBFFI=../libffi/libffi_convenience.la
 547    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 548 fi
 549 AC_SUBST(LIBFFI)
 550 AC_SUBST(LIBFFIINCS)
 551
 552 # See if the user wants to disable JVMPI support.
 553 AC_ARG_ENABLE(jvmpi,
 554   AS_HELP_STRING([--disable-jvmpi],
 555                  [disable JVMPI support]))
 556
 557 if test "$enable_jvmpi" != no; then
 558     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 559 fi
 560
 561 # If the target is an eCos system, use the appropriate eCos
 562 # I/O routines.
 563 # FIXME: this should not be a local option but a global target
 564 # system; at present there is no eCos target.
 565 TARGET_ECOS=${PROCESS-"no"}
 566 AC_ARG_WITH(ecos,
 567 [  --with-ecos             enable runtime eCos target support],
 568 TARGET_ECOS="$with_ecos"
 569 )
 570
 571 PLATFORM_INNER_NAT_HDRS=
 572 case "$TARGET_ECOS" in
 573    no) case "$host" in
 574       *mingw*)
 575             PLATFORM=Win32
 576             PLATFORMNET=Win32
 577             PLATFORMH=win32.h
 578         CHECK_FOR_BROKEN_MINGW_LD
 579       ;;
 580       *)
 581             PLATFORM=Posix
 582             PLATFORMNET=Posix
 583             PLATFORMH=posix.h
 584             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 585       ;;
 586       esac
 587       ;;
 588    *)
 589       PLATFORM=Ecos
 590       PLATFORMNET=NoNet
 591       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 592       PLATFORMH=posix.h
 593       ;;
 594 esac
 595 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 596 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 597
 598 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 599                                       [Define if you have int32_t and uint32_t.]))
 600 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 601                                         [Define if you have int32_t and uint32_t.]))
 602 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 603                                           [Define if you have u_int32_t]))
 604 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 605                                            [Define if you have u_int32_t]))
 606
 607 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 608 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 609
 610 case "$host" in
 611   *-darwin*) DARWIN_CRT=true ;;
 612   *) DARWIN_CRT=false ;;
 613 esac
 614 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 615
 616 # These may not be defined in a non-ANS conformant embedded system.
 617 # FIXME: Should these case a runtime exception in that case?
 618 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 619                                   [Define is you have 'mktime' in <time.h>]))
 620 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 621                                   [Define is you have 'localtime' in <time.h>]))
 622
 623 # Create the subdirectory for natFile.cc, or the attempt
 624 # to create the link will fail.
 625 test -d java || mkdir java
 626 test -d java/io || mkdir java/io
 627 test -d gnu || mkdir gnu
 628 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 629
 630 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 631 test -d java/lang || mkdir java/lang
 632 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 633 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 634
 635 # Likewise for natInetAddress.cc and natVMNetworkInterface.cc.
 636 test -d java/net || mkdir java/net
 637 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 638 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 639
 640 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 641 test -d gnu/java || mkdir gnu/java
 642 test -d gnu/java/net || mkdir gnu/java/net
 643 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 644 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 645
 646 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 647 test -d gnu/java/nio || mkdir gnu/java/nio
 648 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 649 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 650 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 651 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 652
 653 case "${host}" in
 654     *mingw*)
 655       SYSTEMSPEC="-lgdi32 -lws2_32"
 656       if test "${with_win32_nlsapi}" = "unicows"; then
 657         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 658       fi
 659     ;;
 660     *)
 661       SYSTEMSPEC=
 662     ;;
 663 esac
 664 AC_SUBST(SYSTEMSPEC)
 665
 666 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 667 AC_SUBST(LIBGCJTESTSPEC)
 668
 669 AC_ARG_WITH(system-zlib,
 670   AS_HELP_STRING([--with-system-zlib],
 671                  [use installed libz]))
 672 ZLIBSPEC=
 673 AC_SUBST(ZLIBSPEC)
 674 ZLIBTESTSPEC=
 675 AC_SUBST(ZLIBTESTSPEC)
 676
 677 AC_PATH_XTRA
 678
 679 # determine whether to enable the cairo GTK Graphics2D backend
 680 AC_ARG_ENABLE(gtk-cairo,
 681   AS_HELP_STRING([--enable-gtk-cairo],
 682                  [build the cairo Graphics2D implementation on GTK]))
 683 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 684 if test "x${enable_gtk_cairo}" = xyes
 685 then
 686         PKG_CHECK_MODULES(CAIRO, cairo)
 687         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 688 fi
 689 AC_SUBST(CAIRO_LIBS)
 690 AC_SUBST(CAIRO_CFLAGS)
 691 AC_SUBST(PANGOFT2_LIBS)
 692 AC_SUBST(PANGOFT2_CFLAGS)
 693
 694 # FIXME: this should be _libs on some hosts.
 695 libsubdir=.libs
 696
 697 # extra LD Flags which are required for targets
 698 case "${host}" in
 699 *-*-darwin[[0-7]].*)
 700     # For now we have to disable it on darwin[8-9] because it slows down
 701     # the linking phase. A possible bug in ld?
 702     # on Darwin -single_module speeds up loading of the dynamic libraries.
 703     extra_ldflags_libjava=-Wl,-single_module
 704     ;;
 705 esac
 706 AC_SUBST(extra_ldflags_libjava)
 707
 708 # Allow the GC to be disabled.  Can be useful when debugging.
 709 AC_MSG_CHECKING([for garbage collector to use])
 710 AC_ARG_ENABLE(java-gc,
 711   AS_HELP_STRING([--enable-java-gc=TYPE],
 712                  [choose garbage collector (default is boehm)]),
 713   [GC=$enableval],
 714   [GC=boehm])
 715 GCLIBS=
 716 GCINCS=
 717 GCDEPS=
 718 GCSPEC=
 719 JC1GCSPEC=
 720 GCTESTSPEC=
 721 case "$GC" in
 722  boehm)
 723     AC_MSG_RESULT(boehm)
 724     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 725     JC1GCSPEC='-fuse-boehm-gc'
 726     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 727     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 728     GCOBJS=boehm.lo
 729     GCHDR=boehm-gc.h
 730     # The POSIX thread support needs to know this.
 731     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 732     ;;
 733  no)
 734     AC_MSG_RESULT(none)
 735     GCHDR=no-gc.h
 736     ;;
 737  *)
 738     AC_MSG_ERROR([unrecognized collector "$GC"])
 739     ;;
 740 esac
 741 AC_SUBST(GCLIBS)
 742 AC_SUBST(GCINCS)
 743 AC_SUBST(GCDEPS)
 744 AC_SUBST(GCSPEC)
 745 AC_SUBST(JC1GCSPEC)
 746 AC_SUBST(GCTESTSPEC)
 747 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 748 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 749 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 750
 751
 752 AC_MSG_CHECKING([for thread model used by GCC])
 753 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 754 AC_MSG_RESULT([$THREADS])
 755
 756 case "$THREADS" in
 757  no | none | single)
 758     THREADS=none
 759     ;;
 760  posix | posix95 | pthreads)
 761     THREADS=posix
 762     case "$host" in
 763      *-*-linux*)
 764         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 765         ;;
 766     esac
 767     ;;
 768  win32)
 769     ;;
 770  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 771     AC_MSG_ERROR(thread package $THREADS not yet supported)
 772     ;;
 773  *)
 774     AC_MSG_ERROR($THREADS is an unknown thread package)
 775     ;;
 776 esac
 777
 778 THREADCXXFLAGS=
 779 THREADLDFLAGS=
 780 THREADLIBS=
 781 THREADINCS=
 782 THREADDEPS=
 783 THREADH=
 784 THREADSPEC=
 785 case "$THREADS" in
 786  posix)
 787     case "$host" in
 788      *-*-cygwin*)
 789         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 790         ;;
 791      *-*-freebsd[[1234]]*)
 792         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 793         # merely adds pthread_* functions) but it does have a -pthread switch
 794         # which is required at link-time to select -lc_r *instead* of -lc.
 795         THREADLDFLAGS=-pthread
 796         # Don't set THREADSPEC here as might be expected since -pthread is
 797         # not processed when found within a spec file, it must come from
 798         # the command line.  For now, the user must provide the -pthread
 799         # switch to link code compiled with gcj.  In future, consider adding
 800         # support for weak references to pthread_* functions ala gthr.h API.
 801         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 802         ;;
 803      *-*-freebsd*)
 804         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 805         # systems which support threads and -lpthread.
 806         THREADLDFLAGS=-pthread
 807         THREADSPEC=-lpthread
 808         ;;
 809      alpha*-dec-osf* | hppa*-hp-hpux*)
 810         THREADCXXFLAGS=-pthread
 811         # boehm-gc needs some functions from librt, so link that too.
 812         THREADLIBS='-lpthread -lrt'
 813         THREADSPEC='-lpthread -lrt'
 814         ;;
 815      *)
 816         THREADLIBS=-lpthread
 817         THREADSPEC=-lpthread
 818         ;;
 819     esac
 820     THREADH=posix-threads.h
 821     # MIT pthreads doesn't seem to have the mutexattr functions.
 822     # But for now we don't check for it.  We just assume you aren't
 823     # using MIT pthreads.
 824     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 825
 826     # If we're using the Boehm GC, then we happen to know that it
 827     # defines _REENTRANT, so we don't bother.  Eww.
 828     if test "$GC" != boehm; then
 829        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 830     fi
 831     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 832     ;;
 833
 834  win32)
 835     THREADH=win32-threads.h
 836     ;;
 837
 838  none)
 839     THREADH=no-threads.h
 840     ;;
 841 esac
 842 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 843 AC_SUBST(THREADLIBS)
 844 AC_SUBST(THREADINCS)
 845 AC_SUBST(THREADDEPS)
 846 AC_SUBST(THREADSPEC)
 847 AC_SUBST(THREADLDFLAGS)
 848 AC_SUBST(THREADCXXFLAGS)
 849 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 850 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 851 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 852
 853 if test -d sysdep; then true; else mkdir sysdep; fi
 854 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 855 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 856 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 857
 858 HASH_SYNC_SPEC=
 859 # Hash synchronization is only useful with posix threads right now.
 860 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 861    HASH_SYNC_SPEC=-fhash-synchronization
 862    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 863 fi
 864 AC_SUBST(HASH_SYNC_SPEC)
 865
 866 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 867
 868 # We're in the tree with gcc, and need to include some of its headers.
 869 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 870
 871 if test "x${with_newlib}" = "xyes"; then
 872    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 873    # may not work correctly, because the compiler may not be able to
 874    # link executables.
 875
 876    # We assume newlib.  This lets us hard-code the functions we know
 877    # we'll have.
 878    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 879    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 880    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 881    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 882    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 883    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 884    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 885    # This is only for POSIX threads.
 886    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 887    # We also assume we are using gcc, which provides alloca.
 888    AC_DEFINE(HAVE_ALLOCA)
 889
 890    # Assume we do not have getuid and friends.
 891    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 892    PLATFORMNET=NoNet
 893 else
 894    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 895                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 896                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
 897                    nl_langinfo setlocale \
 898                    inet_pton uname inet_ntoa \
 899                    fork execvp pipe sigaction ftruncate mmap])
 900    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 901    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 902    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
 903    AC_CHECK_LIB(dl, dladdr, [
 904        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
 905        AC_CHECK_LIB(dld, dladdr, [
 906        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
 907
 908    if test x"$build" = x"$host"; then
 909      AC_CHECK_FILES(/proc/self/exe, [
 910        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 911    else
 912      case $host in
 913      *-linux*)
 914        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 915        ;;
 916      esac
 917    fi
 918
 919    AM_ICONV
 920    AM_LC_MESSAGES
 921    AC_STRUCT_TIMEZONE
 922
 923    AC_CHECK_FUNCS(gethostbyname_r, [
 924      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 925        [Define if you have the 'gethostbyname_r' function.])
 926      # There are two different kinds of gethostbyname_r.
 927      # We look for the one that returns `int'.
 928      # Hopefully this check is robust enough.
 929      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 930        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 931
 932      case " $GCINCS " in
 933      *" -D_REENTRANT "*) ;;
 934      *)
 935         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 936         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 937         [libjava_cv_gethostbyname_r_needs_reentrant],
 938         [ AC_LANG_PUSH(C++)
 939           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 940             [[gethostbyname_r("", 0, 0);]])],
 941             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 942                 CPPFLAGS_SAVE="$CPPFLAGS"
 943                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 944                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 945                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 946                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 947                 CPPFLAGS="$CPPFLAGS_SAVE"
 948           ])
 949           AC_LANG_POP(C++)
 950         ])
 951         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 952           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 953         fi
 954      ;;
 955      esac
 956
 957      AC_CACHE_CHECK([for struct hostent_data],
 958         [libjava_cv_struct_hostent_data], [dnl
 959         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 960 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 961 # define _REENTRANT 1
 962 #endif
 963 #include <netdb.h>]], [[struct hostent_data data;]])],
 964           [libjava_cv_struct_hostent_data=yes],
 965           [libjava_cv_struct_hostent_data=no])])
 966      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 967        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 968          [Define if struct hostent_data is defined in netdb.h])
 969      fi
 970    ])
 971
 972    # FIXME: libjava source code expects to find a prototype for
 973    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 974    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 975    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 976    # linkage check is enough, yet C++ code requires proper prototypes.)
 977    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 978    AC_CHECK_FUNCS(gethostbyaddr_r, [
 979      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 980        [Define if you have the 'gethostbyaddr_r' function.])
 981      # There are two different kinds of gethostbyaddr_r.
 982      # We look for the one that returns `int'.
 983      # Hopefully this check is robust enough.
 984      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 985        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 986          [Define if gethostbyaddr_r returns 'int'.])])])])
 987
 988    AC_CHECK_FUNCS(gethostname, [
 989      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 990        [Define if you have the 'gethostname' function.])
 991      AC_EGREP_HEADER(gethostname, unistd.h, [
 992        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 993          [Define if gethostname is declared in <unistd.h>.])])])
 994
 995    AC_CHECK_FUNCS(usleep, [
 996      AC_EGREP_HEADER(usleep, unistd.h, [
 997        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 998           [Define if usleep is declared in <unistd.h>.])])])
 999
1000    # Look for these functions in the thread library, but only bother
1001    # if using POSIX threads.
1002    if test "$THREADS" = posix; then
1003       save_LIBS="$LIBS"
1004       LIBS="$LIBS $THREADLIBS"
1005       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1006       # E.g., Solaris.
1007       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1008
1009       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1010       # Solaris 7 the name librt is preferred.
1011       AC_CHECK_FUNCS(sched_yield, , [
1012         AC_CHECK_LIB(rt, sched_yield, [
1013           AC_DEFINE(HAVE_SCHED_YIELD)
1014           THREADLIBS="$THREADLIBS -lrt"
1015           THREADSPEC="$THREADSPEC -lrt"], [
1016           AC_CHECK_LIB(posix4, sched_yield, [
1017             AC_DEFINE(HAVE_SCHED_YIELD)
1018             THREADLIBS="$THREADLIBS -lposix4"
1019             THREADSPEC="$THREADSPEC -lposix4"])])])
1020
1021       AC_CHECK_LIB(rt, clock_gettime, [
1022          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1023          case "$THREADSPEC" in
1024            *-lrt*) ;;
1025            *)
1026              THREADSPEC="$THREADSPEC -lrt"
1027              THREADLIBS="$THREADLIBS -lrt"
1028              ;;
1029          esac])
1030
1031       LIBS="$save_LIBS"
1032
1033       # We can save a little space at runtime if the mutex has m_count
1034       # or __m_count.  This is a nice hack for Linux.
1035       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1036           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1037         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1038              [Define if pthread_mutex_t has m_count member.]), [
1039         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1040             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1041           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1042             [Define if pthread_mutex_t has __m_count member.]))])
1043    fi
1044
1045    # We require a way to get the time.
1046    time_found=no
1047    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1048    if test "$time_found" = no; then
1049       AC_MSG_ERROR([no function found to get the time])
1050    fi
1051
1052    AC_CHECK_FUNCS(memmove)
1053
1054    # We require memcpy.
1055    memcpy_found=no
1056    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1057    if test "$memcpy_found" = no; then
1058       AC_MSG_ERROR([memcpy is required])
1059    fi
1060    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1061    AC_CHECK_LIB(dl, dlopen, [
1062        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1063        AC_CHECK_LIB(dld, dlopen, [
1064        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1065
1066    # Some library-finding code we stole from Tcl.
1067    #--------------------------------------------------------------------
1068    #    Check for the existence of the -lsocket and -lnsl libraries.
1069    #    The order here is important, so that they end up in the right
1070    #    order in the command line generated by make.  Here are some
1071    #    special considerations:
1072    #    1. Use "connect" and "accept" to check for -lsocket, and
1073    #       "gethostbyname" to check for -lnsl.
1074    #    2. Use each function name only once:  can't redo a check because
1075    #       autoconf caches the results of the last check and won't redo it.
1076    #    3. Use -lnsl and -lsocket only if they supply procedures that
1077    #       aren't already present in the normal libraries.  This is because
1078    #       IRIX 5.2 has libraries, but they aren't needed and they're
1079    #       bogus:  they goof up name resolution if used.
1080    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1081    #       To get around this problem, check for both libraries together
1082    #       if -lsocket doesn't work by itself.
1083    #--------------------------------------------------------------------
1084
1085    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1086     [gcj_cv_lib_sockets=
1087      gcj_checkBoth=0
1088      unset ac_cv_func_connect
1089      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1090      if test "$gcj_checkSocket" = 1; then
1091          unset ac_cv_func_connect
1092          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1093                       gcj_checkBoth=1)
1094      fi
1095      if test "$gcj_checkBoth" = 1; then
1096          gcj_oldLibs=$LIBS
1097          LIBS="$LIBS -lsocket -lnsl"
1098          unset ac_cv_func_accept
1099          AC_CHECK_FUNC(accept,
1100                        [gcj_checkNsl=0
1101                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1102          unset ac_cv_func_accept
1103          LIBS=$gcj_oldLibs
1104      fi
1105      unset ac_cv_func_gethostbyname
1106      gcj_oldLibs=$LIBS
1107      LIBS="$LIBS $gcj_cv_lib_sockets"
1108      AC_CHECK_FUNC(gethostbyname, ,
1109                    [AC_CHECK_LIB(nsl, main,
1110                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1111      unset ac_cv_func_gethostbyname
1112      LIBS=$gcj_oldLIBS
1113    ])
1114    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1115
1116    if test "$with_system_zlib" = yes; then
1117       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1118    fi
1119
1120    # Test for Gtk stuff, if asked for.
1121    if test "$use_gtk_awt" = yes; then
1122       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1123       AC_SUBST(GTK_CFLAGS)
1124       AC_SUBST(GTK_LIBS)
1125
1126       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1127       AC_SUBST(GLIB_CFLAGS)
1128       AC_SUBST(GLIB_LIBS)
1129
1130       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1131       AC_SUBST(LIBART_CFLAGS)
1132       AC_SUBST(LIBART_LIBS)
1133
1134       # We require the XTest Extension to support java.awt.Robot.
1135       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1136                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1137                    [${X_LIBS}])
1138    fi
1139
1140    # On Solaris, and maybe other architectures, the Boehm collector
1141    # requires -ldl.
1142    if test "$GC" = boehm; then
1143       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1144    fi
1145 fi
1146
1147 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1148 case $build in
1149     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1150     *)         CLASSPATH_SEPARATOR=':' ;;
1151 esac
1152 AC_SUBST(CLASSPATH_SEPARATOR)
1153
1154 # We must search the source tree for java.lang, since we still don't
1155 # have libgcj.jar nor java/lang/*.class
1156 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1157 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1158
1159 # Since some classes depend on this one, we need its source available
1160 # before we can do any GCJ compilation test :-(
1161 if test ! -f gnu/classpath/Configuration.java; then
1162   test -d gnu || mkdir gnu
1163   test -d gnu/classpath || mkdir gnu/classpath
1164   # Note that it is not crucial that all the values here be correct.
1165   sed -e "s,@prefix@,$prefix," \
1166       -e "s,@VERSION@,$VERSION," \
1167       -e "s,@LIBDEBUG@,false," \
1168       -e "s,@INIT_LOAD_LIBRARY@,false," \
1169       -e "s,@@,$LIBGCJDEBUG," \
1170       -e "s,@default_toolkit@,$TOOLKIT," \
1171       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1172       -e "s,@GTK_CAIRO_ENABLED@,false," \
1173         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1174         > gnu/classpath/Configuration.java
1175   # We do not want to redirect the output of the grep below to /dev/null,
1176   # but we add /dev/null to the input list so that grep will print the
1177   # filename of Configuration.java in case it finds any matches.
1178   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1179     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1180   fi
1181 fi
1182
1183 LT_AC_PROG_GCJ
1184
1185 # Now remove it.
1186 rm -f gnu/classpath/Configuration.java
1187
1188 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1189
1190 AC_CHECK_SIZEOF(void *)
1191
1192 AC_C_BIGENDIAN
1193
1194 ZLIBS=
1195 SYS_ZLIBS=
1196 ZINCS=
1197
1198 if test -z "$ZLIBSPEC"; then
1199    # Use zlib from the GCC tree.
1200    ZINCS='-I$(top_srcdir)/../zlib'
1201    ZLIBS=../zlib/libzgcj_convenience.la
1202 else
1203    # System's zlib.
1204    SYS_ZLIBS="$ZLIBSPEC"
1205 fi
1206 AC_SUBST(ZLIBS)
1207 AC_SUBST(SYS_ZLIBS)
1208 AC_SUBST(ZINCS)
1209 AC_SUBST(DIVIDESPEC)
1210 AC_SUBST(CHECKREFSPEC)
1211 AC_SUBST(EXCEPTIONSPEC)
1212 AC_SUBST(BACKTRACESPEC)
1213 AC_SUBST(IEEESPEC)
1214
1215 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1216 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1217 AC_SUBST(GCC_UNWIND_INCLUDE)
1218
1219 # Process the option "--enable-version-specific-runtime-libs"
1220 # Calculate toolexeclibdir
1221 case ${version_specific_libs} in
1222   yes)
1223     # Need the gcc compiler version to know where to install libraries
1224     # and header files if --enable-version-specific-runtime-libs option
1225     # is selected.
1226     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1227     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1228     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1229     toolexeclibdir=$toolexecmainlibdir
1230     ;;
1231   no)
1232     if test -n "$with_cross_host" &&
1233        test x"$with_cross_host" != x"no"; then
1234       # Install a library built with a cross compiler in tooldir, not libdir.
1235       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1236       toolexecmainlibdir='$(toolexecdir)/lib'
1237     else
1238       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1239       toolexecmainlibdir='$(libdir)'
1240     fi
1241     multi_os_directory=`$CC -print-multi-os-directory`
1242     case $multi_os_directory in
1243       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1244       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1245     esac
1246     ;;
1247 esac
1248 AC_SUBST(toolexecdir)
1249 AC_SUBST(toolexecmainlibdir)
1250 AC_SUBST(toolexeclibdir)
1251
1252 # Determine where the standard .db file is found.
1253 multi_os_directory=`$CC -print-multi-os-directory`
1254 case $multi_os_directory in
1255   .) dbexecdir='$(libdir)/gcj-$(gcc_version)' ;; # Avoid /.
1256   *) dbexecdir='$(libdir)/'$multi_os_directory'/gcj-$(gcc_version)' ;;
1257 esac
1258 AC_SUBST(dbexecdir)
1259
1260 # Determine gcj version number.
1261 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1262 GCJVERSION=$gcjversion
1263 AC_SUBST(GCJVERSION)
1264 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1265
1266 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1267 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1268
1269 TL_AC_GXX_INCLUDE_DIR
1270
1271 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1272 # On that system, sys/ioctl.h will not include sys/filio.h unless
1273 # BSD_COMP is defined; just including sys/filio.h is simpler.
1274 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1275 # for now.  If you change this, you also must update natFile.cc.
1276 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1277                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1278                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1279                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1280                   dirent.h sys/rw_lock.h])
1281 AC_CHECK_HEADERS(inttypes.h, [
1282     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1283     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1284 ])
1285 AC_HEADER_SYS_WAIT
1286
1287 AC_CHECK_TYPE([ssize_t], [int])
1288
1289 AC_MSG_CHECKING([for in_addr_t])
1290 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1291 #if STDC_HEADERS
1292 #include <stdlib.h>
1293 #include <stddef.h>
1294 #endif
1295 #if HAVE_NETINET_IN_H
1296 #include <netinet/in.h>
1297 #endif]], [[in_addr_t foo;]])],
1298   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1299      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1300    AC_MSG_RESULT(yes)],
1301   [AC_MSG_RESULT(no)])
1302
1303 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1304 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1305   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1306      [Define if struct ip_mreq is defined in netinet/in.h.])
1307    AC_MSG_RESULT(yes)],
1308   [AC_MSG_RESULT(no)])
1309
1310 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1311 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1312   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1313      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1314    AC_MSG_RESULT(yes)],
1315   [AC_MSG_RESULT(no)])
1316
1317 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1318 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1319   [AC_DEFINE(HAVE_INET6, 1,
1320      [Define if inet6 structures are defined in netinet/in.h.])
1321    AC_MSG_RESULT(yes)],
1322   [AC_MSG_RESULT(no)])
1323
1324 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1325 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1326 #include <sys/types.h>
1327 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1328   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1329    AC_MSG_RESULT(yes)],
1330   [AC_MSG_RESULT(no)])
1331
1332 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1333 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1334   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1335    AC_MSG_RESULT(yes)],
1336   [AC_MSG_RESULT(no)
1337    AC_MSG_CHECKING([for global timezone variable])
1338    dnl FIXME: we don't want a link check here because that won't work
1339    dnl when cross-compiling.  So instead we make an assumption that
1340    dnl the header file will mention timezone if it exists.
1341    dnl Don't find the win32 function timezone
1342    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1343      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1344       AC_MSG_RESULT(yes)],
1345      [AC_MSG_RESULT(no)
1346        AC_MSG_CHECKING([for global _timezone variable])
1347        dnl FIXME: As above, don't want link check
1348        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1349          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1350             [Define if your platform has the global _timezone variable.])
1351           AC_MSG_RESULT(yes)],
1352           [AC_MSG_RESULT(no)])])])
1353
1354 AC_FUNC_ALLOCA
1355
1356 AC_CHECK_PROGS(PERL, perl, false)
1357
1358 SYSDEP_SOURCES=
1359 SIGNAL_HANDLER_AUX=
1360
1361 case "${host}" in
1362  i?86-*-linux*)
1363     SIGNAL_HANDLER=include/i386-signal.h
1364     ;;
1365  sparc*-sun-solaris*)
1366     SIGNAL_HANDLER=include/sparc-signal.h
1367     ;;
1368 # ia64-*)
1369 #    SYSDEP_SOURCES=sysdep/ia64.c
1370 #    test -d sysdep || mkdir sysdep
1371 #    ;;
1372  hppa*-*-linux*)
1373     SIGNAL_HANDLER=include/pa-signal.h
1374     ;;
1375  hppa*-hp-hpux*)
1376     SIGNAL_HANDLER=include/hppa-signal.h
1377     ;;
1378  ia64-*-linux*)
1379     SIGNAL_HANDLER=include/dwarf2-signal.h
1380     ;;
1381  powerpc*-*-linux*)
1382     SIGNAL_HANDLER=include/powerpc-signal.h
1383     ;;
1384  alpha*-*-linux*)
1385     SIGNAL_HANDLER=include/dwarf2-signal.h
1386     ;;
1387  s390*-*-linux*)
1388     SIGNAL_HANDLER=include/s390-signal.h
1389     ;;
1390  x86_64*-*-linux*)
1391     SIGNAL_HANDLER=include/x86_64-signal.h
1392     SIGNAL_HANDLER_AUX=include/i386-signal.h
1393     ;;
1394  sparc*-*-linux*)
1395     SIGNAL_HANDLER=include/dwarf2-signal.h
1396     ;;
1397  sh*-*-linux*)
1398     SIGNAL_HANDLER=include/sh-signal.h
1399     ;;
1400  *mingw*)
1401     SIGNAL_HANDLER=include/win32-signal.h
1402     ;;
1403  mips*-*-linux*)
1404     SIGNAL_HANDLER=include/mips-signal.h
1405     ;;
1406  *-*-darwin*)
1407     SIGNAL_HANDLER=include/darwin-signal.h
1408     ;;
1409  *)
1410     SIGNAL_HANDLER=include/default-signal.h
1411     ;;
1412 esac
1413
1414 # If we're using sjlj exceptions, forget what we just learned.
1415 if test "$enable_sjlj_exceptions" = yes; then
1416    SIGNAL_HANDLER=include/default-signal.h
1417    SIGNAL_HANDLER_AUX=
1418 fi
1419
1420 AC_SUBST(SYSDEP_SOURCES)
1421
1422 if test -z "$SIGNAL_HANDLER_AUX"; then
1423   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1424 fi
1425
1426 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1427                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1428
1429 if test "${multilib}" = "yes"; then
1430   multilib_arg="--enable-multilib"
1431 else
1432   multilib_arg=
1433 fi
1434
1435 # See if we support thread-local storage.
1436 GCC_CHECK_TLS
1437
1438 # Check if linker supports static linking on a per library basis
1439 LD_START_STATIC_SPEC=
1440 LD_FINISH_STATIC_SPEC=
1441 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1442   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1443     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1444     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1445   fi
1446 fi
1447 AC_SUBST(LD_START_STATIC_SPEC)
1448 AC_SUBST(LD_FINISH_STATIC_SPEC)
1449
1450 here=`${PWDCMD-pwd}`
1451 AC_SUBST(here)
1452
1453 # We get this from the environment.
1454 AC_SUBST(GCJFLAGS)
1455
1456 AC_CONFIG_FILES([
1457 Makefile
1458 libgcj.pc
1459 libgcj.spec
1460 libgcj-test.spec
1461 gcj/Makefile
1462 include/Makefile
1463 testsuite/Makefile
1464 ])
1465
1466 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1467
1468 AC_CONFIG_COMMANDS([default],
1469 [# Only add multilib support code if we just rebuilt top-level Makefile.
1470 case " $CONFIG_FILES " in
1471  *" Makefile "*)
1472    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1473    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1474    ;;
1475 esac
1476 for ac_multi_file in $CONFIG_FILES; do
1477   case $ac_multi_file in
1478   */Makefile)
1479     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1480   esac
1481 done
1482 ],
1483 srcdir=${srcdir}
1484 host=${host}
1485 target=${target}
1486 with_multisubdir=${with_multisubdir}
1487 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1488 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1489 libgcj_basedir=${libgcj_basedir}
1490 CC="${CC}"
1491 CXX="${CXX}"
1492 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1493 )
1494
1495 AC_OUTPUT