gcc/ada/lib-xref.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             L I B . X R E F                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1998-2013, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Csets;    use Csets;
  28 with Elists;   use Elists;
  29 with Errout;   use Errout;
  30 with Nlists;   use Nlists;
  31 with Opt;      use Opt;
  32 with Restrict; use Restrict;
  33 with Rident;   use Rident;
  34 with Sem;      use Sem;
  35 with Sem_Aux;  use Sem_Aux;
  36 with Sem_Prag; use Sem_Prag;
  37 with Sem_Util; use Sem_Util;
  38 with Sem_Warn; use Sem_Warn;
  39 with Sinfo;    use Sinfo;
  40 with Sinput;   use Sinput;
  41 with Snames;   use Snames;
  42 with Stringt;  use Stringt;
  43 with Stand;    use Stand;
  44 with Table;    use Table;
  45
  46 with GNAT.Heap_Sort_G;
  47 with GNAT.HTable;
  48
  49 package body Lib.Xref is
  50
  51    ------------------
  52    -- Declarations --
  53    ------------------
  54
  55    --  The Xref table is used to record references. The Loc field is set
  56    --  to No_Location for a definition entry.
  57
  58    subtype Xref_Entry_Number is Int;
  59
  60    type Xref_Key is record
  61       --  These are the components of Xref_Entry that participate in hash
  62       --  lookups.
  63
  64       Ent : Entity_Id;
  65       --  Entity referenced (E parameter to Generate_Reference)
  66
  67       Loc : Source_Ptr;
  68       --  Location of reference (Original_Location (Sloc field of N parameter
  69       --  to Generate_Reference). Set to No_Location for the case of a
  70       --  defining occurrence.
  71
  72       Typ : Character;
  73       --  Reference type (Typ param to Generate_Reference)
  74
  75       Eun : Unit_Number_Type;
  76       --  Unit number corresponding to Ent
  77
  78       Lun : Unit_Number_Type;
  79       --  Unit number corresponding to Loc. Value is undefined and not
  80       --  referenced if Loc is set to No_Location.
  81
  82       --  The following components are only used for SPARK cross-references
  83
  84       Ref_Scope : Entity_Id;
  85       --  Entity of the closest subprogram or package enclosing the reference
  86
  87       Ent_Scope : Entity_Id;
  88       --  Entity of the closest subprogram or package enclosing the definition,
  89       --  which should be located in the same file as the definition itself.
  90    end record;
  91
  92    type Xref_Entry is record
  93       Key : Xref_Key;
  94
  95       Ent_Scope_File : Unit_Number_Type;
  96       --  File for entity Ent_Scope
  97
  98       Def : Source_Ptr;
  99       --  Original source location for entity being referenced. Note that these
 100       --  values are used only during the output process, they are not set when
 101       --  the entries are originally built. This is because private entities
 102       --  can be swapped when the initial call is made.
 103
 104       HTable_Next : Xref_Entry_Number;
 105       --  For use only by Static_HTable
 106    end record;
 107
 108    package Xrefs is new Table.Table (
 109      Table_Component_Type => Xref_Entry,
 110      Table_Index_Type     => Xref_Entry_Number,
 111      Table_Low_Bound      => 1,
 112      Table_Initial        => Alloc.Xrefs_Initial,
 113      Table_Increment      => Alloc.Xrefs_Increment,
 114      Table_Name           => "Xrefs");
 115
 116    --------------
 117    -- Xref_Set --
 118    --------------
 119
 120    --  We keep a set of xref entries, in order to avoid inserting duplicate
 121    --  entries into the above Xrefs table. An entry is in Xref_Set if and only
 122    --  if it is in Xrefs.
 123
 124    Num_Buckets : constant := 2**16;
 125
 126    subtype Header_Num is Integer range 0 .. Num_Buckets - 1;
 127    type Null_Type is null record;
 128    pragma Unreferenced (Null_Type);
 129
 130    function Hash (F : Xref_Entry_Number) return Header_Num;
 131
 132    function Equal (F1, F2 : Xref_Entry_Number) return Boolean;
 133
 134    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number);
 135
 136    function  HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number;
 137
 138    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number;
 139
 140    pragma Inline (Hash, Equal, HT_Set_Next, HT_Next, Get_Key);
 141
 142    package Xref_Set is new GNAT.HTable.Static_HTable (
 143      Header_Num,
 144      Element    => Xref_Entry,
 145      Elmt_Ptr   => Xref_Entry_Number,
 146      Null_Ptr   => 0,
 147      Set_Next   => HT_Set_Next,
 148      Next       => HT_Next,
 149      Key        => Xref_Entry_Number,
 150      Get_Key    => Get_Key,
 151      Hash       => Hash,
 152      Equal      => Equal);
 153
 154    -----------------------------
 155    -- SPARK Xrefs Information --
 156    -----------------------------
 157
 158    package body SPARK_Specific is separate;
 159
 160    ------------------------
 161    --  Local Subprograms --
 162    ------------------------
 163
 164    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type);
 165    --  Add an entry to the tables of Xref_Entries, avoiding duplicates
 166
 167    procedure Generate_Prim_Op_References (Typ : Entity_Id);
 168    --  For a tagged type, generate implicit references to its primitive
 169    --  operations, for source navigation. This is done right before emitting
 170    --  cross-reference information rather than at the freeze point of the type
 171    --  in order to handle late bodies that are primitive operations.
 172
 173    function Lt (T1, T2 : Xref_Entry) return Boolean;
 174    --  Order cross-references
 175
 176    ---------------
 177    -- Add_Entry --
 178    ---------------
 179
 180    procedure Add_Entry (Key : Xref_Key; Ent_Scope_File : Unit_Number_Type) is
 181    begin
 182       Xrefs.Increment_Last; -- tentative
 183       Xrefs.Table (Xrefs.Last).Key := Key;
 184
 185       --  Set the entry in Xref_Set, and if newly set, keep the above
 186       --  tentative increment.
 187
 188       if Xref_Set.Set_If_Not_Present (Xrefs.Last) then
 189          Xrefs.Table (Xrefs.Last).Ent_Scope_File := Ent_Scope_File;
 190          --  Leave Def and HTable_Next uninitialized
 191
 192          Set_Has_Xref_Entry (Key.Ent);
 193
 194       --  It was already in Xref_Set, so throw away the tentatively-added
 195       --  entry
 196
 197       else
 198          Xrefs.Decrement_Last;
 199       end if;
 200    end Add_Entry;
 201
 202    -----------
 203    -- Equal --
 204    -----------
 205
 206    function Equal (F1, F2 : Xref_Entry_Number) return Boolean is
 207       Result : constant Boolean :=
 208                  Xrefs.Table (F1).Key = Xrefs.Table (F2).Key;
 209    begin
 210       return Result;
 211    end Equal;
 212
 213    -------------------------
 214    -- Generate_Definition --
 215    -------------------------
 216
 217    procedure Generate_Definition (E : Entity_Id) is
 218    begin
 219       pragma Assert (Nkind (E) in N_Entity);
 220
 221       --  Note that we do not test Xref_Entity_Letters here. It is too early
 222       --  to do so, since we are often called before the entity is fully
 223       --  constructed, so that the Ekind is still E_Void.
 224
 225       if Opt.Xref_Active
 226
 227          --  Definition must come from source
 228
 229          --  We make an exception for subprogram child units that have no spec.
 230          --  For these we generate a subprogram declaration for library use,
 231          --  and the corresponding entity does not come from source.
 232          --  Nevertheless, all references will be attached to it and we have
 233          --  to treat is as coming from user code.
 234
 235          and then (Comes_From_Source (E) or else Is_Child_Unit (E))
 236
 237          --  And must have a reasonable source location that is not
 238          --  within an instance (all entities in instances are ignored)
 239
 240          and then Sloc (E) > No_Location
 241          and then Instantiation_Location (Sloc (E)) = No_Location
 242
 243          --  And must be a non-internal name from the main source unit
 244
 245          and then In_Extended_Main_Source_Unit (E)
 246          and then not Is_Internal_Name (Chars (E))
 247       then
 248          Add_Entry
 249            ((Ent => E,
 250              Loc => No_Location,
 251              Typ => ' ',
 252              Eun => Get_Source_Unit (Original_Location (Sloc (E))),
 253              Lun => No_Unit,
 254              Ref_Scope => Empty,
 255              Ent_Scope => Empty),
 256             Ent_Scope_File => No_Unit);
 257
 258          if In_Inlined_Body then
 259             Set_Referenced (E);
 260          end if;
 261       end if;
 262    end Generate_Definition;
 263
 264    ---------------------------------
 265    -- Generate_Operator_Reference --
 266    ---------------------------------
 267
 268    procedure Generate_Operator_Reference
 269      (N : Node_Id;
 270       T : Entity_Id)
 271    is
 272    begin
 273       if not In_Extended_Main_Source_Unit (N) then
 274          return;
 275       end if;
 276
 277       --  If the operator is not a Standard operator, then we generate a real
 278       --  reference to the user defined operator.
 279
 280       if Sloc (Entity (N)) /= Standard_Location then
 281          Generate_Reference (Entity (N), N);
 282
 283          --  A reference to an implicit inequality operator is also a reference
 284          --  to the user-defined equality.
 285
 286          if Nkind (N) = N_Op_Ne
 287            and then not Comes_From_Source (Entity (N))
 288            and then Present (Corresponding_Equality (Entity (N)))
 289          then
 290             Generate_Reference (Corresponding_Equality (Entity (N)), N);
 291          end if;
 292
 293       --  For the case of Standard operators, we mark the result type as
 294       --  referenced. This ensures that in the case where we are using a
 295       --  derived operator, we mark an entity of the unit that implicitly
 296       --  defines this operator as used. Otherwise we may think that no entity
 297       --  of the unit is used. The actual entity marked as referenced is the
 298       --  first subtype, which is the relevant user defined entity.
 299
 300       --  Note: we only do this for operators that come from source. The
 301       --  generated code sometimes reaches for entities that do not need to be
 302       --  explicitly visible (for example, when we expand the code for
 303       --  comparing two record objects, the fields of the record may not be
 304       --  visible).
 305
 306       elsif Comes_From_Source (N) then
 307          Set_Referenced (First_Subtype (T));
 308       end if;
 309    end Generate_Operator_Reference;
 310
 311    ---------------------------------
 312    -- Generate_Prim_Op_References --
 313    ---------------------------------
 314
 315    procedure Generate_Prim_Op_References (Typ : Entity_Id) is
 316       Base_T    : Entity_Id;
 317       Prim      : Elmt_Id;
 318       Prim_List : Elist_Id;
 319
 320    begin
 321       --  Handle subtypes of synchronized types
 322
 323       if Ekind (Typ) = E_Protected_Subtype
 324         or else Ekind (Typ) = E_Task_Subtype
 325       then
 326          Base_T := Etype (Typ);
 327       else
 328          Base_T := Typ;
 329       end if;
 330
 331       --  References to primitive operations are only relevant for tagged types
 332
 333       if not Is_Tagged_Type (Base_T)
 334         or else Is_Class_Wide_Type (Base_T)
 335       then
 336          return;
 337       end if;
 338
 339       --  Ada 2005 (AI-345): For synchronized types generate reference to the
 340       --  wrapper that allow us to dispatch calls through their implemented
 341       --  abstract interface types.
 342
 343       --  The check for Present here is to protect against previously reported
 344       --  critical errors.
 345
 346       Prim_List := Primitive_Operations (Base_T);
 347
 348       if No (Prim_List) then
 349          return;
 350       end if;
 351
 352       Prim := First_Elmt (Prim_List);
 353       while Present (Prim) loop
 354
 355          --  If the operation is derived, get the original for cross-reference
 356          --  reference purposes (it is the original for which we want the xref
 357          --  and for which the comes_from_source test must be performed).
 358
 359          Generate_Reference
 360            (Typ, Ultimate_Alias (Node (Prim)), 'p', Set_Ref => False);
 361          Next_Elmt (Prim);
 362       end loop;
 363    end Generate_Prim_Op_References;
 364
 365    ------------------------
 366    -- Generate_Reference --
 367    ------------------------
 368
 369    procedure Generate_Reference
 370      (E       : Entity_Id;
 371       N       : Node_Id;
 372       Typ     : Character := 'r';
 373       Set_Ref : Boolean   := True;
 374       Force   : Boolean   := False)
 375    is
 376       Actual_Typ     : Character := Typ;
 377       Call           : Node_Id;
 378       Def            : Source_Ptr;
 379       Ent            : Entity_Id;
 380       Ent_Scope      : Entity_Id;
 381       Formal         : Entity_Id;
 382       Kind           : Entity_Kind;
 383       Nod            : Node_Id;
 384       Ref            : Source_Ptr;
 385       Ref_Scope      : Entity_Id;
 386
 387       function Get_Through_Renamings (E : Entity_Id) return Entity_Id;
 388       --  Get the enclosing entity through renamings, which may come from
 389       --  source or from the translation of generic instantiations.
 390
 391       function Is_On_LHS (Node : Node_Id) return Boolean;
 392       --  Used to check if a node is on the left hand side of an assignment.
 393       --  The following cases are handled:
 394       --
 395       --   Variable    Node is a direct descendant of left hand side of an
 396       --               assignment statement.
 397       --
 398       --   Prefix      Of an indexed or selected component that is present in
 399       --               a subtree rooted by an assignment statement. There is
 400       --               no restriction of nesting of components, thus cases
 401       --               such as A.B (C).D are handled properly. However a prefix
 402       --               of a dereference (either implicit or explicit) is never
 403       --               considered as on a LHS.
 404       --
 405       --   Out param   Same as above cases, but OUT parameter
 406
 407       function OK_To_Set_Referenced return Boolean;
 408       --  Returns True if the Referenced flag can be set. There are a few
 409       --  exceptions where we do not want to set this flag, see body for
 410       --  details of these exceptional cases.
 411
 412       ---------------------------
 413       -- Get_Through_Renamings --
 414       ---------------------------
 415
 416       function Get_Through_Renamings (E : Entity_Id) return Entity_Id is
 417          Result : Entity_Id := E;
 418       begin
 419          while Present (Result)
 420            and then Is_Object (Result)
 421            and then Present (Renamed_Object (Result))
 422          loop
 423             Result := Get_Enclosing_Object (Renamed_Object (Result));
 424          end loop;
 425          return Result;
 426       end Get_Through_Renamings;
 427
 428       ---------------
 429       -- Is_On_LHS --
 430       ---------------
 431
 432       --  ??? There are several routines here and there that perform a similar
 433       --      (but subtly different) computation, which should be factored:
 434
 435       --      Sem_Util.Is_LHS
 436       --      Sem_Util.May_Be_Lvalue
 437       --      Sem_Util.Known_To_Be_Assigned
 438       --      Exp_Ch2.Expand_Entry_Parameter.In_Assignment_Context
 439       --      Exp_Smem.Is_Out_Actual
 440
 441       function Is_On_LHS (Node : Node_Id) return Boolean is
 442          N : Node_Id;
 443          P : Node_Id;
 444          K : Node_Kind;
 445
 446       begin
 447          --  Only identifiers are considered, is this necessary???
 448
 449          if Nkind (Node) /= N_Identifier then
 450             return False;
 451          end if;
 452
 453          --  Immediate return if appeared as OUT parameter
 454
 455          if Kind = E_Out_Parameter then
 456             return True;
 457          end if;
 458
 459          --  Search for assignment statement subtree root
 460
 461          N := Node;
 462          loop
 463             P := Parent (N);
 464             K := Nkind (P);
 465
 466             if K = N_Assignment_Statement then
 467                return Name (P) = N;
 468
 469             --  Check whether the parent is a component and the current node is
 470             --  its prefix, but return False if the current node has an access
 471             --  type, as in that case the selected or indexed component is an
 472             --  implicit dereference, and the LHS is the designated object, not
 473             --  the access object.
 474
 475             --  ??? case of a slice assignment?
 476
 477             elsif (K = N_Selected_Component or else K = N_Indexed_Component)
 478               and then Prefix (P) = N
 479             then
 480                --  Check for access type. First a kludge, In some cases this is
 481                --  called too early (see comments in Sem_Ch8.Find_Direct_Name),
 482                --  at a point where the tree is not fully typed yet. In that
 483                --  case we may lack an Etype for N, and we can't check the
 484                --  Etype. For now, we always return False in such a case,
 485                --  but this is clearly not right in all cases ???
 486
 487                if No (Etype (N)) then
 488                   return False;
 489
 490                elsif Is_Access_Type (Etype (N)) then
 491                   return False;
 492
 493                --  Access type case dealt with, keep going
 494
 495                else
 496                   N := P;
 497                end if;
 498
 499             --  All other cases, definitely not on left side
 500
 501             else
 502                return False;
 503             end if;
 504          end loop;
 505       end Is_On_LHS;
 506
 507       ---------------------------
 508       -- OK_To_Set_Referenced --
 509       ---------------------------
 510
 511       function OK_To_Set_Referenced return Boolean is
 512          P : Node_Id;
 513
 514       begin
 515          --  A reference from a pragma Unreferenced or pragma Unmodified or
 516          --  pragma Warnings does not cause the Referenced flag to be set.
 517          --  This avoids silly warnings about things being referenced and
 518          --  not assigned when the only reference is from the pragma.
 519
 520          if Nkind (N) = N_Identifier then
 521             P := Parent (N);
 522
 523             if Nkind (P) = N_Pragma_Argument_Association then
 524                P := Parent (P);
 525
 526                if Nkind (P) = N_Pragma then
 527                   if Nam_In (Pragma_Name (P), Name_Warnings,
 528                                               Name_Unmodified,
 529                                               Name_Unreferenced)
 530                   then
 531                      return False;
 532                   end if;
 533                end if;
 534
 535             --  A reference to a formal in a named parameter association does
 536             --  not make the formal referenced. Formals that are unused in the
 537             --  subprogram body are properly flagged as such, even if calls
 538             --  elsewhere use named notation.
 539
 540             elsif Nkind (P) = N_Parameter_Association
 541               and then N = Selector_Name (P)
 542             then
 543                return False;
 544             end if;
 545          end if;
 546
 547          return True;
 548       end OK_To_Set_Referenced;
 549
 550    --  Start of processing for Generate_Reference
 551
 552    begin
 553       pragma Assert (Nkind (E) in N_Entity);
 554       Find_Actual (N, Formal, Call);
 555
 556       if Present (Formal) then
 557          Kind := Ekind (Formal);
 558       else
 559          Kind := E_Void;
 560       end if;
 561
 562       --  Check for obsolescent reference to package ASCII. GNAT treats this
 563       --  element of annex J specially since in practice, programs make a lot
 564       --  of use of this feature, so we don't include it in the set of features
 565       --  diagnosed when Warn_On_Obsolescent_Features mode is set. However we
 566       --  are required to note it as a violation of the RM defined restriction.
 567
 568       if E = Standard_ASCII then
 569          Check_Restriction (No_Obsolescent_Features, N);
 570       end if;
 571
 572       --  Check for reference to entity marked with Is_Obsolescent
 573
 574       --  Note that we always allow obsolescent references in the compiler
 575       --  itself and the run time, since we assume that we know what we are
 576       --  doing in such cases. For example the calls in Ada.Characters.Handling
 577       --  to its own obsolescent subprograms are just fine.
 578
 579       --  In any case we only generate warnings if we are in the extended main
 580       --  source unit, and the entity itself is not in the extended main source
 581       --  unit, since we assume the source unit itself knows what is going on
 582       --  (and for sure we do not want silly warnings, e.g. on the end line of
 583       --  an obsolescent procedure body).
 584
 585       if Is_Obsolescent (E)
 586         and then not GNAT_Mode
 587         and then not In_Extended_Main_Source_Unit (E)
 588         and then In_Extended_Main_Source_Unit (N)
 589       then
 590          Check_Restriction (No_Obsolescent_Features, N);
 591
 592          if Warn_On_Obsolescent_Feature then
 593             Output_Obsolescent_Entity_Warnings (N, E);
 594          end if;
 595       end if;
 596
 597       --  Warn if reference to Ada 2005 entity not in Ada 2005 mode. We only
 598       --  detect real explicit references (modifications and references).
 599
 600       if Comes_From_Source (N)
 601         and then Is_Ada_2005_Only (E)
 602         and then Ada_Version < Ada_2005
 603         and then Warn_On_Ada_2005_Compatibility
 604         and then (Typ = 'm' or else Typ = 'r' or else Typ = 's')
 605       then
 606          Error_Msg_NE ("& is only defined in Ada 2005?y?", N, E);
 607       end if;
 608
 609       --  Warn if reference to Ada 2012 entity not in Ada 2012 mode. We only
 610       --  detect real explicit references (modifications and references).
 611
 612       if Comes_From_Source (N)
 613         and then Is_Ada_2012_Only (E)
 614         and then Ada_Version < Ada_2012
 615         and then Warn_On_Ada_2012_Compatibility
 616         and then (Typ = 'm' or else Typ = 'r')
 617       then
 618          Error_Msg_NE ("& is only defined in Ada 2012?y?", N, E);
 619       end if;
 620
 621       --  Do not generate references if we are within a postcondition sub-
 622       --  program, because the reference does not comes from source, and the
 623       --  pre-analysis of the aspect has already created an entry for the ali
 624       --  file at the proper source location.
 625
 626       if Chars (Current_Scope) = Name_uPostconditions then
 627          return;
 628       end if;
 629
 630       --  Never collect references if not in main source unit. However, we omit
 631       --  this test if Typ is 'e' or 'k', since these entries are structural,
 632       --  and it is useful to have them in units that reference packages as
 633       --  well as units that define packages. We also omit the test for the
 634       --  case of 'p' since we want to include inherited primitive operations
 635       --  from other packages.
 636
 637       --  We also omit this test is this is a body reference for a subprogram
 638       --  instantiation. In this case the reference is to the generic body,
 639       --  which clearly need not be in the main unit containing the instance.
 640       --  For the same reason we accept an implicit reference generated for
 641       --  a default in an instance.
 642
 643       if not In_Extended_Main_Source_Unit (N) then
 644          if Typ = 'e'
 645            or else Typ = 'I'
 646            or else Typ = 'p'
 647            or else Typ = 'i'
 648            or else Typ = 'k'
 649            or else (Typ = 'b' and then Is_Generic_Instance (E))
 650
 651             --  Allow the generation of references to reads, writes and calls
 652             --  in SPARK mode when the related context comes from an instance.
 653
 654            or else
 655              (GNATprove_Mode
 656                and then In_Extended_Main_Code_Unit (N)
 657                and then (Typ = 'm' or else Typ = 'r' or else Typ = 's'))
 658          then
 659             null;
 660          else
 661             return;
 662          end if;
 663       end if;
 664
 665       --  For reference type p, the entity must be in main source unit
 666
 667       if Typ = 'p' and then not In_Extended_Main_Source_Unit (E) then
 668          return;
 669       end if;
 670
 671       --  Unless the reference is forced, we ignore references where the
 672       --  reference itself does not come from source.
 673
 674       if not Force and then not Comes_From_Source (N) then
 675          return;
 676       end if;
 677
 678       --  Deal with setting entity as referenced, unless suppressed. Note that
 679       --  we still do Set_Referenced on entities that do not come from source.
 680       --  This situation arises when we have a source reference to a derived
 681       --  operation, where the derived operation itself does not come from
 682       --  source, but we still want to mark it as referenced, since we really
 683       --  are referencing an entity in the corresponding package (this avoids
 684       --  wrong complaints that the package contains no referenced entities).
 685
 686       if Set_Ref then
 687
 688          --  Assignable object appearing on left side of assignment or as
 689          --  an out parameter.
 690
 691          if Is_Assignable (E)
 692            and then Is_On_LHS (N)
 693            and then Ekind (E) /= E_In_Out_Parameter
 694          then
 695             --  For objects that are renamings, just set as simply referenced
 696             --  we do not try to do assignment type tracking in this case.
 697
 698             if Present (Renamed_Object (E)) then
 699                Set_Referenced (E);
 700
 701             --  Out parameter case
 702
 703             elsif Kind = E_Out_Parameter then
 704
 705                --  If warning mode for all out parameters is set, or this is
 706                --  the only warning parameter, then we want to mark this for
 707                --  later warning logic by setting Referenced_As_Out_Parameter
 708
 709                if Warn_On_Modified_As_Out_Parameter (Formal) then
 710                   Set_Referenced_As_Out_Parameter (E, True);
 711                   Set_Referenced_As_LHS (E, False);
 712
 713                --  For OUT parameter not covered by the above cases, we simply
 714                --  regard it as a normal reference (in this case we do not
 715                --  want any of the warning machinery for out parameters).
 716
 717                else
 718                   Set_Referenced (E);
 719                end if;
 720
 721             --  For the left hand of an assignment case, we do nothing here.
 722             --  The processing for Analyze_Assignment_Statement will set the
 723             --  Referenced_As_LHS flag.
 724
 725             else
 726                null;
 727             end if;
 728
 729          --  Check for a reference in a pragma that should not count as a
 730          --  making the variable referenced for warning purposes.
 731
 732          elsif Is_Non_Significant_Pragma_Reference (N) then
 733             null;
 734
 735          --  A reference in an attribute definition clause does not count as a
 736          --  reference except for the case of Address. The reason that 'Address
 737          --  is an exception is that it creates an alias through which the
 738          --  variable may be referenced.
 739
 740          elsif Nkind (Parent (N)) = N_Attribute_Definition_Clause
 741            and then Chars (Parent (N)) /= Name_Address
 742            and then N = Name (Parent (N))
 743          then
 744             null;
 745
 746          --  Constant completion does not count as a reference
 747
 748          elsif Typ = 'c'
 749            and then Ekind (E) = E_Constant
 750          then
 751             null;
 752
 753          --  Record representation clause does not count as a reference
 754
 755          elsif Nkind (N) = N_Identifier
 756            and then Nkind (Parent (N)) = N_Record_Representation_Clause
 757          then
 758             null;
 759
 760          --  Discriminants do not need to produce a reference to record type
 761
 762          elsif Typ = 'd'
 763            and then Nkind (Parent (N)) = N_Discriminant_Specification
 764          then
 765             null;
 766
 767          --  All other cases
 768
 769          else
 770             --  Special processing for IN OUT parameters, where we have an
 771             --  implicit assignment to a simple variable.
 772
 773             if Kind = E_In_Out_Parameter
 774               and then Is_Assignable (E)
 775             then
 776                --  For sure this counts as a normal read reference
 777
 778                Set_Referenced (E);
 779                Set_Last_Assignment (E, Empty);
 780
 781                --  We count it as being referenced as an out parameter if the
 782                --  option is set to warn on all out parameters, except that we
 783                --  have a special exclusion for an intrinsic subprogram, which
 784                --  is most likely an instantiation of Unchecked_Deallocation
 785                --  which we do not want to consider as an assignment since it
 786                --  generates false positives. We also exclude the case of an
 787                --  IN OUT parameter if the name of the procedure is Free,
 788                --  since we suspect similar semantics.
 789
 790                if Warn_On_All_Unread_Out_Parameters
 791                  and then Is_Entity_Name (Name (Call))
 792                  and then not Is_Intrinsic_Subprogram (Entity (Name (Call)))
 793                  and then Chars (Name (Call)) /= Name_Free
 794                then
 795                   Set_Referenced_As_Out_Parameter (E, True);
 796                   Set_Referenced_As_LHS (E, False);
 797                end if;
 798
 799             --  Don't count a recursive reference within a subprogram as a
 800             --  reference (that allows detection of a recursive subprogram
 801             --  whose only references are recursive calls as unreferenced).
 802
 803             elsif Is_Subprogram (E)
 804               and then E = Nearest_Dynamic_Scope (Current_Scope)
 805             then
 806                null;
 807
 808             --  Any other occurrence counts as referencing the entity
 809
 810             elsif OK_To_Set_Referenced then
 811                Set_Referenced (E);
 812
 813                --  If variable, this is an OK reference after an assignment
 814                --  so we can clear the Last_Assignment indication.
 815
 816                if Is_Assignable (E) then
 817                   Set_Last_Assignment (E, Empty);
 818                end if;
 819             end if;
 820          end if;
 821
 822          --  Check for pragma Unreferenced given and reference is within
 823          --  this source unit (occasion for possible warning to be issued).
 824
 825          if Has_Unreferenced (E)
 826            and then In_Same_Extended_Unit (E, N)
 827          then
 828             --  A reference as a named parameter in a call does not count
 829             --  as a violation of pragma Unreferenced for this purpose...
 830
 831             if Nkind (N) = N_Identifier
 832               and then Nkind (Parent (N)) = N_Parameter_Association
 833               and then Selector_Name (Parent (N)) = N
 834             then
 835                null;
 836
 837             --  ... Neither does a reference to a variable on the left side
 838             --  of an assignment.
 839
 840             elsif Is_On_LHS (N) then
 841                null;
 842
 843             --  For entry formals, we want to place the warning message on the
 844             --  corresponding entity in the accept statement. The current scope
 845             --  is the body of the accept, so we find the formal whose name
 846             --  matches that of the entry formal (there is no link between the
 847             --  two entities, and the one in the accept statement is only used
 848             --  for conformance checking).
 849
 850             elsif Ekind (Scope (E)) = E_Entry then
 851                declare
 852                   BE : Entity_Id;
 853
 854                begin
 855                   BE := First_Entity (Current_Scope);
 856                   while Present (BE) loop
 857                      if Chars (BE) = Chars (E) then
 858                         Error_Msg_NE -- CODEFIX
 859                           ("??pragma Unreferenced given for&!", N, BE);
 860                         exit;
 861                      end if;
 862
 863                      Next_Entity (BE);
 864                   end loop;
 865                end;
 866
 867             --  Here we issue the warning, since this is a real reference
 868
 869             else
 870                Error_Msg_NE -- CODEFIX
 871                  ("?pragma Unreferenced given for&!", N, E);
 872             end if;
 873          end if;
 874
 875          --  If this is a subprogram instance, mark as well the internal
 876          --  subprogram in the wrapper package, which may be a visible
 877          --  compilation unit.
 878
 879          if Is_Overloadable (E)
 880            and then Is_Generic_Instance (E)
 881            and then Present (Alias (E))
 882          then
 883             Set_Referenced (Alias (E));
 884          end if;
 885       end if;
 886
 887       --  Generate reference if all conditions are met:
 888
 889       if
 890          --  Cross referencing must be active
 891
 892          Opt.Xref_Active
 893
 894          --  The entity must be one for which we collect references
 895
 896          and then Xref_Entity_Letters (Ekind (E)) /= ' '
 897
 898          --  Both Sloc values must be set to something sensible
 899
 900          and then Sloc (E) > No_Location
 901          and then Sloc (N) > No_Location
 902
 903          --  Ignore references from within an instance. The only exceptions to
 904          --  this are default subprograms, for which we generate an implicit
 905          --  reference and compilations in SPARK mode.
 906
 907          and then
 908            (Instantiation_Location (Sloc (N)) = No_Location
 909              or else Typ = 'i'
 910              or else GNATprove_Mode)
 911
 912         --  Ignore dummy references
 913
 914         and then Typ /= ' '
 915       then
 916          if Nkind_In (N, N_Identifier,
 917                          N_Defining_Identifier,
 918                          N_Defining_Operator_Symbol,
 919                          N_Operator_Symbol,
 920                          N_Defining_Character_Literal)
 921            or else Nkind (N) in N_Op
 922            or else (Nkind (N) = N_Character_Literal
 923                      and then Sloc (Entity (N)) /= Standard_Location)
 924          then
 925             Nod := N;
 926
 927          elsif Nkind_In (N, N_Expanded_Name, N_Selected_Component) then
 928             Nod := Selector_Name (N);
 929
 930          else
 931             return;
 932          end if;
 933
 934          --  Normal case of source entity comes from source
 935
 936          if Comes_From_Source (E) then
 937             Ent := E;
 938
 939          --  Entity does not come from source, but is a derived subprogram and
 940          --  the derived subprogram comes from source (after one or more
 941          --  derivations) in which case the reference is to parent subprogram.
 942
 943          elsif Is_Overloadable (E)
 944            and then Present (Alias (E))
 945          then
 946             Ent := Alias (E);
 947             while not Comes_From_Source (Ent) loop
 948                if No (Alias (Ent)) then
 949                   return;
 950                end if;
 951
 952                Ent := Alias (Ent);
 953             end loop;
 954
 955          --  The internally created defining entity for a child subprogram
 956          --  that has no previous spec has valid references.
 957
 958          elsif Is_Overloadable (E)
 959            and then Is_Child_Unit (E)
 960          then
 961             Ent := E;
 962
 963          --  Ditto for the formals of such a subprogram
 964
 965          elsif Is_Overloadable (Scope (E))
 966            and then Is_Child_Unit (Scope (E))
 967          then
 968             Ent := E;
 969
 970          --  Record components of discriminated subtypes or derived types must
 971          --  be treated as references to the original component.
 972
 973          elsif Ekind (E) = E_Component
 974            and then Comes_From_Source (Original_Record_Component (E))
 975          then
 976             Ent := Original_Record_Component (E);
 977
 978          --  If this is an expanded reference to a discriminant, recover the
 979          --  original discriminant, which gets the reference.
 980
 981          elsif Ekind (E) = E_In_Parameter
 982            and then  Present (Discriminal_Link (E))
 983          then
 984             Ent := Discriminal_Link (E);
 985             Set_Referenced (Ent);
 986
 987          --  Ignore reference to any other entity that is not from source
 988
 989          else
 990             return;
 991          end if;
 992
 993          --  In SPARK mode, consider the underlying entity renamed instead of
 994          --  the renaming, which is needed to compute a valid set of effects
 995          --  (reads, writes) for the enclosing subprogram.
 996
 997          if GNATprove_Mode then
 998             Ent := Get_Through_Renamings (Ent);
 999
