gcc/ada/xeinfo.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                          GNAT SYSTEM UTILITIES                           --
   4 --                                                                          --
   5 --                               X E I N F O                                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2001 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  Program to construct C header file a-einfo.h (C version of einfo.ads spec)
  28 --  for use by Gigi. This header file contaInF all definitions and access
  29 --  functions, but does not contain set procedures, since Gigi is not allowed
  30 --  to modify the GNAT tree)
  31
  32 --    Input files:
  33
  34 --       einfo.ads     spec of Einfo package
  35 --       einfo.adb     body of Einfo package
  36
  37 --    Output files:
  38
  39 --       a-einfo.h     Corresponding c header file
  40
  41 --  Note: It is assumed that the input files have been compiled without errors
  42
  43 --  An optional argument allows the specification of an output file name to
  44 --  override the default a-einfo.h file name for the generated output file.
  45
  46 --  Most, but not all of the functions in Einfo can be inlined in the C header.
  47 --  They are the functions identified by pragma Inline in the spec. Functions
  48 --  that cannot be inlined are simply defined in the header.
  49
  50 with Ada.Command_Line;              use Ada.Command_Line;
  51 with Ada.Strings.Unbounded;         use Ada.Strings.Unbounded;
  52 with Ada.Strings.Unbounded.Text_IO; use Ada.Strings.Unbounded.Text_IO;
  53 with Ada.Strings.Maps;              use Ada.Strings.Maps;
  54 with Ada.Strings.Maps.Constants;    use Ada.Strings.Maps.Constants;
  55 with Ada.Text_IO;                   use Ada.Text_IO;
  56
  57 with GNAT.Spitbol;                  use GNAT.Spitbol;
  58 with GNAT.Spitbol.Patterns;         use GNAT.Spitbol.Patterns;
  59 with GNAT.Spitbol.Table_Boolean;    use GNAT.Spitbol.Table_Boolean;
  60
  61 procedure XEinfo is
  62
  63    package TB renames GNAT.Spitbol.Table_Boolean;
  64
  65    Err : exception;
  66
  67    A         : VString := Nul;
  68    B         : VString := Nul;
  69    C         : VString := Nul;
  70    Expr      : VString := Nul;
  71    Filler    : VString := Nul;
  72    Fline     : VString := Nul;
  73    Formal    : VString := Nul;
  74    Formaltyp : VString := Nul;
  75    FN        : VString := Nul;
  76    Line      : VString := Nul;
  77    N         : VString := Nul;
  78    N1        : VString := Nul;
  79    N2        : VString := Nul;
  80    N3        : VString := Nul;
  81    Nam       : VString := Nul;
  82    Name      : VString := Nul;
  83    NewS      : VString := Nul;
  84    Nextlin   : VString := Nul;
  85    OldS      : VString := Nul;
  86    Rtn       : VString := Nul;
  87    Term      : VString := Nul;
  88
  89    InF   : File_Type;
  90    --  Used to read full text of both spec and body
  91
  92    Ofile : File_Type;
  93    --  Used to write output file
  94
  95    wsp      : Pattern := NSpan (' ' & ASCII.HT);
  96    Comment  : Pattern := wsp & "--";
  97    For_Rep  : Pattern := wsp & "for";
  98    Get_Func : Pattern := wsp * A & "function" & wsp & Break (' ') * Name;
  99    Inline   : Pattern := wsp & "pragma Inline (" & Break (')') * Name;
 100    Get_Pack : Pattern := wsp & "package ";
 101    Get_Enam : Pattern := wsp & Break (',') * N & ',';
 102    Find_Fun : Pattern := wsp & "function";
 103    F_Subtyp : Pattern := wsp * A & "subtype " & Break (' ') * N;
 104    G_Subtyp : Pattern := wsp & "subtype" & wsp & Break (' ') * NewS
 105                            & wsp & "is" & wsp & Break (" ;") * OldS
 106                            & wsp & ';' & wsp & Rtab (0);
 107    F_Typ    : Pattern := wsp * A & "type " & Break (' ') * N & " is (";
 108    Get_Nam  : Pattern := wsp * A & Break (",)") * Nam & Len (1) * Term;
 109    Get_Styp : Pattern := wsp * A & "subtype " & Break (' ') * N;
 110    Get_N1   : Pattern := wsp & Break (' ') * N1;
 111    Get_N2   : Pattern := wsp & "-- " & Rest * N2;
 112    Get_N3   : Pattern := wsp & Break (';') * N3;
 113    Get_FN   : Pattern := wsp * C & "function" & wsp & Break (" (") * FN;
 114    Is_Rturn : Pattern := BreakX ('r') & "return";
 115    Is_Begin : Pattern := wsp & "begin";
 116    Get_Asrt : Pattern := wsp & "pragma Assert";
 117    Semicoln : Pattern := BreakX (';');
 118    Get_Cmnt : Pattern := BreakX ('-') * A & "--";
 119    Get_Expr : Pattern := wsp & "return " & Break (';') * Expr;
 120    Chek_End : Pattern := wsp & "end" & BreakX (';') & ';';
 121    Get_B1   : Pattern := BreakX (' ') * A & " in " & Rest * B;
 122    Get_B2   : Pattern := BreakX (' ') * A & " = " & Rest * B;
 123    Get_B3   : Pattern := BreakX (' ') * A & " /= " & Rest * B;
 124    To_Paren : Pattern := wsp * Filler & '(';
 125    Get_Fml  : Pattern := Break (" :") * Formal & wsp & ':' & wsp
 126                            & BreakX (" );") * Formaltyp;
 127    Nxt_Fml  : Pattern := wsp & "; ";
 128    Get_Rtn  : Pattern := wsp & "return" & wsp & BreakX (" ;") * Rtn;
 129    Rem_Prn  : Pattern := wsp & ')';
 130
 131    M : Match_Result;
 132
 133    Lineno : Natural := 0;
 134    --  Line number in spec
 135
 136    V   : Natural;
 137    Ctr : Natural;
 138
 139    Inlined : TB.Table (200);
 140    --  Inlined<N> = True for inlined function, False otherwise
 141
 142    Lastinlined : Boolean;
 143
 144    procedure Badfunc;
 145    --  Signal bad function in body
 146
 147    function Getlin return VString;
 148    --  Get non-comment line (comment lines skipped, also skips FOR rep clauses)
 149    --  Fatal error (raises End_Error exception) if end of file encountered
 150
 151    procedure Must (B : Boolean);
 152    --  Raises Err if the argument (a Match) call, returns False
 153
 154    procedure Sethead (Line : in out VString; Term : String);
 155    --  Process function header into C
 156
 157    -------------
 158    -- Badfunc --
 159    -------------
 160
 161    procedure Badfunc is
 162    begin
 163       Put_Line
 164         (Standard_Error,
 165          "Body for function " & FN & " does not meet requirements");
 166       raise Err;
 167    end Badfunc;
 168
 169    -------------
 170    -- Getlin --
 171    -------------
 172
 173    function Getlin return VString is
 174       Lin : VString;
 175
 176    begin
 177       loop
 178          Lin := Get_Line (InF);
 179          Lineno := Lineno + 1;
 180
 181          if Lin /= ""
 182            and then not Match (Lin, Comment)
 183            and then not Match (Lin, For_Rep)
 184          then
 185             return Lin;
 186          end if;
 187       end loop;
 188    end Getlin;
 189
 190    ----------
 191    -- Must --
 192    ----------
 193
 194    procedure Must (B : Boolean) is
 195    begin
 196       if not B then
 197          raise Err;
 198       end if;
 199    end Must;
 200
 201    -------------
 202    -- Sethead --
 203    -------------
 204
 205    procedure Sethead (Line : in out VString; Term : String) is
 206       Args : VString;
 207
 208    begin
 209       Must (Match (Line, Get_Func, ""));
 210       Args := Nul;
 211
 212       if Match (Line, To_Paren, "") then
 213          Args := Filler & '(';
 214
 215          loop
 216             Must (Match (Line, Get_Fml, ""));
 217             Append (Args, Formaltyp & ' ' & Formal);
 218             exit when not Match (Line, Nxt_Fml);
 219             Append (Args, ",");
 220          end loop;
 221
 222          Match (Line, Rem_Prn, "");
 223          Append (Args, ')');
 224       end if;
 225
 226       Must (Match (Line, Get_Rtn));
 227
 228       if Present (Inlined, Name) then
 229          Put_Line (Ofile, A & "INLINE " & Rtn & ' ' & Name & Args & Term);
 230       else
 231          Put_Line (Ofile, A &  Rtn & ' ' & Name & Args & Term);
 232       end if;
 233    end Sethead;
 234
 235 --  Start of processing for XEinfo
 236
 237 begin
 238    Anchored_Mode := True;
 239
 240    if Argument_Count > 0 then
 241       Create (Ofile, Out_File, Argument (1));
 242    else
 243       Create (Ofile, Out_File, "a-einfo.h");
 244    end if;
 245
 246    Open (InF, In_File, "einfo.ads");
 247
 248    Lineno := 0;
 249
 250    --  Write header to output file
 251
 252    loop
 253       Line := Get_Line (InF);
 254       Lineno := Lineno + 1;
 255       exit when Line = "";
 256
 257       Match (Line,
 258              "--                                 S p e c       ",
 259              "--                              C Header File    ");
 260
 261       Match (Line, "--", "/*");
 262       Match (Line, Rtab (2) * A & "--", M);
 263       Replace (M, A & "*/");
 264       Put_Line (Ofile, Line);
 265    end loop;
 266
 267    Put_Line (Ofile, "");
 268
 269    --  Find and record pragma Inlines
 270
 271    loop
 272       Line := Get_Line (InF);
 273       exit when Match (Line, "   --  END XEINFO INLINES");
 274
 275       if Match (Line, Inline) then
 276          Set (Inlined, Name, True);
 277       end if;
 278    end loop;
 279
 280    --  Skip to package line
 281
 282    Reset (InF, In_File);
 283    Lineno := 0;
 284
 285    loop
 286       Line := Getlin;
 287       exit when Match (Line, Get_Pack);
 288    end loop;
 289
 290    V := 0;
 291    Line := Getlin;
 292    Must (Match (Line, wsp & "type Entity_Kind"));
 293
 294    --  Process entity kind code definitions
 295
 296    loop
 297       Line := Getlin;
 298       exit when not Match (Line, Get_Enam);
 299       Put_Line (Ofile, "   #define " & Rpad (N, 32) & " " & V);
 300       V := V + 1;
 301    end loop;
 302
 303    Must (Match (Line, wsp & Rest * N));
 304    Put_Line (Ofile, "   #define " & Rpad (N, 32) & ' ' & V);
 305    Line := Getlin;
 306
 307    Must (Match (Line, wsp & ");"));
 308    Put_Line (Ofile, "");
 309
 310    --  Loop through subtype and type declarations
 311
 312    loop
 313       Line := Getlin;
 314       exit when Match (Line, Find_Fun);
 315
 316       --  Case of a subtype declaration
 317
 318       if Match (Line, F_Subtyp) then
 319
 320          --  Case of a subtype declaration that is an abbreviation of the
 321          --  form subtype x is y, and if so generate the appropriate typedef
 322
 323          if Match (Line, G_Subtyp) then
 324             Put_Line (Ofile, A & "typedef " & OldS & ' ' & NewS & ';');
 325
 326          --  Otherwise the subtype must be declaring a subrange of Entity_Id
 327
 328          else
 329             Must (Match (Line, Get_Styp));
 330             Line := Getlin;
 331             Must (Match (Line, Get_N1));
 332
 333             loop
 334                Line := Get_Line (InF);
 335                Lineno := Lineno + 1;
 336                exit when not Match (Line, Get_N2);
 337             end loop;
 338
 339             Must (Match (Line, Get_N3));
 340             Put_Line (Ofile, A & "SUBTYPE (" & N & ", Entity_Kind, ");
 341             Put_Line (Ofile, A & "   " & N1 & ", " & N3 & ')');
 342             Put_Line (Ofile, "");
 343          end if;
 344
 345       --  Case of type declaration
 346
 347       elsif Match (Line, F_Typ) then
 348          --  Process type declaration (must be enumeration type)
 349
 350          Ctr := 0;
 351          Put_Line (Ofile, A & "typedef char " & N & ';');
 352
 353          loop
 354             Line := Getlin;
 355             Must (Match (Line, Get_Nam));
 356             Put_Line (Ofile, A & "#define " & Rpad (Nam, 25) & Ctr);
 357             Ctr := Ctr + 1;
 358             exit when Term /= ",";
 359          end loop;
 360
 361          Put_Line (Ofile, "");
 362
 363       --  Neither subtype nor type declaration
 364
 365       else
 366          raise Err;
 367       end if;
 368    end loop;
 369
 370    --  Process function declarations
 371    --  Note: Lastinlined used to control blank lines
 372
 373    Put_Line (Ofile, "");
 374    Lastinlined := True;
 375
 376    --  Loop through function declarations
 377
 378    while Match (Line, Get_FN) loop
 379
 380       --  Non-inlined function
 381
 382       if not Present (Inlined, FN) then
 383          Put_Line (Ofile, "");
 384          Put_Line
 385            (Ofile,
 386             "   #define " & FN & " einfo__" & Translate (FN, Lower_Case_Map));
 387
 388       --  Inlined function
 389
 390       else
 391          if not Lastinlined then
 392             Put_Line (Ofile, "");
 393          end if;
 394       end if;
 395
 396       --  Merge here to output spec
 397
 398       Sethead (Line, ";");
 399       Lastinlined := Get (Inlined, FN);
 400       Line := Getlin;
 401    end loop;
 402
 403    Put_Line (Ofile, "");
 404
 405    --  Read body to find inlined functions
 406
 407    Close (InF);
 408    Open (InF, In_File, "einfo.adb");
 409    Lineno := 0;
 410
 411    --  Loop through input lines to find bodies of inlined functions
 412
 413    while not End_Of_File (InF) loop
 414       Fline := Get_Line (InF);
 415
 416       if Match (Fline, Get_FN)
 417         and then Get (Inlined, FN)
 418       then
 419          --  Here we have an inlined function
 420
 421          if not Match (Fline, Is_Rturn) then
 422             Line := Fline;
 423             Badfunc;
 424          end if;
 425
 426          Line := Getlin;
 427
 428          if not Match (Line, Is_Begin) then
 429             Badfunc;
 430          end if;
 431
 432          --  Skip past pragma Asserts
 433
 434          loop
 435             Line := Getlin;
 436             exit when not Match (Line, Get_Asrt);
 437
 438             --  Pragma asser found, get its continuation lines
 439
 440             loop
 441                exit when Match (Line, Semicoln);
 442                Line := Getlin;
 443             end loop;
 444          end loop;
 445
 446          --  Process return statement
 447
 448          Match (Line, Get_Cmnt, M);
 449          Replace (M, A);
 450
 451          --  Get continuations of return statemnt
 452
 453          while not Match (Line, Semicoln) loop
 454             Nextlin := Getlin;
 455             Match (Nextlin, wsp, " ");
 456             Append (Line, Nextlin);
 457          end loop;
 458
 459          if not Match (Line, Get_Expr) then
 460             Badfunc;
 461          end if;
 462
 463          Line := Getlin;
 464
 465          if not Match (Line, Chek_End) then
 466             Badfunc;
 467          end if;
 468
 469          Match (Expr, Get_B1, M);
 470          Replace (M, "IN (" & A & ", " & B & ')');
 471          Match (Expr, Get_B2, M);
 472          Replace (M, A & " == " & B);
 473          Match (Expr, Get_B3, M);
 474          Replace (M, A & " != " & B);
 475          Put_Line (Ofile, "");
 476          Sethead (Fline, "");
 477          Put_Line (Ofile, C & "   { return " & Expr & "; }");
 478       end if;
 479    end loop;
 480
 481    Put_Line (Ofile, "");
 482    Put_Line
 483      (Ofile,
 484       "/* End of einfo.h (C version of Einfo package specification) */");
 485
 486 exception
 487    when Err =>
 488       Put_Line (Standard_Error, Lineno & ".  " & Line);
 489       Put_Line (Standard_Error, "**** fatal error ****");
 490       Set_Exit_Status (1);
 491
 492    when End_Error =>
 493       Put_Line (Standard_Error, "unexpected end of file");
 494       Put_Line (Standard_Error, "**** fatal error ****");
 495
 496 end XEinfo;