gcc/ada/s-memory.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                         S Y S T E M . M E M O R Y                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This is the default implementation of this package
  33
  34 --  This implementation assumes that the underlying malloc/free/realloc
  35 --  implementation is thread safe, and thus, no additional lock is required.
  36 --  Note that we still need to defer abort because on most systems, an
  37 --  asynchronous signal (as used for implementing asynchronous abort of
  38 --  task) cannot safely be handled while malloc is executing.
  39
  40 --  If you are not using Ada constructs containing the "abort" keyword, then
  41 --  you can remove the calls to Abort_Defer.all and Abort_Undefer.all from
  42 --  this unit.
  43
  44 pragma Compiler_Unit;
  45
  46 with Ada.Exceptions;
  47 with System.Soft_Links;
  48 with System.Parameters;
  49 with System.CRTL;
  50
  51 package body System.Memory is
  52
  53    use Ada.Exceptions;
  54    use System.Soft_Links;
  55
  56    function c_malloc (Size : System.CRTL.size_t) return System.Address
  57     renames System.CRTL.malloc;
  58
  59    procedure c_free (Ptr : System.Address)
  60      renames System.CRTL.free;
  61
  62    function c_realloc
  63      (Ptr : System.Address; Size : System.CRTL.size_t) return System.Address
  64      renames System.CRTL.realloc;
  65
  66    -----------
  67    -- Alloc --
  68    -----------
  69
  70    function Alloc (Size : size_t) return System.Address is
  71       Result      : System.Address;
  72       Actual_Size : size_t := Size;
  73
  74    begin
  75       if Size = size_t'Last then
  76          Raise_Exception (Storage_Error'Identity, "object too large");
  77       end if;
  78
  79       --  Change size from zero to non-zero. We still want a proper pointer
  80       --  for the zero case because pointers to zero length objects have to
  81       --  be distinct, but we can't just go ahead and allocate zero bytes,
  82       --  since some malloc's return zero for a zero argument.
  83
  84       if Size = 0 then
  85          Actual_Size := 1;
  86       end if;
  87
  88       if Parameters.No_Abort then
  89          Result := c_malloc (System.CRTL.size_t (Actual_Size));
  90       else
  91          Abort_Defer.all;
  92          Result := c_malloc (System.CRTL.size_t (Actual_Size));
  93          Abort_Undefer.all;
  94       end if;
  95
  96       if Result = System.Null_Address then
  97          Raise_Exception (Storage_Error'Identity, "heap exhausted");
  98       end if;
  99
 100       return Result;
 101    end Alloc;
 102
 103    ----------
 104    -- Free --
 105    ----------
 106
 107    procedure Free (Ptr : System.Address) is
 108    begin
 109       if Parameters.No_Abort then
 110          c_free (Ptr);
 111       else
 112          Abort_Defer.all;
 113          c_free (Ptr);
 114          Abort_Undefer.all;
 115       end if;
 116    end Free;
 117
 118    -------------
 119    -- Realloc --
 120    -------------
 121
 122    function Realloc
 123      (Ptr  : System.Address;
 124       Size : size_t)
 125       return System.Address
 126    is
 127       Result      : System.Address;
 128       Actual_Size : constant size_t := Size;
 129
 130    begin
 131       if Size = size_t'Last then
 132          Raise_Exception (Storage_Error'Identity, "object too large");
 133       end if;
 134
 135       if Parameters.No_Abort then
 136          Result := c_realloc (Ptr, System.CRTL.size_t (Actual_Size));
 137       else
 138          Abort_Defer.all;
 139          Result := c_realloc (Ptr, System.CRTL.size_t (Actual_Size));
 140          Abort_Undefer.all;
 141       end if;
 142
 143       if Result = System.Null_Address then
 144          Raise_Exception (Storage_Error'Identity, "heap exhausted");
 145       end if;
 146
 147       return Result;
 148    end Realloc;
 149
 150 end System.Memory;