1000             --  If no enclosing object, then it could be a reference to any
1001             --  location not tracked individually, like heap-allocated data.
1002             --  Conservatively approximate this possibility by generating a
1003             --  dereference, and return.
1004
1005             if No (Ent) then
1006                if Actual_Typ = 'w' then
1007                   SPARK_Specific.Generate_Dereference (Nod, 'r');
1008                   SPARK_Specific.Generate_Dereference (Nod, 'w');
1009                else
1010                   SPARK_Specific.Generate_Dereference (Nod, 'r');
1011                end if;
1012
1013                return;
1014             end if;
1015          end if;
1016
1017          --  Record reference to entity
1018
1019          if Actual_Typ = 'p'
1020            and then Is_Subprogram (Nod)
1021            and then Present (Overridden_Operation (Nod))
1022          then
1023             Actual_Typ := 'P';
1024          end if;
1025
1026          --  Comment needed here for special SPARK code ???
1027
1028          if GNATprove_Mode then
1029             Ref := Sloc (Nod);
1030             Def := Sloc (Ent);
1031
1032             Ref_Scope := SPARK_Specific.Enclosing_Subprogram_Or_Package (Nod);
1033             Ent_Scope := SPARK_Specific.Enclosing_Subprogram_Or_Package (Ent);
1034
1035             --  Since we are reaching through renamings in SPARK mode, we may
1036             --  end up with standard constants. Ignore those.
1037
1038             if Sloc (Ent_Scope) <= Standard_Location
1039               or else Def <= Standard_Location
1040             then
1041                return;
1042             end if;
1043
1044             Add_Entry
1045               ((Ent      => Ent,
1046                 Loc       => Ref,
1047                 Typ       => Actual_Typ,
1048                 Eun       => Get_Code_Unit (Def),
1049                 Lun       => Get_Code_Unit (Ref),
1050                 Ref_Scope => Ref_Scope,
1051                 Ent_Scope => Ent_Scope),
1052                Ent_Scope_File => Get_Code_Unit (Ent));
1053
1054          else
1055             Ref := Original_Location (Sloc (Nod));
1056             Def := Original_Location (Sloc (Ent));
1057
1058             --  If this is an operator symbol, skip the initial quote for
1059             --  navigation purposes. This is not done for the end label,
1060             --  where we want the actual position after the closing quote.
1061
1062             if Typ = 't' then
1063                null;
1064
1065             elsif Nkind (N) = N_Defining_Operator_Symbol
1066               or else Nkind (Nod) = N_Operator_Symbol
1067             then
1068                Ref := Ref + 1;
1069             end if;
1070
1071             Add_Entry
1072               ((Ent      => Ent,
1073                 Loc       => Ref,
1074                 Typ       => Actual_Typ,
1075                 Eun       => Get_Source_Unit (Def),
1076                 Lun       => Get_Source_Unit (Ref),
1077                 Ref_Scope => Empty,
1078                 Ent_Scope => Empty),
1079                Ent_Scope_File => No_Unit);
1080
1081             --  Generate reference to the first private entity
1082
1083             if Typ = 'e'
1084               and then Comes_From_Source (E)
1085               and then Nkind (Ent) = N_Defining_Identifier
1086               and then (Is_Package_Or_Generic_Package (Ent)
1087                          or else Is_Concurrent_Type (Ent))
1088               and then Present (First_Private_Entity (E))
1089               and then In_Extended_Main_Source_Unit (N)
1090             then
1091                Add_Entry
1092                  ((Ent       => Ent,
1093                    Loc       => Sloc (First_Private_Entity (E)),
1094                    Typ       => 'E',
1095                    Eun       => Get_Source_Unit (Def),
1096                    Lun       => Get_Source_Unit (Ref),
1097                    Ref_Scope => Empty,
1098                    Ent_Scope => Empty),
1099                   Ent_Scope_File => No_Unit);
1100             end if;
1101          end if;
1102       end if;
1103    end Generate_Reference;
1104
1105    -----------------------------------
1106    -- Generate_Reference_To_Formals --
1107    -----------------------------------
1108
1109    procedure Generate_Reference_To_Formals (E : Entity_Id) is
1110       Formal : Entity_Id;
1111
1112    begin
1113       if Is_Generic_Subprogram (E) then
1114          Formal := First_Entity (E);
1115
1116          while Present (Formal)
1117            and then not Is_Formal (Formal)
1118          loop
1119             Next_Entity (Formal);
1120          end loop;
1121
1122       elsif Ekind (E) in Access_Subprogram_Kind then
1123          Formal := First_Formal (Designated_Type (E));
1124
1125       else
1126          Formal := First_Formal (E);
1127       end if;
1128
1129       while Present (Formal) loop
1130          if Ekind (Formal) = E_In_Parameter then
1131
1132             if Nkind (Parameter_Type (Parent (Formal)))
1133               = N_Access_Definition
1134             then
1135                Generate_Reference (E, Formal, '^', False);
1136             else
1137                Generate_Reference (E, Formal, '>', False);
1138             end if;
1139
1140          elsif Ekind (Formal) = E_In_Out_Parameter then
1141             Generate_Reference (E, Formal, '=', False);
1142
1143          else
1144             Generate_Reference (E, Formal, '<', False);
1145          end if;
1146
1147          Next_Formal (Formal);
1148       end loop;
1149    end Generate_Reference_To_Formals;
1150
1151    -------------------------------------------
1152    -- Generate_Reference_To_Generic_Formals --
1153    -------------------------------------------
1154
1155    procedure Generate_Reference_To_Generic_Formals (E : Entity_Id) is
1156       Formal : Entity_Id;
1157
1158    begin
1159       Formal := First_Entity (E);
1160       while Present (Formal) loop
1161          if Comes_From_Source (Formal) then
1162             Generate_Reference (E, Formal, 'z', False);
1163          end if;
1164
1165          Next_Entity (Formal);
1166       end loop;
1167    end Generate_Reference_To_Generic_Formals;
1168
1169    -------------
1170    -- Get_Key --
1171    -------------
1172
1173    function Get_Key (E : Xref_Entry_Number) return Xref_Entry_Number is
1174    begin
1175       return E;
1176    end Get_Key;
1177
1178    ----------
1179    -- Hash --
1180    ----------
1181
1182    function Hash (F : Xref_Entry_Number) return Header_Num is
1183       --  It is unlikely to have two references to the same entity at the same
1184       --  source location, so the hash function depends only on the Ent and Loc
1185       --  fields.
1186
1187       XE : Xref_Entry renames Xrefs.Table (F);
1188       type M is mod 2**32;
1189
1190       H : constant M := M (XE.Key.Ent) + 2 ** 7 * M (abs XE.Key.Loc);
1191       --  It would be more natural to write:
1192       --
1193       --    H : constant M := M'Mod (XE.Key.Ent) + 2**7 * M'Mod (XE.Key.Loc);
1194       --
1195       --  But we can't use M'Mod, because it prevents bootstrapping with older
1196       --  compilers. Loc can be negative, so we do "abs" before converting.
1197       --  One day this can be cleaned up ???
1198
1199    begin
1200       return Header_Num (H mod Num_Buckets);
1201    end Hash;
1202
1203    -----------------
1204    -- HT_Set_Next --
1205    -----------------
1206
1207    procedure HT_Set_Next (E : Xref_Entry_Number; Next : Xref_Entry_Number) is
1208    begin
1209       Xrefs.Table (E).HTable_Next := Next;
1210    end HT_Set_Next;
1211
1212    -------------
1213    -- HT_Next --
1214    -------------
1215
1216    function HT_Next (E : Xref_Entry_Number) return Xref_Entry_Number is
1217    begin
1218       return Xrefs.Table (E).HTable_Next;
1219    end HT_Next;
1220
1221    ----------------
1222    -- Initialize --
1223    ----------------
1224
1225    procedure Initialize is
1226    begin
1227       Xrefs.Init;
1228    end Initialize;
1229
1230    --------
1231    -- Lt --
1232    --------
1233
1234    function Lt (T1, T2 : Xref_Entry) return Boolean is
1235    begin
1236       --  First test: if entity is in different unit, sort by unit
1237
1238       if T1.Key.Eun /= T2.Key.Eun then
1239          return Dependency_Num (T1.Key.Eun) < Dependency_Num (T2.Key.Eun);
1240
1241       --  Second test: within same unit, sort by entity Sloc
1242
1243       elsif T1.Def /= T2.Def then
1244          return T1.Def < T2.Def;
1245
1246       --  Third test: sort definitions ahead of references
1247
1248       elsif T1.Key.Loc = No_Location then
1249          return True;
1250
1251       elsif T2.Key.Loc = No_Location then
1252          return False;
1253
1254       --  Fourth test: for same entity, sort by reference location unit
1255
1256       elsif T1.Key.Lun /= T2.Key.Lun then
1257          return Dependency_Num (T1.Key.Lun) < Dependency_Num (T2.Key.Lun);
1258
1259       --  Fifth test: order of location within referencing unit
1260
1261       elsif T1.Key.Loc /= T2.Key.Loc then
1262          return T1.Key.Loc < T2.Key.Loc;
1263
1264       --  Finally, for two locations at the same address, we prefer
1265       --  the one that does NOT have the type 'r' so that a modification
1266       --  or extension takes preference, when there are more than one
1267       --  reference at the same location. As a result, in the case of
1268       --  entities that are in-out actuals, the read reference follows
1269       --  the modify reference.
1270
1271       else
1272          return T2.Key.Typ = 'r';
1273       end if;
1274    end Lt;
1275
1276    -----------------------
1277    -- Output_References --
1278    -----------------------
1279
1280    procedure Output_References is
1281
1282       procedure Get_Type_Reference
1283         (Ent   : Entity_Id;
1284          Tref  : out Entity_Id;
1285          Left  : out Character;
1286          Right : out Character);
1287       --  Given an Entity_Id Ent, determines whether a type reference is
1288       --  required. If so, Tref is set to the entity for the type reference
1289       --  and Left and Right are set to the left/right brackets to be output
1290       --  for the reference. If no type reference is required, then Tref is
1291       --  set to Empty, and Left/Right are set to space.
1292
1293       procedure Output_Import_Export_Info (Ent : Entity_Id);
1294       --  Output language and external name information for an interfaced
1295       --  entity, using the format <language, external_name>.
1296
1297       ------------------------
1298       -- Get_Type_Reference --
1299       ------------------------
1300
1301       procedure Get_Type_Reference
1302         (Ent   : Entity_Id;
1303          Tref  : out Entity_Id;
1304          Left  : out Character;
1305          Right : out Character)
1306       is
1307          Sav : Entity_Id;
1308
1309       begin
1310          --  See if we have a type reference
1311
1312          Tref := Ent;
1313          Left := '{';
1314          Right := '}';
1315
1316          loop
1317             Sav := Tref;
1318
1319             --  Processing for types
1320
1321             if Is_Type (Tref) then
1322
1323                --  Case of base type
1324
1325                if Base_Type (Tref) = Tref then
1326
1327                   --  If derived, then get first subtype
1328
1329                   if Tref /= Etype (Tref) then
1330                      Tref := First_Subtype (Etype (Tref));
1331
1332                      --  Set brackets for derived type, but don't override
1333                      --  pointer case since the fact that something is a
1334                      --  pointer is more important.
1335
1336                      if Left /= '(' then
1337                         Left := '<';
1338                         Right := '>';
1339                      end if;
1340
1341                   --  If the completion of a private type is itself a derived
1342                   --  type, we need the parent of the full view.
1343
1344                   elsif Is_Private_Type (Tref)
1345                     and then Present (Full_View (Tref))
1346                     and then Etype (Full_View (Tref)) /= Full_View (Tref)
1347                   then
1348                      Tref := Etype (Full_View (Tref));
1349
1350                      if Left /= '(' then
1351                         Left := '<';
1352                         Right := '>';
1353                      end if;
1354
1355                   --  If non-derived pointer, get directly designated type.
1356                   --  If the type has a full view, all references are on the
1357                   --  partial view that is seen first.
1358
1359                   elsif Is_Access_Type (Tref) then
1360                      Tref := Directly_Designated_Type (Tref);
1361                      Left := '(';
1362                      Right := ')';
1363
1364                   elsif Is_Private_Type (Tref)
1365                     and then Present (Full_View (Tref))
1366                   then
1367                      if Is_Access_Type (Full_View (Tref)) then
1368                         Tref := Directly_Designated_Type (Full_View (Tref));
1369                         Left := '(';
1370                         Right := ')';
1371
1372                      --  If the full view is an array type, we also retrieve
1373                      --  the corresponding component type, because the ali
1374                      --  entry already indicates that this is an array.
1375
1376                      elsif Is_Array_Type (Full_View (Tref)) then
1377                         Tref := Component_Type (Full_View (Tref));
1378                         Left := '(';
1379                         Right := ')';
1380                      end if;
1381
1382                   --  If non-derived array, get component type. Skip component
1383                   --  type for case of String or Wide_String, saves worthwhile
1384                   --  space.
1385
1386                   elsif Is_Array_Type (Tref)
1387                     and then Tref /= Standard_String
1388                     and then Tref /= Standard_Wide_String
1389                   then
1390                      Tref := Component_Type (Tref);
1391                      Left := '(';
1392                      Right := ')';
1393
1394                   --  For other non-derived base types, nothing
1395
1396                   else
1397                      exit;
1398                   end if;
1399
1400                --  For a subtype, go to ancestor subtype
1401
1402                else
1403                   Tref := Ancestor_Subtype (Tref);
1404
1405                   --  If no ancestor subtype, go to base type
1406
1407                   if No (Tref) then
1408                      Tref := Base_Type (Sav);
1409                   end if;
1410                end if;
1411
1412             --  For objects, functions, enum literals, just get type from
1413             --  Etype field.
1414
1415             elsif Is_Object (Tref)
1416               or else Ekind (Tref) = E_Enumeration_Literal
1417               or else Ekind (Tref) = E_Function
1418               or else Ekind (Tref) = E_Operator
1419             then
1420                Tref := Etype (Tref);
1421
1422                --  Another special case: an object of a classwide type
1423                --  initialized with a tag-indeterminate call gets a subtype
1424                --  of the classwide type during expansion. See if the original
1425                --  type in the declaration is named, and return it instead
1426                --  of going to the root type.
1427
1428                if Ekind (Tref) = E_Class_Wide_Subtype
1429                  and then Nkind (Parent (Ent)) = N_Object_Declaration
1430                  and then
1431                    Nkind (Original_Node (Object_Definition (Parent (Ent))))
1432                      = N_Identifier
1433                then
1434                   Tref :=
1435                     Entity
1436                       (Original_Node ((Object_Definition (Parent (Ent)))));
1437                end if;
1438
1439             --  For anything else, exit
1440
1441             else
1442                exit;
1443             end if;
1444
1445             --  Exit if no type reference, or we are stuck in some loop trying
1446             --  to find the type reference, or if the type is standard void
1447             --  type (the latter is an implementation artifact that should not
1448             --  show up in the generated cross-references).
1449
1450             exit when No (Tref)
1451               or else Tref = Sav
1452               or else Tref = Standard_Void_Type;
1453
1454             --  If we have a usable type reference, return, otherwise keep
1455             --  looking for something useful (we are looking for something
1456             --  that either comes from source or standard)
1457
1458             if Sloc (Tref) = Standard_Location
1459               or else Comes_From_Source (Tref)
1460             then
1461                --  If the reference is a subtype created for a generic actual,
1462                --  go actual directly, the inner subtype is not user visible.
1463
1464                if Nkind (Parent (Tref)) = N_Subtype_Declaration
1465                  and then not Comes_From_Source (Parent (Tref))
1466                  and then
1467                   (Is_Wrapper_Package (Scope (Tref))
1468                      or else Is_Generic_Instance (Scope (Tref)))
1469                then
1470                   Tref := First_Subtype (Base_Type (Tref));
1471                end if;
1472
1473                return;
1474             end if;
1475          end loop;
1476
1477          --  If we fall through the loop, no type reference
1478
1479          Tref := Empty;
1480          Left := ' ';
1481          Right := ' ';
1482       end Get_Type_Reference;
1483
1484       -------------------------------
1485       -- Output_Import_Export_Info --
1486       -------------------------------
1487
1488       procedure Output_Import_Export_Info (Ent : Entity_Id) is
1489          Language_Name : Name_Id;
1490          Conv          : constant Convention_Id := Convention (Ent);
1491
1492       begin
1493          --  Generate language name from convention
1494
1495          if Conv  = Convention_C then
1496             Language_Name := Name_C;
1497
1498          elsif Conv = Convention_CPP then
1499             Language_Name := Name_CPP;
1500
1501          elsif Conv = Convention_Ada then
1502             Language_Name := Name_Ada;
1503
1504          else
1505             --  For the moment we ignore all other cases ???
1506
1507             return;
1508          end if;
1509
1510          Write_Info_Char ('<');
1511          Get_Unqualified_Name_String (Language_Name);
1512
1513          for J in 1 .. Name_Len loop
1514             Write_Info_Char (Name_Buffer (J));
1515          end loop;
1516
1517          if Present (Interface_Name (Ent)) then
1518             Write_Info_Char (',');
1519             String_To_Name_Buffer (Strval (Interface_Name (Ent)));
1520
1521             for J in 1 .. Name_Len loop
1522                Write_Info_Char (Name_Buffer (J));
1523             end loop;
1524          end if;
1525
1526          Write_Info_Char ('>');
1527       end Output_Import_Export_Info;
1528
1529    --  Start of processing for Output_References
1530
1531    begin
1532       --  First we add references to the primitive operations of tagged types
1533       --  declared in the main unit.
1534
1535       Handle_Prim_Ops : declare
1536          Ent  : Entity_Id;
1537
1538       begin
1539          for J in 1 .. Xrefs.Last loop
1540             Ent := Xrefs.Table (J).Key.Ent;
1541
1542             if Is_Type (Ent)
1543               and then Is_Tagged_Type (Ent)
1544               and then Is_Base_Type (Ent)
1545               and then In_Extended_Main_Source_Unit (Ent)
1546             then
1547                Generate_Prim_Op_References (Ent);
1548             end if;
1549          end loop;
1550       end Handle_Prim_Ops;
1551
1552       --  Before we go ahead and output the references we have a problem
1553       --  that needs dealing with. So far we have captured things that are
1554       --  definitely referenced by the main unit, or defined in the main
1555       --  unit. That's because we don't want to clutter up the ali file
1556       --  for this unit with definition lines for entities in other units
1557       --  that are not referenced.
1558
1559       --  But there is a glitch. We may reference an entity in another unit,
1560       --  and it may have a type reference to an entity that is not directly
1561       --  referenced in the main unit, which may mean that there is no xref
1562       --  entry for this entity yet in the list of references.
1563
1564       --  If we don't do something about this, we will end with an orphan type
1565       --  reference, i.e. it will point to an entity that does not appear
1566       --  within the generated references in the ali file. That is not good for
1567       --  tools using the xref information.
1568
1569       --  To fix this, we go through the references adding definition entries
1570       --  for any unreferenced entities that can be referenced in a type
1571       --  reference. There is a recursion problem here, and that is dealt with
1572       --  by making sure that this traversal also traverses any entries that
1573       --  get added by the traversal.
1574
1575       Handle_Orphan_Type_References : declare
1576          J    : Nat;
1577          Tref : Entity_Id;
1578          Ent  : Entity_Id;
1579
1580          L, R : Character;
1581          pragma Warnings (Off, L);
1582          pragma Warnings (Off, R);
1583
1584          procedure New_Entry (E : Entity_Id);
1585          --  Make an additional entry into the Xref table for a type entity
1586          --  that is related to the current entity (parent, type ancestor,
1587          --  progenitor, etc.).
1588
1589          ----------------
1590          -- New_Entry --
1591          ----------------
1592
1593          procedure New_Entry (E : Entity_Id) is
1594          begin
1595             pragma Assert (Present (E));
1596
1597             if not Has_Xref_Entry (Implementation_Base_Type (E))
1598               and then Sloc (E) > No_Location
1599             then
1600                Add_Entry
1601                  ((Ent => E,
1602                    Loc => No_Location,
1603                    Typ => Character'First,
1604                    Eun => Get_Source_Unit (Original_Location (Sloc (E))),
1605                    Lun => No_Unit,
1606                    Ref_Scope => Empty,
1607                    Ent_Scope => Empty),
1608                   Ent_Scope_File => No_Unit);
1609             end if;
1610          end New_Entry;
1611
1612       --  Start of processing for Handle_Orphan_Type_References
1613
1614       begin
1615          --  Note that this is not a for loop for a very good reason. The
1616          --  processing of items in the table can add new items to the table,
1617          --  and they must be processed as well.
1618
1619          J := 1;
1620          while J <= Xrefs.Last loop
1621             Ent := Xrefs.Table (J).Key.Ent;
1622             Get_Type_Reference (Ent, Tref, L, R);
1623
1624             if Present (Tref)
1625               and then not Has_Xref_Entry (Tref)
1626               and then Sloc (Tref) > No_Location
1627             then
1628                New_Entry (Tref);
1629
1630                if Is_Record_Type (Ent)
1631                  and then Present (Interfaces (Ent))
1632                then
1633                   --  Add an entry for each one of the given interfaces
1634                   --  implemented by type Ent.
1635
1636                   declare
1637                      Elmt : Elmt_Id := First_Elmt (Interfaces (Ent));
1638                   begin
1639                      while Present (Elmt) loop
1640                         New_Entry (Node (Elmt));
1641                         Next_Elmt (Elmt);
1642                      end loop;
1643                   end;
1644                end if;
1645             end if;
1646
1647             --  Collect inherited primitive operations that may be declared in
1648             --  another unit and have no visible reference in the current one.
1649
1650             if Is_Type (Ent)
1651               and then Is_Tagged_Type (Ent)
1652               and then Is_Derived_Type (Ent)
1653               and then Is_Base_Type (Ent)
1654               and then In_Extended_Main_Source_Unit (Ent)
1655             then
1656                declare
1657                   Op_List : constant Elist_Id := Primitive_Operations (Ent);
1658                   Op      : Elmt_Id;
1659                   Prim    : Entity_Id;
1660
1661                   function Parent_Op (E : Entity_Id) return Entity_Id;
1662                   --  Find original operation, which may be inherited through
1663                   --  several derivations.
1664
1665                   function Parent_Op (E : Entity_Id) return Entity_Id is
1666                      Orig_Op : constant Entity_Id := Alias (E);
1667
1668                   begin
1669                      if No (Orig_Op) then
1670                         return Empty;
1671
1672                      elsif not Comes_From_Source (E)
1673                        and then not Has_Xref_Entry (Orig_Op)
1674                        and then Comes_From_Source (Orig_Op)
1675                      then
1676                         return Orig_Op;
1677                      else
1678                         return Parent_Op (Orig_Op);
1679                      end if;
1680                   end Parent_Op;
1681
1682                begin
1683                   Op := First_Elmt (Op_List);
1684                   while Present (Op) loop
1685                      Prim := Parent_Op (Node (Op));
1686
1687                      if Present (Prim) then
1688                         Add_Entry
1689                           ((Ent => Prim,
1690                             Loc => No_Location,
1691                             Typ => Character'First,
1692                             Eun => Get_Source_Unit (Sloc (Prim)),
1693                             Lun => No_Unit,
1694                             Ref_Scope => Empty,
1695                             Ent_Scope => Empty),
1696                            Ent_Scope_File => No_Unit);
1697                      end if;
1698
1699                      Next_Elmt (Op);
1700                   end loop;
1701                end;
1702             end if;
1703
1704             J := J + 1;
1705          end loop;
1706       end Handle_Orphan_Type_References;
1707
1708       --  Now we have all the references, including those for any embedded
1709       --  type references, so we can sort them, and output them.
1710
1711       Output_Refs : declare
1712
1713          Nrefs : constant Nat := Xrefs.Last;
1714          --  Number of references in table
1715
1716          Rnums : array (0 .. Nrefs) of Nat;
1717          --  This array contains numbers of references in the Xrefs table.
1718          --  This list is sorted in output order. The extra 0'th entry is
1719          --  convenient for the call to sort. When we sort the table, we
1720          --  move the entries in Rnums around, but we do not move the
1721          --  original table entries.
1722
1723          Curxu : Unit_Number_Type;
1724          --  Current xref unit
1725
1726          Curru : Unit_Number_Type;
1727          --  Current reference unit for one entity
1728
1729          Curent : Entity_Id;
1730          --  Current entity
1731
1732          Curnam : String (1 .. Name_Buffer'Length);
1733          Curlen : Natural;
1734          --  Simple name and length of current entity
1735
1736          Curdef : Source_Ptr;
1737          --  Original source location for current entity
1738
1739          Crloc : Source_Ptr;
1740          --  Current reference location
1741
1742          Ctyp : Character;
1743          --  Entity type character
1744
1745          Prevt : Character;
1746          --  reference kind of previous reference
1747
1748          Tref : Entity_Id;
1749          --  Type reference
1750
1751          Rref : Node_Id;
1752          --  Renaming reference
1753
1754          Trunit : Unit_Number_Type;
1755          --  Unit number for type reference
1756
1757          function Lt (Op1, Op2 : Natural) return Boolean;
1758          --  Comparison function for Sort call
1759
1760          function Name_Change (X : Entity_Id) return Boolean;
1761          --  Determines if entity X has a different simple name from Curent
1762
1763          procedure Move (From : Natural; To : Natural);
1764          --  Move procedure for Sort call
1765
1766          package Sorting is new GNAT.Heap_Sort_G (Move, Lt);
1767
1768          --------
1769          -- Lt --
1770          --------
1771
1772          function Lt (Op1, Op2 : Natural) return Boolean is
1773             T1 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op1)));
1774             T2 : Xref_Entry renames Xrefs.Table (Rnums (Nat (Op2)));
1775
1776          begin
1777             return Lt (T1, T2);
1778          end Lt;
1779
1780          ----------
1781          -- Move --
1782          ----------
1783
1784          procedure Move (From : Natural; To : Natural) is
1785          begin
1786             Rnums (Nat (To)) := Rnums (Nat (From));
1787          end Move;
1788
1789          -----------------
1790          -- Name_Change --
1791          -----------------
1792
1793          --  Why a string comparison here??? Why not compare Name_Id values???
1794
1795          function Name_Change (X : Entity_Id) return Boolean is
1796          begin
1797             Get_Unqualified_Name_String (Chars (X));
1798
1799             if Name_Len /= Curlen then
1800                return True;
1801             else
1802                return Name_Buffer (1 .. Curlen) /= Curnam (1 .. Curlen);
1803             end if;
1804          end Name_Change;
1805
1806       --  Start of processing for Output_Refs
1807
1808       begin
1809          --  Capture the definition Sloc values. We delay doing this till now,
1810          --  since at the time the reference or definition is made, private
1811          --  types may be swapped, and the Sloc value may be incorrect. We
1812          --  also set up the pointer vector for the sort.
1813
1814          --  For user-defined operators we need to skip the initial quote and
1815          --  point to the first character of the name, for navigation purposes.
1816
1817          for J in 1 .. Nrefs loop
1818             declare
1819                E   : constant Entity_Id  := Xrefs.Table (J).Key.Ent;
1820                Loc : constant Source_Ptr := Original_Location (Sloc (E));
1821
1822             begin
1823                Rnums (J) := J;
1824
1825                if Nkind (E) = N_Defining_Operator_Symbol then
1826                   Xrefs.Table (J).Def := Loc + 1;
1827                else
1828                   Xrefs.Table (J).Def := Loc;
1829                end if;
1830             end;
1831          end loop;
1832
1833          --  Sort the references
1834
1835          Sorting.Sort (Integer (Nrefs));
1836
1837          --  Initialize loop through references
1838
1839          Curxu  := No_Unit;
1840          Curent := Empty;
1841          Curdef := No_Location;
1842          Curru  := No_Unit;
1843          Crloc  := No_Location;
1844          Prevt  := 'm';
1845
1846          --  Loop to output references
1847
1848          for Refno in 1 .. Nrefs loop
1849             Output_One_Ref : declare
1850                Ent : Entity_Id;
1851
1852                XE : Xref_Entry renames Xrefs.Table (Rnums (Refno));
1853                --  The current entry to be accessed
1854
1855                Left  : Character;
1856                Right : Character;
1857                --  Used for {} or <> or () for type reference
1858
1859                procedure Check_Type_Reference
1860                  (Ent            : Entity_Id;
1861                   List_Interface : Boolean);
1862                --  Find whether there is a meaningful type reference for
1863                --  Ent, and display it accordingly. If List_Interface is
1864                --  true, then Ent is a progenitor interface of the current
1865                --  type entity being listed. In that case list it as is,
1866                --  without looking for a type reference for it.
1867
1868                procedure Output_Instantiation_Refs (Loc : Source_Ptr);
1869                --  Recursive procedure to output instantiation references for
1870                --  the given source ptr in [file|line[...]] form. No output
1871                --  if the given location is not a generic template reference.
1872
1873                procedure Output_Overridden_Op (Old_E : Entity_Id);
1874                --  For a subprogram that is overriding, display information
1875                --  about the inherited operation that it overrides.
1876
1877                --------------------------
1878                -- Check_Type_Reference --
1879                --------------------------
1880
1881                procedure Check_Type_Reference
1882                  (Ent            : Entity_Id;
1883                   List_Interface : Boolean)
1884                is
1885                begin
1886                   if List_Interface then
1887
1888                      --  This is a progenitor interface of the type for which
1889                      --  xref information is being generated.
1890
1891                      Tref  := Ent;
1892                      Left  := '<';
1893                      Right := '>';
1894
1895                   else
1896                      Get_Type_Reference (Ent, Tref, Left, Right);
1897                   end if;
1898
1899                   if Present (Tref) then
1900
1901                      --  Case of standard entity, output name
1902
1903                      if Sloc (Tref) = Standard_Location then
1904                         Write_Info_Char (Left);
1905                         Write_Info_Name (Chars (Tref));
1906                         Write_Info_Char (Right);
1907
1908                      --  Case of source entity, output location
1909
1910                      else
1911                         Write_Info_Char (Left);
1912                         Trunit := Get_Source_Unit (Sloc (Tref));
1913
1914                         if Trunit /= Curxu then
1915                            Write_Info_Nat (Dependency_Num (Trunit));
1916                            Write_Info_Char ('|');
1917                         end if;
1918
1919                         Write_Info_Nat
1920                           (Int (Get_Logical_Line_Number (Sloc (Tref))));
1921
1922                         declare
1923                            Ent  : Entity_Id;
1924                            Ctyp : Character;
1925
1926                         begin
1927                            Ent := Tref;
1928                            Ctyp := Xref_Entity_Letters (Ekind (Ent));
1929
1930                            if Ctyp = '+'
1931                              and then Present (Full_View (Ent))
1932                            then
1933                               Ent := Underlying_Type (Ent);
1934
1935                               if Present (Ent) then
1936                                  Ctyp := Xref_Entity_Letters (Ekind (Ent));
1937                               end if;
1938                            end if;
1939
1940                            Write_Info_Char (Ctyp);
1941                         end;
1942
1943                         Write_Info_Nat
1944                           (Int (Get_Column_Number (Sloc (Tref))));
1945
1946                         --  If the type comes from an instantiation, add the
1947                         --  corresponding info.
1948
1949                         Output_Instantiation_Refs (Sloc (Tref));
1950                         Write_Info_Char (Right);
1951                      end if;
1952                   end if;
1953                end Check_Type_Reference;
1954
1955                -------------------------------
1956                -- Output_Instantiation_Refs --
1957                -------------------------------
1958
1959                procedure Output_Instantiation_Refs (Loc : Source_Ptr) is
1960                   Iloc : constant Source_Ptr := Instantiation_Location (Loc);
1961                   Lun  : Unit_Number_Type;
1962                   Cu   : constant Unit_Number_Type := Curru;
1963
1964                begin
1965                   --  Nothing to do if this is not an instantiation
1966
1967                   if Iloc = No_Location then
1968                      return;
1969                   end if;
1970
1971                   --  Output instantiation reference
1972
1973                   Write_Info_Char ('[');
1974                   Lun := Get_Source_Unit (Iloc);
1975
1976                   if Lun /= Curru then
1977                      Curru := Lun;
1978                      Write_Info_Nat (Dependency_Num (Curru));
1979                      Write_Info_Char ('|');
1980                   end if;
1981
1982                   Write_Info_Nat (Int (Get_Logical_Line_Number (Iloc)));
1983
1984                   --  Recursive call to get nested instantiations
1985
1986                   Output_Instantiation_Refs (Iloc);
1987
1988                   --  Output final ] after call to get proper nesting
1989
1990                   Write_Info_Char (']');
1991                   Curru := Cu;
1992                   return;
1993                end Output_Instantiation_Refs;
1994
1995                --------------------------
1996                -- Output_Overridden_Op --
1997                --------------------------
1998
1999                procedure Output_Overridden_Op (Old_E : Entity_Id) is
2000                   Op : Entity_Id;
2001
2002                begin
2003                   --  The overridden operation has an implicit declaration
2004                   --  at the point of derivation. What we want to display
2005                   --  is the original operation, which has the actual body
2006                   --  (or abstract declaration) that is being overridden.
2007                   --  The overridden operation is not always set, e.g. when
2008                   --  it is a predefined operator.
2009
2010                   if No (Old_E) then
2011                      return;
2012
2013                   --  Follow alias chain if one is present
2014
2015                   elsif Present (Alias (Old_E)) then
2016
2017                      --  The subprogram may have been implicitly inherited
2018                      --  through several levels of derivation, so find the
2019                      --  ultimate (source) ancestor.
2020
2021                      Op := Ultimate_Alias (Old_E);
2022
2023                   --  Normal case of no alias present. We omit generated
2024                   --  primitives like tagged equality, that have no source
2025                   --  representation.
2026
2027                   else
2028                      Op := Old_E;
2029                   end if;
2030
2031                   if Present (Op)
2032                     and then Sloc (Op) /= Standard_Location
2033                     and then Comes_From_Source (Op)
2034                   then
2035                      declare
2036                         Loc      : constant Source_Ptr := Sloc (Op);
2037                         Par_Unit : constant Unit_Number_Type :=
2038                                      Get_Source_Unit (Loc);
2039
2040                      begin
2041                         Write_Info_Char ('<');
2042
2043                         if Par_Unit /= Curxu then
2044                            Write_Info_Nat (Dependency_Num (Par_Unit));
2045                            Write_Info_Char ('|');
2046                         end if;
2047
2048                         Write_Info_Nat (Int (Get_Logical_Line_Number (Loc)));
2049                         Write_Info_Char ('p');
2050                         Write_Info_Nat (Int (Get_Column_Number (Loc)));
2051                         Write_Info_Char ('>');
2052                      end;
2053                   end if;
2054                end Output_Overridden_Op;
2055
2056             --  Start of processing for Output_One_Ref
2057
2058             begin
2059                Ent := XE.Key.Ent;
2060                Ctyp := Xref_Entity_Letters (Ekind (Ent));
2061
2062                --  Skip reference if it is the only reference to an entity,
2063                --  and it is an END line reference, and the entity is not in
2064                --  the current extended source. This prevents junk entries
2065                --  consisting only of packages with END lines, where no
2066                --  entity from the package is actually referenced.
2067
2068                if XE.Key.Typ = 'e'
2069                  and then Ent /= Curent
2070                  and then (Refno = Nrefs
2071                             or else
2072                               Ent /= Xrefs.Table (Rnums (Refno + 1)).Key.Ent)
2073                  and then not In_Extended_Main_Source_Unit (Ent)
2074                then
2075                   goto Continue;
2076                end if;
2077
2078                --  For private type, get full view type
2079
2080                if Ctyp = '+'
2081                  and then Present (Full_View (XE.Key.Ent))
2082                then
2083                   Ent := Underlying_Type (Ent);
2084
2085                   if Present (Ent) then
2086                      Ctyp := Xref_Entity_Letters (Ekind (Ent));
2087                   end if;
2088                end if;
2089
2090                --  Special exception for Boolean
2091
2092                if Ctyp = 'E' and then Is_Boolean_Type (Ent) then
2093                   Ctyp := 'B';
2094                end if;
2095
2096                --  For variable reference, get corresponding type
2097
2098                if Ctyp = '*' then
2099                   Ent := Etype (XE.Key.Ent);
2100                   Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
2101
2102                   --  If variable is private type, get full view type
2103
2104                   if Ctyp = '+'
2105                     and then Present (Full_View (Etype (XE.Key.Ent)))
2106                   then
2107                      Ent := Underlying_Type (Etype (XE.Key.Ent));
2108
2109                      if Present (Ent) then
2110                         Ctyp := Fold_Lower (Xref_Entity_Letters (Ekind (Ent)));
2111                      end if;
2112
2113                   elsif Is_Generic_Type (Ent) then
2114
2115                      --  If the type of the entity is a generic private type,
2116                      --  there is no usable full view, so retain the indication
2117                      --  that this is an object.
2118
2119                      Ctyp := '*';
2120                   end if;
2121
2122                   --  Special handling for access parameters and objects and
2123                   --  components of an anonymous access type.
2124
2125                   if Ekind_In (Etype (XE.Key.Ent),
2126                                E_Anonymous_Access_Type,
2127                                E_Anonymous_Access_Subprogram_Type,
2128                                E_Anonymous_Access_Protected_Subprogram_Type)
2129                   then
2130                      if Is_Formal (XE.Key.Ent)
2131                        or else
2132                          Ekind_In
2133                            (XE.Key.Ent, E_Variable, E_Constant, E_Component)
2134                      then
2135                         Ctyp := 'p';
2136                      end if;
2137
2138                      --  Special handling for Boolean
2139
2140                   elsif Ctyp = 'e' and then Is_Boolean_Type (Ent) then
2141                      Ctyp := 'b';
2142                   end if;
2143                end if;
2144
2145                --  Special handling for abstract types and operations
2146
2147                if Is_Overloadable (XE.Key.Ent)
2148                  and then Is_Abstract_Subprogram (XE.Key.Ent)
2149                then
2150                   if Ctyp = 'U' then
2151                      Ctyp := 'x';            --  Abstract procedure
2152
2153                   elsif Ctyp = 'V' then
2154                      Ctyp := 'y';            --  Abstract function
2155                   end if;
2156
2157                elsif Is_Type (XE.Key.Ent)
2158                  and then Is_Abstract_Type (XE.Key.Ent)
2159                then
2160                   if Is_Interface (XE.Key.Ent) then
2161                      Ctyp := 'h';
2162
2163                   elsif Ctyp = 'R' then
2164                      Ctyp := 'H';            --  Abstract type
2165                   end if;
2166                end if;
2167
2168                --  Only output reference if interesting type of entity
2169
2170                if Ctyp = ' '
2171
2172                --  Suppress references to object definitions, used for local
2173                --  references.
2174
2175                  or else XE.Key.Typ = 'D'
2176                  or else XE.Key.Typ = 'I'
2177
2178                --  Suppress self references, except for bodies that act as
2179                --  specs.
2180
2181                  or else (XE.Key.Loc = XE.Def
2182                            and then
2183                              (XE.Key.Typ /= 'b'
2184                                or else not Is_Subprogram (XE.Key.Ent)))
2185
2186                --  Also suppress definitions of body formals (we only
2187                --  treat these as references, and the references were
2188                --  separately recorded).
2189
2190                  or else (Is_Formal (XE.Key.Ent)
2191                            and then Present (Spec_Entity (XE.Key.Ent)))
2192                then
2193                   null;
2194
2195                else
2196                   --  Start new Xref section if new xref unit
2197
2198                   if XE.Key.Eun /= Curxu then
2199                      if Write_Info_Col > 1 then
2200                         Write_Info_EOL;
2201                      end if;
2202
2203                      Curxu := XE.Key.Eun;
2204
2205                      Write_Info_Initiate ('X');
2206                      Write_Info_Char (' ');
2207                      Write_Info_Nat (Dependency_Num (XE.Key.Eun));
2208                      Write_Info_Char (' ');
2209                      Write_Info_Name
2210                        (Reference_Name (Source_Index (XE.Key.Eun)));
2211                   end if;
2212
2213                   --  Start new Entity line if new entity. Note that we
2214                   --  consider two entities the same if they have the same
2215                   --  name and source location. This causes entities in
2216                   --  instantiations to be treated as though they referred
2217                   --  to the template.
2218
2219                   if No (Curent)
2220                     or else
2221                       (XE.Key.Ent /= Curent
2222                          and then
2223                            (Name_Change (XE.Key.Ent) or else XE.Def /= Curdef))
2224                   then
2225                      Curent := XE.Key.Ent;
2226                      Curdef := XE.Def;
2227
2228                      Get_Unqualified_Name_String (Chars (XE.Key.Ent));
2229                      Curlen := Name_Len;
2230                      Curnam (1 .. Curlen) := Name_Buffer (1 .. Curlen);
2231
2232                      if Write_Info_Col > 1 then
2233                         Write_Info_EOL;
2234                      end if;
2235
2236                      --  Write column number information
2237
2238                      Write_Info_Nat (Int (Get_Logical_Line_Number (XE.Def)));
2239                      Write_Info_Char (Ctyp);
2240                      Write_Info_Nat (Int (Get_Column_Number (XE.Def)));
2241
2242                      --  Write level information
2243
2244                      Write_Level_Info : declare
2245                         function Is_Visible_Generic_Entity
2246                           (E : Entity_Id) return Boolean;
2247                         --  Check whether E is declared in the visible part
2248                         --  of a generic package. For source navigation
2249                         --  purposes, treat this as a visible entity.
2250
2251                         function Is_Private_Record_Component
2252                           (E : Entity_Id) return Boolean;
2253                         --  Check whether E is a non-inherited component of a
2254                         --  private extension. Even if the enclosing record is
2255                         --  public, we want to treat the component as private
2256                         --  for navigation purposes.
2257
2258                         ---------------------------------
2259                         -- Is_Private_Record_Component --
2260                         ---------------------------------
2261
2262                         function Is_Private_Record_Component
2263                           (E : Entity_Id) return Boolean
2264                         is
2265                            S : constant Entity_Id := Scope (E);
2266                         begin
2267                            return
2268                              Ekind (E) = E_Component
2269                                and then Nkind (Declaration_Node (S)) =
2270                                  N_Private_Extension_Declaration
2271                                and then Original_Record_Component (E) = E;
2272                         end Is_Private_Record_Component;
2273
2274                         -------------------------------
2275                         -- Is_Visible_Generic_Entity --
2276                         -------------------------------
2277
2278                         function Is_Visible_Generic_Entity
2279                           (E : Entity_Id) return Boolean
2280                         is
2281                            Par : Node_Id;
2282
2283                         begin
2284                            --  The Present check here is an error defense
2285
2286                            if Present (Scope (E))
2287                              and then Ekind (Scope (E)) /= E_Generic_Package
2288                            then
2289                               return False;
2290                            end if;
2291
2292                            Par := Parent (E);
2293                            while Present (Par) loop
2294                               if
2295                                 Nkind (Par) = N_Generic_Package_Declaration
2296                               then
2297                                  --  Entity is a generic formal
2298
2299                                  return False;
2300
2301                               elsif
2302                                 Nkind (Parent (Par)) = N_Package_Specification
2303                               then
2304                                  return
2305                                    Is_List_Member (Par)
2306                                      and then List_Containing (Par) =
2307                                        Visible_Declarations (Parent (Par));
2308                               else
2309                                  Par := Parent (Par);
2310                               end if;
2311                            end loop;
2312
2313                            return False;
2314                         end Is_Visible_Generic_Entity;
2315
2316                      --  Start of processing for Write_Level_Info
2317
2318                      begin
2319                         if Is_Hidden (Curent)
2320                           or else Is_Private_Record_Component (Curent)
2321                         then
2322                            Write_Info_Char (' ');
2323
2324                         elsif
2325                            Is_Public (Curent)
2326                              or else Is_Visible_Generic_Entity (Curent)
2327                         then
2328                            Write_Info_Char ('*');
2329
2330                         else
2331                            Write_Info_Char (' ');
2332                         end if;
2333                      end Write_Level_Info;
2334
2335                      --  Output entity name. We use the occurrence from the
2336                      --  actual source program at the definition point.
2337
2338                      declare
2339                         Ent_Name : constant String :=
2340                                      Exact_Source_Name (Sloc (XE.Key.Ent));
2341                      begin
2342                         for C in Ent_Name'Range loop
2343                            Write_Info_Char (Ent_Name (C));
2344                         end loop;
2345                      end;
2346
2347                      --  See if we have a renaming reference
2348
2349                      if Is_Object (XE.Key.Ent)
2350                        and then Present (Renamed_Object (XE.Key.Ent))
2351                      then
2352                         Rref := Renamed_Object (XE.Key.Ent);
2353
2354                      elsif Is_Overloadable (XE.Key.Ent)
2355                        and then Nkind (Parent (Declaration_Node (XE.Key.Ent)))
2356                                            = N_Subprogram_Renaming_Declaration
2357                      then
2358                         Rref := Name (Parent (Declaration_Node (XE.Key.Ent)));
2359
2360                      elsif Ekind (XE.Key.Ent) = E_Package
2361                        and then Nkind (Declaration_Node (XE.Key.Ent)) =
2362                                          N_Package_Renaming_Declaration
2363                      then
2364                         Rref := Name (Declaration_Node (XE.Key.Ent));
2365
2366                      else
2367                         Rref := Empty;
2368                      end if;
2369
2370                      if Present (Rref) then
2371                         if Nkind (Rref) = N_Expanded_Name then
2372                            Rref := Selector_Name (Rref);
2373                         end if;
2374
2375                         if Nkind (Rref) = N_Identifier
2376                           or else Nkind (Rref) = N_Operator_Symbol
2377                         then
2378                            null;
2379
2380                         --  For renamed array components, use the array name
2381                         --  for the renamed entity, which reflect the fact that
2382                         --  in general the whole array is aliased.
2383
2384                         elsif Nkind (Rref) = N_Indexed_Component then
2385                            if Nkind (Prefix (Rref)) = N_Identifier then
2386                               Rref := Prefix (Rref);
2387                            elsif Nkind (Prefix (Rref)) = N_Expanded_Name then
2388                               Rref := Selector_Name (Prefix (Rref));
2389                            else
2390                               Rref := Empty;
2391                            end if;
2392
2393                         else
2394                            Rref := Empty;
2395                         end if;
2396                      end if;
2397
2398                      --  Write out renaming reference if we have one
2399
2400                      if Present (Rref) then
2401                         Write_Info_Char ('=');
2402                         Write_Info_Nat
2403                           (Int (Get_Logical_Line_Number (Sloc (Rref))));
2404                         Write_Info_Char (':');
2405                         Write_Info_Nat
2406                           (Int (Get_Column_Number (Sloc (Rref))));
2407                      end if;
2408
2409                      --  Indicate that the entity is in the unit of the current
2410                      --  xref section.
2411
2412                      Curru := Curxu;
2413
2414                      --  Write out information about generic parent, if entity
2415                      --  is an instance.
2416
2417                      if  Is_Generic_Instance (XE.Key.Ent) then
2418                         declare
2419                            Gen_Par : constant Entity_Id :=
2420                                        Generic_Parent
2421                                          (Specification
2422                                             (Unit_Declaration_Node
2423                                                (XE.Key.Ent)));
2424                            Loc     : constant Source_Ptr := Sloc (Gen_Par);
2425                            Gen_U   : constant Unit_Number_Type :=
2426                                        Get_Source_Unit (Loc);
2427
2428                         begin
2429                            Write_Info_Char ('[');
2430
2431                            if Curru /= Gen_U then
2432                               Write_Info_Nat (Dependency_Num (Gen_U));
2433                               Write_Info_Char ('|');
2434                            end if;
2435
2436                            Write_Info_Nat
2437                              (Int (Get_Logical_Line_Number (Loc)));
2438                            Write_Info_Char (']');
2439                         end;
2440                      end if;
2441
2442                      --  See if we have a type reference and if so output
2443
2444                      Check_Type_Reference (XE.Key.Ent, False);
2445
2446                      --  Additional information for types with progenitors,
2447                      --  including synchronized tagged types.
2448
2449                      declare
2450                         Typ  : constant Entity_Id := XE.Key.Ent;
2451                         Elmt : Elmt_Id;
2452
2453                      begin
2454                         if Is_Record_Type (Typ)
2455                           and then Present (Interfaces (Typ))
2456                         then
2457                            Elmt := First_Elmt (Interfaces (Typ));
2458
2459                         elsif Is_Concurrent_Type (Typ)
2460                           and then Present (Corresponding_Record_Type (Typ))
2461                           and then Present (
2462                             Interfaces (Corresponding_Record_Type (Typ)))
2463                         then
2464                            Elmt :=
2465                              First_Elmt (
2466                               Interfaces (Corresponding_Record_Type (Typ)));
2467
2468                         else
2469                            Elmt := No_Elmt;
2470                         end if;
2471
2472                         while Present (Elmt) loop
2473                            Check_Type_Reference (Node (Elmt), True);
2474                            Next_Elmt (Elmt);
2475                         end loop;
2476                      end;
2477
2478                      --  For array types, list index types as well. (This is
2479                      --  not C, indexes have distinct types).
2480
2481                      if Is_Array_Type (XE.Key.Ent) then
2482                         declare
2483                            Indx : Node_Id;
2484                         begin
2485                            Indx := First_Index (XE.Key.Ent);
2486                            while Present (Indx) loop
2487                               Check_Type_Reference
2488                                 (First_Subtype (Etype (Indx)), True);
2489                               Next_Index (Indx);
2490                            end loop;
2491                         end;
2492                      end if;
2493
2494                      --  If the entity is an overriding operation, write info
2495                      --  on operation that was overridden.
2496
2497                      if Is_Subprogram (XE.Key.Ent)
2498                        and then Present (Overridden_Operation (XE.Key.Ent))
2499                      then
2500                         Output_Overridden_Op
2501                           (Overridden_Operation (XE.Key.Ent));
2502                      end if;
2503
2504                      --  End of processing for entity output
2505
2506                      Crloc := No_Location;
2507                   end if;
2508
2509                   --  Output the reference if it is not as the same location
2510                   --  as the previous one, or it is a read-reference that
2511                   --  indicates that the entity is an in-out actual in a call.
2512
2513                   if XE.Key.Loc /= No_Location
2514                     and then
2515                       (XE.Key.Loc /= Crloc
2516                         or else (Prevt = 'm' and then  XE.Key.Typ = 'r'))
2517                   then
2518                      Crloc := XE.Key.Loc;
2519                      Prevt := XE.Key.Typ;
2520
2521                      --  Start continuation if line full, else blank
2522
2523                      if Write_Info_Col > 72 then
2524                         Write_Info_EOL;
2525                         Write_Info_Initiate ('.');
2526                      end if;
2527
2528                      Write_Info_Char (' ');
2529
2530                      --  Output file number if changed
2531
2532                      if XE.Key.Lun /= Curru then
2533                         Curru := XE.Key.Lun;
2534                         Write_Info_Nat (Dependency_Num (Curru));
2535                         Write_Info_Char ('|');
2536                      end if;
2537
2538                      Write_Info_Nat
2539                        (Int (Get_Logical_Line_Number (XE.Key.Loc)));
2540                      Write_Info_Char (XE.Key.Typ);
2541
2542                      if Is_Overloadable (XE.Key.Ent) then
2543                         if (Is_Imported (XE.Key.Ent) and then XE.Key.Typ = 'b')
2544                              or else
2545                            (Is_Exported (XE.Key.Ent) and then XE.Key.Typ = 'i')
2546                         then
2547                            Output_Import_Export_Info (XE.Key.Ent);
2548                         end if;
2549                      end if;
2550
2551                      Write_Info_Nat (Int (Get_Column_Number (XE.Key.Loc)));
2552
2553                      Output_Instantiation_Refs (Sloc (XE.Key.Ent));
2554                   end if;
2555                end if;
2556             end Output_One_Ref;
2557
2558          <<Continue>>
2559             null;
2560          end loop;
2561
2562          Write_Info_EOL;
2563       end Output_Refs;
2564    end Output_References;
2565
2566 --  Start of elaboration for Lib.Xref
2567
2568 begin
2569    --  Reset is necessary because Elmt_Ptr does not default to Null_Ptr,
2570    --  because it's not an access type.
2571
2572    Xref_Set.Reset;
2573 end Lib.Xref;