gcc/ada/a-dirval-mingw.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --             A D A . D I R E C T O R I E S . V A L I D I T Y              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                            (Windows Version)                             --
   9 --                                                                          --
  10 --          Copyright (C) 2004 Free Software Foundation, Inc.               --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNAT was originally developed  by the GNAT team at  New York University. --
  31 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  This is the Windows version of this package
  36
  37 with Ada.Characters.Latin_1; use Ada.Characters.Latin_1;
  38
  39 package body Ada.Directories.Validity is
  40
  41    Invalid_Character : constant array (Character) of Boolean :=
  42                          (NUL .. US | '\'       => True,
  43                           '/' | ':' | '*' | '?' => True,
  44                           '"' | '<' | '>' | '|' => True,
  45                           DEL .. NBSP           => True,
  46                           others                => False);
  47
  48    ---------------------------------
  49    -- Is_Path_Name_Case_Sensitive --
  50    ---------------------------------
  51
  52    function Is_Path_Name_Case_Sensitive return Boolean is
  53    begin
  54       return False;
  55    end Is_Path_Name_Case_Sensitive;
  56
  57    ------------------------
  58    -- Is_Valid_Path_Name --
  59    ------------------------
  60
  61    function Is_Valid_Path_Name (Name : String) return Boolean is
  62       Start : Positive := Name'First;
  63       Last  : Natural;
  64
  65    begin
  66       --  A path name cannot be empty, cannot contain more than 256 characters,
  67       --  cannot contain invalid characters and each directory/file name need
  68       --  to be valid.
  69
  70       if Name'Length = 0 or else Name'Length > 256 then
  71          return False;
  72
  73       else
  74          --  A drive letter may be specified at the beginning
  75
  76          if Name'Length >= 2
  77            and then  Name (Start + 1) = ':'
  78            and then
  79             (Name (Start) in 'A' .. 'Z' or else
  80              Name (Start) in 'a' .. 'z')
  81          then
  82             Start := Start + 2;
  83          end if;
  84
  85          loop
  86             --  Look for the start of the next directory or file name
  87
  88             while Start <= Name'Last and then
  89               (Name (Start) = '\' or Name (Start) = '/')
  90             loop
  91                Start := Start + 1;
  92             end loop;
  93
  94             --  If all directories/file names are OK, return True
  95
  96             exit when Start > Name'Last;
  97
  98             Last := Start;
  99
 100             --  Look for the end of the directory/file name
 101
 102             while Last < Name'Last loop
 103                exit when Name (Last + 1) = '\' or Name (Last + 1) = '/';
 104                Last := Last + 1;
 105             end loop;
 106
 107             --  Check if the directory/file name is valid
 108
 109             if not Is_Valid_Simple_Name (Name (Start .. Last)) then
 110                   return False;
 111             end if;
 112
 113             --  Move to the next name
 114
 115             Start := Last + 1;
 116          end loop;
 117       end if;
 118
 119       --  If Name follows the rules, it is valid
 120
 121       return True;
 122    end Is_Valid_Path_Name;
 123
 124    --------------------------
 125    -- Is_Valid_Simple_Name --
 126    --------------------------
 127
 128    function Is_Valid_Simple_Name (Name : String) return Boolean is
 129       Only_Spaces : Boolean;
 130
 131    begin
 132       --  A file name cannot be empty, cannot contain more than 256 characters,
 133       --  and cannot contain invalid characters.
 134
 135       if Name'Length = 0 or else Name'Length > 256 then
 136          return False;
 137
 138       --  Name length is OK
 139
 140       else
 141          Only_Spaces := True;
 142          for J in Name'Range loop
 143             if Invalid_Character (Name (J)) then
 144                return False;
 145             elsif Name (J) /= ' ' then
 146                Only_Spaces := False;
 147             end if;
 148          end loop;
 149
 150          --  If no invalid chars, and not all spaces, file name is valid.
 151
 152          return not Only_Spaces;
 153       end if;
 154    end Is_Valid_Simple_Name;
 155
 156 end Ada.Directories.Validity;