gcc/ada/s-intman-posix.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS               --
   4 --                                                                          --
   5 --           S Y S T E M . I N T E R R U P T _ M A N A G E M E N T          --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2003, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This is the POSIX threads version of this package
  35
  36 --  PLEASE DO NOT add any dependences on other packages. ??? why not ???
  37 --  This package is designed to work with or without tasking support.
  38
  39 --  See the other warnings in the package specification before making
  40 --  any modifications to this file.
  41
  42 --  Make a careful study of all signals available under the OS, to see which
  43 --  need to be reserved, kept always unmasked, or kept always unmasked. Be on
  44 --  the lookout for special signals that may be used by the thread library.
  45
  46 --  Since this is a multi target file, the signal <-> exception mapping
  47 --  is simple minded. If you need a more precise and target specific
  48 --  signal handling, create a new s-intman.adb that will fit your needs.
  49
  50 --  This file assumes that:
  51
  52 --    SIGFPE, SIGILL, SIGSEGV and SIGBUS exist. They are mapped as follows:
  53 --      SIGPFE  => Constraint_Error
  54 --      SIGILL  => Program_Error
  55 --      SIGSEGV => Storage_Error
  56 --      SIGBUS  => Storage_Error
  57
  58 --    SIGINT exists and will be kept unmasked unless the pragma
  59 --     Unreserve_All_Interrupts is specified anywhere in the application.
  60
  61 --    System.OS_Interface contains the following:
  62 --      SIGADAABORT: the signal that will be used to abort tasks.
  63 --      Unmasked: the OS specific set of signals that should be unmasked in
  64 --                all the threads. SIGADAABORT is unmasked by
  65 --                default
  66 --      Reserved: the OS specific set of signals that are reserved.
  67
  68 with Interfaces.C;
  69 --  used for int and other types
  70
  71 with System.OS_Interface;
  72 --  used for various Constants, Signal and types
  73
  74 package body System.Interrupt_Management is
  75
  76    use Interfaces.C;
  77    use System.OS_Interface;
  78
  79    type Interrupt_List is array (Interrupt_ID range <>) of Interrupt_ID;
  80    Exception_Interrupts : constant Interrupt_List :=
  81      (SIGFPE, SIGILL, SIGSEGV, SIGBUS);
  82
  83    Unreserve_All_Interrupts : Interfaces.C.int;
  84    pragma Import
  85      (C, Unreserve_All_Interrupts, "__gl_unreserve_all_interrupts");
  86
  87    -----------------------
  88    -- Local Subprograms --
  89    -----------------------
  90
  91    procedure Notify_Exception (signo : Signal);
  92    --  This function identifies the Ada exception to be raised using
  93    --  the information when the system received a synchronous signal.
  94    --  Since this function is machine and OS dependent, different code
  95    --  has to be provided for different target.
  96
  97    ----------------------
  98    -- Notify_Exception --
  99    ----------------------
 100
 101    Signal_Mask : aliased sigset_t;
 102    --  The set of signals handled by Notify_Exception
 103
 104    procedure Notify_Exception (signo : Signal) is
 105       Result  : Interfaces.C.int;
 106
 107    begin
 108       --  With the __builtin_longjmp, the signal mask is not restored, so we
 109       --  need to restore it explicitely.
 110
 111       Result := pthread_sigmask (SIG_UNBLOCK, Signal_Mask'Access, null);
 112       pragma Assert (Result = 0);
 113
 114       --  Check that treatment of exception propagation here
 115       --  is consistent with treatment of the abort signal in
 116       --  System.Task_Primitives.Operations.
 117
 118       case signo is
 119          when SIGFPE =>
 120             raise Constraint_Error;
 121          when SIGILL =>
 122             raise Program_Error;
 123          when SIGSEGV =>
 124             raise Storage_Error;
 125          when SIGBUS =>
 126             raise Storage_Error;
 127          when others =>
 128             null;
 129       end case;
 130    end Notify_Exception;
 131
 132    ---------------------------
 133    -- Initialize_Interrupts --
 134    ---------------------------
 135
 136    --  Nothing needs to be done on this platform.
 137
 138    procedure Initialize_Interrupts is
 139    begin
 140       null;
 141    end Initialize_Interrupts;
 142
 143 -------------------------
 144 -- Package Elaboration --
 145 -------------------------
 146
 147 begin
 148    declare
 149       act     : aliased struct_sigaction;
 150       old_act : aliased struct_sigaction;
 151       Result  : System.OS_Interface.int;
 152
 153       function State (Int : Interrupt_ID) return Character;
 154       pragma Import (C, State, "__gnat_get_interrupt_state");
 155       --  Get interrupt state. Defined in a-init.c
 156       --  The input argument is the interrupt number,
 157       --  and the result is one of the following:
 158
 159       User    : constant Character := 'u';
 160       Runtime : constant Character := 'r';
 161       Default : constant Character := 's';
 162       --    'n'   this interrupt not set by any Interrupt_State pragma
 163       --    'u'   Interrupt_State pragma set state to User
 164       --    'r'   Interrupt_State pragma set state to Runtime
 165       --    's'   Interrupt_State pragma set state to System (use "default"
 166       --           system handler)
 167
 168    begin
 169       --  Need to call pthread_init very early because it is doing signal
 170       --  initializations.
 171
 172       pthread_init;
 173
 174       Abort_Task_Interrupt := SIGADAABORT;
 175
 176       act.sa_handler := Notify_Exception'Address;
 177
 178       act.sa_flags := SA_SIGINFO;
 179
 180       --  Setting SA_SIGINFO asks the kernel to pass more than just the signal
 181       --  number argument to the handler when it is called. The set of extra
 182       --  parameters typically includes a pointer to a structure describing
 183       --  the interrupted context. Although the Notify_Exception handler does
 184       --  not use this information, it is actually required for the GCC/ZCX
 185       --  exception propagation scheme because on some targets (at least
 186       --  alpha-tru64), the structure contents are not even filled when this
 187       --  flag is not set.
 188
 189       --  On some targets, we set sa_flags to SA_NODEFER so that during the
 190       --  handler execution we do not change the Signal_Mask to be masked for
 191       --  the Signal.
 192
 193       --  This is a temporary fix to the problem that the Signal_Mask is
 194       --  not restored after the exception (longjmp) from the handler.
 195       --  The right fix should be made in sigsetjmp so that we save
 196       --  the Signal_Set and restore it after a longjmp.
 197
 198       --  Since SA_NODEFER is obsolete, instead we reset explicitely
 199       --  the mask in the exception handler.
 200
 201       Result := sigemptyset (Signal_Mask'Access);
 202       pragma Assert (Result = 0);
 203
 204       --  Add signals that map to Ada exceptions to the mask.
 205       for J in Exception_Interrupts'Range loop
 206          if State (Exception_Interrupts (J)) /= Default  then
 207             Result :=
 208             sigaddset (Signal_Mask'Access, Signal (Exception_Interrupts (J)));
 209             pragma Assert (Result = 0);
 210          end if;
 211       end loop;
 212
 213       act.sa_mask := Signal_Mask;
 214
 215       pragma Assert (Keep_Unmasked = (Interrupt_ID'Range => False));
 216       pragma Assert (Reserve = (Interrupt_ID'Range => False));
 217
 218       --  Process state of exception signals
 219       for J in Exception_Interrupts'Range loop
 220          if State (Exception_Interrupts (J)) /= User then
 221             Keep_Unmasked (Exception_Interrupts (J)) := True;
 222             Reserve (Exception_Interrupts (J)) := True;
 223
 224             if State (Exception_Interrupts (J)) /= Default then
 225                Result :=
 226                  sigaction
 227                  (Signal (Exception_Interrupts (J)), act'Unchecked_Access,
 228                   old_act'Unchecked_Access);
 229                pragma Assert (Result = 0);
 230             end if;
 231          end if;
 232       end loop;
 233
 234       if State (Abort_Task_Interrupt) /= User then
 235          Keep_Unmasked (Abort_Task_Interrupt) := True;
 236          Reserve (Abort_Task_Interrupt) := True;
 237       end if;
 238
 239       --  Set SIGINT to unmasked state as long as it is not in "User"
 240       --  state. Check for Unreserve_All_Interrupts last
 241
 242       if State (SIGINT) /= User then
 243          Keep_Unmasked (SIGINT) := True;
 244          Reserve (SIGINT) := True;
 245       end if;
 246
 247       --  Check all signals for state that requires keeping them
 248       --  unmasked and reserved
 249
 250       for J in Interrupt_ID'Range loop
 251          if State (J) = Default or else State (J) = Runtime then
 252             Keep_Unmasked (J) := True;
 253             Reserve (J) := True;
 254          end if;
 255       end loop;
 256
 257       --  Add the set of signals that must always be unmasked for this target
 258
 259       for J in Unmasked'Range loop
 260          Keep_Unmasked (Interrupt_ID (Unmasked (J))) := True;
 261          Reserve (Interrupt_ID (Unmasked (J))) := True;
 262       end loop;
 263
 264       --  Add target-specific reserved signals
 265
 266       for J in Reserved'Range loop
 267          Reserve (Interrupt_ID (Reserved (J))) := True;
 268       end loop;
 269
 270       --  Process pragma Unreserve_All_Interrupts. This overrides any
 271       --  settings due to pragma Interrupt_State:
 272
 273       if Unreserve_All_Interrupts /= 0 then
 274          Keep_Unmasked (SIGINT) := False;
 275          Reserve (SIGINT) := False;
 276       end if;
 277
 278       --  We do not have Signal 0 in reality. We just use this value
 279       --  to identify non-existent signals (see s-intnam.ads). Therefore,
 280       --  Signal 0 should not be used in all signal related operations hence
 281       --  mark it as reserved.
 282
 283       Reserve (0) := True;
 284    end;
 285 end System.Interrupt_Management;