gcc/ada/a-nudira.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --         A D A . N U M E R I C S . D I S C R E T E _ R A N D O M          --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2006, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  24 -- Boston, MA 02110-1301, USA.                                              --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- GNAT was originally developed  by the GNAT team at  New York University. --
  34 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  35 --                                                                          --
  36 ------------------------------------------------------------------------------
  37
  38 --  Note: the implementation used in this package was contributed by Robert
  39 --  Eachus. It is based on the work of L. Blum, M. Blum, and M. Shub, SIAM
  40 --  Journal of Computing, Vol 15. No 2, May 1986. The particular choices for P
  41 --  and Q chosen here guarantee a period of 562,085,314,430,582 (about 2**49),
  42 --  and the generated sequence has excellent randomness properties. For further
  43 --  details, see the paper "Fast Generation of Trustworthy Random Numbers", by
  44 --  Robert Eachus, which describes both the algorithm and the efficient
  45 --  implementation approach used here.
  46
  47 with Interfaces;
  48
  49 generic
  50    type Result_Subtype is (<>);
  51
  52 package Ada.Numerics.Discrete_Random is
  53
  54    --  The algorithm used here is reliable from a required statistical point of
  55    --  view only up to 48 bits. We try to behave reasonably in the case of
  56    --  larger types, but we can't guarantee the required properties. So
  57    --  generate a warning for these (slightly) dubious cases.
  58
  59    pragma Compile_Time_Warning
  60      (Result_Subtype'Size > 48,
  61       "statistical properties not guaranteed for size > 48");
  62
  63    --  Basic facilities
  64
  65    type Generator is limited private;
  66
  67    function Random (Gen : Generator) return Result_Subtype;
  68
  69    procedure Reset (Gen : Generator);
  70    procedure Reset (Gen : Generator; Initiator : Integer);
  71
  72    --  Advanced facilities
  73
  74    type State is private;
  75
  76    procedure Save  (Gen : Generator; To_State   : out State);
  77    procedure Reset (Gen : Generator; From_State : State);
  78
  79    Max_Image_Width : constant := 80;
  80
  81    function Image (Of_State    : State)  return String;
  82    function Value (Coded_State : String) return State;
  83
  84 private
  85    subtype Int is Interfaces.Integer_32;
  86    subtype Rst is Result_Subtype;
  87
  88    --  We prefer to use 14 digits for Flt, but some targets are more limited
  89
  90    type Flt is digits Positive'Min (14, Long_Long_Float'Digits);
  91
  92    RstF : constant Flt := Flt (Rst'Pos (Rst'First));
  93    RstL : constant Flt := Flt (Rst'Pos (Rst'Last));
  94
  95    Offs : constant Flt := RstF - 0.5;
  96
  97    K1   : constant := 94_833_359;
  98    K1F  : constant := 94_833_359.0;
  99    K2   : constant := 47_416_679;
 100    K2F  : constant := 47_416_679.0;
 101    Scal : constant Flt := (RstL - RstF + 1.0) / (K1F * K2F);
 102
 103    type State is record
 104       X1  : Int := Int (2999 ** 2);
 105       X2  : Int := Int (1439 ** 2);
 106       P   : Int := K1;
 107       Q   : Int := K2;
 108       FP  : Flt := K1F;
 109       Scl : Flt := Scal;
 110    end record;
 111
 112    type Generator is limited record
 113       Gen_State : State;
 114    end record;
 115
 116 end Ada.Numerics.Discrete_Random;