old-autovect-branch/libjava/classpath/m4/acinclude.m4

   1 dnl Used by aclocal to generate configure
   2
   3 dnl -----------------------------------------------------------
   4 AC_DEFUN([CLASSPATH_FIND_JAVAC],
   5 [
   6   user_specified_javac=
   7
   8   CLASSPATH_WITH_GCJ
   9   CLASSPATH_WITH_JIKES
  10   CLASSPATH_WITH_KJC
  11   CLASSPATH_WITH_GCJX
  12   CLASSPATH_WITH_ECJ
  13
  14   if test "x${user_specified_javac}" = x; then
  15     AM_CONDITIONAL(FOUND_GCJ, test "x${GCJ}" != x)
  16     AM_CONDITIONAL(FOUND_JIKES, test "x${JIKES}" != x)
  17     AM_CONDITIONAL(FOUND_ECJ, test "x${ECJ}" != x)
  18   else
  19     AM_CONDITIONAL(FOUND_GCJ, test "x${user_specified_javac}" = xgcj)
  20     AM_CONDITIONAL(FOUND_JIKES, test "x${user_specified_javac}" = xjikes)
  21     AM_CONDITIONAL(FOUND_ECJ, test "x${user_specified_javac}" = xecj)
  22   fi
  23   AM_CONDITIONAL(FOUND_KJC, test "x${user_specified_javac}" = xkjc)
  24   AM_CONDITIONAL(FOUND_GCJX, test "x${user_specified_javac}" = xgcjx)
  25
  26   if test "x${GCJ}" = x && test "x${JIKES}" = x && test "x${user_specified_javac}" != xkjc && test "x${user_specified_javac}" != xgcjx; then
  27       # FIXME: use autoconf error function
  28       echo "configure: cannot find javac, try --with-gcj, --with-jikes, --with-kjc, or --with-gcjx" 1>&2
  29       exit 1
  30   fi
  31 ])
  32
  33 dnl -----------------------------------------------------------
  34 AC_DEFUN([CLASSPATH_WITH_GCJ],
  35 [
  36   AC_ARG_WITH([gcj],
  37               [AS_HELP_STRING(--with-gcj,bytecode compilation with gcj)],
  38   [
  39     if test "x${withval}" != x && test "x${withval}" != xyes && test "x${withval}" != xno; then
  40       CLASSPATH_CHECK_GCJ(${withval})
  41     else
  42       if test "x${withval}" != xno; then
  43         CLASSPATH_CHECK_GCJ
  44       fi
  45     fi
  46     user_specified_javac=gcj
  47   ],
  48   [
  49     CLASSPATH_CHECK_GCJ
  50   ])
  51   AC_SUBST(GCJ)
  52 ])
  53
  54 dnl -----------------------------------------------------------
  55 AC_DEFUN([CLASSPATH_CHECK_GCJ],
  56 [
  57   if test "x$1" != x; then
  58     if test -f "$1"; then
  59       GCJ="$1"
  60     else
  61       AC_PATH_PROG(GCJ, "$1")
  62     fi
  63   else
  64     AC_PATH_PROG(GCJ, "gcj")
  65   fi
  66   dnl Test the given GCJ, but use it as C (!) compiler to check version
  67   if test "x$GCJ" != x; then
  68     AC_MSG_CHECKING([gcj version 4.0])
  69     AC_LANG_PUSH([C])
  70     AC_LANG_CONFTEST(
  71     [[#if __GNUC__ <= 3
  72     #error GCJ 4.0.0 or higher is required
  73     #endif
  74     ]])
  75     $GCJ -E conftest.c > /dev/null
  76     gcj_4_result=$?
  77     if test "x$gcj_4_result" = "x0"; then
  78       AC_MSG_RESULT([4.0 or higher found])
  79     else
  80       AC_MSG_WARN([4.0 or higher required])
  81     fi
  82     AC_LANG_POP
  83   fi
  84 ])
  85
  86 dnl -----------------------------------------------------------
  87 AC_DEFUN([CLASSPATH_WITH_JIKES],
  88 [
  89   AC_ARG_WITH([jikes],
  90               [AS_HELP_STRING(--with-jikes,bytecode compilation with jikes)],
  91   [
  92     if test "x${withval}" != x && test "x${withval}" != xyes && test "x${withval}" != xno; then
  93       CLASSPATH_CHECK_JIKES(${withval})
  94     else
  95       if test "x${withval}" != xno; then
  96         CLASSPATH_CHECK_JIKES
  97       fi
  98     fi
  99     user_specified_javac=jikes
 100   ],
 101   [
 102     CLASSPATH_CHECK_JIKES
 103   ])
 104   AC_SUBST(JIKES)
 105 ])
 106
 107 dnl -----------------------------------------------------------
 108 AC_DEFUN([CLASSPATH_CHECK_JIKES],
 109 [
 110   if test "x$1" != x; then
 111     if test -f "$1"; then
 112       JIKES="$1"
 113     else
 114       AC_PATH_PROG(JIKES, "$1")
 115     fi
 116   else
 117     AC_PATH_PROG(JIKES, "jikes")
 118   fi
 119   if test "x$JIKES" != "x"; then
 120     dnl Require at least version 1.19
 121     AC_MSG_CHECKING(jikes version)
 122     JIKES_VERSION=`$JIKES --version | awk '/^Jikes Compiler/' | cut -d ' ' -f 5`
 123     JIKES_VERSION_MAJOR=`echo "$JIKES_VERSION" | cut -d '.' -f 1`
 124     JIKES_VERSION_MINOR=`echo "$JIKES_VERSION" | cut -d '.' -f 2`
 125     if expr "$JIKES_VERSION_MAJOR" = 1 > /dev/null; then
 126       if expr "$JIKES_VERSION_MINOR" \< 19 > /dev/null; then
 127         JIKES=""
 128       fi
 129     fi
 130     if test "x$JIKES" != "x"; then
 131       AC_MSG_RESULT($JIKES_VERSION)
 132     else
 133       AC_MSG_WARN($JIKES_VERSION: jikes 1.19 or higher required)
 134     fi
 135
 136     JIKESENCODING=
 137     if test -n "`$JIKES --help 2>&1 | grep encoding`"; then
 138        JIKESENCODING='-encoding UTF-8'
 139     fi
 140     AC_SUBST(JIKESENCODING)
 141   fi
 142 ])
 143
 144 dnl -----------------------------------------------------------
 145 AC_DEFUN([CLASSPATH_WITH_KJC],
 146 [
 147   AC_ARG_WITH([kjc],
 148               [AS_HELP_STRING(--with-kjc,bytecode compilation with kjc)],
 149   [
 150     if test "x${withval}" != x && test "x${withval}" != xyes && test "x${withval}" != xno; then
 151       CLASSPATH_CHECK_KJC(${withval})
 152     else
 153       if test "x${withval}" != xno; then
 154         CLASSPATH_CHECK_KJC
 155       fi
 156     fi
 157     user_specified_javac=kjc
 158   ],
 159   [
 160     CLASSPATH_CHECK_KJC
 161   ])
 162   AC_SUBST(KJC)
 163 ])
 164
 165 dnl -----------------------------------------------------------
 166 AC_DEFUN([CLASSPATH_CHECK_KJC],
 167 [
 168   if test "x$1" != x; then
 169     if test -f "$1"; then
 170       KJC="$1"
 171     else
 172       AC_PATH_PROG(KJC, "$1")
 173     fi
 174   else
 175     AC_PATH_PROG(KJC, "kJC")
 176   fi
 177 ])
 178
 179 dnl -----------------------------------------------------------
 180 AC_DEFUN([CLASSPATH_WITH_GCJX],
 181 [
 182   AC_ARG_WITH([gcjx],
 183               [AS_HELP_STRING(--with-gcjx,bytecode compilation with gcjx)],
 184   [
 185     if test "x${withval}" != x && test "x${withval}" != xyes && test "x${withval}" != xno; then
 186       CLASSPATH_CHECK_GCJX(${withval})
 187     else
 188       if test "x${withval}" != xno; then
 189         CLASSPATH_CHECK_GCJX
 190       fi
 191     fi
 192     user_specified_javac=gcjx
 193   ],
 194   [
 195     CLASSPATH_CHECK_GCJX
 196   ])
 197   AC_SUBST(GCJX)
 198 ])
 199
 200 dnl -----------------------------------------------------------
 201 AC_DEFUN([CLASSPATH_CHECK_GCJX],
 202 [
 203   if test "x$1" != x; then
 204     if test -f "$1"; then
 205       GCJX="$1"
 206     else
 207       AC_PATH_PROG(GCJX, "$1")
 208     fi
 209   else
 210     AC_PATH_PROG(GCJX, "gcjx")
 211   fi
 212 ])
 213
 214 dnl -----------------------------------------------------------
 215 AC_DEFUN([CLASSPATH_WITH_JAVAH],
 216 [
 217   AC_ARG_WITH([javah],
 218               [AS_HELP_STRING(--with-javah,specify path or name of a javah-like program)],
 219   [
 220     if test "x${withval}" != x && test "x${withval}" != xyes && test "x${withval}" != xno; then
 221       CLASSPATH_CHECK_JAVAH(${withval})
 222     else
 223       CLASSPATH_CHECK_JAVAH
 224     fi
 225   ],
 226   [
 227     CLASSPATH_CHECK_JAVAH
 228   ])
 229   AM_CONDITIONAL(USER_SPECIFIED_JAVAH, test "x${USER_JAVAH}" != x)
 230   AC_SUBST(USER_JAVAH)
 231 ])
 232
 233 dnl -----------------------------------------------------------
 234 dnl Checking for a javah like program
 235 dnl -----------------------------------------------------------
 236 AC_DEFUN([CLASSPATH_CHECK_JAVAH],
 237 [
 238   if test "x$1" != x; then
 239     if test -f "$1"; then
 240       USER_JAVAH="$1"
 241     else
 242       AC_PATH_PROG(USER_JAVAH, "$1")
 243     fi
 244   else
 245     for javah_name in gcjh javah; do
 246       AC_PATH_PROG(USER_JAVAH, "$javah_name")
 247       if test "x${USER_JAVAH}" != x; then
 248         break
 249       fi
 250     done
 251   fi
 252
 253 #  if test "x${USER_JAVAH}" = x; then
 254 #    echo "configure: cannot find javah" 1>&2
 255 #    exit 1
 256 #  fi
 257 ])
 258
 259 dnl -----------------------------------------------------------
 260 dnl CLASSPATH_WITH_CLASSLIB - checks for user specified classpath additions
 261 dnl -----------------------------------------------------------
 262 AC_DEFUN([CLASSPATH_WITH_CLASSLIB],
 263 [
 264   AC_ARG_WITH([classpath],
 265               [AS_HELP_STRING(--with-classpath,specify path to a classes.zip like file)],
 266   [
 267     if test "x${withval}" = xyes; then
 268       # set user classpath to CLASSPATH from env
 269       AC_MSG_CHECKING(for classlib)
 270       USER_CLASSLIB=${CLASSPATH}
 271       AC_SUBST(USER_CLASSLIB)
 272       AC_MSG_RESULT(${USER_CLASSLIB})
 273       conditional_with_classlib=true
 274     elif test "x${withval}" != x && test "x${withval}" != xno; then
 275       # set user classpath to specified value
 276       AC_MSG_CHECKING(for classlib)
 277       USER_CLASSLIB=${withval}
 278       AC_SUBST(USER_CLASSLIB)
 279       AC_MSG_RESULT(${withval})
 280       conditional_with_classlib=true
 281     fi
 282   ],
 283   [ conditional_with_classlib=false ])
 284   AM_CONDITIONAL(USER_SPECIFIED_CLASSLIB, test "x${conditional_with_classlib}" = xtrue)
 285
 286   AC_ARG_WITH([vm-classes],
 287               [AS_HELP_STRING(--with-vm-classes,specify path to VM override source files)], [vm_classes="$with_vm_classes"],
 288               [vm_classes='${top_srcdir}/vm/reference'])
 289   AC_SUBST(vm_classes)
 290 ])
 291
 292 dnl -----------------------------------------------------------
 293 dnl CLASSPATH_WITH_GLIBJ - specify what to install
 294 dnl -----------------------------------------------------------
 295 AC_DEFUN([CLASSPATH_WITH_GLIBJ],
 296 [
 297   AC_PATH_PROG(ZIP, zip)
 298   AC_ARG_WITH([glibj],
 299               [AS_HELP_STRING([--with-glibj],[define what to install (zip|flat|both|none|build) [default=zip]])],
 300               [
 301                 if test "x${withval}" = xyes || test "x${withval}" = xzip; then
 302                   install_class_files=no
 303                   build_class_files=yes
 304                   use_zip=yes
 305                 elif test "x${withval}" = xboth; then
 306                   install_class_files=yes
 307                   build_class_files=yes
 308                   use_zip=yes
 309                 elif test "x${withval}" = xflat; then
 310                   install_class_files=yes
 311                   build_class_files=yes
 312                   use_zip=no
 313                 elif test "x${withval}" = xno || test "x${withval}" = xnone; then
 314                   install_class_files=no
 315                   build_class_files=no
 316                   use_zip=no
 317                 elif test "x${withval}" = xbuild; then
 318                   install_class_files=no
 319                   build_class_files=yes
 320                   use_zip=no
 321                 else
 322                   AC_MSG_ERROR([unknown value given to --with-glibj])
 323                 fi
 324               ],
 325               [
 326                 install_class_files=no
 327                 use_zip=yes
 328               ])
 329   AM_CONDITIONAL(INSTALL_GLIBJ_ZIP, test "x${use_zip}" = xyes)
 330   AM_CONDITIONAL(INSTALL_CLASS_FILES, test "x${install_class_files}" = xyes)
 331   AM_CONDITIONAL(BUILD_CLASS_FILES, test "x${build_class_files}" = xyes)
 332
 333   AC_ARG_ENABLE([examples],
 334                 [AS_HELP_STRING(--enable-examples,enable build of the examples [default=yes])],
 335                 [case "${enableval}" in
 336                   yes) EXAMPLESDIR="examples" ;;
 337                   no) EXAMPLESDIR="" ;;
 338                   *) AC_MSG_ERROR(bad value ${enableval} for --enable-examples) ;;
 339                 esac],
 340                 [EXAMPLESDIR="examples"])
 341   if test "x${use_zip}" = xno && test "x${install_class_files}" = xno; then
 342     EXAMPLESDIR=""
 343   fi
 344   AC_SUBST(EXAMPLESDIR)
 345 ])
 346
 347 dnl -----------------------------------------------------------
 348 dnl Enable generation of API documentation, with gjdoc if it
 349 dnl has been compiled to an executable (or a suitable script
 350 dnl is in your PATH) or using the argument as gjdoc executable.
 351 dnl -----------------------------------------------------------
 352 AC_DEFUN([CLASSPATH_WITH_GJDOC],
 353 [
 354   AC_ARG_WITH([gjdoc],
 355               AS_HELP_STRING([--with-gjdoc],
 356                              [generate documentation using gjdoc (default is NO)]),
 357               [if test "x${withval}" = xno; then
 358                  WITH_GJDOC=no;
 359                elif test "x${withval}" = xyes -o "x{withval}" = x; then
 360                  WITH_GJDOC=yes;
 361                  AC_PATH_PROG(GJDOC, gjdoc, "no")
 362                  if test "x${GJDOC}" = xno; then
 363                    AC_MSG_ERROR("gjdoc executable not found");
 364                  fi
 365                else
 366                  WITH_GJDOC=yes
 367                  GJDOC="${withval}"
 368                  AC_CHECK_FILE(${GJDOC}, AC_SUBST(GJDOC),
 369                                AC_MSG_ERROR("Cannot use ${withval} as gjdoc executable since it doesn't exist"))
 370                fi],
 371               [WITH_GJDOC=no])
 372
 373   AM_CONDITIONAL(CREATE_API_DOCS, test "x${WITH_GJDOC}" = xyes)
 374 ])
 375
 376 dnl -----------------------------------------------------------
 377 dnl Enable regeneration of parsers using jay
 378 dnl http://www.informatik.uni-osnabrueck.de/alumni/bernd/jay/
 379 dnl -----------------------------------------------------------
 380 AC_DEFUN([REGEN_WITH_JAY],
 381 [
 382   AC_ARG_WITH([jay],
 383               [AS_HELP_STRING(--with-jay,Regenerate the parsers with jay must be given the path to the jay executable)],
 384   [
 385     if test -d "${withval}"; then
 386       JAY_DIR_PATH="${withval}"
 387       AC_PATH_PROG(JAY, jay, "no", ${JAY_DIR_PATH})
 388       if test "x${JAY}" = xno; then
 389         AC_MSG_ERROR("jay executable not found");
 390       fi
 391     else
 392       JAY_DIR_PATH=$(dirname "${withval}")
 393       JAY="${withval}"
 394       AC_SUBST(JAY)
 395     fi
 396     JAY_SKELETON="${JAY_DIR_PATH}/skeleton"
 397     AC_CHECK_FILE(${JAY_SKELETON}, AC_SUBST(JAY_SKELETON),
 398         AC_MSG_ERROR("Expected skeleton file in $(dirname ${withval})"))
 399     JAY_FOUND=yes
 400   ],
 401   [
 402     JAY_FOUND=no
 403   ])
 404   AM_CONDITIONAL(REGEN_PARSERS, test "x${JAY_FOUND}" = xyes)
 405 ])
 406
 407 dnl -----------------------------------------------------------
 408 AC_DEFUN([CLASSPATH_WITH_ECJ],
 409 [
 410   AC_ARG_WITH([ecj],
 411               [AS_HELP_STRING(--with-ecj,bytecode compilation with ecj)],
 412   [
 413     if test "x${withval}" != x && test "x${withval}" != xyes && test "x${withval}" != xno; then
 414       CLASSPATH_CHECK_ECJ(${withval})
 415     else
 416       if test "x${withval}" != xno; then
 417         CLASSPATH_CHECK_ECJ
 418       fi
 419     fi
 420     user_specified_javac=ecj
 421   ],
 422   [
 423     CLASSPATH_CHECK_ECJ
 424   ])
 425   AC_SUBST(ECJ)
 426 ])
 427
 428 dnl -----------------------------------------------------------
 429 AC_DEFUN([CLASSPATH_CHECK_ECJ],
 430 [
 431   if test "x$1" != x; then
 432     if test -f "$1"; then
 433       ECJ="$1"
 434     else
 435       AC_PATH_PROG(ECJ, "$1")
 436     fi
 437   else
 438     AC_PATH_PROG(ECJ, "ecj")
 439   fi
 440 ])