gcc/gen-pass-instances.awk

   1 #  Copyright (C) 2013-2016 Free Software Foundation, Inc.
   2 #
   3 # This program is free software; you can redistribute it and/or modify it
   4 # under the terms of the GNU General Public License as published by the
   5 # Free Software Foundation; either version 3, or (at your option) any
   6 # later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; see the file COPYING3.  If not see
  15 # <http://www.gnu.org/licenses/>.
  16
  17 # This Awk script takes passes.def and writes pass-instances.def,
  18 # counting the instances of each kind of pass, adding an instance number
  19 # to everywhere that NEXT_PASS is used.
  20 # Also handle INSERT_PASS_AFTER, INSERT_PASS_BEFORE and REPLACE_PASS
  21 # directives.
  22 #
  23 # For example, the single-instanced pass:
  24 #     NEXT_PASS (pass_warn_unused_result);
  25 # becomes this in the output:
  26 #     NEXT_PASS (pass_warn_unused_result, 1);
  27 #
  28 # The various instances of
  29 #   NEXT_PASS (pass_copy_prop);
  30 # become:
  31 #   NEXT_PASS (pass_copy_prop, 1);
  32 # through:
  33 #   NEXT_PASS (pass_copy_prop, 8);
  34 # (currently there are 8 instances of that pass)
  35 #
  36 #     INSERT_PASS_AFTER (pass_copy_prop, 1, pass_stv);
  37 # will insert
  38 #     NEXT_PASS (pass_stv, 1);
  39 # immediately after the NEXT_PASS (pass_copy_prop, 1) line,
  40 # similarly INSERT_PASS_BEFORE inserts immediately before that line.
  41 #     REPLACE_PASS (pass_copy_prop, 1, pass_stv, true);
  42 # will replace NEXT_PASS (pass_copy_prop, 1) line with
  43 #     NEXT_PASS (pass_stv, 1, true);
  44 # line and renumber all higher pass_copy_prop instances if any.
  45
  46 # Usage: awk -f gen-pass-instances.awk passes.def
  47
  48 BEGIN {
  49   print "/* This file is auto-generated by gen-pass-instances.awk";
  50   print "   from passes.def.  */";
  51   lineno = 1;
  52 }
  53
  54 function parse_line(line, fnname,       len_of_call, len_of_start,
  55                                         len_of_open, len_of_close,
  56                                         len_of_args, args_start_at,
  57                                         args_str, len_of_prefix,
  58                                         call_starts_at,
  59                                         postfix_starts_at)
  60 {
  61   # Find call expression.
  62   call_starts_at = match(line, fnname " \\(.+\\)");
  63   if (call_starts_at == 0)
  64     return 0;
  65
  66   # Length of the call expression.
  67   len_of_call = RLENGTH;
  68
  69   len_of_start = length(fnname " (");
  70   len_of_open = length("(");
  71   len_of_close = length(")");
  72
  73   # Find arguments
  74   len_of_args = len_of_call - (len_of_start + len_of_close);
  75   args_start_at = call_starts_at + len_of_start;
  76   args_str = substr(line, args_start_at, len_of_args);
  77   split(args_str, args, ",");
  78
  79   # Find call expression prefix
  80   len_of_prefix = call_starts_at - 1;
  81   prefix = substr(line, 1, len_of_prefix);
  82
  83   # Find call expression postfix
  84   postfix_starts_at = call_starts_at + len_of_call;
  85   postfix = substr(line, postfix_starts_at);
  86   return 1;
  87 }
  88
  89 function adjust_linenos(above, increment,       p, i)
  90 {
  91   for (p in pass_lines)
  92     if (pass_lines[p] >= above)
  93       pass_lines[p] += pass_lines[p];
  94   if (increment > 0)
  95     for (i = lineno - 1; i >= above; i--)
  96       lines[i + increment] = lines[i];
  97   else
  98     for (i = above; i < lineno; i++)
  99       lines[i + increment] = lines[i];
 100   lineno += increment;
 101 }
 102
 103 function insert_remove_pass(line, fnname)
 104 {
 105   parse_line($0, fnname);
 106   pass_name = args[1];
 107   if (pass_name == "PASS")
 108     return 1;
 109   pass_num = args[2] + 0;
 110   new_line = prefix "NEXT_PASS (" args[3];
 111   if (args[4])
 112     new_line = new_line ", " args[4];
 113   new_line = new_line ")" postfix;
 114   if (!pass_lines[pass_name, pass_num])
 115     {
 116       print "ERROR: Can't locate instance of the pass mentioned in " fnname;
 117       return 1;
 118     }
 119   return 0;
 120 }
 121
 122 function insert_pass(line, fnname, after,               num)
 123 {
 124   if (insert_remove_pass(line, fnname))
 125     return;
 126   num = pass_lines[pass_name, pass_num];
 127   adjust_linenos(num + after, 1);
 128   pass_name = args[3];
 129   # Set pass_counts
 130   if (args[3] in pass_counts)
 131     pass_counts[pass_name]++;
 132   else
 133     pass_counts[pass_name] = 1;
 134
 135   pass_lines[pass_name, pass_counts[pass_name]] = num + after;
 136   lines[num + after] = new_line;
 137 }
 138
 139 function replace_pass(line, fnname,                     num, i)
 140 {
 141   if (insert_remove_pass(line, "REPLACE_PASS"))
 142     return;
 143   num = pass_lines[pass_name, pass_num];
 144   for (i = pass_counts[pass_name]; i > pass_num; i--)
 145     pass_lines[pass_name, i - 1] = pass_lines[pass_name, i];
 146   delete pass_lines[pass_name, pass_counts[pass_name]];
 147   if (pass_counts[pass_name] == 1)
 148     delete pass_counts[pass_name];
 149   else
 150     pass_counts[pass_name]--;
 151
 152   pass_name = args[3];
 153   # Set pass_counts
 154   if (args[3] in pass_counts)
 155     pass_counts[pass_name]++;
 156   else
 157     pass_counts[pass_name] = 1;
 158
 159   pass_lines[pass_name, pass_counts[pass_name]] = num;
 160   lines[num] = new_line;
 161 }
 162
 163 /INSERT_PASS_AFTER \(.+\)/ {
 164   insert_pass($0, "INSERT_PASS_AFTER", 1);
 165   next;
 166 }
 167
 168 /INSERT_PASS_BEFORE \(.+\)/ {
 169   insert_pass($0, "INSERT_PASS_BEFORE", 0);
 170   next;
 171 }
 172
 173 /REPLACE_PASS \(.+\)/ {
 174   replace_pass($0, "REPLACE_PASS");
 175   next;
 176 }
 177
 178 {
 179   ret = parse_line($0, "NEXT_PASS");
 180   if (ret)
 181     {
 182       pass_name = args[1];
 183
 184       # Set pass_counts
 185       if (pass_name in pass_counts)
 186         pass_counts[pass_name]++;
 187       else
 188         pass_counts[pass_name] = 1;
 189
 190       pass_lines[pass_name, pass_counts[pass_name]] = lineno;
 191     }
 192   lines[lineno++] = $0;
 193 }
 194
 195 END {
 196   delete pass_counts;
 197   for (i = 1; i < lineno; i++)
 198     {
 199       ret = parse_line(lines[i], "NEXT_PASS");
 200       if (ret)
 201         {
 202           # Set pass_name argument, an optional with_arg argument
 203           pass_name = args[1];
 204           with_arg = args[2];
 205
 206           # Set pass_counts
 207           if (pass_name in pass_counts)
 208             pass_counts[pass_name]++;
 209           else
 210             pass_counts[pass_name] = 1;
 211
 212           pass_num = pass_counts[pass_name];
 213
 214           # Print call expression with extra pass_num argument
 215           printf "%s", prefix;
 216           if (with_arg)
 217             printf "NEXT_PASS_WITH_ARG";
 218           else
 219             printf "NEXT_PASS";
 220           printf " (%s, %s", pass_name, pass_num;
 221           if (with_arg)
 222             printf ", %s", with_arg;
 223           printf ")%s\n", postfix;
 224         }
 225       else
 226         print lines[i];
 227     }
 228 }
 229
 230 # Local Variables:
 231 # mode:awk
 232 # c-basic-offset:8
 233 # End: