libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/lib-ld.m4)
   8 sinclude(../config/override.m4)
   9 sinclude(../config/picflag.m4)
  10 sinclude(../config/dfp.m4)
  11 sinclude(../config/unwind_ipinfo.m4)
  12 sinclude(../config/gthr.m4)
  13
  14 AC_PREREQ(2.64)
  15 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  16 AC_CONFIG_SRCDIR([static-object.mk])
  17
  18 # The libgcc should not depend on any header files
  19 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  20   [m4_divert_text([DEFAULTS],
  21     [ac_includes_default='/* none */'])])
  22
  23 AC_ARG_WITH(target-subdir,
  24 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  25 AC_ARG_WITH(cross-host,
  26 [  --with-cross-host=HOST           Configuring with a cross compiler])
  27 AC_ARG_WITH(ld,
  28 [  --with-ld               arrange to use the specified ld (full pathname)])
  29
  30 if test "${srcdir}" = "."; then
  31   if test -n "${with_build_subdir}"; then
  32     libgcc_topdir="${srcdir}/../.."
  33     with_target_subdir=
  34   elif test -z "${with_target_subdir}"; then
  35     libgcc_topdir="${srcdir}/.."
  36   else
  37     if test "${with_target_subdir}" != "."; then
  38       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  39     else
  40       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  41     fi
  42   fi
  43 else
  44   libgcc_topdir="${srcdir}/.."
  45 fi
  46 AC_SUBST(libgcc_topdir)
  47 AC_CONFIG_AUX_DIR($libgcc_topdir)
  48 AC_CONFIG_HEADER(auto-target.h:config.in)
  49
  50 AC_ARG_ENABLE(shared,
  51 [  --disable-shared        don't provide a shared libgcc],
  52 [
  53   case $enable_shared in
  54   yes | no) ;;
  55   *)
  56     enable_shared=no
  57     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  58     for pkg in $enableval; do
  59       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  60         enable_shared=yes
  61       fi
  62     done
  63     IFS="$ac_save_ifs"
  64     ;;
  65   esac
  66 ], [enable_shared=yes])
  67 AC_SUBST(enable_shared)
  68
  69 GCC_PICFLAG
  70 AC_SUBST(PICFLAG)
  71
  72 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  73 AC_ARG_ENABLE(version-specific-runtime-libs,
  74 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  75 [case "$enableval" in
  76  yes) version_specific_libs=yes ;;
  77  no)  version_specific_libs=no ;;
  78  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  79  esac],
  80 [version_specific_libs=no])
  81 AC_MSG_RESULT($version_specific_libs)
  82
  83 AC_ARG_WITH(slibdir,
  84 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
  85 slibdir="$with_slibdir",
  86 if test "${version_specific_libs}" = yes; then
  87   slibdir='$(libsubdir)'
  88 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
  89   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
  90 else
  91   slibdir='$(libdir)'
  92 fi)
  93 AC_SUBST(slibdir)
  94
  95 # Command-line options.
  96 # Very limited version of AC_MAINTAINER_MODE.
  97 AC_ARG_ENABLE([maintainer-mode],
  98   [AC_HELP_STRING([--enable-maintainer-mode],
  99                  [enable make rules and dependencies not useful (and
 100                   sometimes confusing) to the casual installer])],
 101   [case ${enable_maintainer_mode} in
 102      yes) MAINT='' ;;
 103      no) MAINT='#' ;;
 104      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 105    esac
 106    maintainer_mode=${enableval}],
 107   [MAINT='#'])
 108 AC_SUBST([MAINT])dnl
 109
 110 AC_PROG_INSTALL
 111
 112 AC_PROG_AWK
 113 # We need awk; bail out if it's missing.
 114 case ${AWK} in
 115   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 116 esac
 117
 118 AC_CANONICAL_HOST
 119 ACX_NONCANONICAL_HOST
 120 ACX_NONCANONICAL_TARGET
 121 GCC_TOPLEV_SUBDIRS
 122
 123 # Calculate toolexeclibdir
 124 # Also toolexecdir, though it's only used in toolexeclibdir
 125 case ${version_specific_libs} in
 126   yes)
 127     # Need the gcc compiler version to know where to install libraries
 128     # and header files if --enable-version-specific-runtime-libs option
 129     # is selected.
 130     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 131     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 132     ;;
 133   no)
 134     if test -n "$with_cross_host" &&
 135        test x"$with_cross_host" != x"no"; then
 136       # Install a library built with a cross compiler in tooldir, not libdir.
 137       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 138       toolexeclibdir='$(toolexecdir)/lib'
 139     else
 140       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 141       toolexeclibdir='$(libdir)'
 142     fi
 143     multi_os_directory=`$CC -print-multi-os-directory`
 144     case $multi_os_directory in
 145       .) ;; # Avoid trailing /.
 146       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 147     esac
 148     ;;
 149 esac
 150 AC_SUBST(toolexecdir)
 151 AC_SUBST(toolexeclibdir)
 152
 153 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 154 dnl to call AC_CHECK_PROG.
 155 AC_CHECK_TOOL(AR, ar)
 156 AC_CHECK_TOOL(LIPO, lipo, :)
 157 AC_CHECK_TOOL(NM, nm)
 158 AC_CHECK_TOOL(RANLIB, ranlib, :)
 159 AC_CHECK_TOOL(STRIP, strip, :)
 160 AC_PROG_LN_S
 161
 162 GCC_NO_EXECUTABLES
 163 AC_PROG_CC
 164 AC_PROG_CPP_WERROR
 165
 166 AC_CHECK_SIZEOF([double])
 167 AC_CHECK_SIZEOF([long double])
 168 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 169 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 170 AC_SUBST(double_type_size)
 171 AC_SUBST(long_double_type_size)
 172
 173 # Check for decimal float support.
 174 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 175                [AC_COMPILE_IFELSE([_Decimal32 x;], [libgcc_cv_dfp=yes],
 176                                   [libgcc_cv_dfp=no])])
 177 decimal_float=$libgcc_cv_dfp
 178 AC_SUBST(decimal_float)
 179
 180 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 181
 182 # Check for fixed-point support.
 183 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 184                [AC_COMPILE_IFELSE([_Sat _Fract x;], [libgcc_cv_fixed_point=yes],
 185                                   [libgcc_cv_fixed_point=no])])
 186 fixed_point=$libgcc_cv_fixed_point
 187 AC_SUBST(fixed_point)
 188
 189 # For platforms with the unwind ABI which includes an unwind library,
 190 # libunwind, we can choose to use the system libunwind.
 191 # config.gcc also contains tests of with_system_libunwind.
 192 GCC_CHECK_UNWIND_GETIPINFO
 193
 194 # The sjlj test is almost duplicated here and in libgo/configure.ac (for C),
 195 # libstdc++-v3/acinclude.m4 and libjava/configure.ac (for C++), and
 196 # libobjc/configure.ac (for Objective-C).
 197 # FIXME: This should be centralized in config/sjlj.m4.
 198 AC_ARG_ENABLE(sjlj-exceptions,
 199   AC_HELP_STRING([--enable-sjlj-exceptions],
 200                  [force use of builtin_setjmp for exceptions]),
 201   [case "$enableval" in
 202    yes|no|auto) ;;
 203    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 204    esac],
 205   [enable_sjlj_exceptions=auto])
 206
 207 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 208 [libgcc_cv_lib_sjlj_exceptions],
 209 [AC_LANG_CONFTEST(
 210   [AC_LANG_SOURCE([
 211 void bar ();
 212 void clean (int *);
 213 void foo ()
 214 {
 215   int i __attribute__ ((cleanup (clean)));
 216   bar();
 217 }
 218 ])])
 219 CFLAGS_hold=$CFLAGS
 220 CFLAGS="--save-temps -fexceptions"
 221 libgcc_cv_lib_sjlj_exceptions=unknown
 222 AS_IF([ac_fn_c_try_compile],
 223   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 224     libgcc_cv_lib_sjlj_exceptions=yes
 225   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 226     libgcc_cv_lib_sjlj_exceptions=no
 227   fi])
 228 CFLAGS=$CFLAGS_hold
 229 rm -f conftest*
 230 ])
 231
 232 if test "$enable_sjlj_exceptions" = "auto"; then
 233   enable_sjlj_exceptions=$libgcc_cv_lib_sjlj_exceptions
 234 fi
 235
 236 case $enable_sjlj_exceptions in
 237 yes)
 238   AC_DEFINE(LIBGCC_SJLJ_EXCEPTIONS, 1,
 239         [Define if the C compiler is configured for setjmp/longjmp exceptions.])
 240   ;;
 241 no)
 242   ;;
 243 *)
 244   AC_MSG_ERROR([unable to detect exception model])
 245   ;;
 246 esac
 247
 248 AC_LIB_PROG_LD_GNU
 249
 250 AC_MSG_CHECKING([for thread model used by GCC])
 251 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 252 AC_MSG_RESULT([$target_thread_file])
 253
 254 # Check for assembler CFI support.
 255 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 256                [AC_COMPILE_IFELSE(
 257 [asm("\n\
 258         .text\n\
 259         .cfi_startproc\n\
 260         .cfi_personality 0, symbol\n\
 261         .cfi_endproc");],
 262   [libgcc_cv_cfi=yes],
 263   [libgcc_cv_cfi=no])])
 264
 265 # Check 32bit or 64bit
 266 cat > conftest.c <<EOF
 267 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__))
 268 host_address=64
 269 #else
 270 host_address=32
 271 #endif
 272 EOF
 273 eval `${CC-cc} -E conftest.c | grep host_address=`
 274 rm -f conftest.c
 275
 276 # Collect host-machine-specific information.
 277 . ${srcdir}/config.host
 278
 279 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 280 # This is after config.host so we can augment tmake_file.
 281 # Link with -nostartfiles -nodefaultlibs since neither are present while
 282 # building libgcc.
 283 case ${host} in
 284 i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 285   cat > conftest.s <<EOF
 286         .section        .eh_frame,"a",@unwind
 287         .zero   4
 288         .section        .jcr,"aw",@progbits
 289         .zero   8
 290 EOF
 291   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 292       tmake_file="${tmake_file} i386/t-crtstuff"
 293   fi
 294   ;;
 295 esac
 296
 297 # Check for visibility support.  This is after config.host so that
 298 # we can check for asm_hidden_op.
 299 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 300     libgcc_cv_hidden_visibility_attribute, [
 301         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 302         libgcc_cv_hidden_visibility_attribute=no
 303         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 304             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 305                 libgcc_cv_hidden_visibility_attribute=yes
 306             fi
 307         fi
 308         rm -f conftest.*
 309     ])
 310
 311 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 312     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 313 else
 314     vis_hide=
 315 fi
 316 AC_SUBST(vis_hide)
 317
 318 # See if we have thread-local storage.  We can only test assembler
 319 # since link-time and run-time tests require the newly built
 320 # gcc, which can't be used to build executable due to that libgcc
 321 # is yet to be built here.
 322 GCC_CHECK_CC_TLS
 323 set_have_cc_tls=
 324 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 325   set_have_cc_tls="-DHAVE_CC_TLS"
 326 fi
 327 AC_SUBST(set_have_cc_tls)
 328
 329 # See if we have emulated thread-local storage.
 330 GCC_CHECK_EMUTLS
 331 set_use_emutls=
 332 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 333   set_use_emutls="-DUSE_EMUTLS"
 334 fi
 335 AC_SUBST(set_use_emutls)
 336
 337 AC_CACHE_CHECK(for init priority support, libgcc_cv_init_priority, [
 338 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,
 339   [[void ip (void) __attribute__ ((constructor (1)));]])],
 340   [libgcc_cv_init_priority=yes],[libgcc_cv_init_priority=no])])
 341 if test $libgcc_cv_init_priority = yes; then
 342   AC_DEFINE(HAVE_INIT_PRIORITY, 1,
 343   [Define if the compiler supports init priority.])
 344 fi
 345
 346 # Conditionalize the sfp-machine.h header for this target machine.
 347 if test -z "${sfp_machine_header}"; then
 348         sfp_machine_header=$cpu_type/sfp-machine.h
 349         if test -f ${srcdir}/config/${sfp_machine_header}; then
 350                 :
 351         else
 352                 sfp_machine_header=no-sfp-machine.h
 353         fi
 354 fi
 355 AC_SUBST(sfp_machine_header)
 356
 357 # Conditionalize the makefile for this target machine.
 358 tmake_file_=
 359 for f in ${tmake_file}
 360 do
 361         if test -f ${srcdir}/config/$f
 362         then
 363                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 364         fi
 365 done
 366 tmake_file="${tmake_file_}"
 367 AC_SUBST(tmake_file)
 368
 369 # Likewise export definitions for libgcc_tm.h
 370 tm_file_=
 371 for f in ${tm_file}
 372 do
 373         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 374 done
 375 tm_file="${tm_file_}"
 376 AC_SUBST(tm_file)
 377 AC_SUBST(tm_defines)
 378
 379 # Map from thread model to thread header.
 380 GCC_AC_THREAD_HEADER([$target_thread_file])
 381
 382 # Substitute configuration variables
 383 AC_SUBST(cpu_type)
 384 AC_SUBST(extra_parts)
 385 AC_SUBST(asm_hidden_op)
 386 AC_CONFIG_LINKS([enable-execute-stack.c:$enable_execute_stack])
 387 AC_CONFIG_LINKS([unwind.h:$unwind_header])
 388 AC_CONFIG_LINKS([md-unwind-support.h:config/$md_unwind_header])
 389 AC_CONFIG_LINKS([sfp-machine.h:config/$sfp_machine_header])
 390 AC_CONFIG_LINKS([gthr-default.h:$thread_header])
 391
 392 # We need multilib support.
 393 AC_CONFIG_FILES([Makefile])
 394 AC_CONFIG_COMMANDS([default],
 395   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 396 if test -n "$CONFIG_FILES"; then
 397   # FIXME: We shouldn't need to set ac_file
 398   ac_file=Makefile
 399   . ${libgcc_topdir}/config-ml.in
 400 fi]],
 401 [[srcdir=${srcdir}
 402 host=${host}
 403 with_target_subdir=${with_target_subdir}
 404 with_multisubdir=${with_multisubdir}
 405 ac_configure_args="--enable-multilib ${ac_configure_args}"
 406 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 407 libgcc_topdir=${libgcc_topdir}
 408 CC="${CC}"
 409 ]])
 410 AC_OUTPUT