libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([xmalloc.c])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  66 # rely on it - libiberty is built before texinfo.
  67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  68 if test "x$MAKEINFO" = "x"; then
  69     MAKEINFO="@echo makeinfo missing; true"
  70     BUILD_INFO=
  71 else
  72     BUILD_INFO=info
  73     case "$MAKEINFO" in
  74       */missing\ makeinfo*)
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is missing. Info documentation will not be built.])
  78         ;;
  79       *)
  80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  81           x*\ [[1-3]].* )
  82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  83             BUILD_INFO=
  84             AC_MSG_WARN([
  85 *** Makeinfo is too old. Info documentation will not be built.])
  86           ;;
  87         esac
  88         ;;
  89     esac
  90 fi
  91 AC_SUBST(MAKEINFO)
  92 AC_SUBST(BUILD_INFO)
  93
  94 AC_CHECK_PROG(PERL, perl, perl, )
  95 if test x"$PERL" = x""; then
  96   HAVE_PERL='#'
  97 else
  98   HAVE_PERL=''
  99 fi
 100 AC_SUBST(HAVE_PERL)
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl When we start using automake:
 105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 106
 107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 108 dnl to call AC_CHECK_PROG.
 109 AC_CHECK_TOOL(AR, ar)
 110 AC_CHECK_TOOL(RANLIB, ranlib, :)
 111
 112 GCC_NO_EXECUTABLES
 113 AC_PROG_CC
 114 AC_PROG_CPP_WERROR
 115
 116 if test x$GCC = xyes; then
 117   ac_libiberty_warn_cflags='-W -Wall -pedantic -Wwrite-strings -Wstrict-prototypes'
 118 fi
 119 AC_SUBST(ac_libiberty_warn_cflags)
 120
 121 AC_PROG_CC_C_O
 122 # autoconf is lame and doesn't give us any substitution variable for this.
 123 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 124   NO_MINUS_C_MINUS_O=yes
 125 else
 126   OUTPUT_OPTION='-o $@'
 127 fi
 128 AC_SUBST(NO_MINUS_C_MINUS_O)
 129 AC_SUBST(OUTPUT_OPTION)
 130
 131 AC_C_CONST
 132 AC_C_INLINE
 133 AC_C_BIGENDIAN
 134
 135 dnl When we start using libtool:
 136 dnl Default to a non shared library.  This may be overridden by the
 137 dnl configure option --enable-shared.
 138 dnl AM_DISABLE_SHARED
 139
 140 dnl When we start using libtool:
 141 dnl AM_PROG_LIBTOOL
 142
 143 dnl When we start using automake:
 144 dnl AM_CONFIG_HEADER(config.h:config.in)
 145 AC_CONFIG_HEADER(config.h:config.in)
 146
 147 dnl When we start using automake:
 148 dnl AM_MAINTAINER_MODE
 149 dnl AC_EXEEXT
 150
 151 dnl When we start using automake:
 152 dnl AM_PROG_INSTALL
 153 AC_PROG_INSTALL
 154
 155 # Don't build the shared library for build.
 156 if [[ -n "${with_build_subdir}" ]]; then
 157   enable_shared=no
 158 fi
 159
 160 frag=
 161 case "${host}" in
 162   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 163                         frag=mh-aix ;;
 164   *-*-cxux7*)           frag=mh-cxux7 ;;
 165   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 166   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 167   i370-*-opened*)       frag=mh-openedition ;;
 168   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 169 esac
 170
 171 if [[ -n "${frag}" ]]; then
 172   frags=${libiberty_topdir}/libiberty/config/$frag
 173 else
 174   frags=
 175 fi
 176
 177 # If they didn't specify --enable-shared, don't generate shared libs.
 178 case "${enable_shared}" in
 179   yes) shared=yes ;;
 180   no) shared=no ;;
 181   "") shared=no ;;
 182   *) shared=yes ;;
 183 esac
 184 if [[ "${shared}" = "yes" ]]; then
 185   frag=
 186   case "${host}" in
 187     *-*-cygwin*)        ;;
 188     alpha*-*-linux*)    frag=mh-elfalphapic ;;
 189     arm*-*-*)           frag=mh-armpic ;;
 190     hppa*-*-*)          frag=mh-papic ;;
 191     i[[34567]]86-*-* | x86_64-*-*)
 192                         frag=mh-x86pic ;;
 193     powerpc*-*-aix*)    ;;
 194     powerpc*-*-*)       frag=mh-ppcpic ;;
 195     sparc*-*-*)         frag=mh-sparcpic ;;
 196     s390*-*-*)          frag=mh-s390pic ;;
 197     *)                  frag=mh-${host_cpu}pic ;;
 198   esac
 199   if [[ -n "${frag}" ]]; then
 200     frags="${frags} ${libiberty_topdir}/config/${frag}"
 201   fi
 202 fi
 203
 204 echo "# Warning: this fragment is automatically generated" > temp-frag
 205
 206 for frag in ${frags}; do
 207   if [[ -f ${frag} ]]; then
 208     echo "Appending ${frag} to xhost-mkfrag"
 209     echo "# Following fragment copied from ${frag}" >> temp-frag
 210     cat ${frag} >> temp-frag
 211   fi
 212 done
 213
 214 # record if we want to build shared libs.
 215 if [[ "${shared}" = "yes" ]]; then
 216   echo enable_shared = yes >> temp-frag
 217 else
 218   echo enable_shared = no >> temp-frag
 219 fi
 220
 221 frag=xhost-mkfrag
 222 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 223
 224 host_makefile_frag=${frag}
 225 AC_SUBST_FILE(host_makefile_frag)
 226
 227 # It's OK to check for header files.  Although the compiler may not be
 228 # able to link anything, it had better be able to at least compile
 229 # something.
 230 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h)
 231 AC_HEADER_SYS_WAIT
 232 AC_HEADER_TIME
 233
 234 libiberty_AC_DECLARE_ERRNO
 235
 236 # Determine the size of an int for struct fibnode.
 237 AC_CHECK_SIZEOF([int])
 238
 239 AC_CHECK_TYPE(uintptr_t, unsigned long)
 240
 241 # Look for a 64-bit type.
 242 AC_MSG_CHECKING([for a 64-bit type])
 243 AC_CACHE_VAL(liberty_cv_uint64,
 244 [AC_TRY_COMPILE(
 245 [#ifdef HAVE_STDINT_H
 246 #include <stdint.h>
 247 #endif],
 248 [extern uint64_t foo;],
 249 liberty_cv_uint64=uint64_t,
 250 [AC_TRY_COMPILE(
 251 [#ifdef HAVE_LIMITS_H
 252 #include <limits.h>
 253 #endif
 254 #ifndef CHAR_BIT
 255 #define CHAR_BIT 8
 256 #endif],
 257 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 258 liberty_cv_uint64="unsigned long",
 259 [AC_TRY_COMPILE(
 260 [#ifdef HAVE_LIMITS_H
 261 #include <limits.h>
 262 #endif
 263 #ifndef CHAR_BIT
 264 #define CHAR_BIT 8
 265 #endif],
 266 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 267 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 268 AC_MSG_RESULT($liberty_cv_uint64)
 269 if test "$liberty_cv_uint64" != none; then
 270   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 271                      [Define to an unsigned 64-bit type available in the compiler.])
 272 fi
 273
 274 # Given the above check, we always have uintptr_t or a fallback
 275 # definition.  So define HAVE_UINTPTR_T in case any imported code
 276 # relies on it.
 277 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 278
 279 AC_TYPE_PID_T
 280
 281 # This is the list of functions which libiberty will provide if they
 282 # are not available on the host.
 283
 284 funcs="asprintf"
 285 funcs="$funcs atexit"
 286 funcs="$funcs basename"
 287 funcs="$funcs bcmp"
 288 funcs="$funcs bcopy"
 289 funcs="$funcs bsearch"
 290 funcs="$funcs bzero"
 291 funcs="$funcs calloc"
 292 funcs="$funcs clock"
 293 funcs="$funcs ffs"
 294 funcs="$funcs getcwd"
 295 funcs="$funcs getpagesize"
 296 funcs="$funcs gettimeofday"
 297 funcs="$funcs index"
 298 funcs="$funcs insque"
 299 funcs="$funcs memchr"
 300 funcs="$funcs memcmp"
 301 funcs="$funcs memcpy"
 302 funcs="$funcs memmove"
 303 funcs="$funcs mempcpy"
 304 funcs="$funcs memset"
 305 funcs="$funcs mkstemps"
 306 funcs="$funcs putenv"
 307 funcs="$funcs random"
 308 funcs="$funcs rename"
 309 funcs="$funcs rindex"
 310 funcs="$funcs setenv"
 311 funcs="$funcs snprintf"
 312 funcs="$funcs sigsetmask"
 313 funcs="$funcs stpcpy"
 314 funcs="$funcs stpncpy"
 315 funcs="$funcs strcasecmp"
 316 funcs="$funcs strchr"
 317 funcs="$funcs strdup"
 318 funcs="$funcs strncasecmp"
 319 funcs="$funcs strndup"
 320 funcs="$funcs strrchr"
 321 funcs="$funcs strstr"
 322 funcs="$funcs strtod"
 323 funcs="$funcs strtol"
 324 funcs="$funcs strtoul"
 325 funcs="$funcs strverscmp"
 326 funcs="$funcs tmpnam"
 327 funcs="$funcs vasprintf"
 328 funcs="$funcs vfprintf"
 329 funcs="$funcs vprintf"
 330 funcs="$funcs vsnprintf"
 331 funcs="$funcs vsprintf"
 332 funcs="$funcs waitpid"
 333
 334 # Also in the old function.def file: alloca, vfork, getopt.
 335
 336 vars="sys_errlist sys_nerr sys_siglist"
 337
 338 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
 339 checkfuncs="$checkfuncs realpath canonicalize_file_name pstat_getstatic pstat_getdynamic sysmp"
 340 checkfuncs="$checkfuncs getsysinfo table sysctl wait3 wait4 __fsetlocking"
 341
 342 # These are neither executed nor required, but they help keep
 343 # autoheader happy without adding a bunch of text to acconfig.h.
 344 if test "x" = "y"; then
 345   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bsearch bzero calloc clock \
 346   getcwd getpagesize gettimeofday index insque mkstemps memchr memcmp memcpy \
 347   memmove mempcpy memset putenv random rename rindex sigsetmask \
 348   strcasecmp setenv stpcpy stpncpy strchr strdup strncasecmp strndup strrchr strstr \
 349   strtod strtol strtoul strverscmp tmpnam vasprintf vfprintf vprintf \
 350   vsprintf waitpid getrusage on_exit psignal strerror strsignal \
 351   sysconf times sbrk gettimeofday ffs snprintf vsnprintf \
 352   pstat_getstatic pstat_getdynamic sysmp getsysinfo table sysctl wait3 wait4 \
 353   realpath canonicalize_file_name __fsetlocking)
 354   AC_CHECK_DECLS([basename, ffs, asprintf, vasprintf, snprintf, vsnprintf])
 355   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 356   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 357   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 358 fi
 359
 360 # For each of these functions, if the host does not provide the
 361 # function we want to put FN.o in LIBOBJS, and if the host does
 362 # provide the function, we want to define HAVE_FN in config.h.
 363
 364 setobjs=
 365 CHECK=
 366 target_header_dir=
 367 if test -n "${with_target_subdir}"; then
 368
 369   # We are being configured as a target library.  AC_REPLACE_FUNCS
 370   # may not work correctly, because the compiler may not be able to
 371   # link executables.  Note that we may still be being configured
 372   # native.
 373
 374   # If we are being configured for newlib, we know which functions
 375   # newlib provide and which ones we will be expected to provide.
 376
 377   if test "x${with_newlib}" = "xyes"; then
 378     AC_LIBOBJ([asprintf])
 379     AC_LIBOBJ([basename])
 380     AC_LIBOBJ([insque])
 381     AC_LIBOBJ([random])
 382     AC_LIBOBJ([strdup])
 383     AC_LIBOBJ([vasprintf])
 384
 385     for f in $funcs; do
 386       case "$f" in
 387         asprintf | basename | insque | random | strdup | vasprintf)
 388           ;;
 389         *)
 390           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 391           AC_DEFINE_UNQUOTED($n)
 392           ;;
 393       esac
 394     done
 395
 396     # newlib doesnt provide any of the variables in $vars, so we
 397     # dont have to check them here.
 398
 399     # Of the functions in $checkfuncs, newlib only has strerror.
 400     AC_DEFINE(HAVE_STRERROR)
 401
 402     setobjs=yes
 403
 404   fi
 405
 406   # We may wish to install the target headers somewhere.
 407   AC_ARG_ENABLE(install-libiberty,
 408   [  --enable-install-libiberty       Install headers for end users],
 409   enable_install_libiberty=$enableval,
 410   enable_install_libiberty=no)dnl
 411
 412   # Option parsed, now set things appropriately.
 413   case x"$enable_install_libiberty" in
 414     xyes|x)
 415       target_header_dir=libiberty
 416       ;;
 417     xno)
 418       target_header_dir=
 419       ;;
 420     *)
 421       # This could be sanity-checked in various ways...
 422       target_header_dir="${enable_install_libiberty}"
 423       ;;
 424   esac
 425
 426
 427 else
 428
 429    # Not a target library, so we set things up to run the test suite.
 430    CHECK=really-check
 431
 432 fi
 433
 434 AC_SUBST(CHECK)
 435 AC_SUBST(target_header_dir)
 436
 437 case "${host}" in
 438   *-*-cygwin* | *-*-mingw*)
 439     AC_DEFINE(HAVE_SYS_ERRLIST)
 440     AC_DEFINE(HAVE_SYS_NERR)
 441     ;;
 442 esac
 443
 444 if test -z "${setobjs}"; then
 445   case "${host}" in
 446
 447   *-*-vxworks*)
 448     # Handle VxWorks configuration specially, since on VxWorks the
 449     # libraries are actually on the target board, not in the file
 450     # system.
 451     AC_LIBOBJ([basename])
 452     AC_LIBOBJ([getpagesize])
 453     AC_LIBOBJ([insque])
 454     AC_LIBOBJ([random])
 455     AC_LIBOBJ([strcasecmp])
 456     AC_LIBOBJ([strncasecmp])
 457     AC_LIBOBJ([strdup])
 458     AC_LIBOBJ([vfork])
 459     AC_LIBOBJ([waitpid])
 460     AC_LIBOBJ([vasprintf])
 461     for f in $funcs; do
 462       case "$f" in
 463         basename | getpagesize | insque | random | strcasecmp)
 464           ;;
 465         strncasecmp | strdup | vfork | waitpid | vasprintf)
 466           ;;
 467         *)
 468           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 469           AC_DEFINE_UNQUOTED($n)
 470           ;;
 471       esac
 472     done
 473
 474     # VxWorks doesn't provide any of the variables in $vars, so we
 475     # don't have to check them here.
 476
 477     # Of the functions in $checkfuncs, VxWorks only has strerror.
 478     AC_DEFINE(HAVE_STRERROR)
 479
 480     setobjs=yes
 481     ;;
 482
 483   esac
 484 fi
 485
 486 if test -z "${setobjs}"; then
 487
 488   case "${host}" in
 489
 490   *-*-cygwin*)
 491     # The Cygwin library actually uses a couple of files from
 492     # libiberty when it is built.  If we are building a native
 493     # Cygwin, and we run the tests, we will appear to have these
 494     # files.  However, when we go on to build winsup, we will wind up
 495     # with a library which does not have the files, since they should
 496     # have come from libiberty.
 497
 498     # We handle this by removing the functions the winsup library
 499     # provides from our shell variables, so that they appear to be
 500     # missing.
 501
 502     # DJ - only if we're *building* cygwin, not just building *with* cygwin
 503
 504     if test -n "${with_target_subdir}"
 505     then
 506       funcs="`echo $funcs | sed -e 's/random//'`"
 507       AC_LIBOBJ([random])
 508       vars="`echo $vars | sed -e 's/sys_siglist//'`"
 509       checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 510     fi
 511     ;;
 512
 513   *-*-mingw32*)
 514     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 515     # macros, so the test below won't find them.
 516     libiberty_cv_var_sys_nerr=yes
 517     libiberty_cv_var_sys_errlist=yes
 518     ;;
 519
 520   *-*-msdosdjgpp*)
 521     # vfork and fork are stubs.
 522     ac_cv_func_vfork_works=no
 523     ;;
 524
 525   *-*-uwin*)
 526     # Under some versions of uwin, vfork is notoriously buggy and the test
 527     # can hang configure; on other versions, vfork exists just as a stub.
 528     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 529     ac_cv_func_vfork_works=no
 530     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 531     # macros (actually, these are imported from a DLL, but the end effect
 532     # is the same), so the test below won't find them.
 533     libiberty_cv_var_sys_nerr=yes
 534     libiberty_cv_var_sys_errlist=yes
 535     ;;
 536
 537   *-*-*vms*)
 538     # Under VMS, vfork works very different than on Unix. The standard test
 539     # won't work, and it isn't easily adaptable. It makes more sense to
 540     # just force it.
 541     ac_cv_func_vfork_works=yes
 542     ;;
 543
 544   esac
 545
 546   # We haven't set the list of objects yet.  Use the standard autoconf
 547   # tests.  This will only work if the compiler works.
 548   AC_ISC_POSIX
 549   AC_REPLACE_FUNCS($funcs)
 550   libiberty_AC_FUNC_C_ALLOCA
 551   AC_FUNC_FORK
 552   if test $ac_cv_func_vfork_works = no; then
 553     AC_LIBOBJ([vfork])
 554   fi
 555   # We only need _doprnt if we might use it to implement v*printf.
 556   if test $ac_cv_func_vprintf != yes \
 557      || test $ac_cv_func_vfprintf != yes \
 558      || test $ac_cv_func_vsprintf != yes; then
 559     AC_REPLACE_FUNCS(_doprnt)
 560   else
 561     AC_CHECK_FUNCS(_doprnt)
 562   fi
 563
 564   for v in $vars; do
 565     AC_MSG_CHECKING([for $v])
 566     AC_CACHE_VAL(libiberty_cv_var_$v,
 567       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 568                       [eval "libiberty_cv_var_$v=yes"],
 569                       [eval "libiberty_cv_var_$v=no"])])
 570     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 571       AC_MSG_RESULT(yes)
 572       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 573       AC_DEFINE_UNQUOTED($n)
 574     else
 575       AC_MSG_RESULT(no)
 576     fi
 577   done
 578
 579   # special check for _system_configuration because AIX <4.3.2 do not
 580   # contain the `physmem' member.
 581   AC_MSG_CHECKING([for external symbol _system_configuration])
 582   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 583                         [[double x = _system_configuration.physmem;]])],
 584     [AC_MSG_RESULT([yes])
 585     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 586               [Define if you have the _system_configuration variable.])],
 587     [AC_MSG_RESULT([no])])
 588
 589   AC_CHECK_FUNCS($checkfuncs)
 590   AC_CHECK_DECLS([basename, ffs, asprintf, vasprintf, snprintf, vsnprintf])
 591   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 592   AC_CHECK_DECLS([strverscmp])
 593   libiberty_NEED_DECLARATION(canonicalize_file_name)
 594 fi
 595
 596 # Figure out which version of pexecute to use.
 597 case "${host}" in
 598      *-*-mingw* | *-*-winnt*)   pexecute=./pex-win32.o  ;;
 599      *-*-msdosdjgpp*)           pexecute=./pex-djgpp.o  ;;
 600      *-*-msdos*)                pexecute=./pex-msdos.o  ;;
 601      *)                         pexecute=./pex-unix.o   ;;
 602 esac
 603 AC_SUBST(pexecute)
 604
 605 libiberty_AC_FUNC_STRNCMP
 606
 607 # Install a library built with a cross compiler in $(tooldir) rather
 608 # than $(libdir).
 609 if test -z "${with_cross_host}"; then
 610   INSTALL_DEST=libdir
 611 else
 612   INSTALL_DEST=tooldir
 613 fi
 614 AC_SUBST(INSTALL_DEST)
 615
 616 m4_pattern_allow(LIBOBJS)
 617 L=""
 618 for l in x $LIBOBJS; do
 619   case $l in
 620     x) ;;
 621     *) L="$L ./$l" ;;
 622   esac
 623 done
 624 LIBOBJS="$L"
 625
 626 # We need multilib support, but only if configuring for the target.
 627 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 628 AC_CONFIG_COMMANDS([default],
 629   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 630 if test -n "$CONFIG_FILES"; then
 631   if test -n "${with_target_subdir}"; then
 632     # FIXME: We shouldn't need to set ac_file
 633     ac_file=Makefile
 634     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 635     . ${libiberty_topdir}/config-ml.in
 636   fi
 637 fi]],
 638 [[srcdir=${srcdir}
 639 host=${host}
 640 target=${target}
 641 with_target_subdir=${with_target_subdir}
 642 with_multisubdir=${with_multisubdir}
 643 ac_configure_args="--enable-multilib ${ac_configure_args}"
 644 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 645 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 646 libiberty_topdir=${libiberty_topdir}
 647 ]])
 648 AC_OUTPUT