libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:7:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  -Wall:  turns on all automake warnings...
  76 #  -Wno-portability:  ...except this one, since GNU make is now required.
  77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
  78 AH_TEMPLATE(PACKAGE, [Name of package])
  79 AH_TEMPLATE(VERSION, [Version number of package])
  80
  81 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  82 # up critical shell variables.
  83 GLIBCXX_CONFIGURE
  84
  85 AC_LIBTOOL_DLOPEN
  86 AM_PROG_LIBTOOL
  87 AC_SUBST(enable_shared)
  88 AC_SUBST(enable_static)
  89
  90 # Possibly disable most of the library.
  91 ## TODO: Consider skipping unncessary tests altogether in this case, rather
  92 ## than just ignoring the results.  Faster /and/ more correct, win win.
  93 GLIBCXX_ENABLE_HOSTED
  94
  95 # Check for compiler support that doesn't require linking.
  96 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  97 GLIBCXX_ENABLE_PCH($is_hosted)
  98
  99 # Enable all the variable C++ runtime options.
 100 GLIBCXX_ENABLE_CSTDIO
 101 GLIBCXX_ENABLE_CLOCALE
 102 GLIBCXX_ENABLE_ALLOCATOR
 103 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 104 GLIBCXX_ENABLE_C99([yes])
 105 GLIBCXX_ENABLE_LONG_LONG([yes])
 106 GLIBCXX_ENABLE_WCHAR_T([yes])
 107 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 108 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 109 GLIBCXX_ENABLE_DEBUG([no])
 110 GLIBCXX_ENABLE_CXX_FLAGS
 111 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 112
 113 # No surprises, no surprises...
 114 GLIBCXX_ENABLE_THREADS
 115 if test $atomicity_dir = cpu/generic ; then
 116   AC_MSG_WARN([No native atomic operations are provided for this platform.])
 117   if test $target_thread_file = single; then
 118     AC_MSG_WARN([They cannot be faked when thread support is disabled.])
 119     AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
 120   else
 121     AC_MSG_WARN([They will be faked using a mutex.])
 122     AC_MSG_WARN([Performance of certain classes will degrade as a result.])
 123   fi
 124 fi
 125
 126
 127 if $GLIBCXX_IS_NATIVE; then
 128
 129   # We can do more elaborate tests that assume a working linker.
 130   CANADIAN=no
 131
 132   # Check for available headers.
 133   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 134   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h \
 135   sys/types.h sys/ipc.h sys/sem.h])
 136
 137   GLIBCXX_CHECK_COMPILER_FEATURES
 138   GLIBCXX_CHECK_LINKER_FEATURES
 139   GLIBCXX_CHECK_MATH_SUPPORT
 140   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 141   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 142   GLIBCXX_CHECK_ICONV_SUPPORT
 143   GLIBCXX_CHECK_STDLIB_SUPPORT
 144
 145   # For showmanyc_helper().
 146   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 147   GLIBCXX_CHECK_POLL
 148   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 149
 150   # For xsputn_2().
 151   AC_CHECK_HEADERS(sys/uio.h)
 152   GLIBCXX_CHECK_WRITEV
 153
 154   # For the __streamoff_base_type typedef.
 155   GLIBCXX_CHECK_INT64_T
 156
 157   # For LFS support.
 158   GLIBCXX_CHECK_LFS
 159
 160   # For C99 support to TR1.
 161   GLIBCXX_CHECK_C99_TR1
 162
 163   # For TLS support.
 164   GCC_CHECK_TLS
 165
 166   AC_LC_MESSAGES
 167
 168   AC_TRY_COMPILE(
 169     [#include <setjmp.h>],
 170     [sigjmp_buf env;
 171      while (! sigsetjmp (env, 1))
 172        siglongjmp (env, 1);
 173     ],
 174     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
 175
 176   AC_FUNC_MMAP
 177
 178 else
 179
 180   # This lets us hard-code the functionality we know we'll have in the cross
 181   # target environment.  "Let" is a sugar-coated word placed on an especially
 182   # dull and tedious hack, actually.
 183   #
 184   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 185   # that involve linking, can't be used:
 186   #    "cannot open sim-crt0.o"
 187   #    "cannot open crt0.o"
 188   # etc.  All this is because there currently exists no unified, consistent
 189   # way for top level CC information to be passed down to target directories:
 190   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 191   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 192   # crosses can be removed.
 193
 194   # If Canadian cross, then don't pick up tools from the build directory.
 195   # Used only in GLIBCXX_EXPORT_INCLUDES.
 196   if test -n "$with_cross_host" &&
 197      test x"$build_alias" != x"$with_cross_host" &&
 198      test x"$build" != x"$target";
 199   then
 200     CANADIAN=yes
 201   else
 202     CANADIAN=no
 203   fi
 204
 205   # Construct crosses by hand, eliminating bits that need ld...
 206   # GLIBCXX_CHECK_COMPILER_FEATURES
 207   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 208   # GLIBCXX_CHECK_MATH_SUPPORT
 209
 210   # First, test for "known" system libraries.  We may be using newlib even
 211   # on a hosted environment.
 212   if test "x${with_newlib}" = "xyes"; then
 213     os_include_dir="os/newlib"
 214     AC_DEFINE(HAVE_HYPOT)
 215
 216     # GLIBCXX_CHECK_STDLIB_SUPPORT
 217     AC_DEFINE(HAVE_STRTOF)
 218     # AC_FUNC_MMAP
 219     AC_DEFINE(HAVE_MMAP)
 220
 221     AC_DEFINE(HAVE_ACOSF)
 222     AC_DEFINE(HAVE_ASINF)
 223     AC_DEFINE(HAVE_ATAN2F)
 224     AC_DEFINE(HAVE_ATANF)
 225     AC_DEFINE(HAVE_CEILF)
 226     AC_DEFINE(HAVE_COPYSIGN)
 227     AC_DEFINE(HAVE_COPYSIGNF)
 228     AC_DEFINE(HAVE_COSF)
 229     AC_DEFINE(HAVE_COSHF)
 230     AC_DEFINE(HAVE_EXPF)
 231     AC_DEFINE(HAVE_FABSF)
 232     AC_DEFINE(HAVE_FLOORF)
 233     AC_DEFINE(HAVE_FMODF)
 234     AC_DEFINE(HAVE_FREXPF)
 235     AC_DEFINE(HAVE_LDEXPF)
 236     AC_DEFINE(HAVE_LOG10F)
 237     AC_DEFINE(HAVE_LOGF)
 238     AC_DEFINE(HAVE_MODFF)
 239     AC_DEFINE(HAVE_POWF)
 240     AC_DEFINE(HAVE_SINF)
 241     AC_DEFINE(HAVE_SINHF)
 242     AC_DEFINE(HAVE_SQRTF)
 243     AC_DEFINE(HAVE_TANF)
 244     AC_DEFINE(HAVE_TANHF)
 245
 246     AC_DEFINE(HAVE_S_ISREG)
 247     AC_DEFINE(HAVE_S_IFREG)
 248   else
 249     GLIBCXX_CROSSCONFIG
 250   fi
 251
 252   # At some point, we should differentiate between architectures
 253   # like x86, which have long double versions, and alpha/powerpc/etc.,
 254   # which don't. For the time being, punt.
 255   if test x"long_double_math_on_this_cpu" = x"yes"; then
 256     AC_DEFINE(HAVE_ACOSL)
 257     AC_DEFINE(HAVE_ASINL)
 258     AC_DEFINE(HAVE_ATAN2L)
 259     AC_DEFINE(HAVE_ATANL)
 260     AC_DEFINE(HAVE_CEILL)
 261     AC_DEFINE(HAVE_COPYSIGNL)
 262     AC_DEFINE(HAVE_COSL)
 263     AC_DEFINE(HAVE_COSHL)
 264     AC_DEFINE(HAVE_EXPL)
 265     AC_DEFINE(HAVE_FABSL)
 266     AC_DEFINE(HAVE_FLOORL)
 267     AC_DEFINE(HAVE_FMODL)
 268     AC_DEFINE(HAVE_FREXPL)
 269     AC_DEFINE(HAVE_LDEXPL)
 270     AC_DEFINE(HAVE_LOG10L)
 271     AC_DEFINE(HAVE_LOGL)
 272     AC_DEFINE(HAVE_MODFL)
 273     AC_DEFINE(HAVE_POWL)
 274     AC_DEFINE(HAVE_SINCOSL)
 275     AC_DEFINE(HAVE_SINL)
 276     AC_DEFINE(HAVE_SINHL)
 277     AC_DEFINE(HAVE_SQRTL)
 278     AC_DEFINE(HAVE_TANL)
 279     AC_DEFINE(HAVE_TANHL)
 280   fi
 281
 282 fi
 283
 284 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 285 GLIBCXX_ENABLE_SYMVERS([yes])
 286
 287 ac_ldbl_compat=no
 288 case "$target" in
 289   powerpc*-*-*gnu* | \
 290   sparc*-*-linux* | \
 291   s390*-*-linux* | \
 292   alpha*-*-linux*)
 293   AC_TRY_COMPILE(, [
 294 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 295 #error no need for long double compatibility
 296 #endif
 297   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 298   if test "$ac_ldbl_compat" = yes; then
 299     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 300               [Define if compatibility should be provided for -mlong-double-64.])
 301     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 302   fi
 303 esac
 304 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 305
 306 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 307 GLIBCXX_CONFIGURE_TESTSUITE
 308
 309 # Propagate the target-specific source directories through the build chain.
 310 ATOMICITY_SRCDIR=config/${atomicity_dir}
 311 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 312 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 313 OS_INC_SRCDIR=config/${os_include_dir}
 314 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 315 AC_SUBST(ATOMICITY_SRCDIR)
 316 AC_SUBST(ATOMIC_WORD_SRCDIR)
 317 AC_SUBST(CPU_DEFINES_SRCDIR)
 318 AC_SUBST(ABI_TWEAKS_SRCDIR)
 319 AC_SUBST(OS_INC_SRCDIR)
 320
 321 # Determine cross-compile flags and AM_CONDITIONALs.
 322 #AC_SUBST(GLIBCXX_IS_NATIVE)
 323 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 324 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 325 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 326 GLIBCXX_EVALUATE_CONDITIONALS
 327
 328 AC_CACHE_SAVE
 329
 330 if test ${multilib} = yes; then
 331   multilib_arg="--enable-multilib"
 332 else
 333   multilib_arg=
 334 fi
 335
 336 # Export all the install information.
 337 GLIBCXX_EXPORT_INSTALL_INFO
 338
 339 # Export all the include and flag information to Makefiles.
 340 GLIBCXX_EXPORT_INCLUDES
 341 GLIBCXX_EXPORT_FLAGS
 342
 343 if ${CONFIG_SHELL-/bin/sh} ./libtool --tag CXX --features |
 344    grep "enable shared" > /dev/null;
 345 then
 346   LIBSUPCXX_PICFLAGS=-prefer-pic
 347 else
 348   LIBSUPCXX_PICFLAGS=
 349 fi
 350 AC_SUBST(LIBSUPCXX_PICFLAGS)
 351
 352 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 353 dnl which can all be called multiple times as needed, plus one (different)
 354 dnl AC_OUTPUT macro.  This one lists the files to be created:
 355 AC_CONFIG_FILES( \
 356   Makefile \
 357   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
 358   )
 359 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 360
 361 dnl These commands are run at the end of config.status:
 362 AC_CONFIG_COMMANDS([default],
 363 [if test -n "$CONFIG_FILES"; then
 364    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 365    # that multilib installs will end up installed in the correct place.
 366    # The testsuite needs it for multilib-aware ABI baseline files.
 367    # To work around this not being passed down from config-ml.in ->
 368    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 369    # append it here.  Only modify Makefiles that have just been created.
 370    #
 371    # Also, get rid of this simulated-VPATH thing that automake does.
 372    cat > vpsed << \_EOF
 373 s!`test -f '$<' || echo '$(srcdir)/'`!!
 374 _EOF
 375    for i in $SUBDIRS; do
 376     case $CONFIG_FILES in
 377      *${i}/Makefile*)
 378        #echo "Adding MULTISUBDIR to $i/Makefile"
 379        sed -f vpsed $i/Makefile > tmp
 380        grep '^MULTISUBDIR =' Makefile >> tmp
 381        mv tmp $i/Makefile
 382        ;;
 383     esac
 384    done
 385    rm vpsed
 386  fi
 387  (cd include && ${MAKE-make})
 388 ],
 389 [
 390 # Variables needed in config.status (file generation) which aren't already
 391 # passed by autoconf.
 392 SUBDIRS="$SUBDIRS"
 393 ])
 394
 395 dnl And this actually makes things happen:
 396 AC_OUTPUT