gcc/ada/switch-m.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S W I T C H - M                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2012, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Debug;    use Debug;
  27 with Makeutl;  use Makeutl;
  28 with Osint;    use Osint;
  29 with Opt;      use Opt;
  30 with Prj;      use Prj;
  31 with Prj.Env;  use Prj.Env;
  32 with Table;
  33
  34 with System.Multiprocessors; use System.Multiprocessors;
  35
  36 package body Switch.M is
  37
  38    package Normalized_Switches is new Table.Table
  39      (Table_Component_Type => String_Access,
  40       Table_Index_Type     => Integer,
  41       Table_Low_Bound      => 1,
  42       Table_Initial        => 20,
  43       Table_Increment      => 100,
  44       Table_Name           => "Switch.M.Normalized_Switches");
  45    --  This table is used to keep the normalized switches, so that they may be
  46    --  reused for subsequent invocations of Normalize_Compiler_Switches with
  47    --  similar switches.
  48
  49    Initial_Number_Of_Switches : constant := 10;
  50
  51    Global_Switches : Argument_List_Access := null;
  52    --  Used by function Normalize_Compiler_Switches
  53
  54    ---------------------------------
  55    -- Normalize_Compiler_Switches --
  56    ---------------------------------
  57
  58    procedure Normalize_Compiler_Switches
  59      (Switch_Chars : String;
  60       Switches     : in out Argument_List_Access;
  61       Last         : out Natural)
  62    is
  63       Switch_Starts_With_Gnat : Boolean;
  64
  65       Ptr : Integer := Switch_Chars'First;
  66       Max : constant Integer := Switch_Chars'Last;
  67       C   : Character := ' ';
  68
  69       Storing      : String := Switch_Chars;
  70       First_Stored : Positive := Ptr + 1;
  71       Last_Stored  : Positive := First_Stored;
  72
  73       procedure Add_Switch_Component (S : String);
  74       --  Add a new String_Access component in Switches. If a string equal
  75       --  to S is already stored in the table Normalized_Switches, use it.
  76       --  Otherwise add a new component to the table.
  77
  78       --------------------------
  79       -- Add_Switch_Component --
  80       --------------------------
  81
  82       procedure Add_Switch_Component (S : String) is
  83       begin
  84          --  If Switches is null, allocate a new array
  85
  86          if Switches = null then
  87             Switches := new Argument_List (1 .. Initial_Number_Of_Switches);
  88
  89          --  Otherwise, if Switches is full, extend it
  90
  91          elsif Last = Switches'Last then
  92             declare
  93                New_Switches : constant Argument_List_Access :=
  94                                 new Argument_List
  95                                       (1 .. Switches'Length + Switches'Length);
  96             begin
  97                New_Switches (1 .. Switches'Length) := Switches.all;
  98                Last := Switches'Length;
  99                Switches := New_Switches;
 100             end;
 101          end if;
 102
 103          --  If this is the first switch, Last designates the first component
 104
 105          if Last = 0 then
 106             Last := Switches'First;
 107          else
 108             Last := Last + 1;
 109          end if;
 110
 111          --  Look into the table Normalized_Switches for a similar string.
 112          --  If one is found, put it at the added component, and return.
 113
 114          for Index in 1 .. Normalized_Switches.Last loop
 115             if S = Normalized_Switches.Table (Index).all then
 116                Switches (Last) := Normalized_Switches.Table (Index);
 117                return;
 118             end if;
 119          end loop;
 120
 121          --  No string equal to S was found in the table Normalized_Switches.
 122          --  Add a new component in the table.
 123
 124          Switches (Last) := new String'(S);
 125          Normalized_Switches.Append (Switches (Last));
 126       end Add_Switch_Component;
 127
 128    --  Start of processing for Normalize_Compiler_Switches
 129
 130    begin
 131       Last := 0;
 132
 133       if Ptr = Max or else Switch_Chars (Ptr) /= '-' then
 134          return;
 135       end if;
 136
 137       Ptr := Ptr + 1;
 138
 139       Switch_Starts_With_Gnat :=
 140          Ptr + 3 <= Max and then Switch_Chars (Ptr .. Ptr + 3) = "gnat";
 141
 142       if Switch_Starts_With_Gnat then
 143          Ptr := Ptr + 4;
 144          First_Stored := Ptr;
 145       end if;
 146
 147       while Ptr <= Max loop
 148          C := Switch_Chars (Ptr);
 149
 150          --  Processing for a switch
 151
 152          case Switch_Starts_With_Gnat is
 153
 154             when False =>
 155
 156                --  All switches that don't start with -gnat stay as is,
 157                --  except -pg, -Wall, -k8, -w
 158
 159                if Switch_Chars = "-pg" or else Switch_Chars = "-p" then
 160
 161                   --  The gcc driver converts -pg to -p, so that is what
 162                   --  is stored in the ALI file.
 163
 164                   Add_Switch_Component ("-p");
 165
 166                elsif Switch_Chars = "-Wall" then
 167
 168                   --  The gcc driver adds -gnatwa when -Wall is used
 169
 170                   Add_Switch_Component ("-gnatwa");
 171                   Add_Switch_Component ("-Wall");
 172
 173                elsif Switch_Chars = "-k8" then
 174
 175                   --  The gcc driver transforms -k8 into -gnatk8
 176
 177                   Add_Switch_Component ("-gnatk8");
 178
 179                elsif Switch_Chars = "-w" then
 180
 181                   --  The gcc driver adds -gnatws when -w is used
 182
 183                   Add_Switch_Component ("-gnatws");
 184                   Add_Switch_Component ("-w");
 185
 186                elsif Switch_Chars'Length > 6
 187                  and then
 188                    Switch_Chars (Switch_Chars'First .. Switch_Chars'First + 5)
 189                                                              = "--RTS="
 190                then
 191                   Add_Switch_Component (Switch_Chars);
 192
 193                   --  When --RTS=mtp is used, the gcc driver adds -mrtp
 194
 195                   if Switch_Chars = "--RTS=mtp" then
 196                      Add_Switch_Component ("-mrtp");
 197                   end if;
 198
 199                --  Switch for universal addressing on AAMP target
 200
 201                elsif Switch_Chars'Length >= 5
 202                  and then
 203                    Switch_Chars
 204                      (Switch_Chars'First .. Switch_Chars'First + 4) = "-univ"
 205                then
 206                   Add_Switch_Component (Switch_Chars);
 207
 208                --  Switch for specifying AAMP target library
 209
 210                elsif Switch_Chars'Length > 13
 211                  and then
 212                    Switch_Chars (Switch_Chars'First .. Switch_Chars'First + 12)
 213                      = "-aamp_target="
 214                then
 215                   Add_Switch_Component (Switch_Chars);
 216
 217                --  Take only into account switches that are transmitted to
 218                --  gnat1 by the gcc driver and stored by gnat1 in the ALI file.
 219
 220                else
 221                   case C is
 222                      when 'O' | 'W' | 'w' | 'f' | 'd' | 'g' | 'm' =>
 223                         Add_Switch_Component (Switch_Chars);
 224
 225                      when others =>
 226                         null;
 227                   end case;
 228                end if;
 229
 230                return;
 231
 232             when True =>
 233
 234                case C is
 235
 236                   --  One-letter switches
 237
 238                   when 'a' | 'A' | 'b' | 'B' | 'c' | 'C' | 'E' | 'f' |
 239                        'F' | 'g' | 'h' | 'H' | 'I' | 'L' | 'N' | 'o' |
 240                        'p' | 'P' | 'q' | 'Q' | 'r' | 's' | 'S' | 't' |
 241                        'u' | 'U' | 'v' | 'x' | 'X' | 'Z' =>
 242                      Storing (First_Stored) := C;
 243                      Add_Switch_Component
 244                        (Storing (Storing'First .. First_Stored));
 245                      Ptr := Ptr + 1;
 246
 247                   --  One-letter switches followed by a positive number
 248
 249                   when 'D' | 'G' | 'j' | 'k' | 'm' | 'T' =>
 250                      Storing (First_Stored) := C;
 251                      Last_Stored := First_Stored;
 252
 253                      if Ptr <= Max and then Switch_Chars (Ptr) = '=' then
 254                         Ptr := Ptr + 1;
 255                      end if;
 256
 257                      loop
 258                         Ptr := Ptr + 1;
 259                         exit when Ptr > Max
 260                           or else Switch_Chars (Ptr) not in '0' .. '9';
 261                         Last_Stored := Last_Stored + 1;
 262                         Storing (Last_Stored) := Switch_Chars (Ptr);
 263                      end loop;
 264
 265                      Add_Switch_Component
 266                        (Storing (Storing'First .. Last_Stored));
 267
 268                   when 'd' =>
 269                      Storing (First_Stored) := 'd';
 270
 271                      while Ptr < Max loop
 272                         Ptr := Ptr + 1;
 273                         C := Switch_Chars (Ptr);
 274                         exit when C = ASCII.NUL or else C = '/'
 275                           or else C = '-';
 276
 277                         if C in '1' .. '9' or else
 278                            C in 'a' .. 'z' or else
 279                            C in 'A' .. 'Z'
 280                         then
 281                            Storing (First_Stored + 1) := C;
 282                            Add_Switch_Component
 283                              (Storing (Storing'First .. First_Stored + 1));
 284
 285                         else
 286                            Last := 0;
 287                            return;
 288                         end if;
 289                      end loop;
 290
 291                      return;
 292
 293                   when 'e' =>
 294
 295                      --  Some of the gnate... switches are not stored
 296
 297                      Storing (First_Stored) := 'e';
 298                      Ptr := Ptr + 1;
 299
 300                      if Ptr > Max then
 301                         Last := 0;
 302                         return;
 303
 304                      else
 305                         case Switch_Chars (Ptr) is
 306
 307                            when 'D' =>
 308                               Storing (First_Stored + 1 ..
 309                                          First_Stored + Max - Ptr + 1) :=
 310                                   Switch_Chars (Ptr .. Max);
 311                               Add_Switch_Component
 312                                 (Storing (Storing'First ..
 313                                    First_Stored + Max - Ptr + 1));
 314                               Ptr := Max + 1;
 315
 316                            when 'G' =>
 317                               Ptr := Ptr + 1;
 318                               Add_Switch_Component ("-gnateG");
 319
 320                            when 'I' =>
 321                               Ptr := Ptr + 1;
 322
 323                               declare
 324                                  First : constant Positive := Ptr - 1;
 325                               begin
 326                                  if Ptr <= Max and then
 327                                    Switch_Chars (Ptr) = '='
 328                                  then
 329                                     Ptr := Ptr + 1;
 330                                  end if;
 331
 332                                  while Ptr <= Max and then
 333                                        Switch_Chars (Ptr) in '0' .. '9'
 334                                  loop
 335                                     Ptr := Ptr + 1;
 336                                  end loop;
 337
 338                                  Storing (First_Stored + 1 ..
 339                                             First_Stored + Ptr - First) :=
 340                                      Switch_Chars (First .. Ptr - 1);
 341                                  Add_Switch_Component
 342                                    (Storing (Storing'First ..
 343                                       First_Stored + Ptr - First));
 344                               end;
 345
 346                            when 'p' =>
 347                               Ptr := Ptr + 1;
 348
 349                               if Ptr = Max then
 350                                  Last := 0;
 351                                  return;
 352                               end if;
 353
 354                               if Switch_Chars (Ptr) = '=' then
 355                                  Ptr := Ptr + 1;
 356                               end if;
 357
 358                                  --  To normalize, always put a '=' after
 359                                  --  -gnatep. Because that could lengthen the
 360                                  --  switch string, declare a local variable.
 361
 362                               declare
 363                                  To_Store : String (1 .. Max - Ptr + 9);
 364                               begin
 365                                  To_Store (1 .. 8) := "-gnatep=";
 366                                  To_Store (9 .. Max - Ptr + 9) :=
 367                                    Switch_Chars (Ptr .. Max);
 368                                  Add_Switch_Component (To_Store);
 369                               end;
 370
 371                               return;
 372
 373                            when 'S' =>
 374                               Ptr := Ptr + 1;
 375                               Add_Switch_Component ("-gnateS");
 376
 377                            when others =>
 378                               Last := 0;
 379                               return;
 380                         end case;
 381                      end if;
 382
 383                   when 'i' =>
 384                      Storing (First_Stored) := 'i';
 385
 386                      Ptr := Ptr + 1;
 387
 388                      if Ptr > Max then
 389                         Last := 0;
 390                         return;
 391                      end if;
 392
 393                      C := Switch_Chars (Ptr);
 394
 395                      if C in '1' .. '5'
 396                        or else C = '8'
 397                        or else C = 'p'
 398                        or else C = 'f'
 399                        or else C = 'n'
 400                        or else C = 'w'
 401                      then
 402                         Storing (First_Stored + 1) := C;
 403                         Add_Switch_Component
 404                           (Storing (Storing'First .. First_Stored + 1));
 405                         Ptr := Ptr + 1;
 406
 407                      else
 408                         Last := 0;
 409                         return;
 410                      end if;
 411
 412                   --  -gnatl may be -gnatl=<file name>
 413
 414                   when 'l' =>
 415                      Ptr := Ptr + 1;
 416
 417                      if Ptr > Max or else Switch_Chars (Ptr) /= '=' then
 418                         Add_Switch_Component ("-gnatl");
 419
 420                      else
 421                         Add_Switch_Component
 422                           ("-gnatl" & Switch_Chars (Ptr .. Max));
 423                         return;
 424                      end if;
 425
 426                   --  -gnatn may be -gnatn, -gnatn1, or -gnatn2
 427
 428                   when 'n' =>
 429                      Last_Stored := First_Stored;
 430                      Storing (Last_Stored) := 'n';
 431                      Ptr := Ptr + 1;
 432
 433                      if Ptr <= Max
 434                        and then Switch_Chars (Ptr) in '1' .. '2'
 435                      then
 436                         Last_Stored := Last_Stored + 1;
 437                         Storing (Last_Stored) := Switch_Chars (Ptr);
 438                         Ptr := Ptr + 1;
 439                      end if;
 440
 441                      Add_Switch_Component
 442                        (Storing (Storing'First .. Last_Stored));
 443
 444                   --  -gnatR may be followed by '0', '1', '2' or '3',
 445                   --  then by 's'
 446
 447                   when 'R' =>
 448                      Last_Stored := First_Stored;
 449                      Storing (Last_Stored) := 'R';
 450                      Ptr := Ptr + 1;
 451
 452                      if Ptr <= Max
 453                        and then Switch_Chars (Ptr) in '0' .. '9'
 454                      then
 455                         C := Switch_Chars (Ptr);
 456
 457                         if C in '4' .. '9' then
 458                            Last := 0;
 459                            return;
 460
 461                         else
 462                            Last_Stored := Last_Stored + 1;
 463                            Storing (Last_Stored) := C;
 464                            Ptr := Ptr + 1;
 465
 466                            if Ptr <= Max
 467                              and then Switch_Chars (Ptr) = 's'
 468                            then
 469                               Last_Stored := Last_Stored + 1;
 470                               Storing (Last_Stored) := 's';
 471                               Ptr := Ptr + 1;
 472                            end if;
 473                         end if;
 474                      end if;
 475
 476                      Add_Switch_Component
 477                        (Storing (Storing'First .. Last_Stored));
 478
 479                   --  -gnatWx, x = 'h'. 'u', 's', 'e', '8' or 'b'
 480
 481                   when 'W' =>
 482                      Storing (First_Stored) := 'W';
 483                      Ptr := Ptr + 1;
 484
 485                      if Ptr <= Max then
 486                         case Switch_Chars (Ptr) is
 487                            when 'h' | 'u' | 's' | 'e' | '8' | 'b' =>
 488                               Storing (First_Stored + 1) := Switch_Chars (Ptr);
 489                               Add_Switch_Component
 490                                 (Storing (Storing'First .. First_Stored + 1));
 491                               Ptr := Ptr + 1;
 492
 493                            when others =>
 494                               Last := 0;
 495                               return;
 496                         end case;
 497                      end if;
 498
 499                   --  Multiple switches
 500
 501                   when 'V' | 'w' | 'y' =>
 502                      Storing (First_Stored) := C;
 503                      Ptr := Ptr + 1;
 504
 505                      if Ptr > Max then
 506                         if C = 'y' then
 507                            Add_Switch_Component
 508                              (Storing (Storing'First .. First_Stored));
 509
 510                         else
 511                            Last := 0;
 512                            return;
 513                         end if;
 514                      end if;
 515
 516                      --  Loop through remaining switch characters in string
 517
 518                      while Ptr <= Max loop
 519                         C := Switch_Chars (Ptr);
 520                         Ptr := Ptr + 1;
 521
 522                         --  -gnatyMxxx
 523
 524                         if C = 'M' and then Storing (First_Stored) = 'y' then
 525                            Last_Stored := First_Stored + 1;
 526                            Storing (Last_Stored) := 'M';
 527                            while Ptr <= Max loop
 528                               C := Switch_Chars (Ptr);
 529                               exit when C not in '0' .. '9';
 530                               Last_Stored := Last_Stored + 1;
 531                               Storing (Last_Stored) := C;
 532                               Ptr := Ptr + 1;
 533                            end loop;
 534
 535                            --  If there is no digit after -gnatyM,
 536                            --  the switch is invalid.
 537
 538                            if Last_Stored = First_Stored + 1 then
 539                               Last := 0;
 540                               return;
 541
 542                            else
 543                               Add_Switch_Component
 544                                 (Storing (Storing'First .. Last_Stored));
 545                            end if;
 546
 547                         --  --gnatx.x
 548
 549                         elsif C = '.' and then Ptr <= Max then
 550                            Storing (First_Stored + 1) := '.';
 551                            Storing (First_Stored + 2) := Switch_Chars (Ptr);
 552                            Ptr := Ptr + 1;
 553                            Add_Switch_Component
 554                              (Storing (Storing'First .. First_Stored + 2));
 555
 556                         --  All other switches are -gnatxx
 557
 558                         else
 559                            Storing (First_Stored + 1) := C;
 560                            Add_Switch_Component
 561                              (Storing (Storing'First .. First_Stored + 1));
 562                         end if;
 563                      end loop;
 564
 565                   --  -gnat95 -gnat05
 566
 567                   when '0' | '9' =>
 568                      Last_Stored := First_Stored;
 569                      Storing (Last_Stored) := C;
 570                      Ptr := Ptr + 1;
 571
 572                      if Ptr /= Max or else Switch_Chars (Ptr) /= '5' then
 573
 574                         --  Invalid switch
 575
 576                         Last := 0;
 577                         return;
 578
 579                      else
 580                         Last_Stored := Last_Stored + 1;
 581                         Storing (Last_Stored) := '5';
 582                         Add_Switch_Component
 583                           (Storing (Storing'First .. Last_Stored));
 584                         Ptr := Ptr + 1;
 585                      end if;
 586
 587                      --  -gnat12
 588
 589                   when '1' =>
 590                      Last_Stored := First_Stored;
 591                      Storing (Last_Stored) := C;
 592                      Ptr := Ptr + 1;
 593
 594                      if Ptr /= Max or else Switch_Chars (Ptr) /= '2' then
 595
 596                         --  Invalid switch
 597
 598                         Last := 0;
 599                         return;
 600
 601                      else
 602                         Last_Stored := Last_Stored + 1;
 603                         Storing (Last_Stored) := '2';
 604                         Add_Switch_Component
 605                           (Storing (Storing'First .. Last_Stored));
 606                         Ptr := Ptr + 1;
 607                      end if;
 608
 609                      --  -gnat2005 -gnat2012
 610
 611                   when '2' =>
 612                      if Ptr + 3 /= Max then
 613                         Last := 0;
 614                         return;
 615
 616                      elsif Switch_Chars (Ptr + 1 .. Ptr + 3) = "005" then
 617                         Last_Stored := First_Stored + 3;
 618                         Storing (First_Stored .. Last_Stored) := "2005";
 619                         Add_Switch_Component
 620                           (Storing (Storing'First .. Last_Stored));
 621                         Ptr := Max + 1;
 622
 623                      elsif Switch_Chars (Ptr + 1 .. Ptr + 3) = "012" then
 624                         Last_Stored := First_Stored + 3;
 625                         Storing (First_Stored .. Last_Stored) := "2012";
 626                         Add_Switch_Component
 627                           (Storing (Storing'First .. Last_Stored));
 628                         Ptr := Max + 1;
 629
 630                      else
 631
 632                         --  Invalid switch
 633
 634                         Last := 0;
 635                         return;
 636
 637                      end if;
 638
 639                   --  -gnat83
 640
 641                   when '8' =>
 642                      Last_Stored := First_Stored;
 643                      Storing (Last_Stored) := '8';
 644                      Ptr := Ptr + 1;
 645
 646                      if Ptr /= Max or else Switch_Chars (Ptr) /= '3' then
 647
 648                         --  Invalid switch
 649
 650                         Last := 0;
 651                         return;
 652
 653                      else
 654                         Last_Stored := Last_Stored + 1;
 655                         Storing (Last_Stored) := '3';
 656                         Add_Switch_Component
 657                           (Storing (Storing'First .. Last_Stored));
 658                         Ptr := Ptr + 1;
 659                      end if;
 660
 661                   --  Not a valid switch
 662
 663                   when others =>
 664                      Last := 0;
 665                      return;
 666
 667                end case;
 668
 669          end case;
 670       end loop;
 671    end Normalize_Compiler_Switches;
 672
 673    function Normalize_Compiler_Switches
 674      (Switch_Chars : String) return Argument_List
 675    is
 676       Last : Natural;
 677
 678    begin
 679       Normalize_Compiler_Switches (Switch_Chars, Global_Switches, Last);
 680
 681       if Last = 0 then
 682          return (1 .. 0 => null);
 683       else
 684          return Global_Switches (Global_Switches'First .. Last);
 685       end if;
 686    end Normalize_Compiler_Switches;
 687
 688    ------------------------
 689    -- Scan_Make_Switches --
 690    ------------------------
 691
 692    procedure Scan_Make_Switches
 693      (Env               : in out Prj.Tree.Environment;
 694       Switch_Chars      : String;
 695       Success           : out Boolean)
 696    is
 697       Ptr : Integer          := Switch_Chars'First;
 698       Max : constant Integer := Switch_Chars'Last;
 699       C   : Character        := ' ';
 700
 701    begin
 702       --  Assume a good switch
 703
 704       Success := True;
 705
 706       --  Skip past the initial character (must be the switch character)
 707
 708       if Ptr = Max then
 709          Bad_Switch (Switch_Chars);
 710
 711       else
 712          Ptr := Ptr + 1;
 713       end if;
 714
 715       --  A little check, "gnat" at the start of a switch is for the compiler
 716
 717       if Switch_Chars'Length >= Ptr + 3
 718         and then Switch_Chars (Ptr .. Ptr + 3) = "gnat"
 719       then
 720          Success := False;
 721          return;
 722       end if;
 723
 724       C := Switch_Chars (Ptr);
 725
 726       --  Multiple character switches
 727
 728       if Switch_Chars'Length > 2 then
 729          if Switch_Chars = "--create-missing-dirs" then
 730             Setup_Projects := True;
 731
 732          elsif Switch_Chars'Length > Subdirs_Option'Length
 733            and then
 734              Switch_Chars
 735                (Switch_Chars'First ..
 736                 Switch_Chars'First + Subdirs_Option'Length - 1) =
 737                                                             Subdirs_Option
 738          then
 739             Subdirs :=
 740               new String'
 741                 (Switch_Chars
 742                   (Switch_Chars'First + Subdirs_Option'Length ..
 743                    Switch_Chars'Last));
 744
 745          elsif Switch_Chars = Makeutl.Unchecked_Shared_Lib_Imports then
 746             Opt.Unchecked_Shared_Lib_Imports := True;
 747
 748          elsif Switch_Chars = Makeutl.Single_Compile_Per_Obj_Dir_Switch then
 749             Opt.One_Compilation_Per_Obj_Dir := True;
 750
 751          elsif Switch_Chars (Ptr) = '-' then
 752             Bad_Switch (Switch_Chars);
 753
 754          elsif Switch_Chars'Length > 3
 755            and then Switch_Chars (Ptr .. Ptr + 1) = "aP"
 756          then
 757             Add_Directories
 758               (Env.Project_Path,
 759                Switch_Chars (Ptr + 2 .. Switch_Chars'Last));
 760
 761          elsif C = 'v' and then Switch_Chars'Length = 3 then
 762             Ptr := Ptr + 1;
 763             Verbose_Mode := True;
 764
 765             case Switch_Chars (Ptr) is
 766                when 'l' =>
 767                   Verbosity_Level := Opt.Low;
 768
 769                when 'm' =>
 770                   Verbosity_Level := Opt.Medium;
 771
 772                when 'h' =>
 773                   Verbosity_Level := Opt.High;
 774
 775                when others =>
 776                   Success := False;
 777             end case;
 778
 779          elsif C = 'd' then
 780
 781             --  Note: for the debug switch, the remaining characters in this
 782             --  switch field must all be debug flags, since all valid switch
 783             --  characters are also valid debug characters. This switch is not
 784             --  documented on purpose because it is only used by the
 785             --  implementors.
 786
 787             --  Loop to scan out debug flags
 788
 789             while Ptr < Max loop
 790                Ptr := Ptr + 1;
 791                C := Switch_Chars (Ptr);
 792
 793                if C in 'a' .. 'z' or else C in 'A' .. 'Z' then
 794                   Set_Debug_Flag (C);
 795                else
 796                   Bad_Switch (Switch_Chars);
 797                end if;
 798             end loop;
 799
 800          elsif C = 'e' then
 801             Ptr := Ptr + 1;
 802
 803             case Switch_Chars (Ptr) is
 804
 805                --  Processing for eI switch
 806
 807                when 'I' =>
 808                   Ptr := Ptr + 1;
 809                   Scan_Pos (Switch_Chars, Max, Ptr, Main_Index, C);
 810
 811                   if Ptr <= Max then
 812                      Bad_Switch (Switch_Chars);
 813                   end if;
 814
 815                --  Processing for eL switch
 816
 817                when 'L' =>
 818                   if Ptr /= Max then
 819                      Bad_Switch (Switch_Chars);
 820
 821                   else
 822                      Follow_Links_For_Files := True;
 823                      Follow_Links_For_Dirs  := True;
 824                   end if;
 825
 826                --  Processing for eS switch
 827
 828                when 'S' =>
 829                   if Ptr /= Max then
 830                      Bad_Switch (Switch_Chars);
 831
 832                   else
 833                      Commands_To_Stdout := True;
 834                   end if;
 835
 836                when others =>
 837                   Bad_Switch (Switch_Chars);
 838             end case;
 839
 840          elsif C = 'j' then
 841             Ptr := Ptr + 1;
 842
 843             declare
 844                Max_Proc : Nat;
 845
 846             begin
 847                Scan_Nat (Switch_Chars, Max, Ptr, Max_Proc, C);
 848
 849                if Ptr <= Max then
 850                   Bad_Switch (Switch_Chars);
 851
 852                else
 853                   if Max_Proc = 0 then
 854                      Max_Proc := Nat (Number_Of_CPUs);
 855
 856                      if Max_Proc = 0 then
 857                         Max_Proc := 1;
 858                      end if;
 859                   end if;
 860
 861                   Maximum_Processes := Positive (Max_Proc);
 862                end if;
 863             end;
 864
 865          elsif C = 'w' and then Switch_Chars'Length = 3 then
 866             Ptr := Ptr + 1;
 867
 868             if Switch_Chars = "-we" then
 869                Warning_Mode := Treat_As_Error;
 870
 871             elsif Switch_Chars = "-wn" then
 872                Warning_Mode := Normal;
 873
 874             elsif Switch_Chars = "-ws" then
 875                Warning_Mode  := Suppress;
 876
 877             else
 878                Success := False;
 879             end if;
 880
 881          else
 882             Success := False;
 883          end if;
 884
 885       --  Single-character switches
 886
 887       else
 888          Check_Switch : begin
 889
 890             case C is
 891
 892                when 'a' =>
 893                   Check_Readonly_Files := True;
 894
 895                --  Processing for b switch
 896
 897                when 'b' =>
 898                   Bind_Only  := True;
 899                   Make_Steps := True;
 900
 901                --  Processing for B switch
 902
 903                when 'B' =>
 904                   Build_Bind_And_Link_Full_Project := True;
 905
 906                --  Processing for c switch
 907
 908                when 'c' =>
 909                   Compile_Only := True;
 910                   Make_Steps   := True;
 911
 912                --  Processing for C switch
 913
 914                when 'C' =>
 915                   Opt.Create_Mapping_File := True;
 916
 917                --  Processing for D switch
 918
 919                when 'D' =>
 920                   if Object_Directory_Present then
 921                      Osint.Fail ("duplicate -D switch");
 922
 923                   else
 924                      Object_Directory_Present := True;
 925                   end if;
 926
 927                --  Processing for f switch
 928
 929                when 'f' =>
 930                   Force_Compilations := True;
 931
 932                --  Processing for F switch
 933
 934                when 'F' =>
 935                   Full_Path_Name_For_Brief_Errors := True;
 936
 937                --  Processing for h switch
 938
 939                when 'h' =>
 940                   Usage_Requested := True;
 941
 942                --  Processing for i switch
 943
 944                when 'i' =>
 945                   In_Place_Mode := True;
 946
 947                --  Processing for j switch
 948
 949                when 'j' =>
 950                   --  -j not followed by a number is an error
 951
 952                   Bad_Switch (Switch_Chars);
 953
 954                --  Processing for k switch
 955
 956                when 'k' =>
 957                   Keep_Going := True;
 958
 959                --  Processing for l switch
 960
 961                when 'l' =>
 962                   Link_Only  := True;
 963                   Make_Steps := True;
 964
 965                --  Processing for M switch
 966
 967                when 'M' =>
 968                   List_Dependencies := True;
 969
 970                --  Processing for n switch
 971
 972                when 'n' =>
 973                   Do_Not_Execute := True;
 974
 975                --  Processing for o switch
 976
 977                when 'o' =>
 978                   if Output_File_Name_Present then
 979                      Osint.Fail ("duplicate -o switch");
 980                   else
 981                      Output_File_Name_Present := True;
 982                   end if;
 983
 984                --  Processing for p switch
 985
 986                when 'p' =>
 987                   Setup_Projects := True;
 988
 989                --  Processing for q switch
 990
 991                when 'q' =>
 992                   Quiet_Output := True;
 993
 994                --  Processing for R switch
 995
 996                when 'R' =>
 997                   Run_Path_Option := False;
 998
 999                --  Processing for s switch
1000
1001                when 's' =>
1002                   Ptr := Ptr + 1;
1003                   Check_Switches := True;
1004
1005                --  Processing for v switch
1006
1007                when 'v' =>
1008                   Verbose_Mode := True;
1009                   Verbosity_Level := Opt.High;
1010
1011                   --  Processing for x switch
1012
1013                when 'x' =>
1014                   External_Unit_Compilation_Allowed := True;
1015                   Use_Include_Path_File := True;
1016
1017                   --  Processing for z switch
1018
1019                when 'z' =>
1020                   No_Main_Subprogram := True;
1021
1022                   --  Any other small letter is an illegal switch
1023
1024                when others =>
1025                   if C in 'a' .. 'z' then
1026                      Bad_Switch (Switch_Chars);
1027
1028                   else
1029                      Success := False;
1030                   end if;
1031
1032             end case;
1033          end Check_Switch;
1034       end if;
1035    end Scan_Make_Switches;
1036
1037 end Switch.M;