libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/lib-ld.m4)
   8 sinclude(../config/override.m4)
   9 sinclude(../config/picflag.m4)
  10 sinclude(../config/dfp.m4)
  11 sinclude(../config/unwind_ipinfo.m4)
  12 sinclude(../config/gthr.m4)
  13
  14 AC_PREREQ(2.64)
  15 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  16 AC_CONFIG_SRCDIR([static-object.mk])
  17
  18 # The libgcc should not depend on any header files
  19 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  20   [m4_divert_text([DEFAULTS],
  21     [ac_includes_default='/* none */'])])
  22
  23 AC_ARG_WITH(target-subdir,
  24 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  25 AC_ARG_WITH(cross-host,
  26 [  --with-cross-host=HOST           Configuring with a cross compiler])
  27 AC_ARG_WITH(ld,
  28 [  --with-ld               arrange to use the specified ld (full pathname)])
  29
  30 if test "${srcdir}" = "."; then
  31   if test -n "${with_build_subdir}"; then
  32     libgcc_topdir="${srcdir}/../.."
  33     with_target_subdir=
  34   elif test -z "${with_target_subdir}"; then
  35     libgcc_topdir="${srcdir}/.."
  36   else
  37     if test "${with_target_subdir}" != "."; then
  38       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  39     else
  40       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  41     fi
  42   fi
  43 else
  44   libgcc_topdir="${srcdir}/.."
  45 fi
  46 AC_SUBST(libgcc_topdir)
  47 AC_CONFIG_AUX_DIR($libgcc_topdir)
  48 AC_CONFIG_HEADER(auto-target.h:config.in)
  49
  50 AC_ARG_ENABLE(shared,
  51 [  --disable-shared        don't provide a shared libgcc],
  52 [
  53   case $enable_shared in
  54   yes | no) ;;
  55   *)
  56     enable_shared=no
  57     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  58     for pkg in $enableval; do
  59       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  60         enable_shared=yes
  61       fi
  62     done
  63     IFS="$ac_save_ifs"
  64     ;;
  65   esac
  66 ], [enable_shared=yes])
  67 AC_SUBST(enable_shared)
  68
  69 AC_ARG_ENABLE(vtable-verify,
  70 [  --enable-vtable-verify    Enable vtable verification feature ],
  71 [case "$enableval" in
  72  yes) enable_vtable_verify=yes ;;
  73  no)  enable_vtable_verify=no ;;
  74  *)   enable_vtable_verify=no;;
  75  esac],
  76 [enable_vtable_verify=no])
  77 AC_SUBST(enable_vtable_verify)
  78
  79 GCC_PICFLAG
  80 AC_SUBST(PICFLAG)
  81
  82 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  83 AC_ARG_ENABLE(version-specific-runtime-libs,
  84 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  85 [case "$enableval" in
  86  yes) version_specific_libs=yes ;;
  87  no)  version_specific_libs=no ;;
  88  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  89  esac],
  90 [version_specific_libs=no])
  91 AC_MSG_RESULT($version_specific_libs)
  92
  93 AC_ARG_WITH(slibdir,
  94 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
  95 slibdir="$with_slibdir",
  96 if test "${version_specific_libs}" = yes; then
  97   slibdir='$(libsubdir)'
  98 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
  99   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
 100 else
 101   slibdir='$(libdir)'
 102 fi)
 103 AC_SUBST(slibdir)
 104
 105 # Command-line options.
 106 # Very limited version of AC_MAINTAINER_MODE.
 107 AC_ARG_ENABLE([maintainer-mode],
 108   [AC_HELP_STRING([--enable-maintainer-mode],
 109                  [enable make rules and dependencies not useful (and
 110                   sometimes confusing) to the casual installer])],
 111   [case ${enable_maintainer_mode} in
 112      yes) MAINT='' ;;
 113      no) MAINT='#' ;;
 114      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 115    esac
 116    maintainer_mode=${enableval}],
 117   [MAINT='#'])
 118 AC_SUBST([MAINT])dnl
 119
 120 AC_PROG_INSTALL
 121
 122 AC_PROG_AWK
 123 # We need awk; bail out if it's missing.
 124 case ${AWK} in
 125   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 126 esac
 127
 128 AC_CANONICAL_HOST
 129 ACX_NONCANONICAL_HOST
 130 ACX_NONCANONICAL_TARGET
 131 GCC_TOPLEV_SUBDIRS
 132
 133 # Calculate toolexeclibdir
 134 # Also toolexecdir, though it's only used in toolexeclibdir
 135 case ${version_specific_libs} in
 136   yes)
 137     # Need the gcc compiler version to know where to install libraries
 138     # and header files if --enable-version-specific-runtime-libs option
 139     # is selected.
 140     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 141     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 142     ;;
 143   no)
 144     if test -n "$with_cross_host" &&
 145        test x"$with_cross_host" != x"no"; then
 146       # Install a library built with a cross compiler in tooldir, not libdir.
 147       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 148       toolexeclibdir='$(toolexecdir)/lib'
 149     else
 150       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 151       toolexeclibdir='$(libdir)'
 152     fi
 153     multi_os_directory=`$CC -print-multi-os-directory`
 154     case $multi_os_directory in
 155       .) ;; # Avoid trailing /.
 156       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 157     esac
 158     ;;
 159 esac
 160 AC_SUBST(toolexecdir)
 161 AC_SUBST(toolexeclibdir)
 162
 163 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 164 dnl to call AC_CHECK_PROG.
 165 AC_CHECK_TOOL(AR, ar)
 166 AC_CHECK_TOOL(LIPO, lipo, :)
 167 AC_CHECK_TOOL(NM, nm)
 168 AC_CHECK_TOOL(RANLIB, ranlib, :)
 169 AC_CHECK_TOOL(STRIP, strip, :)
 170 AC_PROG_LN_S
 171
 172 GCC_NO_EXECUTABLES
 173 AC_PROG_CC
 174 AC_PROG_CPP_WERROR
 175
 176 AC_CHECK_SIZEOF([double])
 177 AC_CHECK_SIZEOF([long double])
 178 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 179 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 180 AC_SUBST(double_type_size)
 181 AC_SUBST(long_double_type_size)
 182
 183 # Check for decimal float support.
 184 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 185                [AC_COMPILE_IFELSE([_Decimal32 x;], [libgcc_cv_dfp=yes],
 186                                   [libgcc_cv_dfp=no])])
 187 decimal_float=$libgcc_cv_dfp
 188 AC_SUBST(decimal_float)
 189
 190 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 191
 192 # Check for fixed-point support.
 193 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 194                [AC_COMPILE_IFELSE([_Sat _Fract x;], [libgcc_cv_fixed_point=yes],
 195                                   [libgcc_cv_fixed_point=no])])
 196 fixed_point=$libgcc_cv_fixed_point
 197 AC_SUBST(fixed_point)
 198
 199 # For platforms with the unwind ABI which includes an unwind library,
 200 # libunwind, we can choose to use the system libunwind.
 201 # config.gcc also contains tests of with_system_libunwind.
 202 GCC_CHECK_UNWIND_GETIPINFO
 203
 204 # The sjlj test is almost duplicated here and in libgo/configure.ac (for C),
 205 # libstdc++-v3/acinclude.m4 and libjava/configure.ac (for C++), and
 206 # libobjc/configure.ac (for Objective-C).
 207 # FIXME: This should be centralized in config/sjlj.m4.
 208 AC_ARG_ENABLE(sjlj-exceptions,
 209   AC_HELP_STRING([--enable-sjlj-exceptions],
 210                  [force use of builtin_setjmp for exceptions]),
 211   [case "$enableval" in
 212    yes|no|auto) ;;
 213    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 214    esac],
 215   [enable_sjlj_exceptions=auto])
 216
 217 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 218 [libgcc_cv_lib_sjlj_exceptions],
 219 [AC_LANG_CONFTEST(
 220   [AC_LANG_SOURCE([
 221 void bar ();
 222 void clean (int *);
 223 void foo ()
 224 {
 225   int i __attribute__ ((cleanup (clean)));
 226   bar();
 227 }
 228 ])])
 229 CFLAGS_hold=$CFLAGS
 230 CFLAGS="--save-temps -fexceptions"
 231 libgcc_cv_lib_sjlj_exceptions=unknown
 232 AS_IF([ac_fn_c_try_compile],
 233   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 234     libgcc_cv_lib_sjlj_exceptions=yes
 235   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 236     libgcc_cv_lib_sjlj_exceptions=no
 237   fi])
 238 CFLAGS=$CFLAGS_hold
 239 rm -f conftest*
 240 ])
 241
 242 if test "$enable_sjlj_exceptions" = "auto"; then
 243   enable_sjlj_exceptions=$libgcc_cv_lib_sjlj_exceptions
 244 fi
 245
 246 case $enable_sjlj_exceptions in
 247 yes)
 248   AC_DEFINE(LIBGCC_SJLJ_EXCEPTIONS, 1,
 249         [Define if the C compiler is configured for setjmp/longjmp exceptions.])
 250   ;;
 251 no)
 252   ;;
 253 *)
 254   AC_MSG_ERROR([unable to detect exception model])
 255   ;;
 256 esac
 257
 258 AC_LIB_PROG_LD_GNU
 259
 260 AC_MSG_CHECKING([for thread model used by GCC])
 261 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 262 AC_MSG_RESULT([$target_thread_file])
 263
 264 # Check for assembler CFI support.
 265 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 266                [AC_COMPILE_IFELSE(
 267 [asm("\n\
 268         .text\n\
 269         .cfi_startproc\n\
 270         .cfi_personality 0, symbol\n\
 271         .cfi_endproc");],
 272   [libgcc_cv_cfi=yes],
 273   [libgcc_cv_cfi=no])])
 274
 275 # Check 32bit or 64bit
 276 cat > conftest.c <<EOF
 277 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__))
 278 host_address=64
 279 #else
 280 host_address=32
 281 #endif
 282 EOF
 283 eval `${CC-cc} -E conftest.c | grep host_address=`
 284 rm -f conftest.c
 285
 286 # Collect host-machine-specific information.
 287 . ${srcdir}/config.host
 288
 289 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 290 # This is after config.host so we can augment tmake_file.
 291 # Link with -nostartfiles -nodefaultlibs since neither are present while
 292 # building libgcc.
 293 case ${host} in
 294 i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 295   cat > conftest.s <<EOF
 296         .section        .eh_frame,"a",@unwind
 297         .zero   4
 298         .section        .jcr,"aw",@progbits
 299         .zero   8
 300 EOF
 301   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 302       tmake_file="${tmake_file} i386/t-crtstuff"
 303   fi
 304   ;;
 305 esac
 306
 307 # Check for visibility support.  This is after config.host so that
 308 # we can check for asm_hidden_op.
 309 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 310     libgcc_cv_hidden_visibility_attribute, [
 311         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 312         libgcc_cv_hidden_visibility_attribute=no
 313         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 314             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 315                 libgcc_cv_hidden_visibility_attribute=yes
 316             fi
 317         fi
 318         rm -f conftest.*
 319     ])
 320
 321 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 322     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 323 else
 324     vis_hide=
 325 fi
 326 AC_SUBST(vis_hide)
 327
 328 # See if we have thread-local storage.  We can only test assembler
 329 # since link-time and run-time tests require the newly built
 330 # gcc, which can't be used to build executable due to that libgcc
 331 # is yet to be built here.
 332 GCC_CHECK_CC_TLS
 333 set_have_cc_tls=
 334 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 335   set_have_cc_tls="-DHAVE_CC_TLS"
 336 fi
 337 AC_SUBST(set_have_cc_tls)
 338
 339 # See if we have emulated thread-local storage.
 340 GCC_CHECK_EMUTLS
 341 set_use_emutls=
 342 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 343   set_use_emutls="-DUSE_EMUTLS"
 344 fi
 345 AC_SUBST(set_use_emutls)
 346
 347 AC_CACHE_CHECK(for init priority support, libgcc_cv_init_priority, [
 348 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,
 349   [[void ip (void) __attribute__ ((constructor (1)));]])],
 350   [libgcc_cv_init_priority=yes],[libgcc_cv_init_priority=no])])
 351 if test $libgcc_cv_init_priority = yes; then
 352   AC_DEFINE(HAVE_INIT_PRIORITY, 1,
 353   [Define if the compiler supports init priority.])
 354 fi
 355
 356 # Conditionalize the sfp-machine.h header for this target machine.
 357 if test -z "${sfp_machine_header}"; then
 358         sfp_machine_header=$cpu_type/sfp-machine.h
 359         if test -f ${srcdir}/config/${sfp_machine_header}; then
 360                 :
 361         else
 362                 sfp_machine_header=no-sfp-machine.h
 363         fi
 364 fi
 365 AC_SUBST(sfp_machine_header)
 366
 367 # Conditionalize the makefile for this target machine.
 368 tmake_file_=
 369 for f in ${tmake_file}
 370 do
 371         if test -f ${srcdir}/config/$f
 372         then
 373                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 374         fi
 375 done
 376 tmake_file="${tmake_file_}"
 377 AC_SUBST(tmake_file)
 378
 379 # Likewise export definitions for libgcc_tm.h
 380 tm_file_=
 381 for f in ${tm_file}
 382 do
 383         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 384 done
 385 tm_file="${tm_file_}"
 386 AC_SUBST(tm_file)
 387 AC_SUBST(tm_defines)
 388
 389 # Map from thread model to thread header.
 390 GCC_AC_THREAD_HEADER([$target_thread_file])
 391
 392 # Substitute configuration variables
 393 AC_SUBST(cpu_type)
 394 AC_SUBST(extra_parts)
 395 AC_SUBST(asm_hidden_op)
 396 AC_CONFIG_LINKS([enable-execute-stack.c:$enable_execute_stack])
 397 AC_CONFIG_LINKS([unwind.h:$unwind_header])
 398 AC_CONFIG_LINKS([md-unwind-support.h:config/$md_unwind_header])
 399 AC_CONFIG_LINKS([sfp-machine.h:config/$sfp_machine_header])
 400 AC_CONFIG_LINKS([gthr-default.h:$thread_header])
 401
 402 # We need multilib support.
 403 AC_CONFIG_FILES([Makefile])
 404 AC_CONFIG_COMMANDS([default],
 405   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 406 if test -n "$CONFIG_FILES"; then
 407   # FIXME: We shouldn't need to set ac_file
 408   ac_file=Makefile
 409   . ${libgcc_topdir}/config-ml.in
 410 fi]],
 411 [[srcdir=${srcdir}
 412 host=${host}
 413 with_target_subdir=${with_target_subdir}
 414 with_multisubdir=${with_multisubdir}
 415 ac_configure_args="--enable-multilib ${ac_configure_args}"
 416 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 417 libgcc_topdir=${libgcc_topdir}
 418 CC="${CC}"
 419 ]])
 420 AC_OUTPUT