gcc/ada/sinput-c.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S I N P U T . C                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2004 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Ada.Unchecked_Conversion;
  28
  29 with GNAT.OS_Lib; use GNAT.OS_Lib;
  30 with Namet;       use Namet;
  31 with Opt;         use Opt;
  32 with System;      use System;
  33
  34 package body Sinput.C is
  35
  36    ---------------
  37    -- Load_File --
  38    ---------------
  39
  40    function Load_File (Path : String) return Source_File_Index is
  41       Src  : Source_Buffer_Ptr;
  42       X    : Source_File_Index;
  43       Lo   : Source_Ptr;
  44       Hi   : Source_Ptr;
  45
  46       Source_File_FD : File_Descriptor;
  47       --  The file descriptor for the current source file. A negative value
  48       --  indicates failure to open the specified source file.
  49
  50       Len : Integer;
  51       --  Length of file. Assume no more than 2 gigabytes of source!
  52
  53       Actual_Len : Integer;
  54
  55       Path_Id : Name_Id;
  56       File_Id : Name_Id;
  57
  58    begin
  59       if Path = "" then
  60          return No_Source_File;
  61       end if;
  62
  63       Source_File.Increment_Last;
  64       X := Source_File.Last;
  65
  66       if X = Source_File.First then
  67          Lo := First_Source_Ptr;
  68       else
  69          Lo := Source_File.Table (X - 1).Source_Last + 1;
  70       end if;
  71
  72       Name_Len := Path'Length;
  73       Name_Buffer (1 .. Name_Len) := Path;
  74       Path_Id := Name_Find;
  75       Name_Buffer (Name_Len + 1) := ASCII.NUL;
  76
  77       --  Open the source FD, note that we open in binary mode, because as
  78       --  documented in the spec, the caller is expected to handle either
  79       --  DOS or Unix mode files, and there is no point in wasting time on
  80       --  text translation when it is not required.
  81
  82       Source_File_FD := Open_Read (Name_Buffer'Address, Binary);
  83
  84       if Source_File_FD = Invalid_FD then
  85          Source_File.Decrement_Last;
  86          return No_Source_File;
  87
  88       end if;
  89
  90       Len := Integer (File_Length (Source_File_FD));
  91
  92       --  Set Hi so that length is one more than the physical length,
  93       --  allowing for the extra EOF character at the end of the buffer
  94
  95       Hi := Lo + Source_Ptr (Len);
  96
  97       --  Do the actual read operation
  98
  99       declare
 100          subtype Actual_Source_Buffer is Source_Buffer (Lo .. Hi);
 101          --  Physical buffer allocated
 102
 103          type Actual_Source_Ptr is access Actual_Source_Buffer;
 104          --  This is the pointer type for the physical buffer allocated
 105
 106          Actual_Ptr : constant Actual_Source_Ptr := new Actual_Source_Buffer;
 107          --  And this is the actual physical buffer
 108
 109       begin
 110          --  Allocate source buffer, allowing extra character at end for EOF
 111
 112          --  Some systems (e.g. VMS) have file types that require one
 113          --  read per line, so read until we get the Len bytes or until
 114          --  there are no more characters.
 115
 116          Hi := Lo;
 117          loop
 118             Actual_Len := Read (Source_File_FD, Actual_Ptr (Hi)'Address, Len);
 119             Hi := Hi + Source_Ptr (Actual_Len);
 120             exit when Actual_Len = Len or Actual_Len <= 0;
 121          end loop;
 122
 123          Actual_Ptr (Hi) := EOF;
 124
 125          --  Now we need to work out the proper virtual origin pointer to
 126          --  return. This is exactly Actual_Ptr (0)'Address, but we have
 127          --  to be careful to suppress checks to compute this address.
 128
 129          declare
 130             pragma Suppress (All_Checks);
 131
 132             pragma Warnings (Off);
 133             --  The following unchecked conversion is aliased safe, since it
 134             --  is not used to create improperly aliased pointer values.
 135
 136             function To_Source_Buffer_Ptr is new
 137               Ada.Unchecked_Conversion (Address, Source_Buffer_Ptr);
 138
 139             pragma Warnings (On);
 140
 141          begin
 142             Src := To_Source_Buffer_Ptr (Actual_Ptr (0)'Address);
 143          end;
 144       end;
 145
 146       --  Read is complete, close the file and we are done (no need to test
 147       --  status from close, since we have successfully read the file!)
 148
 149       Close (Source_File_FD);
 150
 151       --  Get the file name, without path information
 152
 153       declare
 154          Index : Positive := Path'Last;
 155
 156       begin
 157          while Index > Path'First loop
 158             exit when Path (Index - 1) = '/';
 159             exit when Path (Index - 1) = Directory_Separator;
 160             Index := Index - 1;
 161          end loop;
 162
 163          Name_Len := Path'Last - Index + 1;
 164          Name_Buffer (1 .. Name_Len) := Path (Index .. Path'Last);
 165          File_Id := Name_Find;
 166       end;
 167
 168       declare
 169          S : Source_File_Record renames Source_File.Table (X);
 170
 171       begin
 172          S := (Debug_Source_Name   => File_Id,
 173                File_Name           => File_Id,
 174                File_Type           => Config,
 175                First_Mapped_Line   => No_Line_Number,
 176                Full_Debug_Name     => Path_Id,
 177                Full_File_Name      => Path_Id,
 178                Full_Ref_Name       => Path_Id,
 179                Identifier_Casing   => Unknown,
 180                Inlined_Body        => False,
 181                Instantiation       => No_Location,
 182                Keyword_Casing      => Unknown,
 183                Last_Source_Line    => 1,
 184                License             => Unknown,
 185                Lines_Table         => null,
 186                Lines_Table_Max     => 1,
 187                Logical_Lines_Table => null,
 188                Num_SRef_Pragmas    => 0,
 189                Reference_Name      => File_Id,
 190                Sloc_Adjust         => 0,
 191                Source_Checksum     => 0,
 192                Source_First        => Lo,
 193                Source_Last         => Hi,
 194                Source_Text         => Src,
 195                Template            => No_Source_File,
 196                Time_Stamp          => Empty_Time_Stamp);
 197
 198          Alloc_Line_Tables (S, Opt.Table_Factor * Alloc.Lines_Initial);
 199          S.Lines_Table (1) := Lo;
 200       end;
 201
 202       Set_Source_File_Index_Table (X);
 203       return X;
 204    end Load_File;
 205
 206 end Sinput.C;