gcc/ada/s-exngen.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --                       S Y S T E M . E X N _ G E N                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2001, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 package body System.Exn_Gen is
  35
  36    --------------------
  37    -- Exn_Float_Type --
  38    --------------------
  39
  40    function Exn_Float_Type
  41      (Left  : Type_Of_Base;
  42       Right : Integer)
  43       return  Type_Of_Base
  44    is
  45       pragma Suppress (Division_Check);
  46       pragma Suppress (Overflow_Check);
  47       pragma Suppress (Range_Check);
  48
  49       Result : Type_Of_Base := 1.0;
  50       Factor : Type_Of_Base := Left;
  51       Exp    : Integer := Right;
  52
  53    begin
  54       --  We use the standard logarithmic approach, Exp gets shifted right
  55       --  testing successive low order bits and Factor is the value of the
  56       --  base raised to the next power of 2. For positive exponents we
  57       --  multiply the result by this factor, for negative exponents, we
  58       --  Division by this factor.
  59
  60       if Exp >= 0 then
  61          loop
  62             if Exp rem 2 /= 0 then
  63                Result := Result * Factor;
  64             end if;
  65
  66             Exp := Exp / 2;
  67             exit when Exp = 0;
  68             Factor := Factor * Factor;
  69          end loop;
  70
  71          return Result;
  72
  73       --  Negative exponent. For a zero base, we should arguably return an
  74       --  infinity of the right sign, but it is not clear that there is
  75       --  proper authorization to do so, so for now raise Constraint_Error???
  76
  77       elsif Factor = 0.0 then
  78          raise Constraint_Error;
  79
  80       --  Here we have a non-zero base and a negative exponent
  81
  82       else
  83          --  For the negative exponent case, a constraint error during this
  84          --  calculation happens if Factor gets too large, and the proper
  85          --  response is to return 0.0, since what we essentially have is
  86          --  1.0 / infinity, and the closest model number will be zero.
  87
  88          begin
  89             loop
  90                if Exp rem 2 /= 0 then
  91                   Result := Result * Factor;
  92                end if;
  93
  94                Exp := Exp / 2;
  95                exit when Exp = 0;
  96                Factor := Factor * Factor;
  97             end loop;
  98
  99             return 1.0 / Result;
 100
 101          exception
 102
 103             when Constraint_Error =>
 104                return 0.0;
 105          end;
 106       end if;
 107    end Exn_Float_Type;
 108
 109    ----------------------
 110    -- Exn_Integer_Type --
 111    ----------------------
 112
 113    --  Note that negative exponents get a constraint error because the
 114    --  subtype of the Right argument (the exponent) is Natural.
 115
 116    function Exn_Integer_Type
 117      (Left  : Type_Of_Base;
 118       Right : Natural)
 119       return  Type_Of_Base
 120    is
 121       pragma Suppress (Division_Check);
 122       pragma Suppress (Overflow_Check);
 123
 124       Result : Type_Of_Base := 1;
 125       Factor : Type_Of_Base := Left;
 126       Exp    : Natural := Right;
 127
 128    begin
 129       --  We use the standard logarithmic approach, Exp gets shifted right
 130       --  testing successive low order bits and Factor is the value of the
 131       --  base raised to the next power of 2.
 132
 133       --  Note: it is not worth special casing the cases of base values -1,0,+1
 134       --  since the expander does this when the base is a literal, and other
 135       --  cases will be extremely rare.
 136
 137       if Exp /= 0 then
 138          loop
 139             if Exp rem 2 /= 0 then
 140                Result := Result * Factor;
 141             end if;
 142
 143             Exp := Exp / 2;
 144             exit when Exp = 0;
 145             Factor := Factor * Factor;
 146          end loop;
 147       end if;
 148
 149       return Result;
 150    end Exn_Integer_Type;
 151
 152 end System.Exn_Gen;