gcc/opt-functions.awk

   1 #  Copyright (C) 2003-2014 Free Software Foundation, Inc.
   2 #  Contributed by Kelley Cook, June 2004.
   3 #  Original code from Neil Booth, May 2003.
   4 #
   5 # This program is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by the
   7 # Free Software Foundation; either version 3, or (at your option) any
   8 # later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 # Some common subroutines for use by opt[ch]-gen.awk.
  20
  21 # Define some helpful character classes, for portability.
  22 BEGIN {
  23         lower = "abcdefghijklmnopqrstuvwxyz"
  24         upper = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
  25         digit = "0123456789"
  26         alnum = lower "" upper "" digit
  27 }
  28
  29 # Return nonzero if FLAGS contains a flag matching REGEX.
  30 function flag_set_p(regex, flags)
  31 {
  32     # Ignore the arguments of flags with arguments.
  33     gsub ("\\([^)]+\\)", "", flags);
  34     return (" " flags " ") ~ (" " regex " ")
  35 }
  36
  37 # Return STRING if FLAGS contains a flag matching regexp REGEX,
  38 # otherwise return the empty string.
  39 function test_flag(regex, flags, string)
  40 {
  41         if (flag_set_p(regex, flags))
  42                 return string
  43         return ""
  44 }
  45
  46 # Return a field initializer, with trailing comma, for a field that is
  47 # 1 if FLAGS contains a flag matching REGEX and 0 otherwise.
  48 function flag_init(regex, flags)
  49 {
  50         if (flag_set_p(regex, flags))
  51                 return "1 /* " regex " */, "
  52         else
  53                 return "0, "
  54 }
  55
  56 # If FLAGS contains a "NAME(...argument...)" flag, return the value
  57 # of the argument.  Return the empty string otherwise.
  58 function opt_args(name, flags)
  59 {
  60         flags = " " flags
  61         if (flags !~ " " name "\\(")
  62                 return ""
  63         sub(".* " name "\\(", "", flags)
  64         if (flags ~ "^{")
  65         {
  66                 sub ("^{", "", flags)
  67                 sub("}\\).*", "", flags)
  68         }
  69         else
  70                 sub("\\).*", "", flags)
  71
  72         return flags
  73 }
  74
  75 # Return the Nth comma-separated element of S.  Return the empty string
  76 # if S does not contain N elements.
  77 function nth_arg(n, s)
  78 {
  79         while (n-- > 0) {
  80                 if (s !~ ",")
  81                         return ""
  82                 sub("[^,]*, *", "", s)
  83         }
  84         sub(",.*", "", s)
  85         return s
  86 }
  87
  88 # Return a bitmask of CL_* values for option flags FLAGS.
  89 function switch_flags (flags)
  90 {
  91         result = "0"
  92         for (j = 0; j < n_langs; j++) {
  93                 regex = langs[j]
  94                 gsub ( "\\+", "\\+", regex )
  95                 result = result test_flag(regex, flags, " | " macros[j])
  96         }
  97         result = result \
  98           test_flag("Common", flags, " | CL_COMMON") \
  99           test_flag("Target", flags, " | CL_TARGET") \
 100           test_flag("Driver", flags, " | CL_DRIVER") \
 101           test_flag("Joined", flags, " | CL_JOINED") \
 102           test_flag("JoinedOrMissing", flags, " | CL_JOINED") \
 103           test_flag("Separate", flags, " | CL_SEPARATE") \
 104           test_flag("Undocumented", flags,  " | CL_UNDOCUMENTED") \
 105           test_flag("NoDWARFRecord", flags,  " | CL_NO_DWARF_RECORD") \
 106           test_flag("Warning", flags,  " | CL_WARNING") \
 107           test_flag("Optimization", flags,  " | CL_OPTIMIZATION")
 108         sub( "^0 \\| ", "", result )
 109         return result
 110 }
 111
 112 # Return bit-field initializers for option flags FLAGS.
 113 function switch_bit_fields (flags)
 114 {
 115         vn = var_name(flags);
 116         if (host_wide_int[vn] == "yes")
 117                 hwi = "Host_Wide_Int"
 118         else
 119                 hwi = ""
 120         result = ""
 121         sep_args = opt_args("Args", flags)
 122         if (sep_args == "")
 123                 sep_args = 0
 124         else
 125                 sep_args--
 126         result = result sep_args ", "
 127
 128         result = result \
 129           flag_init("SeparateAlias", flags) \
 130           flag_init("NegativeAlias", flags) \
 131           flag_init("NoDriverArg", flags) \
 132           flag_init("RejectDriver", flags) \
 133           flag_init("RejectNegative", flags) \
 134           flag_init("JoinedOrMissing", flags) \
 135           flag_init("UInteger", flags) \
 136           flag_init("Host_Wide_Int", hwi) \
 137           flag_init("ToLower", flags) \
 138           flag_init("Report", flags)
 139
 140         sub(", $", "", result)
 141         return result
 142 }
 143
 144 # If FLAGS includes a Var flag, return the name of the variable it specifies.
 145 # Return the empty string otherwise.
 146 function var_name(flags)
 147 {
 148         return nth_arg(0, opt_args("Var", flags))
 149 }
 150
 151 # Return the name of the variable if FLAGS has a HOST_WIDE_INT variable.
 152 # Return the empty string otherwise.
 153 function host_wide_int_var_name(flags)
 154 {
 155         split (flags, array, "[ \t]+")
 156         if (array[1] == "HOST_WIDE_INT")
 157                 return array[2]
 158         else
 159                 return ""
 160 }
 161
 162 # Return true if the option described by FLAGS has a globally-visible state.
 163 function global_state_p(flags)
 164 {
 165         return (var_name(flags) != "" \
 166                 || opt_args("Mask", flags) != "" \
 167                 || opt_args("InverseMask", flags) != "")
 168 }
 169
 170 # Return true if the option described by FLAGS must have some state
 171 # associated with it.
 172 function needs_state_p(flags)
 173 {
 174         return (flag_set_p("Target", flags) \
 175                 && !flag_set_p("Alias.*", flags) \
 176                 && !flag_set_p("Ignore", flags))
 177 }
 178
 179 # If FLAGS describes an option that needs state without a public
 180 # variable name, return the name of that field, minus the initial
 181 # "x_", otherwise return "".  NAME is the name of the option.
 182 function static_var(name, flags)
 183 {
 184         if (global_state_p(flags) || !needs_state_p(flags))
 185                 return ""
 186         gsub ("[^" alnum "]", "_", name)
 187         return "VAR_" name
 188 }
 189
 190 # Return the type of variable that should be associated with the given flags.
 191 function var_type(flags)
 192 {
 193         if (flag_set_p("Defer", flags))
 194                 return "void *"
 195         else if (flag_set_p("Enum.*", flags)) {
 196                 en = opt_args("Enum", flags);
 197                 return enum_type[en] " "
 198         }
 199         else if (!flag_set_p("Joined.*", flags) && !flag_set_p("Separate", flags))
 200                 return "int "
 201         else if (flag_set_p("UInteger", flags))
 202                 return "int "
 203         else
 204                 return "const char *"
 205 }
 206
 207 # Return the type of variable that should be associated with the given flags
 208 # for use within a structure.  Simple variables are changed to signed char
 209 # type instead of int to save space.
 210 function var_type_struct(flags)
 211 {
 212         if (flag_set_p("UInteger", flags))
 213                 return "int "
 214         else if (flag_set_p("Enum.*", flags)) {
 215                 en = opt_args("Enum", flags);
 216                 return enum_type[en] " "
 217         }
 218         else if (!flag_set_p("Joined.*", flags) && !flag_set_p("Separate", flags)) {
 219                 if (flag_set_p(".*Mask.*", flags)) {
 220                         if (host_wide_int[var_name(flags)] == "yes")
 221                                 return "HOST_WIDE_INT "
 222                         else
 223                                 return "int "
 224                 }
 225                 else
 226                         return "signed char "
 227         }
 228         else
 229                 return "const char *"
 230 }
 231
 232 # Given that an option has flags FLAGS, return an initializer for the
 233 # "var_enum", "var_type" and "var_value" fields of its cl_options[] entry.
 234 function var_set(flags)
 235 {
 236         if (flag_set_p("Defer", flags))
 237                 return "0, CLVC_DEFER, 0"
 238         s = nth_arg(1, opt_args("Var", flags))
 239         if (s != "")
 240                 return "0, CLVC_EQUAL, " s
 241         s = opt_args("Mask", flags);
 242         if (s != "") {
 243                 vn = var_name(flags);
 244                 if (vn)
 245                         return "0, CLVC_BIT_SET, OPTION_MASK_" s
 246                 else
 247                         return "0, CLVC_BIT_SET, MASK_" s
 248         }
 249         s = nth_arg(0, opt_args("InverseMask", flags));
 250         if (s != "") {
 251                 vn = var_name(flags);
 252                 if (vn)
 253                         return "0, CLVC_BIT_CLEAR, OPTION_MASK_" s
 254                 else
 255                         return "0, CLVC_BIT_CLEAR, MASK_" s
 256         }
 257         if (flag_set_p("Enum.*", flags)) {
 258                 en = opt_args("Enum", flags);
 259                 return enum_index[en] ", CLVC_ENUM, 0"
 260         }
 261         if (var_type(flags) == "const char *")
 262                 return "0, CLVC_STRING, 0"
 263         return "0, CLVC_BOOLEAN, 0"
 264 }
 265
 266 # Given that an option called NAME has flags FLAGS, return an initializer
 267 # for the "flag_var" field of its cl_options[] entry.
 268 function var_ref(name, flags)
 269 {
 270         name = var_name(flags) static_var(name, flags)
 271         if (name != "")
 272                 return "offsetof (struct gcc_options, x_" name ")"
 273         if (opt_args("Mask", flags) != "")
 274                 return "offsetof (struct gcc_options, x_target_flags)"
 275         if (opt_args("InverseMask", flags) != "")
 276                 return "offsetof (struct gcc_options, x_target_flags)"
 277         return "-1"
 278 }
 279
 280 # Given the option called NAME return a sanitized version of its name.
 281 function opt_sanitized_name(name)
 282 {
 283         gsub ("[^" alnum "]", "_", name)
 284         return name
 285 }
 286
 287 # Given the option called NAME return the appropriate enum for it.
 288 function opt_enum(name)
 289 {
 290         return "OPT_" opt_sanitized_name(name)
 291 }
 292
 293 # Given the language called NAME return a sanitized version of its name.
 294 function lang_sanitized_name(name)
 295 {
 296     gsub( "[^" alnum "_]", "X", name )
 297     return name
 298 }
 299
 300 # Search for a valid var_name among all OPTS equal to option NAME.
 301 # If not found, return "".
 302 function search_var_name(name, opt_numbers, opts, flags, n_opts)
 303 {
 304     opt_var_name = var_name(flags[opt_numbers[name]]);
 305     if (opt_var_name != "") {
 306         return opt_var_name;
 307     }
 308     for (k = 0; k < n_opts; k++) {
 309         if (opts[k] == name && var_name(flags[k]) != "") {
 310             return var_name(flags[k]);
 311         }
 312     }
 313     return ""
 314 }
 315
 316 # Handle LangEnabledBy(ENABLED_BY_LANGS, ENABLEDBY_NAME, ENABLEDBY_POSARG,
 317 # ENABLEDBY_NEGARG). This function does not return anything.
 318 function lang_enabled_by(enabledby_langs, enabledby_name, enabledby_posarg, enabledby_negarg)
 319 {
 320     n_enabledby_arg_langs = split(enabledby_langs, enabledby_arg_langs, " ");
 321     enabledby_index = opt_numbers[enabledby_name];
 322     if (enabledby_index == "") {
 323         print "#error LangEnabledby: " enabledby_name
 324     } else {
 325         if (enabledby_posarg != "" && enabledby_negarg != "") {
 326             with_args = "," enabledby_posarg "," enabledby_negarg
 327         } else if (enabledby_posarg == "" && enabledby_negarg == "") {
 328             with_args = ""
 329         } else {
 330             print "#error LangEnabledBy("enabledby_langs","enabledby_name", " \
 331                 enabledby_posarg", " enabledby_negargs                  \
 332                 ") with three arguments, it should have either 2 or 4"
 333         }
 334
 335         for (j = 1; j <= n_enabledby_arg_langs; j++) {
 336             lang_name = lang_sanitized_name(enabledby_arg_langs[j]);
 337             lang_index = lang_numbers[enabledby_arg_langs[j]];
 338             if (enables[lang_name,enabledby_name] == "") {
 339                 enabledby[lang_name,n_enabledby_lang[lang_index]] = enabledby_name;
 340                 n_enabledby_lang[lang_index]++;
 341             }
 342             enables[lang_name,enabledby_name] = enables[lang_name,enabledby_name] opts[i] with_args ";";
 343         }
 344     }
 345 }
 346