gcc/ada/s-intman-posix.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --           S Y S T E M . I N T E R R U P T _ M A N A G E M E N T          --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This is the POSIX threads version of this package
  35
  36 --  Make a careful study of all signals available under the OS, to see which
  37 --  need to be reserved, kept always unmasked, or kept always unmasked. Be on
  38 --  the lookout for special signals that may be used by the thread library.
  39
  40 --  Since this is a multi target file, the signal <-> exception mapping
  41 --  is simple minded. If you need a more precise and target specific
  42 --  signal handling, create a new s-intman.adb that will fit your needs.
  43
  44 --  This file assumes that:
  45
  46 --    SIGFPE, SIGILL, SIGSEGV and SIGBUS exist. They are mapped as follows:
  47 --      SIGPFE  => Constraint_Error
  48 --      SIGILL  => Program_Error
  49 --      SIGSEGV => Storage_Error
  50 --      SIGBUS  => Storage_Error
  51
  52 --    SIGINT exists and will be kept unmasked unless the pragma
  53 --     Unreserve_All_Interrupts is specified anywhere in the application.
  54
  55 --    System.OS_Interface contains the following:
  56 --      SIGADAABORT: the signal that will be used to abort tasks.
  57 --      Unmasked: the OS specific set of signals that should be unmasked in
  58 --                all the threads. SIGADAABORT is unmasked by
  59 --                default
  60 --      Reserved: the OS specific set of signals that are reserved.
  61
  62 package body System.Interrupt_Management is
  63
  64    use Interfaces.C;
  65    use System.OS_Interface;
  66
  67    type Interrupt_List is array (Interrupt_ID range <>) of Interrupt_ID;
  68    Exception_Interrupts : constant Interrupt_List :=
  69      (SIGFPE, SIGILL, SIGSEGV, SIGBUS);
  70
  71    Unreserve_All_Interrupts : Interfaces.C.int;
  72    pragma Import
  73      (C, Unreserve_All_Interrupts, "__gl_unreserve_all_interrupts");
  74
  75    -----------------------
  76    -- Local Subprograms --
  77    -----------------------
  78
  79    function State (Int : Interrupt_ID) return Character;
  80    pragma Import (C, State, "__gnat_get_interrupt_state");
  81    --  Get interrupt state. Defined in init.c The input argument is the
  82    --  interrupt number, and the result is one of the following:
  83
  84    User    : constant Character := 'u';
  85    Runtime : constant Character := 'r';
  86    Default : constant Character := 's';
  87    --    'n'   this interrupt not set by any Interrupt_State pragma
  88    --    'u'   Interrupt_State pragma set state to User
  89    --    'r'   Interrupt_State pragma set state to Runtime
  90    --    's'   Interrupt_State pragma set state to System (use "default"
  91    --           system handler)
  92
  93    procedure Notify_Exception
  94      (signo    : Signal;
  95       siginfo  : System.Address;
  96       ucontext : System.Address);
  97    --  This function identifies the Ada exception to be raised using the
  98    --  information when the system received a synchronous signal. Since this
  99    --  function is machine and OS dependent, different code has to be provided
 100    --  for different target.
 101
 102    ----------------------
 103    -- Notify_Exception --
 104    ----------------------
 105
 106    Signal_Mask : aliased sigset_t;
 107    --  The set of signals handled by Notify_Exception
 108
 109    procedure Notify_Exception
 110      (signo    : Signal;
 111       siginfo  : System.Address;
 112       ucontext : System.Address)
 113    is
 114       pragma Unreferenced (siginfo);
 115
 116       Result : Interfaces.C.int;
 117
 118    begin
 119       --  With the __builtin_longjmp, the signal mask is not restored, so we
 120       --  need to restore it explicitely.
 121
 122       Result := pthread_sigmask (SIG_UNBLOCK, Signal_Mask'Access, null);
 123       pragma Assert (Result = 0);
 124
 125       --  Perform the necessary context adjustments prior to a raise
 126       --  from a signal handler.
 127
 128       Adjust_Context_For_Raise (signo, ucontext);
 129
 130       --  Check that treatment of exception propagation here is consistent with
 131       --  treatment of the abort signal in System.Task_Primitives.Operations.
 132
 133       case signo is
 134          when SIGFPE =>
 135             raise Constraint_Error;
 136          when SIGILL =>
 137             raise Program_Error;
 138          when SIGSEGV =>
 139             raise Storage_Error;
 140          when SIGBUS =>
 141             raise Storage_Error;
 142          when others =>
 143             null;
 144       end case;
 145    end Notify_Exception;
 146
 147    ----------------
 148    -- Initialize --
 149    ----------------
 150
 151    Initialized : Boolean := False;
 152
 153    procedure Initialize is
 154       act     : aliased struct_sigaction;
 155       old_act : aliased struct_sigaction;
 156       Result  : System.OS_Interface.int;
 157
 158    begin
 159       if Initialized then
 160          return;
 161       end if;
 162
 163       Initialized := True;
 164
 165       --  Need to call pthread_init very early because it is doing signal
 166       --  initializations.
 167
 168       pthread_init;
 169
 170       Abort_Task_Interrupt := SIGADAABORT;
 171
 172       act.sa_handler := Notify_Exception'Address;
 173
 174       act.sa_flags := SA_SIGINFO;
 175
 176       --  Setting SA_SIGINFO asks the kernel to pass more than just the signal
 177       --  number argument to the handler when it is called. The set of extra
 178       --  parameters includes a pointer to the interrupted context, which the
 179       --  ZCX propagation scheme needs.
 180
 181       --  Most man pages for sigaction mention that sa_sigaction should be set
 182       --  instead of sa_handler when SA_SIGINFO is on.  In practice, the two
 183       --  fields are actually union'ed and located at the same offset.
 184
 185       --  On some targets, we set sa_flags to SA_NODEFER so that during the
 186       --  handler execution we do not change the Signal_Mask to be masked for
 187       --  the Signal.
 188
 189       --  This is a temporary fix to the problem that the Signal_Mask is not
 190       --  restored after the exception (longjmp) from the handler. The right
 191       --  fix should be made in sigsetjmp so that we save the Signal_Set and
 192       --  restore it after a longjmp.
 193
 194       --  Since SA_NODEFER is obsolete, instead we reset explicitely the mask
 195       --  in the exception handler.
 196
 197       Result := sigemptyset (Signal_Mask'Access);
 198       pragma Assert (Result = 0);
 199
 200       --  Add signals that map to Ada exceptions to the mask
 201
 202       for J in Exception_Interrupts'Range loop
 203          if State (Exception_Interrupts (J)) /= Default  then
 204             Result :=
 205             sigaddset (Signal_Mask'Access, Signal (Exception_Interrupts (J)));
 206             pragma Assert (Result = 0);
 207          end if;
 208       end loop;
 209
 210       act.sa_mask := Signal_Mask;
 211
 212       pragma Assert (Keep_Unmasked = (Interrupt_ID'Range => False));
 213       pragma Assert (Reserve = (Interrupt_ID'Range => False));
 214
 215       --  Process state of exception signals
 216
 217       for J in Exception_Interrupts'Range loop
 218          if State (Exception_Interrupts (J)) /= User then
 219             Keep_Unmasked (Exception_Interrupts (J)) := True;
 220             Reserve (Exception_Interrupts (J)) := True;
 221
 222             if State (Exception_Interrupts (J)) /= Default then
 223                Result :=
 224                  sigaction
 225                  (Signal (Exception_Interrupts (J)), act'Unchecked_Access,
 226                   old_act'Unchecked_Access);
 227                pragma Assert (Result = 0);
 228             end if;
 229          end if;
 230       end loop;
 231
 232       if State (Abort_Task_Interrupt) /= User then
 233          Keep_Unmasked (Abort_Task_Interrupt) := True;
 234          Reserve (Abort_Task_Interrupt) := True;
 235       end if;
 236
 237       --  Set SIGINT to unmasked state as long as it is not in "User" state.
 238       --  Check for Unreserve_All_Interrupts last
 239
 240       if State (SIGINT) /= User then
 241          Keep_Unmasked (SIGINT) := True;
 242          Reserve (SIGINT) := True;
 243       end if;
 244
 245       --  Check all signals for state that requires keeping them unmasked and
 246       --  reserved
 247
 248       for J in Interrupt_ID'Range loop
 249          if State (J) = Default or else State (J) = Runtime then
 250             Keep_Unmasked (J) := True;
 251             Reserve (J) := True;
 252          end if;
 253       end loop;
 254
 255       --  Add the set of signals that must always be unmasked for this target
 256
 257       for J in Unmasked'Range loop
 258          Keep_Unmasked (Interrupt_ID (Unmasked (J))) := True;
 259          Reserve (Interrupt_ID (Unmasked (J))) := True;
 260       end loop;
 261
 262       --  Add target-specific reserved signals
 263
 264       for J in Reserved'Range loop
 265          Reserve (Interrupt_ID (Reserved (J))) := True;
 266       end loop;
 267
 268       --  Process pragma Unreserve_All_Interrupts. This overrides any settings
 269       --  due to pragma Interrupt_State:
 270
 271       if Unreserve_All_Interrupts /= 0 then
 272          Keep_Unmasked (SIGINT) := False;
 273          Reserve (SIGINT) := False;
 274       end if;
 275
 276       --  We do not really have Signal 0. We just use this value to identify
 277       --  non-existent signals (see s-intnam.ads). Therefore, Signal should not
 278       --  be used in all signal related operations hence mark it as reserved.
 279
 280       Reserve (0) := True;
 281    end Initialize;
 282
 283 end System.Interrupt_Management;